home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / d_surfppc.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  5.6 KB  |  236 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. ##
  21. ## Quake for AMIGA
  22. ##
  23. ## d_surfPPC.s
  24. ##
  25. ## Define WOS for PowerOpen ABI, otherwise SVR4-ABI is used.
  26. ##
  27.  
  28. .include        "macrosPPC.i"
  29.  
  30. #
  31. # external references
  32. #
  33.  
  34.     xrefa    r_drawsurf
  35.     xrefa    d_lightstylevalue
  36.     xrefv    r_framecount
  37.     xrefv    surfscale
  38.     xrefv    c_surf
  39.  
  40.     xrefv    R_TextureAnimation
  41.     xrefv    R_DrawSurface
  42.     xrefv    D_SCAlloc
  43.  
  44.  
  45. #
  46. # defines
  47. #
  48.  
  49. .set    MSURFACE_VISFRAME   ,0
  50. .set    MSURFACE_DLIGHTFRAME,4
  51. .set    MSURFACE_DLIGHTBITS ,8
  52. .set    MSURFACE_PLANE      ,12
  53. .set    MSURFACE_FLAGS      ,16
  54. .set    MSURFACE_FIRSTEDGE  ,20
  55. .set    MSURFACE_NUMEDGES   ,24
  56. .set    MSURFACE_CACHESPOTS ,28
  57. .set    MSURFACE_TEXTUREMINS,44
  58. .set    MSURFACE_EXTENTS    ,48
  59. .set    MSURFACE_TEXINFO    ,52
  60. .set    MSURFACE_STYLES     ,56
  61. .set    MSURFACE_SAMPLES    ,60
  62. .set    MSURFACE_SIZEOF_EXP ,6
  63. .set    MSURFACE_SIZEOF     ,(1<<MSURFACE_SIZEOF_EXP)
  64.  
  65. .set    DRAWSURF_SURFDAT    ,0
  66. .set    DRAWSURF_ROWBYTES   ,4
  67. .set    DRAWSURF_SURF       ,8
  68. .set    DRAWSURF_LIGHTADJ   ,12
  69. .set    DRAWSURF_TEXTURE    ,28
  70. .set    DRAWSURF_SURFMIP    ,32
  71. .set    DRAWSURF_SURFWIDTH  ,36
  72. .set    DRAWSURF_SURFHEIGHT ,40
  73. .set    DRAWSURF_SIZEOF     ,44
  74.  
  75. .set    SURF_NEXT           ,0
  76. .set    SURF_PREV           ,4
  77. .set    SURF_SPANS          ,8
  78. .set    SURF_KEY            ,12
  79. .set    SURF_LAST_U         ,16
  80. .set    SURF_SPANSTATE      ,20
  81. .set    SURF_FLAGS          ,24
  82. .set    SURF_DATA           ,28
  83. .set    SURF_ENTITY         ,32
  84. .set    SURF_NEARZI         ,36
  85. .set    SURF_INSUBMODEL     ,40
  86. .set    SURF_D_ZIORIGIN     ,44
  87. .set    SURF_D_ZISTEPU      ,48
  88. .set    SURF_D_ZISTEPV      ,52
  89. .set    SURF_SIZEOF_EXP     ,6
  90. .set    SURF_SIZEOF         ,(1<<SURF_SIZEOF_EXP)
  91.  
  92. .set    MTEXINFO_VECS       ,0
  93. .set    MTEXINFO_MIPADJUST  ,32
  94. .set    MTEXINFO_TEXTURE    ,36
  95. .set    MTEXINFO_FLAGS      ,40
  96. .set    MTEXINFO_SIZEOF     ,44
  97.  
  98. .set    SURFCACHE_NEXT      ,0
  99. .set    SURFCACHE_OWNER     ,4
  100. .set    SURFCACHE_LIGHTADJ  ,8
  101. .set    SURFCACHE_DLIGHT    ,24
  102. .set    SURFCACHE_SIZE      ,28
  103. .set    SURFCACHE_WIDTH     ,32
  104. .set    SURFCACHE_HEIGHT    ,36
  105. .set    SURFCACHE_MIPSCALE  ,40
  106. .set    SURFCACHE_TEXTURE   ,44
  107. .set    SURFCACHE_DATA      ,48
  108. .set    SURFCACHE_SIZEOF    ,52
  109.  
  110.  
  111.  
  112.  
  113.  
  114. ###########################################################################
  115. #
  116. #       surfcache_t *D_CacheSurface (msurface_t *surface, int miplevel)
  117. #
  118. ###########################################################################
  119.  
  120.     funcdef    D_CacheSurface
  121.  
  122.     init    0,4,4,1
  123.     stmw    r28,gb(r1)
  124.     stfd    f14,fb(r1)
  125.  
  126.     mr      r31,r3
  127.     mr      r30,r4
  128.     lwz     r3,MSURFACE_TEXINFO(r31)
  129.     lwz     r3,MTEXINFO_TEXTURE(r3)
  130.     call    R_TextureAnimation
  131.     lxa     r29,r_drawsurf
  132.     stw     r3,DRAWSURF_TEXTURE(r29)
  133.     mr      r9,r3
  134.     lxa     r3,d_lightstylevalue
  135.     lbz     r4,MSURFACE_STYLES(r31)
  136.     slwi    r4,r4,2
  137.     lwzx    r5,r3,r4
  138.     stw     r5,DRAWSURF_LIGHTADJ(r29)
  139.     lbz     r4,MSURFACE_STYLES+1(r31)
  140.     slwi    r4,r4,2
  141.     lwzx    r6,r3,r4
  142.     stw     r6,DRAWSURF_LIGHTADJ+1*4(r29)
  143.     lbz     r4,MSURFACE_STYLES+2(r31)
  144.     slwi    r4,r4,2
  145.     lwzx    r7,r3,r4
  146.     stw     r7,DRAWSURF_LIGHTADJ+2*4(r29)
  147.     lbz     r4,MSURFACE_STYLES+3(r31)
  148.     slwi    r4,r4,2
  149.     lwzx    r8,r3,r4
  150.     stw     r8,DRAWSURF_LIGHTADJ+3*4(r29)
  151.     slwi    r0,r30,2
  152.     la      r4,MSURFACE_CACHESPOTS(r31)
  153.     lwzx    r3,r4,r0                #r3 = cache
  154.     mr.     r3,r3
  155.     lw      r28,r_framecount
  156.     beq     .cont2
  157.     lwz     r10,SURFCACHE_DLIGHT(r3)
  158.     cmpwi   cr1,r10,0
  159.     lwz     r12,MSURFACE_DLIGHTFRAME(r31)
  160.     cmpw    cr2,r28,r12
  161.     lwz     r4,SURFCACHE_TEXTURE(r3)
  162.     crandc  eq,4*cr1+eq,4*cr2+eq
  163.     cmpw    cr3,r4,r9
  164.     lwz     r11,SURFCACHE_LIGHTADJ(r3)
  165.     crand   eq,eq,4*cr3+eq
  166.     cmpw    cr4,r11,r5
  167.     lwz     r4,SURFCACHE_LIGHTADJ+1*4(r3)
  168.     crand   eq,eq,4*cr4+eq
  169.     cmpw    cr5,r4,r6
  170.     lwz     r11,SURFCACHE_LIGHTADJ+2*4(r3)
  171.     crand   eq,eq,4*cr5+eq
  172.     cmpw    cr6,r11,r7
  173.     lwz     r4,SURFCACHE_LIGHTADJ+3*4(r3)
  174.     crand   eq,eq,4*cr6+eq
  175.     cmpw    cr7,r4,r8
  176.     crand   eq,eq,4*cr7+eq
  177.     beq     .exit
  178. .cont2:
  179.     mr.     r3,r3
  180.     slwi    r0,r30,23
  181.     lis     r11,0x3f800000@h
  182.     ori     r11,r11,0x3f800000@l
  183.     subf    r0,r0,r11
  184.     stw     r0,local(r1)
  185.     lfs     f14,local(r1)        #f14 = surfscale
  186.     stw     r30,DRAWSURF_SURFMIP(r29)
  187.     lha     r4,MSURFACE_EXTENTS(r31)
  188.     sraw    r4,r4,r30
  189.     stw     r4,DRAWSURF_SURFWIDTH(r29)
  190.     stw     r4,DRAWSURF_ROWBYTES(r29)
  191.     lha     r11,MSURFACE_EXTENTS+1*2(r31)
  192.     sraw    r11,r11,r30
  193.     stw     r11,DRAWSURF_SURFHEIGHT(r29)
  194.     bne     .nocache
  195.     mr      r3,r4
  196.     mullw   r4,r4,r11
  197.     call    D_SCAlloc
  198.     slwi    r4,r30,2
  199.     addi    r0,r4,MSURFACE_CACHESPOTS
  200.     add     r4,r31,r0
  201.     stw     r3,0(r4)
  202.     stw     r4,SURFCACHE_OWNER(r3)
  203.     stfs    f14,SURFCACHE_MIPSCALE(r3)
  204. .nocache:
  205.     lwz     r4,MSURFACE_DLIGHTFRAME(r31)
  206.     cmpw    r4,r28
  207.     bne     .else
  208.     li    r0,1
  209.     stw    r0,SURFCACHE_DLIGHT(r3)
  210.     b       .cont
  211. .else:
  212.     li    r0,0
  213.     stw    r0,SURFCACHE_DLIGHT(r3)
  214. .cont:
  215.     la      r4,SURFCACHE_DATA(r3)
  216.     stw     r4,DRAWSURF_SURFDAT(r29)
  217.     stw     r9,SURFCACHE_TEXTURE(r3)
  218.     stw     r5,SURFCACHE_LIGHTADJ(r3)
  219.     stw     r6,SURFCACHE_LIGHTADJ+1*4(r3)
  220.     stw     r7,SURFCACHE_LIGHTADJ+2*4(r3)
  221.     stw     r8,SURFCACHE_LIGHTADJ+3*4(r3)
  222.     stw     r31,DRAWSURF_SURF(r29)
  223.     lw      r5,c_surf
  224.     mr      r31,r3
  225.     addi    r5,r5,1
  226.     sw      r5,c_surf
  227.     call    R_DrawSurface
  228.     mr      r3,r31
  229.  
  230. .exit:
  231.     lfd    f14,fb(r1)
  232.     lmw    r28,gb(r1)
  233.     exit
  234.  
  235.     funcend    D_CacheSurface
  236.