home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / r_surf68k.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  8.0 KB  |  392 lines
  1. * 
  2. * Copyright (C) 1996-1997 Id Software, Inc. 
  3. * 
  4. * This program is free software; you can redistribute it and/or 
  5. * modify it under the terms of the GNU General Public License 
  6. * as published by the Free Software Foundation; either version 2 
  7. * of the License, or (at your option) any later version. 
  8. * 
  9. * This program is distributed in the hope that it will be useful, 
  10. * but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. * 
  13. * See the GNU General Public License for more details. 
  14. * 
  15. * You should have received a copy of the GNU General Public License 
  16. * along with this program; if not, write to the Free Software 
  17. * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. * 
  19.  
  20. **
  21. ** Quake for AMIGA
  22. ** r_surf.c assembler implementations by Frank Wille <frank@phoenix.owl.de>
  23. **
  24.  
  25. ; viddef_t
  26.         rsreset
  27. buffer        rs.l    1
  28. colormap    rs.l    1
  29. ; etc...
  30.  
  31.  
  32.     code
  33.  
  34.     xref    _pbasesource
  35.     xref    _prowdestbase
  36.     xref    _r_numvblocks
  37.     xref    _r_lightptr
  38.     xref    _r_lightwidth
  39.     xref    _sourcetstep
  40.     xref    _surfrowbytes
  41.     xref    _r_sourcemax
  42.     xref    _r_stepback
  43.     xref    _vid
  44.  
  45.  
  46.     xdef    _R_DrawSurfaceBlock8_mip0
  47.     cnop    0,4
  48. _R_DrawSurfaceBlock8_mip0:
  49.     movem.l    d1-d7/a2-a6,-(sp)
  50.     setso    0
  51. .v    so.l    1            ; saved d1-field is used as .v
  52.  
  53.     move.l    _vid+colormap,a4
  54.     move.l    _sourcetstep,a5
  55.     move.l    _surfrowbytes,a6
  56.  
  57. ; psource = pbasesource;
  58. ; prowdest = prowdestbase;
  59.     move.l    _pbasesource,a2        ; a2 psource
  60.     move.l    _prowdestbase,a3    ; a3 prowdest
  61.  
  62. ; for (v=0 ; v<r_numvblocks ; v++) {
  63.     move.l    _r_numvblocks,(sp)    ; .v
  64.     beq    .quit
  65.  
  66. .vloop:
  67. ; lightleft = r_lightptr[0];
  68. ; lightright = r_lightptr[1];
  69.     move.l    _r_lightptr,a0
  70.     move.l    (a0)+,d6        ; d6 lightleft
  71.     move.l    (a0),d7            ; d7 lightright
  72.  
  73. ; r_lightptr += r_lightwidth;
  74. ; lightleftstep = (r_lightptr[0] - lightleft) >> 4;
  75. ; lightrightstep = (r_lightptr[1] - lightright) >> 4;
  76.     move.l    _r_lightwidth,d0
  77.     lea    -4(a0,d0.l*4),a0
  78.     move.l    a0,_r_lightptr
  79.     move.l    (a0)+,d1
  80.     sub.l    d6,d1
  81.     lsr.l    #4,d1            ; d1 lightleftstep
  82.     move.l    (a0),d2
  83.     sub.l    d7,d2
  84.     lsr.l    #4,d2            ; d2 lightrightstep
  85.  
  86. ; for (i=0 ; i<16 ; i++) {
  87.     moveq    #15,d5
  88.  
  89. ; lighttemp = lightleft - lightright;
  90. ; lightstep = lighttemp >> 4;
  91. ; light = lightright;
  92. .1:    move.l    d6,d4
  93.     sub.l    d7,d4
  94.     lsr.l    #4,d4            ; d4 lightstep
  95.     move.l    d7,d3            ; d3 light
  96.  
  97. ; for (b=15; b>=0; b--) {
  98.     moveq    #16,d0
  99.     add.w    d0,a2
  100.     add.w    d0,a3
  101.  
  102. ; pix = psource[b];
  103. ; prowdest[b] = ((unsigned char *)vid.colormap)[(light & 0xFF00) + pix];
  104. ; light += lightstep;
  105.     REPT    16
  106.     move.w    d3,d0
  107.     move.b    -(a2),d0
  108.     move.b    (a4,d0.l),-(a3)
  109.     add.l    d4,d3
  110.     ENDR
  111.  
  112. ; psource += sourcetstep;
  113. ; lightright += lightrightstep;
  114. ; lightleft += lightleftstep;
  115. ; prowdest += surfrowbytes;
  116.     add.l    a5,a2
  117.     add.l    a6,a3
  118.     add.l    d1,d6
  119.     add.l    d2,d7
  120.     dbf    d5,.1
  121.  
  122. ; if (psource >= r_sourcemax) psource -= r_stepback;
  123.     cmp.l    _r_sourcemax,a2
  124.     blo.b    .2
  125.     sub.l    _r_stepback,a2
  126.  
  127. .2:    subq.l    #1,(sp)            ; .v
  128.     bne    .vloop
  129. .quit:    movem.l    (sp)+,d1-d7/a2-a6
  130.     rts
  131.  
  132.  
  133.     xdef    _R_DrawSurfaceBlock8_mip1
  134.     cnop    0,4
  135. _R_DrawSurfaceBlock8_mip1:
  136.     movem.l    d1-d7/a2-a6,-(sp)
  137.     setso    0
  138. .v    so.l    1            ; saved d1-field is used as .v
  139.  
  140.     move.l    _vid+colormap,a4
  141.     move.l    _sourcetstep,a5
  142.     move.l    _surfrowbytes,a6
  143.  
  144. ; psource = pbasesource;
  145. ; prowdest = prowdestbase;
  146.     move.l    _pbasesource,a2        ; a2 psource
  147.     move.l    _prowdestbase,a3    ; a3 prowdest
  148.  
  149. ; for (v=0 ; v<r_numvblocks ; v++) {
  150.     move.l    _r_numvblocks,(sp)    ; .v
  151.     beq    .quit
  152.  
  153. .vloop:
  154. ; lightleft = r_lightptr[0];
  155. ; lightright = r_lightptr[1];
  156.     move.l    _r_lightptr,a0
  157.     move.l    (a0)+,d6        ; d6 lightleft
  158.     move.l    (a0),d7            ; d7 lightright
  159.  
  160. ; r_lightptr += r_lightwidth;
  161. ; lightleftstep = (r_lightptr[0] - lightleft) >> 3;
  162. ; lightrightstep = (r_lightptr[1] - lightright) >> 3;
  163.     move.l    _r_lightwidth,d0
  164.     lea    -4(a0,d0.l*4),a0
  165.     move.l    a0,_r_lightptr
  166.     move.l    (a0)+,d1
  167.     sub.l    d6,d1
  168.     lsr.l    #3,d1            ; d1 lightleftstep
  169.     move.l    (a0),d2
  170.     sub.l    d7,d2
  171.     lsr.l    #3,d2            ; d2 lightrightstep
  172.  
  173. ; for (i=0 ; i<8 ; i++) {
  174.     moveq    #7,d5
  175.  
  176. ; lighttemp = lightleft - lightright;
  177. ; lightstep = lighttemp >> 3;
  178. ; light = lightright;
  179. .1:    move.l    d6,d4
  180.     sub.l    d7,d4
  181.     lsr.l    #3,d4            ; d4 lightstep
  182.     move.l    d7,d3            ; d3 light
  183.  
  184. ; for (b=7; b>=0; b--) {
  185.     moveq    #8,d0
  186.     add.w    d0,a2
  187.     add.w    d0,a3
  188.  
  189. ; pix = psource[b];
  190. ; prowdest[b] = ((unsigned char *)vid.colormap)[(light & 0xFF00) + pix];
  191. ; light += lightstep;
  192.     REPT    8
  193.     move.w    d3,d0
  194.     move.b    -(a2),d0
  195.     move.b    (a4,d0.l),-(a3)
  196.     add.l    d4,d3
  197.     ENDR
  198.  
  199. ; psource += sourcetstep;
  200. ; lightright += lightrightstep;
  201. ; lightleft += lightleftstep;
  202. ; prowdest += surfrowbytes;
  203.     add.l    a5,a2
  204.     add.l    a6,a3
  205.     add.l    d1,d6
  206.     add.l    d2,d7
  207.     dbf    d5,.1
  208.  
  209. ; if (psource >= r_sourcemax) psource -= r_stepback;
  210.     cmp.l    _r_sourcemax,a2
  211.     blo.b    .2
  212.     sub.l    _r_stepback,a2
  213.  
  214. .2:    subq.l    #1,(sp)            ; .v
  215.     bne    .vloop
  216. .quit:    movem.l    (sp)+,d1-d7/a2-a6
  217.     rts
  218.  
  219.  
  220.     xdef    _R_DrawSurfaceBlock8_mip2
  221.     cnop    0,4
  222. _R_DrawSurfaceBlock8_mip2:
  223.     movem.l    d1-d7/a2-a6,-(sp)
  224.     setso    0
  225. .v    so.l    1            ; saved d1-field is used as .v
  226.  
  227.     move.l    _vid+colormap,a4
  228.     move.l    _sourcetstep,a5
  229.     move.l    _surfrowbytes,a6
  230.  
  231. ; psource = pbasesource;
  232. ; prowdest = prowdestbase;
  233.     move.l    _pbasesource,a2        ; a2 psource
  234.     move.l    _prowdestbase,a3    ; a3 prowdest
  235.  
  236. ; for (v=0 ; v<r_numvblocks ; v++) {
  237.     move.l    _r_numvblocks,(sp)    ; .v
  238.     beq    .quit
  239.  
  240. .vloop:
  241. ; lightleft = r_lightptr[0];
  242. ; lightright = r_lightptr[1];
  243.     move.l    _r_lightptr,a0
  244.     move.l    (a0)+,d6        ; d6 lightleft
  245.     move.l    (a0),d7            ; d7 lightright
  246.  
  247. ; r_lightptr += r_lightwidth;
  248. ; lightleftstep = (r_lightptr[0] - lightleft) >> 2;
  249. ; lightrightstep = (r_lightptr[1] - lightright) >> 2;
  250.     move.l    _r_lightwidth,d0
  251.     lea    -4(a0,d0.l*4),a0
  252.     move.l    a0,_r_lightptr
  253.     move.l    (a0)+,d1
  254.     sub.l    d6,d1
  255.     lsr.l    #2,d1            ; d1 lightleftstep
  256.     move.l    (a0),d2
  257.     sub.l    d7,d2
  258.     lsr.l    #2,d2            ; d2 lightrightstep
  259.  
  260. ; for (i=0 ; i<4 ; i++) {
  261.     moveq    #3,d5
  262.  
  263. ; lighttemp = lightleft - lightright;
  264. ; lightstep = lighttemp >> 3;
  265. ; light = lightright;
  266. .1:    move.l    d6,d4
  267.     sub.l    d7,d4
  268.     lsr.l    #2,d4            ; d4 lightstep
  269.     move.l    d7,d3            ; d3 light
  270.  
  271. ; for (b=3; b>=0; b--) {
  272.     moveq    #4,d0
  273.     add.w    d0,a2
  274.     add.w    d0,a3
  275.  
  276. ; pix = psource[b];
  277. ; prowdest[b] = ((unsigned char *)vid.colormap)[(light & 0xFF00) + pix];
  278. ; light += lightstep;
  279.     REPT    4
  280.     move.w    d3,d0
  281.     move.b    -(a2),d0
  282.     move.b    (a4,d0.l),-(a3)
  283.     add.l    d4,d3
  284.     ENDR
  285.  
  286. ; psource += sourcetstep;
  287. ; lightright += lightrightstep;
  288. ; lightleft += lightleftstep;
  289. ; prowdest += surfrowbytes;
  290.     add.l    a5,a2
  291.     add.l    a6,a3
  292.     add.l    d1,d6
  293.     add.l    d2,d7
  294.     dbf    d5,.1
  295.  
  296. ; if (psource >= r_sourcemax) psource -= r_stepback;
  297.     cmp.l    _r_sourcemax,a2
  298.     blo.b    .2
  299.     sub.l    _r_stepback,a2
  300.  
  301. .2:    subq.l    #1,(sp)            ; .v
  302.     bne    .vloop
  303. .quit:    movem.l    (sp)+,d1-d7/a2-a6
  304.     rts
  305.  
  306.  
  307.     xdef    _R_DrawSurfaceBlock8_mip3
  308.     cnop    0,4
  309. _R_DrawSurfaceBlock8_mip3:
  310.     movem.l    d1-d7/a2-a6,-(sp)
  311.     setso    0
  312. .v    so.l    1            ; saved d1-field is used as .v
  313.  
  314.     move.l    _vid+colormap,a4
  315.     move.l    _sourcetstep,a5
  316.     move.l    _surfrowbytes,a6
  317.  
  318. ; psource = pbasesource;
  319. ; prowdest = prowdestbase;
  320.     move.l    _pbasesource,a2        ; a2 psource
  321.     move.l    _prowdestbase,a3    ; a3 prowdest
  322.  
  323. ; for (v=0 ; v<r_numvblocks ; v++) {
  324.     move.l    _r_numvblocks,(sp)    ; .v
  325.     beq    .quit
  326.  
  327. .vloop:
  328. ; lightleft = r_lightptr[0];
  329. ; lightright = r_lightptr[1];
  330.     move.l    _r_lightptr,a0
  331.     move.l    (a0)+,d6        ; d6 lightleft
  332.     move.l    (a0),d7            ; d7 lightright
  333.  
  334. ; r_lightptr += r_lightwidth;
  335. ; lightleftstep = (r_lightptr[0] - lightleft) >> 1;
  336. ; lightrightstep = (r_lightptr[1] - lightright) >> 1;
  337.     move.l    _r_lightwidth,d0
  338.     lea    -4(a0,d0.l*4),a0
  339.     move.l    a0,_r_lightptr
  340.     move.l    (a0)+,d1
  341.     sub.l    d6,d1
  342.     lsr.l    #1,d1            ; d1 lightleftstep
  343.     move.l    (a0),d2
  344.     sub.l    d7,d2
  345.     lsr.l    #1,d2            ; d2 lightrightstep
  346.  
  347. ; for (i=0 ; i<2 ; i++) {
  348.     moveq    #1,d5
  349.  
  350. ; lighttemp = lightleft - lightright;
  351. ; lightstep = lighttemp >> 1;
  352. ; light = lightright;
  353. .1:    move.l    d6,d4
  354.     sub.l    d7,d4
  355.     lsr.l    #1,d4            ; d4 lightstep
  356.     move.l    d7,d3            ; d3 light
  357.  
  358. ; for (b=1; b>=0; b--) {
  359.     moveq    #2,d0
  360.     add.w    d0,a2
  361.     add.w    d0,a3
  362.  
  363. ; pix = psource[b];
  364. ; prowdest[b] = ((unsigned char *)vid.colormap)[(light & 0xFF00) + pix];
  365. ; light += lightstep;
  366.     REPT    2
  367.     move.w    d3,d0
  368.     move.b    -(a2),d0
  369.     move.b    (a4,d0.l),-(a3)
  370.     add.l    d4,d3
  371.     ENDR
  372.  
  373. ; psource += sourcetstep;
  374. ; lightright += lightrightstep;
  375. ; lightleft += lightleftstep;
  376. ; prowdest += surfrowbytes;
  377.     add.l    a5,a2
  378.     add.l    a6,a3
  379.     add.l    d1,d6
  380.     add.l    d2,d7
  381.     dbf    d5,.1
  382.  
  383. ; if (psource >= r_sourcemax) psource -= r_stepback;
  384.     cmp.l    _r_sourcemax,a2
  385.     blo.b    .2
  386.     sub.l    _r_stepback,a2
  387.  
  388. .2:    subq.l    #1,(sp)            ; .v
  389.     bne    .vloop
  390. .quit:    movem.l    (sp)+,d1-d7/a2-a6
  391.     rts
  392.