home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 109 / EnigmaAmiga109CD.iso / software / testi / corsoasm / sorgenti6 / lezione10e1.s < prev    next >
Text File  |  1995-10-23  |  6KB  |  215 lines
  1.  
  2. ; Lezione10e1.s    Blittata normale con copper monitor
  3. ;        Tasto sinistro per uscire.
  4.  
  5.     SECTION    CiriCop,CODE
  6.  
  7. ;    Include    "DaWorkBench.s"    ; togliere il ; prima di salvare con "WO"
  8.  
  9. *****************************************************************************
  10.     include    "startup1.s"    ; Salva Copperlist Etc.
  11. *****************************************************************************
  12.  
  13.         ;5432109876543210
  14. DMASET    EQU    %1000001111000000    ; copper,bitplane,blitter DMA
  15.  
  16.  
  17. START:
  18.  
  19.     MOVE.L    #BITPLANE,d0    ; dove puntare
  20.     LEA    BPLPOINTERS,A1    ; puntatori COP
  21.     MOVEQ    #3-1,D1        ; numero di bitplanes (qua sono 3)
  22. POINTBP:
  23.     move.w    d0,6(a1)
  24.     swap    d0
  25.     move.w    d0,2(a1)
  26.     swap    d0
  27.     ADD.L    #40*256,d0        ; + LUNGHEZZA DI UNA PLANE !!!!!
  28.     addq.w    #8,a1
  29.     dbra    d1,POINTBP
  30.  
  31.     lea    $dff000,a5        ; CUSTOM REGISTER in a5
  32.     MOVE.W    #DMASET,$96(a5)        ; DMACON - abilita bitplane, copper
  33.     move.l    #COPPERLIST,$80(a5)    ; Puntiamo la nostra COP
  34.     move.w    d0,$88(a5)        ; Facciamo partire la COP
  35.     move.w    #0,$1fc(a5)        ; Disattiva l'AGA
  36.     move.w    #$c00,$106(a5)        ; Disattiva l'AGA
  37.     move.w    #$11,$10c(a5)        ; Disattiva l'AGA
  38.  
  39.     move.w    #0,ogg_x
  40.     move.w    #0,ogg_y
  41.  
  42. mouse:
  43.  
  44.     addq.w    #1,ogg_y
  45.     cmp.w    #130,ogg_y
  46.     beq.s    fine
  47.  
  48.     MOVE.L    #$1ff00,d1    ; bit per la selezione tramite AND
  49.     MOVE.L    #$0f400,d2    ; linea da aspettare = $F4
  50. Waity1:
  51.     MOVE.L    4(A5),D0    ; VPOSR e VHPOSR - $dff004/$dff006
  52.     ANDI.L    D1,D0        ; Seleziona solo i bit della pos. verticale
  53.     CMPI.L    D2,D0        ; aspetta la linea $F4
  54.     BNE.S    Waity1
  55.  
  56. ;       \\\|||///
  57. ;     .  =======
  58. ;    / \| O   O |
  59. ;    \ / \`___'/
  60. ;     #   _| |_
  61. ;    (#) (     )
  62. ;     #\//|* *|\\
  63. ;     #\/(  *  )/
  64. ;     #   =====
  65. ;     #   ( U )
  66. ;     #   || ||
  67. ;    .#---'| |`----.
  68. ;    `#----' `-----'
  69.  
  70.     move.w    #$f00,$180(a5)        ; cambia il colore di sfondo
  71.     bsr.s    DisegnaOggetto        ; disegna il bob
  72.  
  73.     btst    #6,2(a5)
  74. WBlit_coppermonitor:
  75.     btst    #6,2(a5)     ; attendi che il blitter abbia finito
  76.     bne.s    wblit_coppermonitor
  77.  
  78.     move.w    #$000,$180(a5)        ; rimetti lo sfondo nero
  79.  
  80.     bra.s    mouse
  81.  
  82. fine:
  83.     rts
  84.  
  85.  
  86. ;****************************************************************************
  87. ; Questa routine disegna il BOB alle coordinate specificate nelle variabili
  88. ; X_OGG e Y_OGG.
  89. ;****************************************************************************
  90.  
  91. DisegnaOggetto:
  92.     lea    bitplane,a0    ; destinazione in a0
  93.     move.w    ogg_y(pc),d0    ; coordinata Y
  94.     mulu.w    #40,d0        ; calcola indirizzo: ogni riga e` costituita da
  95.                 ; 40 bytes
  96.     add.w    d0,a0        ; aggiungi all'indirizzo di partenza
  97.  
  98.     move.w    ogg_x(pc),d0    ; coordinata X
  99.     move.w    d0,d1        ; copia
  100.     and.w    #$000f,d0    ; si selezionano i primi 4 bit perche' vanno
  101.                 ; inseriti nello shifter del canale A 
  102.     lsl.w    #8,d0        ; i 4 bit vengono spostati sul nibble alto
  103.     lsl.w    #4,d0        ; della word...
  104.     or.w    #$09f0,d0    ; ...giusti per inserirsi nel registro BLTCON0
  105.     lsr.w    #3,d1        ; (equivalente ad una divisione per 8)
  106.                 ; arrotonda ai multipli di 8 per il puntatore
  107.                 ; allo schermo, ovvero agli indirizzi dispari
  108.                 ; (anche ai byte, quindi)
  109.                 ; x es.: un 16 come coordinata diventa il
  110.                 ; byte 2 
  111.     and.w    #$fffe,d1    ; escludo il bit 0 del
  112.     add.w    d1,a0        ; somma all'indirizzo del bitplane, trovando
  113.                 ; l'indirizzo giusto di destinazione
  114.  
  115.     lea    figura,a1    ; puntatore sorgente
  116.     moveq    #3-1,d7        ; ripeti per ogni plane
  117. PlaneLoop:
  118.     btst    #6,2(a5)
  119. WBlit2:
  120.     btst    #6,2(a5)         ; attendi che il blitter abbia finito
  121.     bne.s    wblit2
  122.  
  123.     move.l    #$ffffffff,$44(a5)    ; BLTAFWM = $ffff fa passare tutto
  124.                     ; BLTALWM = $0000 azzera l'ultima word
  125.  
  126.  
  127.     move.w    d0,$40(a5)        ; BLTCON0 (usa A+D)
  128.     move.w    #$0000,$42(a5)        ; BLTCON1 (nessun modo speciale)
  129.     move.l    #$00000004,$64(a5)    ; BLTAMOD=0
  130.                     ; BLTDMOD=40-36=4 come al solito
  131.  
  132.     move.l    a1,$50(a5)        ; BLTAPT  (fisso alla figura sorgente)
  133.     move.l    a0,$54(a5)        ; BLTDPT  (linee di schermo)
  134.     move.w    #(64*45)+18,$58(a5)    ; BLTSIZE (via al blitter !)
  135.  
  136.     lea    2*18*45(a1),a1        ; punta al prossimo plane sorgente
  137.                     ; ogni plane e` largo 18 words e alto
  138.                     ; 45 righe
  139.  
  140.     lea    40*256(a0),a0        ; punta al prossimo plane destinazione
  141.     dbra    d7,PlaneLoop
  142.  
  143.     rts
  144.  
  145. OGG_Y:        dc.w    0    ; qui viene memorizzata la Y dell'oggetto
  146. OGG_X:        dc.w    0    ; qui viene memorizzata la X dell'oggetto
  147. MOUSE_Y:    dc.b    0    ; qui viene memorizzata la Y del mouse
  148. MOUSE_X:    dc.b    0    ; qui viene memorizzata la X del mouse
  149.  
  150. ;****************************************************************************
  151.  
  152.     SECTION    GRAPHIC,DATA_C
  153.  
  154. COPPERLIST:
  155.     dc.w    $8E,$2c81    ; DiwStrt
  156.     dc.w    $90,$2cc1    ; DiwStop
  157.     dc.w    $92,$38        ; DdfStart
  158.     dc.w    $94,$d0        ; DdfStop
  159.     dc.w    $102,0        ; BplCon1
  160.     dc.w    $104,0        ; BplCon2
  161.     dc.w    $108,0        ; VALORE MODULO 0
  162.     dc.w    $10a,0        ; ENTRAMBI I MODULI ALLO STESSO VALORE.
  163.  
  164.     dc.w    $100,$3200    ; bplcon0 - 3 bitplanes lowres
  165.  
  166. BPLPOINTERS:
  167.     dc.w $e0,$0000,$e2,$0000    ;primo     bitplane
  168.     dc.w $e4,$0000,$e6,$0000
  169.     dc.w $e8,$0000,$ea,$0000
  170.  
  171.     dc.w    $0180,$000    ; color0
  172.     dc.w    $0182,$475    ; color1
  173.     dc.w    $0184,$fff    ; color2
  174.     dc.w    $0186,$ccc    ; color3
  175.     dc.w    $0188,$999    ; color4
  176.     dc.w    $018a,$232    ; color5
  177.     dc.w    $018c,$777    ; color6
  178.     dc.w    $018e,$444    ; color7
  179.  
  180.     dc.w    $FFFF,$FFFE    ; Fine della copperlist
  181.  
  182. ;****************************************************************************
  183.  
  184. ; Questi sono i dati che compongono la figura del bob.
  185. ; Il bob e` in formato normale, largo 288 pixel (18 words)
  186. ; alto 45 righe e formato da 3 bitplanes
  187.  
  188. Figura:
  189.     incbin    copmon.raw
  190.  
  191. ;****************************************************************************
  192.  
  193.     section    gnippi,bss_C
  194.  
  195. BITPLANE:
  196.         ds.b    40*256    ; 3 bitplanes
  197.         ds.b    40*256
  198.         ds.b    40*256
  199.  
  200.     end
  201.  
  202. ;****************************************************************************
  203.  
  204. In questo esempio effettuiamo una copia mediante il blitter di un rettangolo
  205. largo 18 words, alto 45 righe e formato da 3 bitplanes in formato normale
  206. (quindi sono necessarie 3 blittate separate). Mediante il "copper monitor"
  207. misuriamo la velocita` dell'operazione. La copia inizia quando il pennello
  208. elettronico raggiunge la riga $f4. A questo punto, subito prima di iniziare
  209. la copia cambiamo il COLOR 0. Quando la copia e` finita rimettiamo lo sfondo
  210. al colore iniziale (nero).
  211. Potete vedere mediante questa routine come la dimensione della blittata
  212. influenzi la velocita`: provate a cambiare la larghezza e/o l'altezza e
  213. osservate i risultati. Comodo il "copper monitor", vero?
  214.  
  215.