home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / r_alias68k.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  6.3 KB  |  288 lines
  1. * 
  2. * Copyright (C) 1996-1997 Id Software, Inc. 
  3. * 
  4. * This program is free software; you can redistribute it and/or 
  5. * modify it under the terms of the GNU General Public License 
  6. * as published by the Free Software Foundation; either version 2 
  7. * of the License, or (at your option) any later version. 
  8. * 
  9. * This program is distributed in the hope that it will be useful, 
  10. * but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. * 
  13. * See the GNU General Public License for more details. 
  14. * 
  15. * You should have received a copy of the GNU General Public License 
  16. * along with this program; if not, write to the Free Software 
  17. * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. * 
  19.  
  20. **
  21. ** Quake for AMIGA
  22. ** r_alias.c assembler implementations by Frank Wille <frank@phoenix.owl.de>
  23. **
  24.  
  25.         XREF    _aliastransform
  26.         XREF    _r_avertexnormals
  27.         XREF    _r_plightvec
  28.         XREF    _r_ambientlight
  29.         XREF    _r_shadelight
  30.         XREF    _ziscale
  31.         XREF    _aliasxscale
  32.         XREF    _aliasyscale
  33.         XREF    _aliasxcenter
  34.         XREF    _aliasycenter
  35.  
  36.         XDEF    _R_AliasTransformVector
  37.         XDEF    _R_AliasTransformFinalVert
  38.         XDEF    _R_AliasProjectFinalVert
  39.  
  40.  
  41. FV_V                    =       0
  42. FV_FLAGS                =       24
  43. FV_RESERVED             =       28
  44. FV_SIZEOF               =       32
  45. FV_SIZEOF_EXP           =       5
  46.  
  47. TV_V                    =       0
  48. TV_LIGHTNORMALINDEX     =       3
  49.  
  50. SV_ONSEAM               =       0
  51. SV_S                    =       4
  52. SV_T                    =       8
  53.  
  54.         fpu
  55.  
  56.  
  57.  
  58.  
  59. ******************************************************************************
  60. *
  61. *       void _R_AliasTransformVector (vec3_t in, vec3_t out)
  62. *
  63. ******************************************************************************
  64.  
  65.         cnop    0,4
  66. _R_AliasTransformVector
  67.  
  68. *****   stackframe
  69.  
  70.         rsreset
  71. .fpuregs        rs.x    4
  72.         rs.l    1
  73. .in             rs.l    1
  74. .out            rs.l    1
  75.  
  76.         fmovem.x        fp2-fp5,-(sp)
  77.         move.l  .in(sp),a0
  78.         move.l  .out(sp),a1
  79.         fmove.s (a0)+,fp0
  80.         fmove.s (a0)+,fp1
  81.         fmove.s (a0)+,fp2
  82.         lea     _aliastransform,a0
  83.         fmove.s (a0)+,fp3
  84.         fmul    fp0,fp3
  85.         fmove.s (a0)+,fp4
  86.         fmul    fp1,fp4
  87.         fadd    fp4,fp3
  88.         fmove.s (a0)+,fp4
  89.         fmul    fp2,fp4
  90.         fadd    fp4,fp3
  91.         fadd.s  (a0)+,fp3
  92.         fmove.s fp3,(a1)+
  93.         fmove.s (a0)+,fp3
  94.         fmul    fp0,fp3
  95.         fmove.s (a0)+,fp4
  96.         fmul    fp1,fp4
  97.         fadd    fp4,fp3
  98.         fmove.s (a0)+,fp4
  99.         fmul    fp2,fp4
  100.         fadd    fp4,fp3
  101.         fadd.s  (a0)+,fp3
  102.         fmove.s fp3,(a1)+
  103.         fmul.s  (a0)+,fp0
  104.         fmul.s  (a0)+,fp1
  105.         fadd    fp1,fp0
  106.         fmul.s  (a0)+,fp2
  107.         fadd    fp2,fp0
  108.         fadd.s  (a0)+,fp0
  109.         fmove.s fp0,(a1)+
  110.         fmovem.x        (sp)+,fp2-fp5
  111.         rts
  112.  
  113.  
  114.  
  115.  
  116.  
  117.  
  118. ******************************************************************************
  119. *
  120. *       void _R_AliasTransformFinalVert (finalvert_t *fv, auxvert_t *av,
  121. *                                      trivertx_t *pverts, stvert_t *pstverts)
  122. *
  123. ******************************************************************************
  124.  
  125.         cnop    0,4
  126. _R_AliasTransformFinalVert
  127.  
  128. *****   stackframe
  129.  
  130.         rsreset
  131. .fpuregs        rs.x    3
  132. .intregs        rs.l    1
  133.         rs.l    1
  134. .fv             rs.l    1
  135. .av             rs.l    1
  136. .tv             rs.l    1
  137. .sv             rs.l    1
  138.  
  139.  
  140.         move.l  a2,-(sp)
  141.         fmovem.x        fp2-fp4,-(sp)
  142.         move.l  .av(sp),a1
  143.         move.l  .tv(sp),a2
  144.  
  145. *        av->fv[0] = DotProduct(pverts->v, aliastransform[0]) +
  146. *                        aliastransform[0][3];
  147. *        av->fv[1] = DotProduct(pverts->v, aliastransform[1]) +
  148. *                        aliastransform[1][3];
  149. *        av->fv[2] = DotProduct(pverts->v, aliastransform[2]) +
  150. *                        aliastransform[2][3];
  151.  
  152.         lea     _aliastransform,a0
  153.         moveq   #0,d0
  154.         move.b  (a2),d0
  155.         fmove.l d0,fp0
  156.         move.b  1(a2),d0
  157.         fmove.l d0,fp1
  158.         move.b  2(a2),d0
  159.         fmove.l d0,fp2
  160.         fmove.s (a0)+,fp3
  161.         fmul    fp0,fp3
  162.         fmove.s (a0)+,fp4
  163.         fmul    fp1,fp4
  164.         fadd    fp4,fp3
  165.         fmove.s (a0)+,fp4
  166.         fmul    fp2,fp4
  167.         fadd    fp4,fp3
  168.         fadd.s  (a0)+,fp3
  169.         fmove.s fp3,(a1)+
  170.         fmove.s (a0)+,fp3
  171.         fmul    fp0,fp3
  172.         fmove.s (a0)+,fp4
  173.         fmul    fp1,fp4
  174.         fadd    fp4,fp3
  175.         fmove.s (a0)+,fp4
  176.         fmul    fp2,fp4
  177.         fadd    fp4,fp3
  178.         fadd.s  (a0)+,fp3
  179.         fmove.s fp3,(a1)+
  180.         fmove.s (a0)+,fp3
  181.         fmul    fp0,fp3
  182.         fmove.s (a0)+,fp4
  183.         fmul    fp1,fp4
  184.         fadd    fp4,fp3
  185.         fmove.s (a0)+,fp4
  186.         fmul    fp2,fp4
  187.         fadd    fp4,fp3
  188.         fadd.s  (a0)+,fp3
  189.         fmove.s fp3,(a1)+
  190.  
  191. *        fv->v[2] = pstverts->s;
  192. *        fv->v[3] = pstverts->t;
  193. *
  194. *        fv->flags = pstverts->onseam;
  195.  
  196.         move.l  .fv(sp),a0
  197.         move.l  .sv(sp),a1
  198.         move.l  SV_S(a1),8(a0)
  199.         move.l  SV_T(a1),12(a0)
  200.         move.l  SV_ONSEAM(a1),FV_FLAGS(a0)
  201.  
  202. *        plightnormal = r_avertexnormals[pverts->lightnormalindex];
  203. *        lightcos = DotProduct (plightnormal, r_plightvec);
  204. *        temp = r_ambientlight;
  205.  
  206.         lea     _r_avertexnormals,a1
  207.         moveq   #0,d0
  208.         move.b  TV_LIGHTNORMALINDEX(a2),d0
  209.         muls    #12,d0
  210.         add.l   d0,a1
  211.         lea     _r_plightvec,a2
  212.         fmove.s (a2)+,fp0
  213.         fmove.s (a2)+,fp1
  214.         fmove.s (a2)+,fp2
  215.         fmul.s  (a1)+,fp0
  216.         fmul.s  (a1)+,fp1
  217.         fadd    fp1,fp0
  218.         fmul.s  (a1)+,fp2
  219.         fadd    fp2,fp0
  220.         move.l  _r_ambientlight,d0
  221.  
  222. *        if (lightcos < 0)
  223. *        {
  224. *                temp += (int)(r_shadelight * lightcos);
  225. *
  226. *        // clamp; because we limited the minimum ambient and shading light, we
  227. *        // don't have to clamp low light, just bright
  228. *                if (temp < 0)
  229. *                        temp = 0;
  230. *        }
  231. *
  232. *        fv->v[4] = temp;
  233.  
  234.         ftst    fp0
  235.         fboge.b .cont
  236.         fmul.s  _r_shadelight,fp0
  237.         fmove.l fp0,d1
  238.         add.l   d1,d0
  239.         bge.b   .cont
  240.         moveq   #0,d0
  241. .cont
  242.         move.l  d0,16(a0)
  243.         fmovem.x        (sp)+,fp2-fp4
  244.         move.l  (sp)+,a2
  245.         rts
  246.  
  247.  
  248.  
  249.  
  250.  
  251.  
  252.  
  253. ******************************************************************************
  254. *
  255. *       void _R_AliasProjectFinalVert (finalvert_t *fv, auxvert_t *av,)
  256. *
  257. ******************************************************************************
  258.  
  259.         cnop    0,4
  260. _R_AliasProjectFinalVert
  261.  
  262. *****   stackframe
  263.  
  264.         rsreset
  265.         rs.l    1
  266. .fv             rs.l    1
  267. .av             rs.l    1
  268.  
  269.  
  270.         move.l  .av(sp),a0
  271.         move.l  .fv(sp),a1
  272.         fmove.s 8(a0),fp0
  273.         fmove.s #1,fp1
  274.         fdiv    fp0,fp1
  275.         fmove.s _ziscale,fp0
  276.         fmul    fp1,fp0
  277.         fmove.l fp0,20(a1)
  278.         fmove.s _aliasxscale,fp0
  279.         fmul    fp1,fp0
  280.         fmul.s  (a0),fp0
  281.         fadd.s  _aliasxcenter,fp0
  282.         fmove.l fp0,(a1)
  283.         fmul.s  _aliasyscale,fp1
  284.         fmul.s  4(a0),fp1
  285.         fadd.s  _aliasycenter,fp1
  286.         fmove.l fp1,4(a1)
  287.         rts
  288.