CD-ROM Magazin 1995 November/CD_11_95.BIN/share95/tools/zipserv/zip_clnt.fr_/zip_clnt.fr

Text File | 1995-06-22 | 10KB | 240 lines

VERSION 2.00
Begin Form ZipClientForm
   Caption         =   "Zip Client"
   ClientHeight    =   6216
   ClientLeft      =   876
   ClientTop       =   1536
   ClientWidth     =   6420
   Height          =   6636
   Left            =   828
   LinkTopic       =   "Form1"
   ScaleHeight     =   6216
   ScaleWidth      =   6420
   Top             =   1164
   Width           =   6516
   Begin CommandButton btnDDLUnzip
      Caption         =   "DDL &Unzip"
      Height          =   396
      Left            =   4656
      TabIndex        =   3
      Top             =   3720
      Width           =   972
   End
   Begin CommandButton btnDDLZip
      Caption         =   "DDL &Zip"
      Height          =   396
      Left            =   624
      TabIndex        =   2
      Top             =   3708
      Width           =   972
   End
   Begin CommandButton DDETestButton
      Caption         =   "&DDE Test"
      Height          =   396
      Left            =   2052
      TabIndex        =   1
      Top             =   2952
      Width           =   2040
   End
   Begin Label DDELabel
      Alignment       =   2  'Center
      Caption         =   "Label1"
      Height          =   960
      Left            =   684
      TabIndex        =   0
      Top             =   720
      Visible         =   0   'False
      Width           =   5208
   End
End
Option Explicit

Sub btnDDLUnzip_Click ()
    'see the ZIPSERV.DLL Function declarations in ZIPSERV.VB module
    'always add ZIPSERV.VB to your module

    Dim x As Integer
    Dim ZipName As String
    Dim Destination As String
    Dim FileToUnZip As String
    Dim RestorePath As Integer
    Dim OverWrite As Integer
    Dim Password As String
    Dim WorkPath As String
    Dim ZipServerDLLPath As String
    Dim Comment$
    'lets give some values
    ZipName = "C:\SAMPLE.ZIP"       'in the sample we gave a directory that must exist on your computer
                                    'we used the same zipfile that we created with the 'DDL Zip' button
    Destination = "A:\"             'lets restore it on a floppy diskette
    FileToUnZip = "d*.*"            'all files in the Zipfile that starts with character 'd' will be restored
    RestorePath = True              'lets create the directories on the floppy
    OverWrite = True                'unless you used the same floppy the second time it has no effect
                                    'however using remote unzipping set it always True
    Password = "MYSELF"             'you must use the same password that you used at zipping!
    WorkPath = "C:\"                'we gave here a path that usually has read/write access
    ZipServerDLLPath = WinSysPath() 'In NetWare put a REM in front of this line
                                    'this is the standard place for ZIPSERV/DLL in the Single User Edfition
    '                               , but make sure it also has read/write access. If a Null string is
    '                               passed automatically the Window/System directory will be taken.
    '                               In the Network Edition a value must be passed, and the directory must
    '                               be on a Network drive, selected when ZipServer was installed. It is
    '                               recommended that to place ZipServerDLLPath value to the environ table
    '                               and retrieve it in applications with the Environ$(VariableName) function.
    '                               ZipError -102 will be returned if the path passed is incorrect or the licence is missing.
    'ZipServerDLLPath = Environ$("ZipServPath")  'In NetWare remove the REM

    Mousepointer = 11

    'we just used the existing label for display, it has nothing to do now with DDE
    DDELabel = GetZipComment(ZipName) + " This is a good example. Now, remote unzipping is in process."
    DDELabel.Visible = True
    DDELabel.ForeColor = QBColor(1)
    DDELabel.FontSize = 10
    'in a real application you might want to check here if there is a diskette in A drive
    'and it is ready for processing
    'put the Display ON
    DisplayProcess True
    x = Unzip(ZipName, Destination, FileToUnZip, RestorePath, OverWrite, Password, WorkPath, ZipServerDLLPath)
    'remove the display
    DisplayProcess False
    Mousepointer = 0
    If Not x = 0 Then
       MsgBox ZipError(x)
    End If
    DDELabel = ""
    DDELabel.Visible = False
End Sub

Sub btnDDLZip_Click ()
    'see the ZIPSERV.DLL Function declarations in ZIPSERV.VB module
    'always add ZIPSERV.VB to your module

    Dim x As Integer
    Dim ZipName As String
    Dim FileToZip As String
    Dim KeepDate As Integer
    Dim StorePath As Integer
    Dim Recurse As Integer
    Dim Password As String
    Dim WorkPath As String
    Dim ZipServerDLLPath As String
    Dim Comment$
    'lets give some values
    ZipName = "C:\SAMPLE.ZIP"       'in the sample we dave a directory that must exist on your computer
    FileToZip = "C:\WINDOWS\*.INI"  'this directory and wild carded files usually exist
    KeepDate = True                 'since it is not an update now this value does not matter
    StorePath = True                'lets store the path
    Recurse = True                  'it would able to recreate the windows subdirectories at unzipping
    Password = "MYSELF"             'you must use the same password at unzipping!
    WorkPath = "C:\"                'we gave here a path that usually has read/write access
    ZipServerDLLPath = WinSysPath() 'In NetWare put a REM in front of this line
                                    'this is the standard place for ZIPSERV/DLL in the Single User Edfition
    '                               , but make sure it also has read/write access. If a Null string is
    '                               passed automatically the Window/System directory will be taken.
    '                               In the Network Edition a value must be passed, and the directory must
    '                               be on a Network drive, selected when ZipServer was installed. It is
    '                               recommended that to place ZipServerDLLPath value to the environ table
    '                               and retrieve it in applications with the Environ$(VariableName) function.
    '                               ZipError -102 will be returned if the path passed is incorrect or the licence is missing.
    'ZipServerDLLPath = Environ$("ZipServPath")  'In NetWare remove the REM
    Comment$ = "ZipServer is the best available Windows utility for Zipping and Unzipping. It gives you much more power than any similar software."
    Mousepointer = 11

    'we just used the existing label for display, it has nothing to do now with DDE
    DDELabel.Visible = True
    DDELabel = "Remote Zipping is in process"
    'put the display On
    DisplayProcess True
    x = Zip(ZipName, FileToZip, KeepDate, StorePath, Recurse, Password, WorkPath, ZipServerDLLPath)
    'Remove the display
    DisplayProcess False
    Mousepointer = 0
    If x = 0 Then  'no error
       AddZipComment ZipName, Comment$
    Else
       MsgBox ZipError(x), 48
    End If
    DDELabel = ""
    DDELabel.Visible = False
End Sub

Sub DDETestButton_Click ()
    Dim DDEMessage$, start&, SourceApp$, SourceForm$, SourceControl$
    Dim x As Integer
    'Communicate with hidden Zip Server.
    SourceApp$ = "ZIPSERV"
    SourceForm$ = "ZipForm"
    SourceControl$ = "DDELabel"
    DDELabel.LinkTopic = SourceApp$ + "|" + SourceForm$
    DDELabel.LinkItem = SourceControl$
    On Error Resume Next
    DDELabel.LinkMode = 1'Automatic
    If Err Then
       Err = 0
       x = Shell("C:\ZIPSERV\ZIPSERV.EXE -1")
       DoEvents
       start& = Timer
       Do
          Err = 0
          DDELabel.LinkMode = 1
       Loop Until Err = 0 Or Timer - start& > 1
       If Err Then
          MsgBox IIf(x > 0, "Unable to establish connection with Zip Server. Zip Server was loaded and remained in memory.", "Unable to establish connection with Zip Server. Zip Server was not found.")
          End
       End If
    End If
    'give values here before calling ZipPass
    ZipInfo.ZipFile = "C:\ZIPDDE.ZIP"
    ZipInfo.Task = 0
    ZipInfo.Destination = ""
    ZipInfo.FilesToZip = "C:\DOS\*.COM"
    ZipInfo.KeepDate = True
    ZipInfo.OverWrite = False
    ZipInfo.StorePath = True
    ZipInfo.Recursive = True
    ZipInfo.RestorePath = True
    ZipInfo.Comment = "Sample ZIP file by ZipServer"
    ZipInfo.Password = "REDEI"
    DDEMessage$ = ZipPass$()
    Mousepointer = 11
    SendDDE DDEMessage$
    start& = Timer
    Do
       DoEvents
    Loop Until (DDELabel.Caption = "-1") Or Timer - start& > 60
    DDELabel.Visible = True
    Mousepointer = 0
    DoEvents
    'To terminate the DDE server, send nothing:
    MsgBox "Zip Server will be removed from memory."  'REM out to bypass it
    SendDDE ""
    DDELabel.LinkMode = 0' None
End Sub

Sub Form_Load ()
    Dim x As Integer
    Dim OurDrive$
    'before the first call to the ZIPSERV.DDL we have to change the
    'drive to the one where the ZIPSERV.DDL resides
    OurDrive$ = HomeDrive$()
    ChDrive OurDrive$
    'now make a call to ZIPSERV.DDL, just for loading it into memory
    x = DriveType(Left$(OurDrive$, 1))
End Sub

Sub SendDDE (DDEInstruction$)
    'Send and receive DDE commands/results to/from the
    'hidden DDE Zip server, using the local DDE Label control
    DDELabel.Caption = UCase$(DDEInstruction$)
    DDELabel.LinkPoke
    DoEvents
    If Not UCase$(DDEInstruction$) = "" Then     'Unload server
       DDELabel.LinkRequest
       If Not DDELabel.Caption = "-1" Then '"-1" successful execution
          MsgBox "Zip Server's Response: " + DDELabel.Caption
       End If
    End If
End Sub