home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 109 / EnigmaAmiga109CD.iso / software / testi / corsoasm / sorgenti6 / lezione10e2r.s < prev    next >
Text File  |  1995-10-23  |  7KB  |  248 lines
  1.  
  2. ; Lezione10e2r.s    Cancellazione e disegno rawblit con copper monitor
  3. ;            Tasto sinistro per uscire.
  4.  
  5.     SECTION    CiriCop,CODE
  6.  
  7. ;    Include    "DaWorkBench.s"    ; togliere il ; prima di salvare con "WO"
  8.  
  9. *****************************************************************************
  10.     include    "startup1.s"    ; Salva Copperlist Etc.
  11. *****************************************************************************
  12.  
  13.         ;5432109876543210
  14. DMASET    EQU    %1000001111000000    ; copper,bitplane,blitter DMA
  15.  
  16.  
  17. START:
  18.  
  19.     MOVE.L    #BITPLANE,d0    ; dove puntare
  20.     LEA    BPLPOINTERS,A1    ; puntatori COP
  21.     MOVEQ    #3-1,D1        ; numero di bitplanes (qua sono 3)
  22. POINTBP:
  23.     move.w    d0,6(a1)
  24.     swap    d0
  25.     move.w    d0,2(a1)
  26.     swap    d0
  27.     ADD.L    #40,d0        ; + LUNGHEZZA DI UNA RIGA !!!!!
  28.     addq.w    #8,a1
  29.     dbra    d1,POINTBP
  30.  
  31.     lea    $dff000,a5        ; CUSTOM REGISTER in a5
  32.     MOVE.W    #DMASET,$96(a5)        ; DMACON - abilita bitplane, copper
  33.     move.l    #COPPERLIST,$80(a5)    ; Puntiamo la nostra COP
  34.     move.w    d0,$88(a5)        ; Facciamo partire la COP
  35.     move.w    #0,$1fc(a5)        ; Disattiva l'AGA
  36.     move.w    #$c00,$106(a5)        ; Disattiva l'AGA
  37.     move.w    #$11,$10c(a5)        ; Disattiva l'AGA
  38.  
  39.     move.w    #0,ogg_x
  40.     move.w    #0,ogg_y
  41.  
  42. mouse:
  43.  
  44.     addq.w    #1,ogg_y
  45.     cmp.w    #130,ogg_y
  46.     beq.s    fine
  47.  
  48.     MOVE.L    #$1ff00,d1    ; bit per la selezione tramite AND
  49.     MOVE.L    #$0d000,d2    ; linea da aspettare = $D0
  50. Waity1:
  51.     MOVE.L    4(A5),D0    ; VPOSR e VHPOSR - $dff004/$dff006
  52.     ANDI.L    D1,D0        ; Seleziona solo i bit della pos. verticale
  53.     CMPI.L    D2,D0        ; aspetta la linea $D0
  54.     BNE.S    Waity1
  55.  
  56. ;       \\\|||///
  57. ;     .  =======
  58. ;    / \| O   O |
  59. ;    \ / \`___'/
  60. ;     #   _| |_
  61. ;    (#) (     )
  62. ;     #\//|* *|\\
  63. ;     #\/(  *  )/
  64. ;     #   =====
  65. ;     #   ( U )
  66. ;     #   || ||
  67. ;    .#---'| |`----.
  68. ;    `#----' `-----'
  69.  
  70.     bsr.s    CancellaOggetto        ; cancella il bob
  71.  
  72.     move    #$0b0,$180(a5)        ; schermo verde scuro quando il
  73.                     ; PROCESSORE ha finito la cancellazione
  74.  
  75.     bsr.s    DisegnaOggetto        ; disegna il bob
  76.  
  77.     move    #$b00,$180(a5)        ; schermo verde scuro quando il
  78.                     ; PROCESSORE ha finito il disegno
  79.  
  80.     btst    #6,2(a5)
  81. WBlit_coppermonitor:
  82.     btst    #6,2(a5)     ; attendi che il blitter abbia finito
  83.     bne.s    wblit_coppermonitor
  84.  
  85.     move.w    #$000,$180(a5)
  86.  
  87.     bra.s    mouse
  88.  
  89. fine:
  90.     rts
  91.  
  92.  
  93. ;*****************************************************************************
  94. ; Questa routine cancella il BOB mediante il blitter. La cancellazione
  95. ; viene fatta sul rettangolo che racchiude il bob
  96. ;****************************************************************************
  97.  
  98. CancellaOggetto:
  99.     lea    bitplane,a0    ; destinazione in a0
  100.     move.w    ogg_y(pc),d0    ; coordinata Y
  101.     mulu.w    #3*40,d0    ; calcola indirizzo: ogni riga e` costituita da
  102.                 ; 3 planes di 40 bytes
  103.     add.w    d0,a0        ; aggiungi all'indirizzo di partenza
  104.  
  105.     move.w    ogg_x(pc),d1    ; coordinata X
  106.     lsr.w    #3,d1        ; (equivalente ad una divisione per 8)
  107.                 ; arrotonda ai multipli di 8 per il puntatore
  108.                 ; allo schermo, ovvero agli indirizzi dispari
  109.                 ; (anche ai byte, quindi)
  110.                 ; x es.: un 16 come coordinata diventa il
  111.                 ; byte 2 
  112.     and.w    #$fffe,d1    ; escludo il bit 0 del
  113.     add.w    d1,a0        ; somma all'indirizzo del bitplane, trovando
  114.                 ; l'indirizzo giusto di destinazione
  115.  
  116.     btst    #6,2(a5)
  117. WBlit3:
  118.     btst    #6,2(a5)     ; attendi che il blitter abbia finito
  119.     bne.s    wblit3
  120.  
  121.     move.w    #$0f0,$180(a5)        ; coppermonitor! schermo verde durante
  122.                     ; la cancellazione.
  123.  
  124.     move.l    #$01000000,$40(a5)    ; BLTCON0 e BLTCON1: Cancella
  125.     move.w    #$0004,$66(a5)        ; BLTDMOD=40-36=4
  126.     move.l    a0,$54(a5)        ; BLTDPT
  127.     move.w    #(3*64*45)+18,$58(a5)    ; BLTSIZE (via al blitter !)
  128.                     ; cancella il rettangolo che racchiude
  129.                     ; il BOB
  130.  
  131.     rts                
  132.  
  133. ;****************************************************************************
  134. ; Questa routine disegna il BOB alle coordinate specificate nelle variabili
  135. ; X_OGG e Y_OGG.
  136. ;****************************************************************************
  137.  
  138. DisegnaOggetto:
  139.     lea    bitplane,a0    ; destinazione in a0
  140.     move.w    ogg_y(pc),d0    ; coordinata Y
  141.     mulu.w    #3*40,d0    ; calcola indirizzo: ogni riga e` costituita da
  142.                 ; 3 planes di 40 bytes ciascuno
  143.     add.w    d0,a0        ; aggiungi all'indirizzo di partenza
  144.  
  145.     move.w    ogg_x(pc),d0    ; coordinata X
  146.     move.w    d0,d1        ; copia
  147.     and.w    #$000f,d0    ; si selezionano i primi 4 bit perche' vanno
  148.                 ; inseriti nello shifter del canale A 
  149.     lsl.w    #8,d0        ; i 4 bit vengono spostati sul nibble alto
  150.     lsl.w    #4,d0        ; della word...
  151.     or.w    #$09f0,d0    ; ...giusti per inserirsi nel registro BLTCON0
  152.     lsr.w    #3,d1        ; (equivalente ad una divisione per 8)
  153.                 ; arrotonda ai multipli di 8 per il puntatore
  154.                 ; allo schermo, ovvero agli indirizzi dispari
  155.                 ; (anche ai byte, quindi)
  156.                 ; x es.: un 16 come coordinata diventa il
  157.                 ; byte 2 
  158.     and.w    #$fffe,d1    ; escludo il bit 0 del
  159.     add.w    d1,a0        ; somma all'indirizzo del bitplane, trovando
  160.                 ; l'indirizzo giusto di destinazione
  161.  
  162.  
  163.     btst    #6,2(a5)
  164. WBlit2:
  165.     btst    #6,2(a5)         ; attendi che il blitter abbia finito
  166.     bne.s    wblit2
  167.  
  168.     move.w    #$f00,$180(a5)
  169.  
  170.     move.l    #$ffffffff,$44(a5)    ; BLTAFWM = $ffff fa passare tutto
  171.                     ; BLTALWM = $0000 azzera l'ultima word
  172.  
  173.  
  174.     move.w    d0,$40(a5)        ; BLTCON0 (usa A+D)
  175.     move.w    #$0000,$42(a5)        ; BLTCON1 (nessun modo speciale)
  176.     move.l    #$00000004,$64(a5)    ; BLTAMOD=0
  177.                     ; BLTDMOD=40-36=4 come al solito
  178.  
  179.     move.l    #figura,$50(a5)        ; BLTAPT  (fisso alla figura sorgente)
  180.     move.l    a0,$54(a5)        ; BLTDPT  (linee di schermo)
  181.     move.w    #(3*64*45)+18,$58(a5)    ; BLTSIZE (via al blitter !)
  182.  
  183.     rts
  184.  
  185. OGG_Y:        dc.w    0    ; qui viene memorizzata la Y dell'oggetto
  186. OGG_X:        dc.w    0    ; qui viene memorizzata la X dell'oggetto
  187. MOUSE_Y:    dc.b    0    ; qui viene memorizzata la Y del mouse
  188. MOUSE_X:    dc.b    0    ; qui viene memorizzata la X del mouse
  189.  
  190. ;****************************************************************************
  191.  
  192.     SECTION    GRAPHIC,DATA_C
  193.  
  194. COPPERLIST:
  195.     dc.w    $8E,$2c81    ; DiwStrt
  196.     dc.w    $90,$2cc1    ; DiwStop
  197.     dc.w    $92,$38        ; DdfStart
  198.     dc.w    $94,$d0        ; DdfStop
  199.     dc.w    $102,0        ; BplCon1
  200.     dc.w    $104,0        ; BplCon2
  201.     dc.w    $108,80        ; VALORE MODULO 80
  202.     dc.w    $10a,80        ; ENTRAMBI I MODULI ALLO STESSO VALORE.
  203.  
  204.     dc.w    $100,$3200    ; bplcon0 - 3 bitplanes lowres
  205.  
  206. BPLPOINTERS:
  207.     dc.w $e0,$0000,$e2,$0000    ;primo     bitplane
  208.     dc.w $e4,$0000,$e6,$0000
  209.     dc.w $e8,$0000,$ea,$0000
  210.  
  211.     dc.w    $0180,$000    ; color0
  212.     dc.w    $0182,$475    ; color1
  213.     dc.w    $0184,$fff    ; color2
  214.     dc.w    $0186,$ccc    ; color3
  215.     dc.w    $0188,$999    ; color4
  216.     dc.w    $018a,$232    ; color5
  217.     dc.w    $018c,$777    ; color6
  218.     dc.w    $018e,$444    ; color7
  219.  
  220.     dc.w    $FFFF,$FFFE    ; Fine della copperlist
  221.  
  222. ;****************************************************************************
  223.  
  224. ; Questi sono i dati che compongono la figura del bob.
  225. ; Il bob e` in formato normale, largo 288 pixel (18 words)
  226. ; alto 45 righe e formato da 3 bitplanes
  227.  
  228. Figura:
  229.     incbin    copmon.rawblit
  230.  
  231. ;****************************************************************************
  232.  
  233.     section    gnippi,bss_C
  234.  
  235. BITPLANE:
  236.         ds.b    40*256    ; 3 bitplanes
  237.         ds.b    40*256
  238.         ds.b    40*256
  239.  
  240.     end
  241.  
  242. ;****************************************************************************
  243.  
  244. Questo programma e` la versione rawblit di lezione10e2.s.
  245. Questa volta il copper monitor ci evidenzia anche il tempo impiegato dal
  246. processore evidenziando in questo modo i vantaggi del rawblit.
  247.  
  248.