home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / r_bspppc.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  7.5 KB  |  327 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. ##
  21. ## Quake for AMIGA
  22. ##
  23. ## r_bspPPC.s
  24. ##
  25. ## Define WOS for PowerOpen ABI, otherwise SVR4-ABI is used.
  26. ##
  27.  
  28. .include        "macrosPPC.i"
  29.  
  30. #
  31. # external references
  32. #
  33.  
  34.     xrefv    r_visframecount
  35.     xrefv    r_framecount
  36.     xrefv    r_currentkey
  37.     xrefv    r_drawpolys
  38.     xrefv    r_worldpolysbacktofront
  39.     xrefv    pbtofpolys
  40.     xrefv    numbtofpolys
  41.     xrefv    pfrustum_indexes
  42.     xrefa    modelorg
  43.     xrefa    vpn
  44.     xrefa    vright
  45.     xrefa    vup
  46.     xrefa    view_clipplanes
  47.     xrefv    currententity
  48.     xrefa    screenedge
  49.     xrefa    entity_rotation
  50.  
  51. .ifdef    __STORM__
  52.     xrefv    sin__r
  53.     xrefv    cos__r
  54. .else
  55.     xrefv    sin
  56.     xrefv    cos
  57. .endif
  58.  
  59. #
  60. # defines
  61. #
  62.  
  63. .set    PITCH                ,0
  64. .set    YAW                  ,1
  65. .set    ROLL                 ,2
  66.  
  67. .set    CLIP_NORMAL          ,0
  68. .set    CLIP_DIST            ,12
  69. .set    CLIP_NEXT            ,16
  70. .set    CLIP_LEFTEDGE        ,20
  71. .set    CLIP_RIGHTEDGE       ,21
  72. .set    CLIP_RESERVED        ,22
  73. .set    CLIP_SIZEOF          ,24
  74.  
  75. .set    MPLANE_NORMAL        ,0
  76. .set    MPLANE_DIST          ,12
  77. .set    MPLANE_TYPE          ,16
  78. .set    MPLANE_SIGNBITS      ,17
  79. .set    MPLANE_SIZEOF        ,20
  80.  
  81. .set    ENTITY_FORCELINK     ,0
  82. .set    ENTITY_UPDATE_TYPE   ,4
  83. .set    ENTITY_BASELINE      ,8
  84. .set    ENTITY_MSGTIME       ,52
  85. .set    ENTITY_MSG_ORIGINS   ,60
  86. .set    ENTITY_ORIGIN        ,84
  87. .set    ENTITY_MSG_ANGLES    ,96
  88. .set    ENTITY_ANGLES        ,120
  89. .set    ENTITY_MODEL         ,132
  90. .set    ENTITY_EFRAG         ,136
  91. .set    ENTITY_FRAME         ,140
  92. .set    ENTITY_SYNCBASE      ,144
  93. .set    ENTITY_COLORMAP      ,148
  94. .set    ENTITY_EFFECTS       ,152
  95. .set    ENTITY_SKINNUM       ,156
  96. .set    ENTITY_VISFRAME      ,160
  97. .set    ENTITY_DLIGHTFRAME   ,164
  98. .set    ENTITY_DLIGHTBITS    ,168
  99. .set    ENTITY_TRIVIAL_ACCEPT,172
  100. .set    ENTITY_TOPNODE       ,176
  101. .set    ENTITY_SIZEOF        ,216
  102.  
  103.  
  104.  
  105.  
  106.  
  107. ###########################################################################
  108. #
  109. #       void R_RotateBmodel (void)
  110. #
  111. ###########################################################################
  112.  
  113.     funcdef    R_RotateBmodel
  114.  
  115.     init    0,0,1,18
  116.     stw    r31,gb(r1)
  117.     stfd    f14,fb+0*8(r1)
  118.     stfd    f15,fb+1*8(r1)
  119.     stfd    f16,fb+2*8(r1)
  120.     stfd    f17,fb+3*8(r1)
  121.     stfd    f18,fb+4*8(r1)
  122.     stfd    f19,fb+5*8(r1)
  123.     stfd    f20,fb+6*8(r1)
  124.     stfd    f21,fb+7*8(r1)
  125.     stfd    f22,fb+8*8(r1)
  126.     stfd    f23,fb+9*8(r1)
  127.     stfd    f24,fb+10*8(r1)
  128.     stfd    f25,fb+11*8(r1)
  129.     stfd    f26,fb+12*8(r1)
  130.     stfd    f27,fb+13*8(r1)
  131.     stfd    f28,fb+14*8(r1)
  132.     stfd    f29,fb+15*8(r1)
  133.     stfd    f30,fb+16*8(r1)
  134.     stfd    f31,fb+17*8(r1)
  135.  
  136.     ls      f14,cPI
  137.     lw      r31,currententity
  138.     lfs     f1,ENTITY_ANGLES+YAW*4(r31)
  139.     fmuls   f15,f1,f14
  140.     fmr     f1,f15
  141.     mcall    sin
  142.     fmr     f16,f1                  #f16 = s [YAW]
  143.     fmr     f1,f15
  144.     mcall    cos
  145.     fmr     f17,f1                  #f17 = c [YAW]
  146.     lfs     f1,ENTITY_ANGLES+PITCH*4(r31)
  147.     fmuls   f15,f1,f14
  148.     fmr     f1,f15
  149.     mcall    sin
  150.     fmr     f18,f1                  #f18 = s [PITCH]
  151.     fmr     f1,f15
  152.     mcall    cos
  153.     fmr     f19,f1                  #f19 = c [PITCH] = 32(a2)
  154.     lfs     f1,ENTITY_ANGLES+ROLL*4(r31)
  155.     fmuls   f15,f1,f14
  156.     fmr     f1,f15
  157.     mcall    sin
  158.     fmr     f20,f1                  #f20 = s [ROLL]
  159.     fmr     f1,f15
  160.     mcall    cos
  161.     fmuls   f0,f17,f19
  162.     fmr     f15,f1                  #f15 = c [ROLL]
  163.     lxa     r3,entity_rotation     #r3 = entity_rotation
  164.     stfs    f0,0(r3)                #f0 = entity_rotation [0,0]
  165.     fmuls   f1,f16,f19              #f1 = 4(a2)
  166.     fneg    f2,f18                  #f2 = 8(a2)
  167.     fneg    f3,f16
  168.     fmuls   f4,f17,f18
  169.     stfs    f3,12(r3)               #f3 = entity_rotation[1,0]
  170.     stfs    f4,24(r3)               #f4 = entity_rotation[2,0]
  171.     fmuls   f5,f16,f18              #f5 = 28(a2)
  172.     fmuls   f6,f20,f2
  173.     fmsubs  f7,f15,f1,f6
  174.     fmuls   f8,f20,f1
  175.     stfs    f7,4(r3)                #f7 = entity_rotation[0,1]
  176.     fmuls   f12,f20,f19
  177.     fmadds  f9,f2,f15,f8
  178.     fmuls   f10,f17,f15
  179.     stfs    f9,8(r3)                #f9 = entity_rotation[0,2]
  180.     stfs    f10,16(r3)              #f10 = entity_rotation[1,1]
  181.     fmuls   f2,f19,f15
  182.     fmuls   f11,f17,f20
  183.     fmsubs  f13,f15,f5,f12
  184.     stfs    f11,20(r3)              #f11 = entity_rotation[1,2]
  185.     stfs    f13,28(r3)              #f13 = entity_rotation[2,1]
  186.     fmadds  f1,f20,f5,f2
  187.     stfs    f1,32(r3)               #f1 = entity_rotation[2,2]
  188.     lxa     r7,modelorg
  189.     lfs     f19,0(r7)               #f19 = modelorg[0]
  190.     lfs     f20,4(r7)               #f20 = modelorg[1]
  191.     lfs     f21,8(r7)               #f21 = modelorg[2]
  192.     lxa     r4,vpn
  193.     lfs     f2,0(r4)                #f2 = vpn[0]
  194.     lfs     f6,4(r4)                #f6 = vpn[1]
  195.     lfs     f8,8(r4)                #f8 = vpn[2]
  196.     lxa     r5,vright
  197.     lfs     f12,0(r5)               #f12 = vright[0]
  198.     lfs     f14,4(r5)               #f14 = vright[1]
  199.     lfs     f15,8(r5)               #f15 = vright[2]
  200.     lxa     r6,vup
  201.     lfs     f16,0(r6)               #f16 = vup[0]
  202.     lfs     f17,4(r6)               #f17 = vup[1]
  203.     lfs     f18,8(r6)               #f18 = vup[2]
  204.  
  205.     fmuls   f22,f19,f0
  206.     fmuls   f25,f2,f0
  207.     fmuls   f28,f12,f0
  208.     fmuls   f31,f16,f0
  209.     fmadds  f22,f20,f7,f22
  210.     fmadds  f25,f6,f7,f25
  211.     fmadds  f28,f14,f7,f28
  212.     fmadds  f31,f17,f7,f31
  213.     fmadds  f22,f21,f9,f22
  214.     fmadds  f25,f8,f9,f25
  215.     fmadds  f28,f15,f9,f28
  216.     fmadds  f31,f18,f9,f31
  217.     fmuls   f23,f19,f3
  218.     fmuls   f26,f2,f3
  219.     fmuls   f29,f12,f3
  220.     fmuls   f0,f16,f3
  221.     fmadds  f23,f20,f10,f23
  222.     fmadds  f26,f6,f10,f26
  223.     fmadds  f29,f14,f10,f29
  224.     fmadds  f0,f17,f10,f0
  225.     fmadds  f23,f21,f11,f23
  226.     fmadds  f26,f8,f11,f26
  227.     fmadds  f29,f15,f11,f29
  228.     fmadds  f0,f18,f11,f0
  229.     fmuls   f24,f19,f4
  230.     fmuls   f27,f2,f4
  231.     fmuls   f30,f12,f4
  232.     fmuls   f7,f16,f4
  233.     fmadds  f24,f20,f13,f24
  234.     fmadds  f27,f6,f13,f27
  235.     fmadds  f30,f14,f13,f30
  236.     fmadds  f7,f17,f13,f7
  237.     fmadds  f21,f21,f1,f24
  238.     fmadds  f8,f8,f1,f27
  239.     fmadds  f15,f15,f1,f30
  240.     fmadds  f18,f18,f1,f7
  241.     fmr     f19,f22
  242.     fmr     f2,f25
  243.     fmr     f12,f28
  244.     fmr     f16,f31
  245.     fmr     f20,f23
  246.     fmr     f6,f26
  247.     fmr     f14,f29
  248.     fmr     f17,f0
  249.  
  250.     li      r0,4
  251.     mtctr   r0
  252.     lxa     r8,screenedge
  253.     subi    r8,r8,4
  254.     lxa     r9,view_clipplanes
  255.     subi    r9,r9,4
  256. .loop:
  257.     lfsu    f0,4(r8)
  258.     lfsu    f7,4(r8)
  259.     lfsu    f9,4(r8)
  260.     fmuls   f3,f16,f7
  261.     fmuls   f10,f17,f7
  262.     fmuls   f11,f18,f7
  263.     fmadds  f3,f2,f9,f3
  264.     fmadds  f10,f6,f9,f10
  265.     fmadds  f11,f8,f9,f11
  266.     fnmsubs f3,f12,f0,f3
  267.     stfsu   f3,4(r9)
  268.     fmuls   f3,f3,f19
  269.     fnmsubs f10,f14,f0,f10
  270.     stfsu   f10,4(r9)
  271.     fmadds  f3,f10,f20,f3
  272.     fnmsubs f11,f15,f0,f11
  273.     stfsu   f11,4(r9)
  274.     fmadds  f3,f11,f21,f3
  275.     la      r8,MPLANE_SIZEOF-12(r8)
  276.     stfsu   f3,4(r9)
  277.     la      r9,CLIP_SIZEOF-16(r9)
  278.     bdnz    .loop
  279.  
  280.     stfs    f19,0(r7)
  281.     stfs    f20,4(r7)
  282.     stfs    f21,8(r7)
  283.     stfs    f2,0(r4)
  284.     stfs    f6,4(r4)
  285.     stfs    f8,8(r4)
  286.     stfs    f12,0(r5)
  287.     stfs    f14,4(r5)
  288.     stfs    f15,8(r5)
  289.     stfs    f16,0(r6)
  290.     stfs    f17,4(r6)
  291.     stfs    f18,8(r6)
  292.  
  293.     lfd    f14,fb+0*8(r1)
  294.     lfd    f15,fb+1*8(r1)
  295.     lfd    f16,fb+2*8(r1)
  296.     lfd    f17,fb+3*8(r1)
  297.     lfd    f18,fb+4*8(r1)
  298.     lfd    f19,fb+5*8(r1)
  299.     lfd    f20,fb+6*8(r1)
  300.     lfd    f21,fb+7*8(r1)
  301.     lfd    f22,fb+8*8(r1)
  302.     lfd    f23,fb+9*8(r1)
  303.     lfd    f24,fb+10*8(r1)
  304.     lfd    f25,fb+11*8(r1)
  305.     lfd    f26,fb+12*8(r1)
  306.     lfd    f27,fb+13*8(r1)
  307.     lfd    f28,fb+14*8(r1)
  308.     lfd    f29,fb+15*8(r1)
  309.     lfd    f30,fb+16*8(r1)
  310.     lfd    f31,fb+17*8(r1)
  311.     lwz    r31,gb(r1)
  312.     exit
  313.  
  314.     funcend    R_RotateBmodel
  315.  
  316.  
  317.  
  318.  
  319. .ifdef    WOS
  320.     .tocd
  321. .else
  322.     .data
  323. .endif
  324.  
  325. lab cPI
  326.     .float    0.017453293        # => M_PI*2/360
  327.