Enigma Amiga Life 109/EnigmaAmiga109CD.iso/software/grafica/showamiga96_install/install_showamiga96

Text File | 2000-02-02 | 27KB | 992 lines

;=============================================================================
; English strings (default)
;=============================================================================

        (set #startupmsg1
            (cat
                "\n\n\nWelcome to ShowAmiga96 V2.3b,          \n"
                "          the bootpic-viewer Picasso96."
                "\n\n\n\n\nThis software is subject to the \"Standard Amiga FD-Software Copyright Note\"."
                "\nIt is MAILWARE as defined in paragraph 4b."
                "\nFor more information please read \"AFD-COPYRIGHT\" (Version 1 or higher)."
            )
        )
        (set #startupmsg2
            (cat
                "\n\n\nIn contrast to ShowAmiga96 V1.x this version will be installed in its own directory. \n\n"
                "The installer will create an environment variable which points to the installation directory "
                "(no assign needed).\n\n"
                "The call of the mainprog will be inserted into Startup-Sequence automatically. The closer "
                "will be copied into the WBstartup drawer."
            )
        )
        (set #startupmsg22
            (cat
                "\n\n\nThere is already an (older) Version of ShowAmiga96 2.x installed on your system. \n\n"
                "The installer will update the program files, your settings and images won´t be changed."
            )
        )
        (set #getpath1    "Select the install directory for ShowAmiga96 V2.3b. A drawer called ShowAmiga96 will be created there."
        )
        (set #getpath11 "Please select the ShowAmiga96 drawer to update."
        )
        (set #getpath2    "Please select your WBstartup drawer for the Closer."
        )
        (set #getpath3    "Please select your Prefs drawer for the preferences program."
        )
        (set #getpath4    "Please select your L drawer for the HappyENV handler."
        )
        (set #copy6    "Which translations should be installed?"
        )
        (set #getdriver
            (cat
                "To show the bootpic as early as possible, ShowAmiga96 has to start the "
                "Picasso96-monitordriver by itself.\nPlease select your Picasso96-monitordriver."
            )
        )
        (set #startupmsg3    "\nAdjusting ShowAmiga96 initial prefs..."
        )
        (set #startupmsg4
            (cat
                "\nThe installation has been completed.\n\nAfter a reset you can enjoy "
                "your new bootpic. Should you encounter problems, try to find some help "
                "in the documentation. "
                "Otherwise don´t hesitate to contact me :-)\n\n"
                "Heiko Müller\n"
                "Ernst-Reuter-Str. 8\n"
                "31275 Lehrte\n"
                "Germany\n\n"
                "[e-mail]"
            )
        )
        (set #startupmsg5
            (cat
                "\nDownload-Hint\n\nThe default bootpic (Amiga_800x600) is included in this archive just as a 8 bit image in a "
                "resolution of 800x600 pixels.\nIf you use a Workbench with another resolution/colordepth, you probably want to "
                "a add a bootpic with correct dimensions to avoid annoying screenmode changes.\n\n"
                "You can download the files (bootpic and transfer anim) in IFF-ILBM format from my homepage:\n\n"
                "http://www.relaysoft.onlinehome.de"
            )
        )
        (set #nodriver1    "\nThe specified file \""
        )
        (set #nodriver2    "\" doesn´t exist! Please select an existing file."
        )
        (set #startupmsg6
            (cat
                "\nThe installer inserts the ShowAmiga96-call into the startup-sequence. "
                "A backup file called \"Startup-Sequence.SA96\" will be created in S:.\n\n"
                "If necessary, you can edit the startup-sequence yourself later, but "
                "please read the documentation!!!"
            )
        )
        (set #startupmsg6a
            (cat
                "\nStarting with this version ShowAmiga96 requires Martin Gierichs HappyENV-Handler. "
                "\nThe Installer will change the startup-sequence now (see help for details). "
                "A backup called "
                "\"Startup-Sequence.HAPPYENV\" will be created in S:.\n\n"
                "If necessary, you can edit the startup-sequence yourself later, but "
                "please read the documentation!!!"
            )
        )
        (set #startupmsg7    "\nRunning prefs program..."
        )
        (set #startupmsg8
            (cat
                "\nThe installer will search for the old call of ShowAmiga96 and will remove it from startup-sequence."
                "Also the old closer will be deleted from the wbstartup-drawer.\n\n"
                "If you changed the calls of ShowAmiga96 and/or of the closer, you probably "
                "have to remove the old yourself."
            )
        )
        (set #startupmsg9
            (cat
                "\nThe old ShowAmiga96-call has been removed from startup-sequence, but the installer was "
                "unable to delete the closer (ShowAmiga96_Close) from the WBstartup-drawer.\n\n"
                "Please remove the old closer yourself or replace it with the new one."
            )
        )
        (set #help1
            (cat
                "\nThe ShowAmiga96 directory contains no user accessable files.\n\n"
                "So it needn´t be placed in Utilities, you can hide it somewhere else.\n\n"
                "A directory called ´ShowAmiga96´ will be created by the installer."
            )
        )
        (set #help11
            (cat
                "\nThe installer suggests the directory of the old installation.\n"
                "The installer will update the old files in this directory und in the subdirs."
            )
        )
        (set #help2
            (cat
                "\nThe closer must be called at the end of the boot process.\n\n"
                "This normally happens in the WBstartup drawer."
            )
        )
        (set #help3
            (cat
                "\nThe prefs programm is used to control the complete behavior of ShowAmiga96.\n\n"
                "The best place is the prefs drawer."
            )
        )
        (set #help6
            (cat
                "\nShowAmiga96 opens its screen before the monitor drivers from DEVS:Monitors are loaded. "
                "That´s the reason why ShowAmiga96 has to start the Picasso96-driver itself, all other "
                "monitordrivers are loaded a bit later. To pick the correct P96-driver, the installer "
                "needs your help."
            )
        )
        (set #help7
            (cat
                "\nNormally, ShowAmiga96 is launched directly after the command ´SetPatch´ in the Startup-Sequence. The installer "
                "is able the insert the call itself.\nIf you have changed your Startup-Sequence or if you use more than one, "
                "you may skip this part and enter the call yourself later. "
                "You will find a description how to do this in the documentation (page Installation)."
            )
        )
        (set #help7a
            (cat
                "If HappyENV is not installed yet, the startup-sequence will be changed like this:\n\n"
                ";BEGIN ShowAmiga96\n"
                "C:MountENV\n"
                "sys:utilities/ShowAmiga96/Bin/showamiga96_Rev239C18\n"
                ";END ShowAmiga96\n\n"
                "{...}\n\n"
                ";C:Copy >NIL: ENVARC: RAM:ENV ALL NOREQ\n\n"
                "{...}\n\n"
                ";Assign >NIL: ENV: RAM:ENV"
            )
        )
        (set #help8
            (cat
                "\nThe installer is able to find and disable the old ShowAmiga96 command in your Startup-Sequence itself. "
            )
        )
        (set #help9
            (cat
                "No help available."
            )
        )
        (set #warn1
            (cat
                "\nWarning!\n\n"
                "ShowAmiga96 requires at least Picasso96 V1.40\n"
                "You use an older version which could lead to\n"
                "problems."
            )
        )
        (set #warn2
            (cat
                "\nAttention!\n\n\n"
                "Please do not remove ShowAmiga96_Close from your WBstartup drawer or make sure that you launch it "
                "from somewhere else.\n\nShowAmiga96 needs the program to react on the WBstartup close condition AND "
                "to display errors that occured while booting."
            )
        )
        (set #nohelp "No help available.")
        (set #copydefs
            (cat
                "Do you want to copy the default image (Amiga_800x600) and the fitting anim ?"
            )
        )
        (set #agname "ShowAmiga96_GB.guide")
        (set #catsdef 2)




;=============================================================================
; German strings
;=============================================================================

(if
    (= @language "deutsch")
    (
        (set #startupmsg1
            (cat
                "\n\n\nWillkommen zu ShowAmiga96 V2.3b,          \n"
                "          dem Bootbild-Anzeiger für Picasso96."
                "\n\n\n\n\nDiese Software unterliegt der \"Standard Amiga FD-Software Copyright Note\"."
                "\nSie ist MAILWARE wie definiert in Absatz 4b."
                "\nFür mehr Informationen lies bitte \"AFD-COPYRIGHT\" (Version 1 oder höher)."
            )
        )
        (set #startupmsg2
            (cat
                "\n\n\nIm Gegensatz zu ShowAmiga96 V1.x wird diese Version in einem eigenen Verzeichnis installiert. \n\n"
                "Um auf ein ASSIGN zu verzichten, legt das Install-Script eine ENV-Variable an, die auf "
                "das Installationsverzeichnis verweist.\n\n"
                "Der Aufruf des Programms kann wie bisher automatisch in die Startup-Sequence eingetragen werden lassen, das "
                "Schließprogramm wird ins WBStartup-Verzeichnis kopiert."
            )
        )
        (set #startupmsg22
            (cat
                "\n\n\nEs ist bereits eine (ältere) Version von ShowAmiga96 V2.x auf Ihrem System vorhanden.\n\n"
                "Der Installer wird nur die Programmdateien austauschen, die Einstellungen und Bilder bleiben erhalten"
            )
        )
        (set #getpath1    "Bitte wählen Sie den Installationsort für ShowAmiga96 V2.3b aus. Ein Verzeichnis namens ShowAmiga96 wird automatisch erstellt."
        )
        (set #getpath11 "Bitte geben Sie das Verzeichnis an, in dem das Update durchgeführt werden soll."
        )
        (set #getpath2    "Bitte wählen Sie Ihr WBStartup-Verzeichnis für das Schließprogramm aus."
        )
        (set #getpath3    "Bitte wählen Sie Ihr Prefs-Verzeichnis für das Einstellungsprogramm aus."
        )
        (set #getpath4    "Bitte wählen Sie Ihr L-Verzeichnis für den HappyENV-Handler aus."
        )
        (set #copy6    "Welche Übersetzungen kopieren?"
        )
        (set #getdriver
            (cat
                "ShowAmiga96 startet den Picasso96-Monitortreiber unabhängig von den übrigen Treibern. "
                "Wählen Sie bitte Ihren P96-Monitortreiber aus."
            )
        )
        (set #startupmsg3    "\nPasse ShowAmiga96-Grundeinstellungen an..."
        )
        (set #startupmsg4
            (cat
                "\nDie Installation ist jetzt abgeschlossen.\n\nNach einem Neustart können "
                "Sie sich an Ihrem neuen Bootbild erfreuen. Sollten Probleme auftreten, "
                "so mag ein Blick in die Anleitung sicherlich hilfreich sein. "
                "Ansonsten bin ich ja auch noch da ;-)\n\n"
                "Heiko Müller\n"
                "Ernst-Reuter-Str. 8\n"
                "31275 Lehrte\n\n"
                "[e-mail]"
            )
        )
        (set #startupmsg5
            (cat
                "\nDownload-Hinweis\n\nDas default-Bootbild (Amiga_800x600) ist in diesem Archiv nur als 8-Bit Image in der "
                "Auflösung 800x600 Pixel enthalten.\nWenn Sie eine Workbench mit anderer Auflösung/Farbtiefe "
                "fahren, möchten Sie wahrscheinlich das Bootbild in einer passenden Größe hinzufügen, um "
                "lästige Screenmodewechsel zu vermeiden.\n\n"
                "Die Dateien (Bootbild und Transfer-Anim) im IFF-ILBM-Format können von meiner Homepage "
                "heruntergeladen werden:\n\n"
                "http://www.relaysoft.onlinehome.de"
            )
        )
        (set #nodriver1    "\nDie angegebene Datei \""
        )
        (set #nodriver2    "\" existiert nicht! Wählen Sie bitte eine vorhandene Datei."
        )
        (set #startupmsg6
            (cat
                "\nDas Installationsprogramm fügt jetzt den ShowAmiga96-Aufruf in die "
                "Startup-Sequence ein. Eine Sicherungskopie wird unter dem Namen "
                "\"Startup-Sequence.SA96\" in S: angelegt.\n\n"
                "Wenn Sie wollen, können Sie die Änderung später auch von Hand vornehmen, "
                "aber dabei unbedingt die Anleitung beachten!!!"
            )
        )
        (set #startupmsg6a
            (cat
                "\nShowAmiga96 benötigt ab Version 2.3b den HappyENV-Handler von Martin Gierich. "
                "\nDas Installationsprogramm nimmt jetzt Änderungen an der Startup-Sequence vor (Hilfe für Details), die "
                "für den Betrieb von HappyENV nötig sind. Eine Sicherungskopie wird unter dem Namen "
                "\"Startup-Sequence.HAPPYENV\" in S: angelegt.\n\n"
                "Wenn Sie wollen, können Sie die Änderung später auch von Hand vornehmen, "
                "aber dabei unbedingt die Anleitung beachten!!!"
            )
        )
        (set #startupmsg7    "\nStarte Einstellungsprogramm..."
        )
        (set #startupmsg8
            (cat
                "\nDas Installationsprogramm prüft jetzt, ob eine alte Version von ShowAmiga96 in der Startup-Sequence aufgerufen wird. "
                "Dieser Aufruf wird nicht mehr benötigt und auskommentiert.\n\nWeiterhin wird versucht, das alte Schließprogramm (ShowAmiga96_Close) aus der "
                "WBstartup-Schublade zu löschen."
            )
        )
        (set #startupmsg9
            (cat
                "\nDer alte ShowAmiga96-Aufruf wurde aus der Startup-Sequence entfernt, das Schließprogramm "
                "konnte jedoch nicht gelöscht werden.\n\n"
                "Bitte entfernen Sie vor dem nächsten Neustart den alten Aufruf von ShowAmiga96_Close per Hand, falls Sie "
                "das Programm nicht bereits mit der neuen Version überschrieben haben."
            )
        )
        (set #help1
            (cat
                "\nDas ShowAmiga96-Verzeichnis enthält keine Dateien, auf die der User direkten Zugriff haben muß.\n\n"
                "Es muß also nicht unbedingt in Utilities liegen, sondern kann auch irgendwo ´versteckt´ werden.\n\n"
                "Ein Verzeichnis namens ´ShowAmiga96´ wird automatisch vom Installer angelegt."
            )
        )
        (set #help11
            (cat
                "\nDer Installer schlägt automatisch das Verzeichnis der aktuellen ShowAmiga96-Installation vor.\n"
                "In diesem und den Unterverzeichnissen werden die veralteten Programmdateien ausgetauscht."
            )
        )
        (set #help2
            (cat
                "\nDas Schließprogramm muß unbedingt am Ende des Bootvorgangs gestartet werden.\n\n"
                "Standardmäßig wird es in das WBStartup-Verzeichnis kopiert und mit der niedrigsten STARTPRI aufgerufen."
            )
        )
        (set #help3
            (cat
                "\nMit dem Prefs-Programm wird das gesamte Verhalten von ShowAmiga96 kontrolliert.\n\n"
                "Die Prefs-Schublade der Workbench ist der geeignete Platz für die Installation."
            )
        )
        (set #help6
            (cat
                "\nDamit ShowAmiga96 seinen Bildschirm schon zu Beginn der Startup-Sequence öffnen kann, "
                "muß es den Picasso96-Treiber zuvor selbst starten. Alle übrigen "
                "werden ganz normal etwas später aktiviert.\nUm aus der Vielzahl der möglichen P96-Monitor"
                "treiber den richtigen herauszufinden, ist der Installer auf Ihre Hilfe angewiesen."
            )
        )
        (set #help7
            (cat
                "\nFür gewöhnlich wird ShowAmiga96 am direkt nach dem Befehl "SetPatch" in der Startup-Sequence gestartet. Der Installer "
                "kann den Aufruf selbst in die Datei eintragen.\nWenn Sie Ihre Startup-Sequence stark verändert "
                "haben oder ShowAmiga96 an einer anderen Stelle starten wollen, können Sie diesen Teil überspringen "
                "und später nach Anleitung den Aufruf per Hand eintragen."
            )
        )
        (set #help7a
            (cat
                "Falls HappyENV noch nicht installiert ist, wird die Startup-Sequence folgendermaßen geändert:\n\n"
                ";BEGIN ShowAmiga96\n"
                "C:MountENV\n"
                "sys:utilities/ShowAmiga96/Bin/showamiga96_Rev239C18\n"
                ";END ShowAmiga96\n\n"
                "{...}\n\n"
                ";C:Copy >NIL: ENVARC: RAM:ENV ALL NOREQ\n\n"
                "{...}\n\n"
                ";Assign >NIL: ENV: RAM:ENV"
            )
        )
        (set #help8
            (cat
                "\nDer Installer kann den alten Aufruf von ShowAmiga96 in der Startup-Sequence finden und auskommentieren. "
                "\nWenn Sie dies per Hand machen wollen, denken Sie bitte daran, ggf. auch den Aufruf für das alte Schließprogramm zu "
                "entfernen, falls es sich nicht in WBstartup befindet und automatisch überschrieben wird."
            )
        )
        (set #help9
            (cat
                "\nVoreinstellungsmäßig wurde das alte Schließprogramm in die WBstartup-Schublade kopiert. "
                "Bei Bedarf könnte es aber auch an einem anderen Ort installiert werden und der Aufruf "
                "beispielsweise aus einem Skript erfolgen.\n\n"
                "Der Installer hat das Schließprogramm nicht in der WBstartup-Schublade gefunden, so daß Sie "
                "den abgeänderten Aufruf per Hand entfernen müssen.\n\n"
                "AUSNAHME: Das alte Schließprogramm wurde durch das neue überschrieben. In diesem Fall "
                "kann alles unverändert bleiben."
            )
        )
        (set #warn1
            (cat
                "\nWarnung!\n\n"
                "ShowAmiga96 benötigt mindestens Picasso96 V1.40\n"
                "Sie benutzen eine ältere Version, mit der es\n"
                "Probleme geben könnte."
            )
        )
        (set #warn2
            (cat
                "\nAchtung!\n\n\n"
                "Bitte entfernen Sie ShowAmiga96_Close nicht aus Ihrer WBstartup-Schublade oder stellen Sie sicher, daß das "
                "Programm nach dem Booten auf andere Weise gestartet wird.\n\nShowAmiga96 verwendet es neben dem Setzen der "
                "WBstartup-Schließbedingung auch zum Anzeigen von Fehlern, die während des Bootvorgangs aufgetreten sind."
            )
        )
        (set #nohelp "Keine Hilfe verfügbar")
        (set #copydefs
            (cat
                "Soll das Default-Bild (Amiga_800x600) und die passende Anim kopiert werden ?"
            )
        )
        (set #agname "ShowAmiga96_D.guide")
        (set #catsdef 1)
    )
)

;=============================================================================
; Spanish strings
;=============================================================================

(if
    (= @language "español")
    (
        (set #agname "ShowAmiga96_E.guide")
        (set #catsdef 4)
    )
)

;=============================================================================
; Swedish strings
;=============================================================================

(if
    (= @language "svenska")
    (
        (set #agname "ShowAmiga96_S.guide")
        (set #catsdef 8)
    )
)


;=============================================================================
; Defaults einstellen
;=============================================================================

(set #oldpath (getenv("SHOWAMIGA96")))
(set #mainpath "Sys:Utilities/")
(set #closepath "Sys:WBstartup/")
(set #prefspath "Sys:Prefs/")
(set #lpath "Sys:L/")
(set #cpath "Sys:C/")
(set #driverpath "DEVS:Monitors/")
(set #localepath "Sys:Locale/Catalogs/")
(set #editsseq1 "bin/editsseq ")
(set #editsseq2 "bin/editsseq2")
(set #checkexist "bin/checkexist")
(set #remold "bin/remold ")
;(set #saveenvarc "bin/saveenvarc ")


;=============================================================================
; Los geht´s
;=============================================================================

(complete 0)
(message    #startupmsg1
    (all)
)

(set #vernum (getversion "LIBS:Picasso96API.library"))

(if(< #vernum 131340)
    (
        (message    #warn1
            (all)
        )
    )
)

(if(<>(#oldpath)(""))
    (
        (set #mainpath #oldpath)
        (message    #startupmsg22
            (all)
        )
        (welcome)
        (set #mainpath
            (askdir    (prompt    #getpath11)
                (help    #help11)
                (default    #mainpath)
            )
        )
        (set #isupdate true)
    )
    (
        (message    #startupmsg2
            (all)
        )
        (welcome)
        (set #mainpath
            (askdir    (prompt    #getpath1)
                (help    #help1)
                (default    #mainpath)
            )
        )
        (set #mainpath (tackon #mainpath "ShowAmiga96"))
        (set #isupdate false)
    )
)


;=============================================================================
; Installationspfade einholen
;=============================================================================

(complete 5)
(set #closepath
    (askdir    (prompt    #getpath2)
        (help    #help2)
        (default    #closepath)
    )
)
(message    #warn2
    (all)
)

(complete 7)
(set #prefspath
    (askdir    (prompt    #getpath3)
        (help    #help3)
        (default    #prefspath)
    )
)

(complete 10)
(set #lpath
    (askdir    (prompt    #getpath4)
        (help    #nohelp)
        (default    #lpath)
    )
)


;=============================================================================
; Kataloge kopieren
;=============================================================================

(complete 15)
(set #catsdef
        (askoptions
        (prompt    #copy6)
        (help    #nohelp)
        (choices    "Deutsch"
                "English"
                "Español"
                "Svenska")
        (default    #catsdef)
    )
)

(if    (BITAND #catsdef 1)
    (
        (copyfiles
            (source    "Locale/Catalogs/deutsch")
            (prompt    #copy6)
            (help    #nohelp)
            (dest    (tackon #localepath "deutsch"))
            (all)
        )
    )
)
(if    (BITAND #catsdef 4)
    (
        (copyfiles
            (source    "Locale/Catalogs/Español")
            (prompt    #copy6)
            (help    #nohelp)
            (dest    (tackon #localepath "Español"))
            (all)
        )
    )
)
(if    (BITAND #catsdef 8)
    (
        (copyfiles
            (source    "Locale/Catalogs/Svenska")
            (prompt    #copy6)
            (help    #nohelp)
            (dest    (tackon #localepath "Svenska"))
            (all)
        )
    )
)


;=============================================================================
; bei Firstinstall nach Monitortreibernamen fragen und Startup-Sequence ändern
;=============================================================================

(complete 20)
(if(not #isupdate)
    (
        (while (OR (= (fileonly(#driverpath)) "") (NOT #driverok))
            (
                (set #driverpath
                    (askfile    (prompt    #getdriver)
                        (help    #help6)
                        (default    #driverpath)
                    )
                )
                (set #driverok (exists #driverpath (noreq)))
                (if (NOT #driverok)
                    (message    (cat #nodriver1 #driverpath #nodriver2) (all))
                )
            )
        )

        (run #remold
            (prompt    #startupmsg8)
            (help    #help8)
            (confirm)
        )
        (if(=(exists "env:killedoldsa96" (noreq)) 1)
            (
                (delete "env:killedoldsa96" (safe))
                (if (= (exists "sys:wbstartup/showamiga96_close" (noreq)) 1)
                    (delete "sys:wbstartup/showamiga96_close" (infos))
                    (message    #startupmsg9
                        (help    #nohelp)
                        (all)
                    )
                )
            )
        )
    )
)


;=============================================================================
; ENVs erstellen
;=============================================================================

(complete 25)
(textfile
    (dest    "ENV:SHOWAMIGA96")
    (append    #mainpath)
)
(complete 27)
(textfile
    (dest    "ENVARC:SHOWAMIGA96")
    (append    #mainpath)
)


;=============================================================================
; Verzeichnis erstellen
;=============================================================================

(complete 29)
(if(not #isupdate)
    (
        (makedir #mainpath
            (infos)
        )
    )
)


;=============================================================================
; Bin kopieren
;=============================================================================

(complete 30)
(set #binpath (tackon #mainpath "Bin"))
(copyfiles
    (source    "Bin")
    (help    #nohelp)
    (dest    #binpath)
    (all)
)


;=============================================================================
; Module kopieren
;=============================================================================

(complete 55)
(set #modpath (tackon #mainpath "Modules"))
(copyfiles
    (source    "Modules")
    (help    #nohelp)
    (dest    #modpath)
    (all)
)


;=============================================================================
; Anleitungen kopieren
;=============================================================================

(complete 63)
(set #dokupath (tackon #mainpath "Docs"))
(copyfiles
    (source    "Docs")
    (help    #nohelp)
    (dest    #dokupath)
    (all)
)


;=============================================================================
; Images/Anims kopieren
;=============================================================================

(complete 65)
(set #ideapath (tackon #mainpath ".sa96idea"))
(set #ideaok (exists #ideapath (noreq)))
(set #idebpath (tackon #mainpath ".sa96ideb"))
(set #idebok (exists #idebpath (noreq)))
(set #animpath (tackon #mainpath "Anims"))
(set #imgpath (tackon #mainpath "Images"))

(if (NOT #ideaok)
    (
        (if(not #isupdate)
            ( ; neue Inst
                (copyfiles
                    (source    "Images")
                    (help    #nohelp)
                    (dest    #imgpath)
                    (all)
                )
                (copyfiles
                    (source    "Anims")
                    (help    #nohelp)
                    (dest    #animpath)
                    (all)
                )
            )
            ( ; Update von 2.2
                (if(= (askbool(prompt #copydefs)(help #nohelp)) 1)
                    (
                        (copyfiles
                            (source    "Images")
                            (help    #nohelp)
                            (dest    #imgpath)
                            (all)
                        )
                        (copyfiles
                            (source    "Anims")
                            (help    #nohelp)
                            (dest    #animpath)
                            (all)
                        )
                    )
                )
            )
        )
    )
)



;=============================================================================
; Anims Verzeichnis erstellen
;=============================================================================

(complete 75)
(set #animok (exists #animpath (noreq)))
(if (NOT #animok)
    (
        makedir #animpath
    )
)

;=============================================================================
; Rest kopieren und Prefs anpassen
;=============================================================================

(complete 80)
(if(not #isupdate)
    (
        (copyfiles
            (source    "")
            (choices    ".order" ".prefs" ".sa96id")
            (dest    #mainpath)
        )

        (set #prefsini (cat "bin/setprefs " #driverpath))
        (complete 82)
        (working    #startupmsg3)
        (run #prefsini
            (prompt    #startupmsg3)
        )
    )
)
(copyfiles
    (source    ".sa96idea")
    (dest    #mainpath)
)


;(set #saveenvarc (cat "bin/saveenvarc " (expandpath "ENVARC:") " " (tackon #binpath "ShowAmiga96_Rev208711")))
;(run #saveenvarc
;    (prompt    #startupmsg3)
;)


(set #closefile (tackon #closepath "ShowAmiga96_Close"))
(set #iconposx -1)
(set #iconposy -1)
(set #iconok (exists #closefile (noreq)))
(if (= #iconok 1)
    (
        (iconinfo
            (dest #closefile)
            (getposition "#iconposx" "#iconposy")
        )
    )
)

(copyfiles
    (source    "WBStartup/ShowAmiga96_Close")
    (help    #nohelp)
    (infos)
    (noposition)
    (dest    #closepath)
)

(tooltype
    (dest #closefile)
    (setposition #iconposx #iconposy)
)

(complete 85)

(set #prefsfile (tackon #prefspath "ShowAmiga96_Prefs"))
(set #defpicturedir "")
(set #iconposx -1)
(set #iconposy -1)

(set #iconok (exists #prefsfile (noreq)))
(if (= #iconok 1)
    (
        (iconinfo
            (dest #prefsfile)
            (gettooltype "DEFPICTUREDIR" "#defpicturedir")
        )
        (iconinfo
            (dest #prefsfile)
            (getposition "#iconposx" "#iconposy")
        )
    )
)


(copyfiles
    (source    "Prefs/ShowAmiga96_Prefs")
    (help    #nohelp)
    (noposition)
    (infos)
    (dest    #prefspath)
)

(copyfiles
    (source    "HappyENV/HappyENV-Handler")
    (help    #nohelp)
    (dest    #lpath)
)

(copyfiles
    (source    "HappyENV/MountENV")
    (help    #nohelp)
    (dest    #cpath)
)

(makedir (tackon #mainpath "HappyENV")
)

(copyfiles
    (source    "HappyENV/HappyENV.guide")
    (dest    (tackon #mainpath "HappyENV"))
)

(if(<> #defpicturedir "")
    (
        (tooltype
            (dest #prefsfile)
            (settooltype "DEFPICTUREDIR" #defpicturedir)
        )
    )
    (
        (tooltype
            (dest #prefsfile)
            (settooltype "(DEFPICTUREDIR" "<Bildquelldateiverzeichnis>)")
        )
    )
)

(tooltype
    (dest #prefsfile)
    (setposition #iconposx #iconposy)
)



;=============================================================================
; ShowAmiga96 in Startup-sequence eintragen
;=============================================================================

(complete 90)

(run (cat #checkexist " SHOWAMIGA96_REV2"))
(if(=(exists "env:sa96notexists" (noreq)) 1)
    (
        ; noch gar keine 2.x installiert
        (set #binpath1 (tackon #binpath "ShowAmiga96_Rev208711"))
        (set #editsseq1 (cat #editsseq1 #binpath1))
        (run #editsseq1
            (prompt    #startupmsg6)
            (help    #help7)
            (confirm)
        )
    )
)

(run (cat #checkexist " SHOWAMIGA96_REV208711"))
(if(=(exists "env:sa96notexists" (noreq)) 0)
    (
        ; Version 2.0, 2.1, 2.2 oder 2.3 ist installiert
        (run (cat #editsseq2 " save")
        )
        (run #editsseq2
            (prompt    #startupmsg6a)
            (help    #help7a)
            (confirm)
        )
    )
)


;=============================================================================
; Prefs starten und Installation verlassen
;=============================================================================


(run (tackon #binpath "getdriver"))
(set #driverpathname (getenv "showamiga96_driver"))
(set #driverpathname (cat #driverpathname ""))
(if(>((strlen #driverpathname)) 2)
    (
        (tooltype
            (dest #driverpathname)
            (settooltype "QUIET" "Yes")
        )
    )
)

(complete 100)
(message    #startupmsg4
    (all)
)
(message    #startupmsg5
    (all)
)



(if(not #isupdate)
    (
        (set #prefspath (tackon #prefspath "ShowAmiga96_Prefs"))
        (set #prefspath (cat "run >nil: " #prefspath))
        (run #prefspath
            (prompt    #startupmsg7)
        )
    )
    (
        (if (NOT #ideaok)
            (
                (run (cat "run >nil: bin/showag docs/" #agname " Neu"))
            )
        )

    )
)
(if (NOT #idebok)
    (
        (run (cat "run >nil: bin/showag docs/" #agname " Neua"))
    )
)

(exit (quiet))