home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 109 / EnigmaAmiga109CD.iso / software / utilities / shellscr / src / args.e next >
Encoding:
Text File  |  1999-11-21  |  6.2 KB  |  205 lines
  1. /****** args.m/--overview-- *******************************************
  2. * 
  3. *   PURPOSE
  4. *       To provide ReadArgs() parsing for both CLI and WB.
  5. * 
  6. *   OVERVIEW
  7. *       AmigaDOS 2.0 has a very powerful argument parser known as
  8. *       ReadArgs(). It allows you to specify a simple template,
  9. *       which describes how arguments will be parsed and will fill
  10. *       an array of LONGs.
  11. *
  12. *       This module provides a readargs() call, which uses the
  13. *       Workbench startup message to go through a list of selected icons'
  14. *       tooltypes, and matches those tooltypes like arguments on the
  15. *       command line.
  16. *
  17. *       Used in ShellScr by Kyzer/CSG
  18. *
  19. ****************************************************************************
  20. *
  21. *
  22. */
  23.  
  24. ->example:
  25. ->  IF rdargs := readargs('CX_PRIORITY/N, CX_POPKEY, CX_POPUP/S',
  26. ->                       args:=NEW [0,0,0], wbmessage)
  27. ->
  28. ->    cx_pri := IF args[0] THEN Long(args[0]) ELSE 0
  29. ->    hotkey := IF args[1] THEN args[1] ELSE 'ctrl alt del'
  30. ->    popup  := args[2]
  31. ->    [....]
  32. ->    FreeArgs(rdargs)
  33. ->  ENDIF
  34.  
  35. -> FIXES:
  36. -> - (06.04.98) Gags when directories are selected. Fixed.
  37. -> - (04.05.98) Fixed memory-trashing bug.
  38. -> - (02.09.98) Stops quoting already-quoted strings
  39.  
  40. -> TODO:
  41. -> - support =YES and =NO tooltypes in switches
  42. -> - special case (list of icon names) to /M switched variables
  43.  
  44. OPT MODULE,OSVERSION=36
  45.  
  46. MODULE 'icon', 'dos/rdargs', 'workbench/startup', 'workbench/workbench'
  47. DEF iconbase
  48.  
  49. -> Basically, we run through all the selected icons' tooltypes from
  50. -> first (our own icon) to last. if the left part of a tooltype
  51. -> (in 'BLA=FISH', the left part is 'BLA') is judged by DOS to be
  52. -> a keyword from the template (this includes parsing aliases for
  53. -> keywords) then we insert it and its right part (if there is one)
  54. -> into a list in the appropriate place, which can overwrite tooltypes
  55. -> already there (eg, selected icons override default settings in our
  56. -> own icon). Once we have this list of keywords and values, we can make
  57. -> a single string with all these keywords and values, and give it to
  58. -> ReadArgs.
  59.  
  60. -> The code that splits a tooltype into left and right parts is clever
  61. -> enough to ignore 'disabled' tooltypes which begin with '(', and also
  62. -> ignores tooltypes beginning IM1= or IM2= for performance reasons (NewIcons
  63. -> contain a lot of these tooltypes for their icon data)
  64.  
  65. EXPORT PROC readargs(template:PTR TO CHAR, args, wbmsg:PTR TO wbstartup) HANDLE
  66.   DEF rdargs=NIL, tooltype, name, val, m, n, arg, dir, len,
  67.       arglst=NIL:PTR TO LONG,     -> a list to all our args and their values
  68.       dobj=NIL:PTR TO diskobject, -> diskobject of 'current icon'
  69.       tooltypes:PTR TO LONG       -> tooltypes of 'current icon'
  70.  
  71.   -> If we were run from shell, then just parse as normal
  72.   IF wbmsg = NIL THEN RETURN ReadArgs(template, args, NIL)
  73.  
  74.   -> make sure icon.library is available
  75.   IF (iconbase := OpenLibrary('icon.library', 36))=NIL THEN Raise("LIB")
  76.  
  77.   -> make a big enough list to hold all name/value pairs for template
  78.   IF (arglst := List(len :=getlistlen(template)))=NIL THEN Raise("MEM")
  79.   DEC len
  80.  
  81.   -> Go through all tooltypes in all selected icons
  82.   FOR m := 0 TO wbmsg.numargs - 1
  83.     dir := CurrentDir(wbmsg.arglist[m].lock)
  84.     dobj := GetDiskObject(wbmsg.arglist[m].name)
  85.     CurrentDir(dir)
  86.  
  87.     IF dobj
  88.       IF tooltypes := dobj.tooltypes
  89.         WHILE tooltype := tooltypes[]++
  90.           -> split up tooltype
  91.           name, val := ttsplit(tooltype)
  92.           IF name
  93.             -> if in template, place into appropriate list entry
  94.             IF (arg := FindArg(template, name)) <> -1
  95.               n := Shl(arg, 1)
  96.               IF arg := arglst[ n ] THEN DisposeLink(arg)
  97.               IF arg := arglst[n+1] THEN DisposeLink(arg)
  98.               arglst[ n ] := name
  99.               arglst[n+1] := val
  100.             ELSE
  101.               IF name THEN DisposeLink(name)
  102.               IF val  THEN DisposeLink(val)
  103.             ENDIF
  104.           ENDIF
  105.         ENDWHILE
  106.       ENDIF
  107.       FreeDiskObject(dobj); dobj := NIL
  108.     ENDIF
  109.   ENDFOR
  110.  
  111.   -> calculate length of final 'arg string' to be parsed by ReadArgs()
  112.   m := 0
  113.   FOR n := 0 TO len DO IF arg := arglst[n] THEN m := m + 3 + EstrLen(arg)
  114.  
  115.   IF (m := String(m))=NIL THEN Raise("MEM")
  116.   StrCopy(m, '')
  117.  
  118.   -> concatenate final arg settings into one big string
  119.   FOR n:=0 TO len
  120.     IF arg := arglst[n]
  121.       -> append either 'arg ' or '"arg" ' if arg has spaces in it
  122.       IF (InStr(arg, ' ') = -1) AND (arg[] <> "\q")
  123.         StrAdd(m, arg)
  124.         StrAdd(m, ' ')
  125.       ELSE        
  126.         StrAdd(m, '"')
  127.         StrAdd(m, arg)
  128.         StrAdd(m, '" ')
  129.       ENDIF
  130.     ENDIF
  131.   ENDFOR
  132.  
  133.   -> perform the ReadArgs call on our constructed string
  134.   rdargs := ReadArgs(template, args,
  135.     [m, EstrLen(m), 0, NIL, NIL, 0, NIL, RDAF_NOPROMPT]
  136.   )
  137.  
  138.   -> throw away big string
  139.   DisposeLink(m)
  140.  
  141. EXCEPT DO
  142.   IF arglst
  143.     FOR n := 0 TO len
  144.       IF arg := arglst[n] THEN DisposeLink(arg)
  145.     ENDFOR
  146.     DisposeLink(arglst)
  147.   ENDIF
  148.  
  149.   IF dobj     THEN FreeDiskObject(dobj)
  150.   IF iconbase THEN CloseLibrary(iconbase); iconbase := NIL
  151.  
  152.   ReThrow()
  153. ENDPROC rdargs
  154.  
  155.  
  156.  
  157. PROC ttsplit(s:PTR TO CHAR)
  158.   -> of something 'blah=foo', returns 'blah', 'foo'
  159.   -> of something 'blah', returns 'blah', NIL
  160.   -> of something beginning '(', 'IM1=' or 'IM2=', returns NIL, NIL
  161.  
  162.   DEF div, len, l, r
  163.  
  164.   -> ignore disabled tooltypes, newicon tooltypes, and blank ones
  165.   IF s = NIL THEN RETURN NIL, NIL
  166.   IF (s[]="(") OR (s[]="\0") OR
  167.      StrCmp(s, 'IM1=', 4) OR StrCmp(s, 'IM2=', 4) THEN
  168.     RETURN NIL, NIL
  169.  
  170.   len := StrLen(s)
  171.   div := InStr(s, '=') -> find '=' divisor
  172.  
  173.   IF div = -1
  174.     -> no '=' present in string - return copy of left half
  175.     IF l := String(len) THEN StrCopy(l, s)
  176.     RETURN l, NIL
  177.   ENDIF
  178.  
  179.   -> allocate left and right strings
  180.   l := String(div + 1)
  181.   r := String(len - div)
  182.  
  183.   -> if either string allocation failed, free either and return NIL
  184.   IF (l AND r)=NIL
  185.     IF l THEN DisposeLink(l)
  186.     IF r THEN DisposeLink(r)
  187.     RETURN NIL, NIL
  188.   ENDIF
  189.  
  190.   MidStr(l, s, 0, div) -> copy left of '=' to l
  191.   MidStr(r, s, div+1) -> copy right of '=' to r
  192. ENDPROC l, r
  193.  
  194. PROC getlistlen(template)
  195.     MOVEQ    #1, D0
  196.     MOVE.L    template, A0
  197. __cnt:    MOVE.B    (A0)+, D1
  198.     BEQ.S    __end
  199.     CMP.B    #",", D1
  200.     BNE.S    __cnt
  201.     ADDQ    #1, D0
  202.     BRA.S    __cnt
  203. __end:    ASL.W    #1, D0
  204. ENDPROC D0
  205.