home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 106 / EnigmaAmiga106CD.iso / software / utilities / printmanager39 / install < prev    next >
Encoding:
Text File  |  1999-08-12  |  5.8 KB  |  251 lines

  1. ; $VER: Installer script for PrintManager 1.10 (27.05.99) © 1997-1999 by Stephan Rupprecht
  2.  
  3. ;--- localize strings ----
  4. (if (= @language "deutsch")
  5. (
  6.     (set #wrongver "PrintManager benötigt mindestens AmigaOS3.0.\nInstallation kann nicht durchgeführt werden.")
  7.     (set #askdir_prompt "Bitte wählen Sie das Zielverzeichnis für den PrintManager")
  8.     (set #install_doc "Bitte wählen Sie das Verzeichnis für die Anleitung")
  9.     (set #no_doc "Anleitung nicht installieren")
  10.     (set #patch_err "Die Version für 68020 Prozessoren kann nicht erstellt werden")
  11.     (set #apply_020patch "Ein 68020+ Prozessor wurde erkannt.\nEs wird nun eine optimierte Version des Programms erstellt ...\n\nGPatch ist (c) 1997-1999 by Ralf Gruner")
  12.     (set #apply_fparpatch "Die fastpar.device wird nun auf den aktuellen Stand gebracht.\n")
  13.     (set #apply_fparpatch_err "Update der fastpar.device kann nicht durchgeführt werden")
  14.     (set #gtdrag_prompt "Soll die gtdrag.library installiert werden?")
  15.     (set #gtdrag_help "Die gtdrag.library von Axel Dörfler ermöglicht es Ihnen die Auftragsliste mittels "Ziehen und Fallenlassen" (DragNDrop) zu verändern.")
  16. )
  17. (
  18.     (if (= @language "español")
  19.     (
  20.         (set #wrongver "PrintManager requiere al menos S.O. 3.0\nInstalación abortada.")
  21.         (set #askdir_prompt "Por favor, elija el cajón donde desea que PrintManager sea instalado.")
  22.         (set #install_doc "Por favor, elija el cajón donde desea instalar la documentación.")
  23.         (set #no_doc "No instalar documentación")
  24.         (set #patch_err "¡Imposible crear versión 68020+!")
  25.         (set #apply_020patch "He encontrado un procesador 68020+:\ncreando versión optimizada de PrintManager...\n\nGPatch es (c) 1997-1999 de Ralf Gruner")
  26.         (set #apply_fparpatch "Ahora se va actualizar `fastpar.device' (37.6).")
  27.         (set #apply_fparpatch_err "Intento fallido de actualizar `fastpar.device'")
  28.         (set #gtdrag_prompt "¿Desea instalar la biblioteca `gtdrag.library'?")
  29.         (set #gtdrag_help "La biblioteca `gtdrag.library' de Axel Dörfler le permite modificar la lista de tareas simplemente arrastrando y soltando las entradas.")
  30.     )
  31.     (
  32.         (set #wrongver "PrintManager requires at least AmigaOS3.0\nInstallation aborted.")
  33.         (set #askdir_prompt "Please select the drawer where PrintManger should be installed")
  34.         (set #install_doc "Please select the drawer for the documentation")
  35.         (set #no_doc "Don't install doc")
  36.         (set #patch_err "Failed to create 68020+ version")
  37.         (set #apply_020patch "Found a 68020+ cpu.\nCreating optimized version of PrintManager now ...\n\nGPatch is (c) 1997-1999 by Ralf Gruner")
  38.         (set #apply_fparpatch "Now going to update fastpar.device (37.6).")
  39.         (set #apply_fparpatch_err "Failed to update fastpar.device")
  40.         (set #gtdrag_prompt "Do you wish to install gtdrag.library?")
  41.         (set #gtdrag_help "gtdrag.library by Axel Dörfler allows you to change the joblist by Drag'N'Drop.")
  42.     )
  43.     )
  44. )
  45. )
  46.  
  47. ;--- check os version ---
  48. (set #vernum (getversion "exec.library" (resident)))
  49. (set #vernum (/ #vernum 65536))
  50.  
  51. (if(< #vernum 39)
  52.     (abort #wrongver)
  53. )
  54.  
  55. ;--- copy main program ---
  56. (set @default-dest
  57.     (askdir
  58.         (prompt #askdir_prompt)
  59.         (help @askdir-help)
  60.         (default "SYS:WBStartup")
  61.     )
  62. )
  63.  
  64. (if (patmatch "68000|68010" (database "cpu"))
  65. (
  66.     (copyfiles
  67.         (help @copyfiles-help)
  68.         (source "PrintManager")
  69.         (dest @default-dest)
  70.     )
  71. )
  72. ;--- 020+ cpu installed, create optimized version
  73. (
  74.     (message #apply_020patch)
  75.  
  76.     (set #newname
  77.         (tackon @default-dest "PrintManager" )
  78.     )
  79.  
  80.     (set #cmd
  81.         (cat "gpatch PrintManager 020patch.gp " #newname)
  82.     )
  83.     
  84.     (set #err 
  85.         (run #cmd   
  86.         )
  87.     )
  88.     
  89.     (if (> #err 0)
  90.         (abort #patch_err)
  91.     )
  92. )
  93. )
  94.  
  95. ;--- copy .info file if neccessary ---
  96. (set #info_path (tackon @default-dest "PrintManager.info") )
  97.  
  98. (if (not (exists #info_path) )
  99.     (copyfiles
  100.         (help @copyfiles-help)
  101.         (source "PrintManager.info")
  102.         (dest @default-dest)
  103.     )
  104. )
  105.  
  106. ;--- delete spool.device ---
  107. (if (exists "DEVS:spool.device") 
  108.     (delete "DEVS:spool.device"
  109.     )
  110. )
  111.  
  112. ;--- copy catalog ---
  113. (if (NOT (= @language "english")) 
  114. (
  115.     (set #src_name
  116.         (tackon "Catalogs/" @language)
  117.     )
  118.  
  119.     (set #dst_name
  120.         (tackon "LOCALE:" #src_name)
  121.     )
  122.  
  123.     (set #src_name
  124.         (tackon #src_name "printmanager.catalog")
  125.     )
  126.  
  127.     (if (exists #src_name (noreq))
  128.     (
  129.         (copyfiles
  130.             (help @copyfiles-help)
  131.             (source #src_name)
  132.             (dest #dst_name)
  133.         )
  134.     )
  135.         (message "Sorry, there is no " @language " catalog available at the moment!")
  136.     ) 
  137. )
  138. )
  139.  
  140. ;--- copy doc ---
  141. (set #progdir
  142.     (cat "PROGDIR:" " (aka " @default-dest ")" )
  143. )
  144.  
  145. (set #helpdir
  146.     (tackon "HELP:" @language)
  147. )
  148.  
  149. (set #choice
  150.     (askchoice
  151.         (prompt #install_doc)
  152.         (help @askchoice-help)
  153.         (choices #helpdir #progdir #no_doc)
  154.         (default 0)
  155.     )
  156. )
  157.  
  158. (if (< #choice 2)
  159. (
  160.     (if (exists "HELP:PrintManager.guide")
  161.     (
  162.         (Delete "HELP:PrintManager.guide")
  163.     )
  164.     )
  165.  
  166.     (if (= #choice 1)
  167.     (
  168.         (set #dst_name @default-dest)
  169.     )
  170.         (set #dst_name #helpdir)
  171.     )
  172.     
  173.     (set #src_name
  174.         (cat "docs®forms/" @language "/PrintManager.guide")
  175.     )
  176.  
  177.     (if (NOT (exists #src_name) )
  178.     (
  179.         (set #src_name "docs/english/PrintManager.guide")
  180.     )
  181.     )
  182.  
  183.     (copyfiles
  184.         (help  @copyfiles-help)
  185.         (source #src_name)
  186.         (dest #dst_name)
  187.     )
  188.     
  189.     (set #src_name
  190.         (cat #src_name ".info")
  191.     )    
  192.     
  193.     (copyfiles
  194.         (help  @copyfiles-help)
  195.         (source #src_name)
  196.         (dest #dst_name)
  197.     )
  198. )
  199. )
  200.  
  201. (copylib
  202.     (source "libs/gtdrag.library")
  203.     (dest "LIBS:")
  204.     (prompt #gtdrag_prompt)
  205.     (help #gtdrag_help)
  206.     (confirm)
  207. )
  208.  
  209. ;--- update fastpar.device ---
  210. ;--- revision check doesn't work due a bug in 'getversion' ---
  211. ;(set #vernum (getversion "devs:fastpar.device"))
  212. ;(set #ver (/ #vernum 65536))
  213. ;(set #rev (- #vernum (* #ver 65536) ) )
  214.  
  215. ;(if(< #rev 6)
  216. ;(
  217.  
  218. (if(exists "DEVS:fastpar.device")
  219. (
  220.     (set #err
  221.         (run "C:Version DEVS:fastpar.device REVISION 6")
  222.     )
  223.     
  224.     (if (<> 0 #err)
  225.     (
  226.         (message #apply_fparpatch)
  227.  
  228.         (set #err 
  229.             (run "gpatch DEVS:fastpar.device fastpar.ptch t:fastpar.device")
  230.         )
  231.  
  232.         (if (> #err 0)
  233.         (
  234.             (message #apply_fparpatch_err)
  235.         )
  236.         (
  237.             (copyfiles
  238.                 (help @copyfiles-help)
  239.                 (source "t:fastpar.device")
  240.                 (dest "devs:")
  241.             )
  242.  
  243.             (delete "t:fastpar.device")
  244.         )
  245.         )
  246.     )
  247.     )
  248. )
  249. )
  250. ;--- eof ---
  251.