Enigma Amiga Life 109/EnigmaAmiga109CD.iso/software/varie/gdtrash1.1rev.2/arexx/trashdelete.dopus5

Text File | 2000-01-19 | 5KB | 251 lines

/* Full Dopus Delete command with Trashcan feature */
/* By Nils-Erik Reklev Skilnand*/

parse arg portname handle
if portname='' then portname='DOPUS.1'
address value portname

options results

if handle="" then do

lister query source
handle=result
if rc~=0 then exit
end
lf='0a'x

if (show('p','ArcDir'space(handle,0))) then do
    lister request handle '"Warning:"'lf'"DelTrash does not work with ArcDir"'lf'"Please configure the Delete button with the normal"'lf'" Delete command for another mouse button"'lf'"Example: Left mouse button DelTrash"'lf'"Right mouse button Delete (dopus command Delete)" Ok'
    exit
end

if open(1,'Env:trash.prefs','R') then do
    do i=1 to 6
        prefs.i = readln(1)
    end

    if prefs.4 ~="" then trashpath=prefs.4
    Call close(1)
end

lister query Handle selfiles stem files.
lister query Handle seldirs stem dirs.
IF (files.count=0&dirs.count=0) then exit

i=1;argm='';fuckthem=0;un=0

lister query Handle path
pfad=result

entries=0
lister query handle selentries
allents=result
do while allents~=''
    entries=entries+1
    parse var allents '"' name.entries '"' allents
    lister query handle entry '"'name.entries'"' stem fileinfo.
    type.entries=fileinfo.type
    name1.entries=name.entries
    name.entries ='"'pfad || name.entries'"'
    prot.entries = fileinfo.protstring
end

lister set handle newprogress name info bar
lister set handle newprogress title "Removing Files ..."
lister set handle newprogress info "Number of files: "entries

lister request handle '"Warning: You cannot get back"'lf'"What you delete! OK to delete"'lf'""'lf'"'files.count' file(s) and"'lf'"'dirs.count' drawer(s)(and their contents)?" Proceed|DeleteAll|Trash All|Cancel'

if rc=1 then do
    call subdel
end
if rc=2 then do
    do i=i to entries
        if (lastpos('d',prot.i)=0&argm~='force'&fuckthem=0) then call pro
        if lastpos('d',prot.i)=0 then do
            select
                when (ch=1|ch=2) then call del
                when ch=3 then call pro
                when ch=4 then nop
                otherwise nop
            end
        end
        else call del

    end
end

if rc=3 then do
    do i=i to entries
        if (lastpos('d',prot.i)=0&argm~='force'&fuckthem=0) then call pro
        if lastpos('d',prot.i)=0 then do
            select
                when (ch=1|ch=2) then call trash
                when ch=3 then call pro
                when ch=4 then nop
                otherwise nop
            end
        end
        else call trash
    end
end

lister clear handle progress
Lister refresh handle full
exit

SubDel:
if i>entries then return
lister request handle '"Delete 'name1.i' ?" Delete|Delete All|Trash|Trash All|Skip|Abort'
select
    when rc=1 then do
        if (lastpos('d',prot.i)=0&argm~='force'&fuckthem=0) then call pro
        if lastpos('d',prot.i)=0 then do
            select
                when ch=2 then do
                    call del
                    i=i+1
                end
                when ch=3 then call subdel
                when ch=4 then do
                    i=i+1
                end
                otherwise nop
            end
        end
        else do
            call del
            i=i+1
        end
        call subdel

    end

    when rc=2 then do
        do i=i to entries
            if (lastpos('d',prot.i)=0&argm~='force'&fuckthem=0) then call pro
            if lastpos('d',prot.i)=0 then do
                select
                    when (ch=1|ch=2) then call del
                    when ch=3 then do
                        i=i-1
                        call pro
                    end
                    when ch=4 then nop
                    otherwise nop
                end
            end
            else call del

        end
    end

    when rc=3 then do
        if (lastpos('d',prot.i)=0&argm~='force'&fuckthem=0) then call pro
        if lastpos('d',prot.i)=0 then do
            select
                when ch=2 then do
                    call trash
                    i=i+1
                end
                when ch=3 then call subdel
                when ch=4 then do
                    i=i+1
                end
                otherwise nop
            end
        end
        else do
            call trash
            i=i+1
        end
        call subdel
    end

    when rc=4 then do
        do i=i to entries
            if (lastpos('d',prot.i)=0&argm~='force'&fuckthem=0) then call pro
            if lastpos('d',prot.i)=0 then do
                select
                    when (ch=1|ch=2) then call trash
                    when ch=3 then do
                        i=i-1
                        call pro
                    end
                    when ch=4 then nop
                    otherwise nop
                end
            end
            else call trash

        end
    end

    when rc=5 then do
        lister set handle newprogress info entries "/" entries-i Name1.i
            lister set handle newprogress bar entries i
        i=i+1
        call subdel
    end
otherwise nop
end
return

pro:
lister request handle '""'name1.i'" is protected against deletion."'lf'"Unprotect and try again?" Unprotect|Unprotect All|Skip|Skip All|Abort'
select
    when rc=1 then do
        address command 'protect 'name.i' +d'
        prot.i='d'
        ch=1
    end

    when rc=2 then do
        argm='force'
        prot.i='d'
        ch=2
    end

    when rc=3 then do
        i=i+1
        ch=3
    end

    when rc=4 then do
        fuckthem=1
        ch=4
    end

    when rc=0 then do
        lister clear handle progress
        Lister refresh handle full
        exit
    end
otherwise nop
end
return

Del:
address command 'Delete all 'argm' 'name.i''
lister set handle newprogress info entries "/" entries-i Name1.i
lister set handle newprogress bar entries i
return

Trash:
if argm='force' then address command 'protect all 'name.i' +d'
if type.i < 0 then do
    address command 'Move 'name.i' to 'trashpath''
    address command 'Echo >'trashpath||strip(name1.i,B,'"')||.path' 'pfad''
    Address Command 'SetDate 'trashpath||strip(name1.i,B,'"')''
end

lister set handle newprogress info entries "/" entries-i Name1.i
lister set handle newprogress bar entries i

if type.i > 0 then do
    address command 'Move 'name.i' to 'trashpath||strip(name1.i,B,'"')''
    address command 'Echo >'trashpath||strip(name1.i,B,'"')||.path' 'pfad''
    Address Command 'SetDate 'trashpath||strip(name1.i,B,'"')''
end
return