home *** CD-ROM | disk | FTP | other *** search
/ ARM Club 3 / TheARMClub_PDCD3.iso / hensa / programming / gamesuite_1 / GameSuite / Sources / Amnesia / AmSource
Encoding:
Text File  |  1995-08-24  |  53.5 KB  |  3,047 lines
  1.  
  2. #name Amnesia
  3. #type &ffa
  4. #base 0
  5.  
  6. #set Service_Amnesia=&80320
  7.  
  8. #set errorlim    = 100
  9. #set def_tables = 32
  10.  
  11. #set coordshift = 12
  12.  
  13. #set remoteID=&006E0000 ;must be present before a remote routine
  14.  
  15. #set BF_static        = 1
  16. #set BF_qwa        = 1<<1
  17. #set BF_intoff        = 1<<2
  18.  
  19. #set A_type_tidy    = 0
  20. #set A_type_messy    = 1
  21. #set A_type_static    = 2
  22.  
  23. #set R_skip_advance    = 1
  24. #set R_tst        = 1<<1
  25. #set R_alive        = 1<<31
  26.  
  27. #set PF_advance        = 1<<23
  28. #set PF_plot        = 1<<22
  29. #set PF_process        = 1<<21
  30.  
  31. #set Amf_plot        = 1<<0
  32. #set Amf_user_plot    = 1<<1
  33. #set Amf_velocity    = 1<<2
  34. #set Amf_gravity    = 1<<3
  35. #set Amf_use_plot_ofs    = 1<<4
  36. #set Amf_anim        = 1<<5
  37. #set Amf_make_objsize    = 1<<6
  38. #set Amf_colch        = 1<<7
  39. #set Amf_attn_timer    = 1<<8
  40. #set Amf_dest_timer    = 1<<9
  41. #set Amf_attn        = 1<<10
  42. #set Amf_timer2        = 1<<11
  43. #set Amf_zero_vec    = 1<<12
  44. #set Amf_game_horiz    = 1<<13
  45. #set Amf_game_vert    = 1<<14
  46. #set Amf_plot_window    = 1<<15
  47. #set Amf_kill_window    = 1<<16
  48. #set Amf_colch_window    = 1<<17
  49. #set Amf_save        = 1<<18
  50. #set Amf_remote        = 1<<19
  51. #set Amf_noleft        = 1<<20
  52. #set Amf_noright    = 1<<21
  53. #set Amf_noup        = 1<<22
  54. #set Amf_nodown        = 1<<23
  55.  
  56.  
  57. #set Amf_attn_mask    = &FF<<24
  58.  
  59. #set Amf_imask  = Amf_plot + Amf_velocity + Amf_gravity + Amf_use_plot_ofs + Amf_anim + Amf_make_objsize + Amf_colch + Amf_dest_timer + Amf_zero_vec + Amf_plot_window + Amf_save + Amf_colch_window + Amf_timer2 + Amf_remote
  60.  
  61. ;imask are the events which are never returned to the user
  62.  
  63. struct v {
  64.   .areastart    DCD 0
  65.   .areatype    DCD 0
  66.   .areasize    DCD 0
  67.   .gamewindow    DBD 4; 4 words
  68.   .plotwindow    DBD 4; 4 words
  69.   .killwindow    DBD 4; 4 words
  70.   .plotxofs     DCD 0
  71.   .plotyofs    DCD 0
  72.   .gravx    DCD 0
  73.   .gravy    DCD 0
  74.   .colch0    DCD 0
  75.   .colch1    DCD 0
  76.   .colch3    DCD 0
  77.   .colchsave    DBD 4; 4 words - save area for colch regs
  78.   .colchboxes    DBD 8; 8 words - store area for bounding boxes
  79.   .errorctr    DCD 0
  80.   .errorblock   DCD 0
  81.   .errortable   DCD 0
  82.   .remote    DCD 0
  83.   .remoteR12    DCD 0
  84.   .buffer     DBD 16 ; 16 words
  85.   .temp0      DCD 0
  86.   .temp1      DCD 0
  87.   .temp2      DCD 0
  88.   .sizeof
  89. }
  90.  
  91. struct b {
  92.   .id        DCD 0
  93.   .ptr      DCD 0
  94.   .name        DBB 8 ; 8 bytes
  95.   .size        DCD 0
  96.   .flags    DCD 0
  97.   .sizeof
  98. }
  99.  
  100. struct t {
  101.   .id        DCD 0
  102.   .ptr         DCD 0
  103.   .name        DBB 8 ; 8 bytes
  104.   .size        DCD 0
  105.   .flags    DCD 0
  106.   .objsize    DCD 0
  107.   .number    DCD 0
  108.   .tabflags    DCD 0
  109.   .next        DCD 0
  110.   .sizeof
  111. }
  112.  
  113. struct save {
  114.   .id        DCD 0
  115.   .name        DBB 8 ; 8 bytes
  116.   .objsize    DCD 0
  117.   .number    DCD 0
  118.   .gap        DCD 0
  119.   .sizeof
  120. }
  121.  
  122. struct h {
  123.   .id        DCD 0
  124.   .ptr        DCD 0
  125.   .name        DBB 8 ; 8 bytes
  126.   .size        DCD 0
  127.   .flags    DCD 0
  128.   .type        DCD 0
  129.   .areasize    DCD 0
  130.   .tlist    DCD 0
  131.   .sizeof
  132. }
  133.  
  134. struct o {
  135.   .type        DCD 0
  136.   .flags    DCD 0
  137.   .x        DCD 0
  138.   .y        DCD 0
  139.   .xvec        DCD 0
  140.   .yvec        DCD 0
  141.   .timer    DCD 0
  142.   .size        DCD 0
  143.   .timer2    DCD 0
  144.   .sizeof
  145. }
  146.  
  147. struct c {    
  148.   .id        DCD 0
  149.   .ptr        DCD 0
  150.   .name        DBB 8 ; 8 bytes
  151.   .size        DCD 0
  152.   .flags    DCD 0
  153.   .writeofs    DCD 0
  154.   .sizeof
  155. }
  156.   
  157. struct cent {
  158.   .ofs        DCD 0
  159.   .minx         DCD 0
  160.   .miny         DCD 0
  161.   .maxx         DCD 0
  162.   .maxy         DCD 0
  163.   .sizeof
  164. } 
  165.   
  166. struct tlist {
  167.   .number    DCD 0
  168.   .sizeof
  169. }
  170. .start
  171. DCD 0
  172. DCD init
  173. DCD final
  174. DCD service
  175. DCD title
  176. DCD help
  177. DCD commandtable
  178. DCD &49600
  179. DCD swicode
  180. DCD switab
  181. DCD 0
  182.  
  183. .title
  184. DCB "Amnesia"
  185. DCB 0
  186. .help
  187. DCB "Amnesia        1.50 (20 Apr 1995)"
  188. DCB 0
  189. ALIGN
  190. .commandtable
  191. DCB "Amnesia",0
  192. ALIGN
  193. DCD 0
  194. DCD 0
  195. DCD 0
  196. DCD amnesiahelp
  197.  
  198. DCB "Amnesia"
  199. DCB 0
  200. ALIGN
  201. DCD amscode
  202. DCD &000cff01
  203. DCD amssyntax
  204. DCD amshelp
  205.  
  206. DCB "AmnesiaFlags",0
  207. ALIGN
  208. DCD 0
  209. DCD 0
  210. DCD 0
  211. DCD flagshelp
  212. DCB "AmnesiaObjects",0
  213. ALIGN
  214. DCD 0
  215. DCD 0
  216. DCD 0
  217. DCD objectshelp
  218. DCB "AmnesiaSWIs",0
  219. ALIGN
  220. DCD 0
  221. DCD 0
  222. DCD 0
  223. DCD swishelp
  224.  
  225. DCD 0; *** END MARKER ***
  226.  
  227. .amnesiahelp
  228. DCB 27,0," is a module which provides memory allocation functions and handling routines for on-screen objects in a versatile form.  See the help files in the ",27,0," application for details.",10,13
  229. DCB "Copyright A.Southgate 1994 - may be used and distributed freely.",10,13
  230. DCB "Amnesia was written and is maintained by Andy Southgate - permanent address 5 Longview, Sutton, Cambs.",10,13
  231. DCB 0
  232. .amshelp
  233. DCB 27,0," issues an Amnesia SWI from the command line.  Its mainly used by me for testing.  The SWI tail means the letters after Amnesia_ .  If TO is appended register results are returned.  String parameters should be entered in SINGLE quotes ('These ones')",10,13
  234. .amssyntax
  235. DCB "Syntax : *Amnesia <SWI tail> [<R0> [<R1> [<R2> .... <R9>]]] [TO]",10,13
  236. DCB "Example: *Amnesia ClaimBlock 0 &800 'Aliens' 2_1101",0
  237. .flagshelp
  238. DCB "Amnesia area types area",10,13
  239. DCB "0 - Tidy mode",10,13
  240. DCB "1 - Messy mode",10,13
  241. DCB "2 - Static mode",10,13
  242. DCB "Amnesia block flags are (bit - action)",10,13
  243. DCB "0 - Block is static - must not be moved",10,13
  244. DCB "1 - Quad word align block",10,13
  245. DCB "2 - Disable interrupts while moving block",10,13
  246. DCB "Amnesia table flags are (bit - action)",10,13
  247. DCB "0 - Objects require collision checking facilities",10,13
  248.  
  249. DCB "Amnesia object flags are (bit - action)",10,13
  250. DCB "0 - FastSpr plot",10,13
  251. DCB "1 - User plot",10,13
  252. DCB "2 - Use velocity",10,13
  253. DCB "3 - Apply Gravity",10,13
  254. DCB "4 - Use plot offsets",10,13
  255. DCB "5 - Use timer for FastSpr animation",10,13
  256. DCB "6 - Make up the object size (from FastSpr file)",10,13
  257. DCB "7 - Collison check object",10,13
  258. DCB "8 - Generate attention request if timer expires",10,13
  259. DCB "9 - Destroy object if timer expires",10,13
  260. DCB "10 - Request attention always",10,13
  261. DCB "11 - Run timer 2",10,13
  262. DCB "12 - Zero velocity (and this bit) after first addition",10,13
  263. DCB "13 - Attention if outside game window (horizontal)",10,13
  264. DCB "14 - Attention if outside game window (vertical)",10,13
  265. DCB "15 - Use plot window",10,13
  266. DCB "16 - Use kill window",10,13
  267. DCB "17 - Add to the collision checking table only if object inside plot window",10,13
  268. DCB "18 - Object needs saving by Amnesia_TableSave",10,13
  269. DCB "19 - reserved",10,13
  270. DCB "Bits 20-23 are transient flags for the user.  They are zeroed on each process pass",10,13
  271. DCB "Bits 24-31 are the user attention trigger bits.  If a user attention request bit is set when calling Amnesia_SelectTable, then all of the objects with that bit set in their flags will return for attention.",10,13
  272.  
  273. DCB 0
  274. .objectshelp
  275. DCB "The structure of an amnesia object is as follows :",10,13
  276. DCB "base+0",9,"The object type.  If this is zero the object is ignored.  This number is passed to FastSpr as a sprite number when requested.",10,13
  277. DCB "base+4",9,"The flag word (see AmnesiaFlags)",10,13
  278. DCB "base+8",9,"The x coordinate (pixels per process pass << 12)",10,13
  279. DCB "base+12",9,"The y coordinate",10,13
  280. DCB "base+16",9,"The x velocity (added to the x coord every process pass",10,13
  281. DCB "base+20",9,"The y velocity",10,13
  282. DCB "base+24",9,"The timer.  Amnesia performs a SUB R0,R0,R0,LSL #16 to this value on each process pass",10,13
  283. DCB "base+28",9,"The object size [x size][y size] in pixels, 16 bit values",10,13
  284. DCB "base+32",9,"The second timer",10,13
  285. DCB "Only the first two entries are always required.  The rest may be required depending on the settings of the flag word",10,13
  286. DCB 0
  287.  
  288. .swishelp
  289. DCB "Amnesia supports the following SWIs.",10,13,10,13
  290. DCB 34,"Amnesia_Init",34,",start_address,size,area_type",10,13
  291. DCB 34,"Amnesia_ClaimBlock",34,",ptr_address,size,name,block_flags",10,13
  292. DCB 34,"Amnesia_ReleaseBlock",34,",block_address",10,13
  293. DCB 34,"Amnesia_ExtendBlock",34,",ptr_address,length",10,13
  294. DCB 34,"Amnesia_DescribeBlock",34,",block_address or block_number TO block_address,size,data_start,data_size,name,ptr_address,block_flags",10,13
  295. DCB 34,"Amnesia_ClaimTable",34,",table_number,table_flags,name,number_of_objects,object_size",10,13
  296. DCB 34,"Amnesia_ReleaseTable",34,",table_number",10,13
  297. DCB 34,"Amnesia_ExtendTable",34,",table_number,,number_of_objects",10,13
  298. DCB 34,"Amnesia_WipeTable",34,",table_number",10,13
  299. DCB 34,"Amnesia_CountObjects",34,",table_number TO number_of_objects",10,13
  300.  
  301. DCB 34,"Amnesia_Tidy",34,"",10,13
  302. DCB 34,"Amnesia_MakeObject",34,",table_number,object parameters in R1-R8",10,13
  303. DCB 34,"Amnesia_MakeObjectSpace",34,",table_number TO ,object_address",10,13
  304. DCB 34,"Amnesia_SelectTable",34,",table_number,process_type,plot TO R0,R1,R2",10,13
  305. DCB 34,"Amnesia_ProcessTable",34,",R0,R1,R2 (from above) TO R0,obj_address,reason code",10,13
  306. DCB 34,"Amnesia_DeleteObject",34,",,obj_address",10,13
  307. DCB 34,"Amnesia_SetWindow",34,",window_number,min_x,min_y,max_x,max_y",10,13
  308. DCB 34,"Amnesia_ReadWindow",34,",window_number TO ,min_x,min_y,max_x,max_y",10,13
  309. DCB 34,"Amnesia_SetPlotOffset",34,",x,y",10,13
  310. DCB 34,"Amnesia_ReadPlotOffset",34," TO x,y",10,13
  311. DCB 34,"Amnesia_CollisionCheck",34,",table_number,table_number TO object_address,object_address,R2,R3",10,13
  312. DCB 34,"Amnesia_GetColchBoxes",34," TO minx1,miny1,maxx1,maxy1,minx2,miny2,maxx2,maxy2",10,13
  313.  
  314. DCB 34,"Amnesia_LoadFile",34,",ptr_address,filename,pathname",10,13
  315. DCB 34,"Amnesia_SaveFile",34,",block_address,filename,filetype",10,13
  316. DCB 34,"Amnesia_LoadTable",34,",table_number,filename,pathname",10,13
  317. DCB 34,"Amnesia_SaveTable",34,",table_number,filename",10,13
  318. DCB 34,"Amnesia_GetTableAddress",34,",table_number TO table_address",10,13
  319. DCB 34,"Amnesia_Blocks",34,10,13
  320. DCB 0
  321.  
  322. ALIGN
  323. .r12temp
  324. DCD 0
  325. .amscode
  326. STMFD R13!,{R7-R11,R14}
  327. STR R12,r12temp
  328. LDR R12,[R12]
  329. ADR R3,switails
  330. STR R0,[R12,#v.temp0]  ;command tail
  331. STR R1,[R12,#v.temp1]  ;number of parms
  332. MOV R0,#0
  333. STR R0,[R12,#v.temp2]
  334. MOV R9,#0; swi name table entry counter
  335. .loop9
  336. LDR R2,[R12,#v.temp0]
  337.  
  338. ._loop
  339. LDRB R0,[R2]
  340. CMP R0,#" "
  341. ADDEQ R2,R2,#1
  342. BEQ _loop
  343. ._loop
  344. LDRB R0,[R2],#1
  345.  
  346. CMP R0,#"."
  347. BEQ amsfounddot
  348. CMP R0,#32
  349. BLE amsspace
  350. BIC R0,R0,#32
  351. LDRB R1,[R3],#1
  352. BIC R1,R1,#32
  353. CMP R1,R0
  354. BEQ _loop
  355. ._loop
  356. LDRB R1,[R3],#1
  357. CMP R1,#0
  358. BNE _loop
  359. LDRB R1,[R3]
  360. CMP R1,#0
  361. BEQ amsnomatch
  362. ADD R9,R9,#1
  363. .amsskip
  364. B loop9
  365. .amsspace
  366. LDRB R1,[R3]
  367. CMP R1,#0
  368. BEQ amsfound
  369. B amsskip
  370. .amsnomatch
  371. LDMFD R13!,{R7-R11,R14}
  372.  
  373. B amsnomatcherr
  374. .amsfounddot
  375. LDR R4,[R12,#v.temp1]; number of parms
  376. LDRB R0,[R2]
  377. CMP R0,#" "
  378. CMPNE R0,#&0D; end marker
  379. ADDNE R4,R4,#1
  380. STR R4,[R12,#v.temp1]
  381. B amsfound
  382.  
  383. .amsfound
  384. STR R2,[R12,#v.temp0]
  385. ADD R10,R12,#v.buffer
  386. MOV R1,#10
  387. MOV R0,#0;clear buffer
  388.  
  389. ._loop
  390. STR R0,[R10],#4
  391. SUBS R1,R1,#1
  392. BGT _loop
  393.  
  394. LDR R1,[R12,#v.temp0]; command string
  395. LDR R4,[R12,#v.temp1]; number of parms
  396. ADD R10,R12,#v.buffer;write address
  397. .loop3
  398. CMP R4,#1
  399. BLE amsreaddone
  400. .loop4
  401. LDRB R3,[R1]
  402. CMP R3,#"T"
  403. CMPNE R3,#"t"
  404. BEQ amsto
  405. CMP R3,#" "
  406. ADDEQ R1,R1,#1
  407. BEQ loop4
  408. CMP R3,#"'"; quotes character
  409. BEQ amsstring
  410. MOV R0,#&8000000A
  411. SWI XOS_ReadUnsigned
  412. BVS badnumber
  413. STR R2,[R10],#4
  414. .amsstringins
  415. SUB R4,R4,#1
  416. B loop3
  417. .amsstring
  418. STR R1,[R10],#4
  419. ADD R1,R1,#1
  420. ._loop
  421. LDRB R3,[R1]
  422. CMP R3,#32
  423. BLT amsstringins
  424. ADD R1,R1,#1
  425. CMP R3,#"'"; quotes
  426. BNE _loop
  427. B amsstringins
  428.  
  429. .amsreaddone
  430. MOV R11,R9; set swi modulo
  431. ADD R10,R12,#v.buffer
  432. LDMIA R10,{R0-R9}
  433. LDR R12,r12temp
  434. BL swicode
  435.  
  436. MOV R10,PC
  437. STMFD R13!,{PC}
  438. LDR R12,r12temp
  439. LDR R12,[R12]
  440. LDR R11,[R12,#v.temp2]
  441. CMP R11,#1
  442. BLEQ showregs
  443. LDMFD R13!,{R10}
  444. TEQP PC,R10
  445. LDMFD R13!,{R7-R11,PC}
  446.  
  447. .amsto
  448. MOV R0,#1
  449. STR R0,[R12,#v.temp2]
  450. B amsreaddone
  451.  
  452.  
  453. .showregs
  454. STMFD R13!,{R0,R14}
  455. STMFD R13!,{R10}
  456. ADD R10,R12,#v.buffer
  457. STMIA R10,{R0-R9}
  458. MOV R11,#0
  459. .loop5
  460. SWI 256+"R"
  461. ADD R0,R11,#"0"
  462. SWI OS_WriteC
  463. SWI OS_WriteS
  464. DCB "  = &",0
  465. ALIGN
  466. LDR R0,[R10],#4
  467. ADD R1,R12,#v.temp0
  468. MOV R2,#12
  469. SWI OS_ConvertHex8
  470. SWI OS_Write0
  471. SWI 256+" "
  472. CMP R11,#3
  473. CMPNE R11,#7
  474. SWIEQ OS_NewLine
  475. ADD R11,R11,#1
  476. CMP R11,#10
  477. BLT loop5
  478. SWI OS_NewLine
  479. LDMFD R13!,{R0}
  480. SWI OS_WriteS
  481. DCB "Mode ",0
  482. ALIGN
  483. AND R1,R0,#3
  484. CMP R1,#3
  485. SWIEQ 256+"S"
  486. SWIEQ 256+"V"
  487. SWIEQ 256+"C"
  488. CMP R1,#0
  489. SWIEQ 256+"U"
  490. SWIEQ 256+"S"
  491. SWIEQ 256+"R"
  492. SWI OS_WriteS
  493. DCB " flags set: ",0
  494. ALIGN
  495. TST R0,#1<<31
  496. SWIEQ 256+"n"
  497. SWINE 256+"N"
  498. TST R0,#1<<30
  499. SWIEQ 256+"z"
  500. SWINE 256+"Z"
  501. TST R0,#1<<29
  502. SWIEQ 256+"c"
  503. SWINE 256+"C"
  504. TST R0,#1<<28
  505. SWIEQ 256+"v"
  506. SWINE 256+"V"
  507. TST R0,#1<<27
  508. SWIEQ 256+"i"
  509. SWINE 256+"I"
  510. TST R0,#1<<26
  511. SWIEQ 256+"f"
  512. SWINE 256+"F"
  513. SWI OS_NewLine
  514. LDMFD R13!,{R0,PC}
  515.  
  516. .tidystr
  517. DCB "Tidy",0
  518. .messystr
  519. DCB "Messy",0
  520. .staticstr
  521. DCB "Static",0
  522. .unknownstr
  523. DCB "*Unknown*",0
  524. ALIGN
  525.  
  526. .blocksswi
  527. STMFD R13!,{R1-R9,R14}
  528. LDR R11,[R12,#v.areastart]
  529. MOV R0,#0
  530. STR R0,[R12,#v.errorctr]
  531.  
  532. SWI OS_WriteS
  533. DCB "Amnesia area - type : ",0
  534. ALIGN
  535. LDR R1,[R12,#v.areatype]
  536. AND R1,R1,#&FF
  537. ADR R0,unknownstr
  538. CMP R1,#A_type_tidy
  539. ADREQ R0,tidystr
  540. CMP R1,#A_type_messy
  541. ADREQ R0,messystr
  542. CMP R1,#A_type_static
  543. ADREQ R0,staticstr
  544. SWI OS_Write0
  545. SWI OS_WriteS
  546. DCB ".",10,13,"Address ",0
  547. ALIGN
  548.  
  549. MOV R0,R11
  550. BL writehex
  551. MOV R0,R11
  552. MOV R1,R0
  553. SWI OS_ValidateAddress
  554. LDMCSFD R13!,{R1-R9,R14}
  555. BCS badareaerr
  556.  
  557. SWI OS_WriteS
  558. DCB ", size ",0
  559. ALIGN
  560. LDR R0,[R11,#h.areasize]
  561. BL writehex
  562. CMP R0,#24
  563. LDMLTFD R13!,{R1-R9,R14}
  564. BLT badareaerr
  565.  
  566. MOV R0,R11
  567. LDR R1,[R11,#h.areasize]
  568. ADD R1,R0,R1
  569. SWI OS_ValidateAddress
  570. LDMCSFD R13!,{R1-R9,R14}
  571. BCS badareaerr
  572. SWI OS_WriteS
  573. DCB ", free ",0
  574. ALIGN
  575. BL getfreespace
  576. BLVS blocksbadfree
  577. BLVC writehex
  578. SWI OS_WriteS
  579. DCB ", available ",0
  580. ALIGN
  581. BL getavailablespace
  582. BLVS blocksbadfree
  583. BLVC writehex
  584. SWI OS_WriteS
  585. DCB ".",10,13,10,0
  586. ALIGN
  587. LDR R0,[R11,#h.areasize]
  588. ADD R11,R11,R0;point to end of block
  589.  
  590. MOV R8,#0
  591. .loop7
  592. SUB R10,R11,#8
  593. ._loop
  594. LDR R9,[R10],#-4
  595. CMP R9,#0
  596. BEQ _loop
  597. LDR R10,[R11,#-4]!
  598. CMP R10,#-1
  599. BEQ amsblocksend
  600. CMP R10,#0
  601. BLEQ noblockinfo
  602. BL blockinfo
  603. LDMVSFD R13!,{R1-R9,R14}
  604. BVS err
  605. .noblockinfo
  606. ADD R8,R8,#1
  607. LDR R0,[R12,#v.errorctr]
  608. CMP R0,#errorlim
  609. LDMGTFD R13!,{R1-R9,R14}
  610. BGT toomanyerr
  611. SWI OS_ReadEscapeState
  612. BCC loop7
  613. .amsblocksend
  614. LDR R0,[R12,#v.errortable]
  615. CMP R0,#-1
  616. BLNE printerrortable
  617. LDR R0,[R12,#v.errorblock]
  618. CMP R0,#-1
  619. BLNE printerrorblock
  620.  
  621. LDMFD R13!,{R1-R9,PC}
  622.  
  623. .printerrorblock
  624. STMFD R13!,{R14}
  625. SWI OS_WriteS
  626. DCB "Error occurred during attempt to access block at ",0
  627. ALIGN
  628. LDR R0,[R12,#v.errorblock]
  629. BL writehex
  630. SWI OS_WriteS
  631. DCB ".",10,13,0
  632. ALIGN
  633. MOV R0,#-1
  634. STR R0,[R12,#v.errorblock]
  635. LDMFD R13!,{PC}
  636.  
  637.  
  638.  
  639. .printerrortable
  640. STMFD R13!,{R14}
  641. SWI OS_WriteS
  642. DCB "Error occurred during access to table number ",0
  643. ALIGN
  644. LDR R0,[R12,#v.errortable]
  645. BIC R0,R0,#&FFFF<<16
  646. ADD R1,R12,#v.buffer
  647. MOV R2,#16
  648. SWI OS_ConvertCardinal4
  649. SWI OS_Write0
  650. SWI OS_WriteS
  651. DCB ".",10,13,0
  652. ALIGN
  653. MOV R0,#-1
  654. STR R0,[R12,#v.errortable]
  655. LDMFD R13!,{PC}
  656.  
  657. .blockstr
  658. DCB "Block  ",0
  659. .tablestr
  660. DCB "TBlock ",0
  661. ALIGN
  662.  
  663.  
  664. .blockinfo
  665. STMFD R13!,{R8-R11,R14}
  666. MOV R0,R8
  667. BL describeblockswi
  668. BVS blockinfoerr
  669. .blockinfoerrins
  670. STMFD R13!,{R0-R3}
  671. ADR R0,blockstr
  672. TST R6,#1<<31
  673. ADRNE R0,tablestr
  674. SWI OS_Write0
  675. MOV R0,R8
  676. ADD R1,R12,#v.temp0
  677. MOV R2,#12
  678. SWI OS_ConvertCardinal2
  679. SWI OS_Write0
  680. CMP R8,#10
  681. SWILT 256+" "
  682. CMP R8,#100
  683. SWILT 256+" "
  684. SWI OS_WriteS
  685. DCB "-",0
  686. ALIGN
  687. MOV R3,#8
  688. MOV R1,R4
  689. .loop8
  690. LDRB R0,[R1],#1
  691. CMP R0,#0
  692. MOVEQ R0,#32
  693. CMP R0,#32
  694. MOVLT R0,#"."
  695. SWI OS_WriteC
  696. SUBS R3,R3,#1
  697. BGT loop8
  698. LDMFD R13!,{R0-R3}
  699. SWI OS_WriteS
  700. DCB " ",0
  701. ALIGN
  702. MOV R0,R0
  703. BL writehex
  704. ;SWI OS_WriteS
  705. ;DCB " size ",0
  706. ;ALIGN
  707. ;MOV R0,R1
  708. ;BL writehex
  709.  
  710. SWI OS_WriteS
  711. DCB " data ",0
  712. ALIGN
  713. MOV R0,R2
  714. BL writehex
  715. SWI OS_WriteS
  716. DCB " space ",0
  717. ALIGN
  718. MOV R0,R3
  719. BL writehex
  720. SWI OS_WriteS
  721. DCB " ptr ",0
  722. ALIGN
  723. MOV R0,R5
  724. BL writehex
  725. ;SWI OS_WriteS
  726. ;DCB " flg ",0
  727. ;ALIGN
  728. ;MOV R0,R6
  729. ;BL writehex
  730. SWI OS_NewLine
  731. BL integcheck
  732. .blockinfoskip
  733. LDMFD R13!,{R8-R11,PC}
  734.  
  735. .blockinfoerr
  736. SWI OS_WriteS
  737. DCB "*** Cannot find reference to next block - table list corrupt",13,10,0
  738. ALIGN
  739. BL errorinc
  740. B blockinfoskip
  741.  
  742. .integcheck
  743. STMFD R13!,{R14}
  744. LDR R0,[R10,#b.id]
  745. LDR R1,blockid
  746. CMP R0,R1
  747. BLNE noblockid
  748. LDR R0,[R10,#b.size]
  749. ADD R1,R10,R0
  750. CMP R9,#-1
  751. CMPNE R1,R9
  752. BLNE badblocktable
  753. LDMFD R13!,{PC}
  754.  
  755. .noblockid
  756. STMFD R13!,{R14}
  757. SWI OS_WriteS
  758. DCB "*** Block corrupt : guard word is ",0
  759. ALIGN
  760. BL writehex
  761. SWI OS_WriteS
  762. DCB ", should be ",0
  763. ALIGN
  764. MOV R0,R1
  765. BL writehex
  766. SWI OS_WriteS
  767. DCB 10,13,0
  768. ALIGN
  769. BL errorinc
  770. LDMFD R13!,{PC}
  771.  
  772. .badblocktable
  773. STMFD R13!,{R14}
  774. SWI OS_WriteS
  775. DCB "Gap    ",0
  776. ALIGN
  777. SUB R0,R9,R1
  778. CMP R0,#12
  779. BLE notgapintidy
  780. LDR R0,[R12,#v.areatype]
  781. AND R0,R0,#&FF
  782. CMP R0,#A_type_tidy
  783. BNE notgapintidy
  784. SWI OS_WriteS
  785. DCB " *** IN TIDY HEAP *** size ",0
  786. ALIGN
  787. .notgapintidy
  788. SUB R0,R9,R1
  789. BL writehex
  790. SWI OS_WriteS
  791. DCB " bytes. ",10,13,0
  792. ALIGN
  793. CMP R0,#0
  794. LDMGEFD R13!,{PC}
  795. SWI OS_WriteS
  796. DCB "*** Negative Gap - area corrupt",10,13,0
  797. ALIGN
  798. BL errorinc
  799.  
  800. LDMFD R13!,{PC}
  801.  
  802. .errorinc
  803. LDR R0,[R12,#v.errorctr]
  804. ADD R0,R0,#1
  805. STR R0,[R12,#v.errorctr]
  806. MOV PC,R14
  807.  
  808. .blocksbadfree
  809. STMFD R13!,{R14}
  810. SWI OS_WriteS
  811. DCB "*Unknown*",0
  812. ALIGN
  813. LDMFD R13!,{PC}^;keep flags
  814.  
  815.  
  816.  
  817.  
  818. .writehex
  819. STMFD R13!,{R0-R2,R14}
  820. SWI 256+"&"
  821. ADD R1,R12,#v.temp0
  822. MOV R2,#12
  823. SWI OS_ConvertHex8
  824. SWI OS_Write0
  825. LDMFD R13!,{R0-R2,PC}
  826.  
  827. .switab
  828. DCB "Amnesia",0
  829. .switails
  830. DCB "Init",0
  831. DCB "ClaimBlock",0
  832. DCB "ReleaseBlock",0
  833. DCB "ClaimTable",0
  834. DCB "ReleaseTable",0
  835. DCB "Tidy",0
  836. DCB "SelectTable",0
  837. DCB "ProcessTable",0
  838. DCB "CollisionCheck",0
  839. DCB "GetColchBoxes",0
  840. DCB "SetPlotOffset",0
  841. DCB "ReadPlotOffset",0
  842.  
  843. DCB "SetWindow",0
  844. DCB "ReadWindow",0
  845. DCB "MakeObject",0
  846. DCB "MakeObjectSpace",0
  847. DCB "DeleteObject",0
  848.  
  849. DCB "LoadFile",0
  850. DCB "SaveFile",0
  851. DCB "ExtendBlock",0
  852. DCB "ExtendTable",0
  853. DCB "WipeTable",0
  854. DCB "CountObjects",0
  855. DCB "SetGravity",0
  856. DCB "ReadGravity",0
  857. DCB "DescribeBlock",0
  858. DCB "Blocks",0
  859. DCB "SaveTable",0
  860. DCB "LoadTable",0
  861. DCB "GetTableAddress",0
  862. DCB "LoadHammered",0
  863. DCB "Remote",0
  864. DCB 0; *** END MARKER ***
  865. #set swis = 32
  866. ALIGN
  867.  
  868. .swicode
  869. CMP R11,#swis
  870. BGE badswino
  871. LDR R12,[R12]
  872. LDR R10,[R12,#v.areastart]
  873. CMP R10,#0
  874. BEQ swinostart
  875. .swinostartins
  876. ADR R10,swiofstab
  877. LDR R10,[R10,R11,LSL #2]
  878. ADR R11,swiofstab
  879. ADD PC,R10,R11
  880. .swiofstab
  881. DCD initswi         - swiofstab
  882. DCD claimblockswi     - swiofstab
  883. DCD releaseblockswi     - swiofstab
  884. DCD claimtableswi     - swiofstab
  885. DCD releasetableswi     - swiofstab
  886. DCD tidyswi         - swiofstab
  887. DCD selecttableswi     - swiofstab
  888. DCD processtableswi    - swiofstab
  889. DCD colchswi        - swiofstab
  890. DCD colchboxesswi    - swiofstab
  891. DCD setplotofsswi    - swiofstab
  892. DCD readplotofsswi    - swiofstab
  893. DCD setwindowswi    - swiofstab
  894. DCD readwindowswi    - swiofstab
  895. DCD makeobjectswi     - swiofstab
  896. DCD makeobjectspaceswi    - swiofstab
  897. DCD deleteobjectswi     - swiofstab
  898. DCD loadfileswi        - swiofstab
  899. DCD savefileswi        - swiofstab
  900. DCD extendblockswi    - swiofstab
  901. DCD notyeterr        - swiofstab
  902. DCD wipetabswi        - swiofstab
  903. DCD countobjectsswi     - swiofstab
  904. DCD setgravityswi    - swiofstab
  905. DCD readgravityswi    - swiofstab
  906. DCD describeblockswi     - swiofstab
  907. DCD blocksswi         - swiofstab
  908. DCD savetableswi    - swiofstab
  909. DCD loadtableswi    - swiofstab
  910. DCD gettableaddrswi    - swiofstab
  911. DCD loadhammeredswi    - swiofstab
  912. DCD remoteswi        - swiofstab
  913. .badswino
  914. B unknownswi
  915.  
  916. .swinostart
  917. CMP R11,#0
  918. BEQ swinostartins
  919. B notiniterr
  920.  
  921. .initswi
  922. STMFD R13!,{R1-R9,R14}
  923. BL discardarea
  924. BIC R0,R0,#3
  925. ADD R1,R1,#3
  926. BIC R1,R1,#3
  927. CMP R1,#0
  928. LDMEQFD R13!,{R1-R9,PC}
  929. CMP R1,#h.sizeof+8
  930. LDMLTFD R13!,{R1-R9,R14}
  931. BLT noroomerr
  932. STR R0,[R12,#v.areastart]
  933. STR R1,[R12,#v.areasize]
  934. STR R2,[R12,#v.areatype]
  935. CMP R0,#0
  936. BLEQ getarearma
  937. BVS noarearma
  938. LDR R0,[R12,#v.areastart]
  939. LDR R1,[R12,#v.areasize]
  940. CMP R0,#0
  941. CMP R1,#0
  942. BEQ badinitswi
  943. ADD R1,R0,R1
  944. SWI OS_ValidateAddress
  945. BCS badinitswi
  946. BL initarea
  947. MOV R0,#-1
  948. STR R0,[R12,#v.errortable]
  949. STR R0,[R12,#v.errorblock]
  950. BL maketlist
  951. LDMVSFD R13!,{R1-R9,R14}
  952. BVS err
  953. LDMFD R13!,{R1-R9,PC}
  954. .badinitswi
  955. MOV R0,#0
  956. STR R0,[R12,#v.areastart]
  957. LDMFD R13!,{R1-R9,R14}
  958. MOV R1,#0
  959. B badblockerr
  960. .noarearma
  961. MOV R0,#0
  962. STR R0,[R12,#v.areastart]
  963. LDMFD R13!,{R1-R9,R14}
  964. MOV R1,#0
  965. B noroomrmaerr
  966.  
  967. .blockid
  968. DCB "AmBl"
  969. ALIGN
  970.  
  971. .initarea
  972. STMFD R13!,{R14}
  973. LDR R10,[R12,#v.areastart]
  974. ADR R0,blockid
  975. LDR R0,[R0]
  976. STR R0,[R10,#h.id]
  977. MOV R0,#0
  978. STR R0,[R10,#h.tlist]
  979. STR R0,[R10,#h.ptr]
  980. MOV R0,#&40000000
  981. STR R0,[R10,#h.flags]
  982. LDR R0,[R12,#v.areatype]
  983. STR R0,[R10,#h.type]
  984. LDR R0,[R12,#v.areasize]
  985. STR R0,[R10,#h.areasize]
  986. MOV R0,#h.sizeof
  987. STR R0,[R10,#h.size]
  988. ADD R0,R10,#h.name
  989. ADR R1,areanamestr
  990. MOV R2,#8
  991. BL strncpy
  992. LDR R0,[R12,#v.areasize]
  993. LDR R1,[R12,#v.areastart]
  994. ADD R1,R0,R1
  995. MOV R0,R10
  996. STR R0,[R1,#-4]
  997. MVN R0,#0
  998. STR R0,[R1,#-8]
  999. MVN R0,#&7F000000
  1000. MOV R1,R0
  1001. MOV R2,#&7F000000
  1002. MOV R3,R0
  1003. ADD R4,R12,#v.gamewindow
  1004. STMIA R4!,{R0-R3}
  1005. STMIA R4!,{R0-R3}
  1006. STMIA R4!,{R0-R3}
  1007. LDMFD R13!,{PC}
  1008. .areanamestr
  1009. DCB "Header",0
  1010. ALIGN
  1011.  
  1012. .setwindowswi
  1013. STMFD R13!,{R0-R4,R14}
  1014. CMP R0,#2
  1015. LDMGTFD R13!,{R0-R4,R14}
  1016. BGT windownonerr
  1017. CMP R1,R3
  1018. CMPLE R2,R4
  1019. LDMGTFD R13!,{R0-R4,R14}
  1020. BGT windowdodgyerr
  1021. ADD R0,R12,R0,LSL #4
  1022. ADD R0,R0,#v.gamewindow
  1023. STMIA R0,{R1-R4}
  1024. LDMFD R13!,{R0-R4,PC}^
  1025.  
  1026. .readwindowswi
  1027. STMFD R13!,{R0,R14}
  1028. CMP R0,#2
  1029. LDMGTFD R13!,{R0,R14}
  1030. BGT windownonerr
  1031. ADD R0,R12,R0,LSL #4
  1032. ADD R0,R0,#v.gamewindow
  1033. LDMIA R0,{R1-R4}
  1034. LDMFD R13!,{R0,PC}^
  1035.  
  1036.  
  1037.  
  1038. .tidyswi
  1039. STMFD R13!,{R1-R9,R14}
  1040. MOV R5,#0    ;just do the pointers
  1041. BL tidyblocks
  1042. LDMVSFD R13!,{R1-R9,PC}
  1043. MOV R5,#1    ;now do the blocks
  1044. BL tidyblocks
  1045. LDMFD R13!,{R1-R9,PC}
  1046.  
  1047. .tidyblocks
  1048. STMFD R13!,{R14}
  1049. LDR R11,[R12,#v.areastart]
  1050. LDR R0,[R11,#h.areasize]
  1051. ADD R10,R11,R0 ;scan the blocks
  1052. MOV R6,R10; read from R10, write to R6
  1053. MOV R8,R11
  1054. .loop10
  1055. LDR R9,[R10,#-4]!
  1056. CMP R9,#0
  1057. BEQ loop10
  1058. SUB R6,R6,#4; writing to R6 removes zero entries from the
  1059.         ;block table
  1060. CMP R9,#-1
  1061. BEQ tidydone
  1062. CMP R8,R9
  1063. BGT tidyoverlap
  1064. LDR R4,[R9,#b.ptr]
  1065. CMP R4,#0
  1066. MOVEQ R8,R9; do not move if no pointer
  1067.  
  1068. LDR R4,[R9,#b.flags]
  1069. TST R4,#BF_static
  1070. MOVNE R8,R9; do not move if static
  1071. TST R4,#BF_qwa
  1072. BICNE R8,R8,#15
  1073. ADDNE R8,R8,#12  ;quad word align copy destination
  1074. CMP R8,R9
  1075. LDMGTFD R13!,{R14}
  1076. BGT qwaerr 
  1077.  
  1078. MOV R0,R8
  1079. MOV R1,R9
  1080. MOV R2,R5; update pointer or move flag
  1081. LDR R7,[R9,#b.size]
  1082. TST R4,#BF_intoff
  1083. CMPNE R5,#0; the real move
  1084. SWINE OS_IntOff
  1085. BL moveblock
  1086. LDMVSFD R13!,{PC}
  1087. TST R4,#BF_intoff
  1088. CMPNE R5,#0
  1089. SWINE OS_IntOn
  1090.  
  1091. CMP R5,#0
  1092. STRNE R8,[R6]; update the block table
  1093. ADD R8,R8,R7
  1094. B loop10
  1095. .tidydone
  1096. CMP R5,#0
  1097. MVN R0,#0
  1098. STRNE R0,[R6]
  1099. LDMFD R13!,{PC}
  1100.  
  1101. .tidyoverlap
  1102. LDMFD R13!,{R14}
  1103. B areacorrupterr
  1104.  
  1105. .moveblock
  1106. ; R0 = destination
  1107. ; R1 = address of entry in block table
  1108. ; R2 = update pointer(0) or move(1)
  1109.  
  1110. STMFD R13!,{R1-R9,R14}
  1111. LDR R4,blockid
  1112. LDR R5,[R1,#b.id]
  1113. CMP R5,R4
  1114. MOVNE R0,R1; for v.errorblock
  1115. LDMNEFD R13!,{R1-R9,R14}
  1116. BNE movenonblockerr
  1117. CMP R0,R1
  1118. LDMEQFD R13!,{R1-R9,PC}
  1119. LDR R4,[R1,#b.ptr]
  1120. LDR R5,[R4]
  1121. LDR R6,[R10]
  1122. ADD R6,R6,#b.sizeof;  The block table points to the start of the block
  1123.         ; whereas the user pointer points to the start of free space
  1124. CMP R5,R6
  1125. CMPNE R2,#1; do this test only on the first (R2=0) pass
  1126. BNE inconblock
  1127. ADD R6,R0,#b.sizeof
  1128. CMP R2,#0
  1129. STREQ R6,[R4]; replace the user pointer
  1130. LDMEQFD R13!,{R1-R9,PC}
  1131. LDR R2,[R1,#b.size]
  1132. .loop11
  1133. LDR R5,[R1],#4
  1134. STR R5,[R0],#4
  1135. SUBS R2,R2,#4
  1136. BGT loop11
  1137. LDMFD R13!,{R1-R9,PC}
  1138.  
  1139. .inconblock
  1140. STR R1,[R12,#v.errorblock]
  1141. LDMFD R13!,{R1-R9,R14}
  1142. B inconblockerr
  1143.  
  1144.  
  1145. .tlisttext
  1146. DCB "TableLst"
  1147. ALIGN
  1148.  
  1149. .maketlist
  1150. STMFD R13!,{R0-R3,R14}
  1151. MOV R0,#0
  1152. BL getblockaddr
  1153. LDMVSFD R13!,{R1-R4,PC};discard stacked R0-R3
  1154. MOV R11,R0
  1155. ADD R0,R11,#h.tlist
  1156. MOV R1,#tlist.sizeof+8*def_tables
  1157. ADR R2,tlisttext
  1158. MOV R3,#0
  1159. BL claimblockswi
  1160. LDMVSFD R13!,{R1-R4,R14}
  1161. BVS tlisterr
  1162. LDR R10,[R11,#h.tlist]
  1163. MOV R0,#def_tables
  1164. STR R0,[R10,#tlist.number]
  1165. LDMFD R13!,{R0-R3,PC}
  1166.  
  1167. .wipeblock
  1168. STMFD R13!,{R1-R2,R14}
  1169. LDR R1,[R0,#b.size]
  1170. ADD R0,R0,#b.sizeof
  1171. SUB R1,R1,#b.sizeof
  1172. MOV R2,#0
  1173. ._loop
  1174. STR R2,[R0],#4
  1175. SUBS R1,R1,#4
  1176. BGT _loop
  1177. LDMFD R13!,{R1-R2,PC}
  1178.  
  1179. .getblockaddr
  1180. STMFD R13!,{R1-R3,R14}
  1181. MOV R3,R0
  1182. LDR R1,[R12,#v.areastart]
  1183. LDR R2,[R12,#v.areasize]
  1184. ADD R1,R1,R2
  1185. ._loop
  1186. LDR R2,[R1,#-4]!
  1187. CMP R2,#-1
  1188. MOVEQ R0,R3
  1189. LDMEQFD R13!,{R1-R3,R14}
  1190. BEQ getblockerr
  1191. SUBS R0,R0,#1
  1192. BPL _loop
  1193. MOV R0,R2
  1194. LDMFD R13!,{R1-R3,PC}^
  1195.  
  1196. .claimtableswi
  1197. STMFD R13!,{R1-R10,R14}
  1198. MOV R6,R0
  1199. MOV R8,R1
  1200. MOV R7,R3
  1201. BL gettlistaddr
  1202. LDMVSFD R13!,{R1-R10,R14}
  1203. BVS err
  1204. MOV R10,R0
  1205. LDR R0,[R10]
  1206. CMP R0,#0
  1207. BEQ noprevtable
  1208. MOV R0,R6; original R0
  1209. BL releasetableswi
  1210. LDMVSFD R13!,{R1-R10,R14}
  1211. BVS err
  1212. .noprevtable
  1213. MOV R0,#0
  1214. STR R0,[R10,#4]; indicate no colch table
  1215. MUL R1,R3,R4
  1216. ADD R1,R1,#t.sizeof-b.sizeof
  1217.  
  1218. ;MOV R2,R2; name
  1219. MOV R3,#0
  1220. MOV R0,R10
  1221. BL claimblockswi
  1222. LDMVSFD R13!,{R1-R10,R14}
  1223. BVS err
  1224.  
  1225. SUB R9,R0,#b.sizeof
  1226. STR R8,[R9,#t.tabflags]; was R1
  1227. STR R7,[R9,#t.number]  ; was R3
  1228. STR R4,[R9,#t.objsize]
  1229. MOV R0,#0
  1230. STR R0,[R9,#t.next]
  1231. MOV R0,#&80000000
  1232. STR R0,[R9,#t.flags]
  1233. MOV R0,R7
  1234. TST R8,#1; is collision checking required?
  1235. BEQ noclaimcolch
  1236. BL claimcolchtab
  1237. LDMVSFD R13!,{R1-R10,PC}
  1238. .noclaimcolch
  1239. LDMFD R13!,{R1-R10,PC}^
  1240.  
  1241. .colchstr
  1242. DCB "ColChk",0,0
  1243. ALIGN
  1244.  
  1245. .claimcolchtab
  1246. STMFD R13!,{R8-R10,R14}
  1247. ADD R0,R12,#v.temp0
  1248. ADR R1,colchstr
  1249. LDMIA R1,{R2,R3}
  1250. STMIA R0,{R2,R3}
  1251. ADD R1,R0,#6
  1252. MOV R0,R6
  1253. MOV R2,#2
  1254. SWI XOS_ConvertCardinal1
  1255. CMP R0,R0; clear V
  1256. LDR R0,[R9,#t.number]
  1257. MOV R2,#cent.sizeof
  1258. MUL R1,R0,R2
  1259. ADD R1,R1,#c.sizeof - b.sizeof
  1260. ADD R0,R10,#4
  1261. ADD R2,R12,#v.temp0
  1262. MOV R3,#0
  1263. BL claimblockswi
  1264. LDMVSFD R13!,{R8-R10,PC}
  1265. LDR R8,[R10,#4]
  1266. SUB R8,R8,#b.sizeof
  1267. MOV R0,#c.sizeof
  1268. STR R0,[R8,#c.writeofs]
  1269. LDMFD R13!,{R8-R10,PC}^
  1270.  
  1271. .releasetableswi
  1272. STMFD R13!,{R10,R14}
  1273. BL gettlistaddr
  1274. LDMVSFD R13!,{R10,PC}
  1275. MOV R9,R0
  1276. LDR R0,[R0]
  1277. BL releaseblockswi
  1278. LDMVSFD R13!,{R10,PC}
  1279. LDR R0,[R9,#4]
  1280. CMP R0,#0
  1281. LDMEQFD R13!,{R10,PC}
  1282. BL releaseblockswi
  1283. LDMFD R13!,{R10,PC}; includes returning error
  1284.  
  1285. .wipetabswi
  1286. .wipetab
  1287. STMFD R13!,{R1-R5,R14}
  1288. BL gettableaddr
  1289. LDMVSFD R13!,{R1-R5,R14}
  1290. BVS err
  1291. SUB R0,R0,#b.sizeof
  1292. ADD R5,R0,#t.sizeof
  1293. LDR R3,[R0,#t.number]
  1294. LDR R4,[R0,#t.objsize]
  1295. MOV R1,#0
  1296. STR R1,[R0,#t.next]
  1297. MOV R0,#0
  1298.  
  1299. ._loop
  1300. STR R0,[R5],R4
  1301. SUBS R3,R3,#1
  1302. BGT _loop
  1303. LDMFD R13!,{R1-R5,PC}
  1304.  
  1305. .gettableaddrswi
  1306. .gettableaddr
  1307. STMFD R13!,{R1-R2,R14}
  1308. MOV R2,R0
  1309. BL gettlistaddr
  1310. LDMVSFD R13!,{R1-R2,PC}
  1311. LDR R1,[R0]
  1312. CMP R1,#0
  1313. MOVEQ R0,R2
  1314. LDMEQFD R13!,{R1-R2,R14}
  1315. BEQ notableerr
  1316. MOV R0,R1
  1317. LDMFD R13!,{R1-R2,PC}
  1318.  
  1319. .gettlistaddr
  1320. STMFD R13!,{R1-R2,R14}
  1321. BIC R0,R0,#&FF<<24
  1322. LDR R1,[R12,#v.areastart]
  1323. LDR R2,[R1,#h.tlist]
  1324. CMP R2,#0
  1325. LDMEQFD R13!,{R1-R2,R14}
  1326. BEQ notlisterr
  1327. LDR R1,[R2,#tlist.number]
  1328. CMP R0,#0
  1329. MOVLT R0,#&7F000000
  1330. CMP R0,R1
  1331. LDMGEFD R13!,{R1-R2,R14}
  1332. BGE tabletoohigherr
  1333. ADD R2,R2,#tlist.sizeof
  1334. ADD R0,R2,R0,LSL #3
  1335. LDMFD R13!,{R1-R2,PC}
  1336.  
  1337. .loadtableswi
  1338. STMFD R13!,{R1-R9,R14}
  1339. BL gettlistaddr
  1340. LDMVSFD R13!,{R1-R9,PC}
  1341. MOV R11,R0
  1342. LDR R11,[R11]
  1343. CMP R11,#0
  1344. LDMEQFD R13!,{R1-R9,R14}
  1345. BEQ notableerr
  1346. SUB R11,R11,#b.sizeof
  1347. LDR R9,[R11,#t.objsize]; table objsize
  1348. LDR R8,[R11,#t.number]
  1349. BL openloadfile
  1350. LDMVSFD R13!,{R1-R9,PC}
  1351. CMP R0,#0
  1352. LDMEQFD R13!,{R1-R9,R14}
  1353. MOVEQ R2,#0
  1354. BEQ notafileerr
  1355. MOV R7,R0; our file handle
  1356. MOV R0,#3
  1357. MOV R1,R7
  1358. ADD R10,R12,#v.buffer
  1359. MOV R2,R10
  1360. MOV R3,#save.sizeof
  1361. MOV R4,#0
  1362. SWI XOS_GBPB
  1363. LDMVSFD R13!,{R1-R9,PC}
  1364.  
  1365. LDR R6,[R10,#save.objsize]
  1366. CMP R6,R9
  1367. BLNE objsizewarn
  1368. ADD R0,R11,#t.name
  1369. ADD R1,R10,#save.name
  1370. LDMIA R0,{R2-R3}
  1371. LDMIA R1,{R4-R5}
  1372. CMP R2,R4
  1373. CMPEQ R3,R5
  1374. BLNE namematchwarn
  1375. LDR R5,[R10,#save.number]
  1376. ADD R10,R11,#t.sizeof
  1377. .loopg1
  1378. CMP R5,#0
  1379. BLE endloadtable
  1380. LDR R0,[R10]
  1381. CMP R0,#0
  1382. BNE loadtableskip
  1383. BL foundloadtable
  1384. LDMVSFD R13!,{R1-R9,PC}
  1385. .loadtableskip
  1386. ADD R10,R10,R9
  1387. SUBS R8,R8,#1
  1388. BGT loopg1
  1389. .endloadtable
  1390. BL closefile
  1391. MOV R0,R5
  1392. CMP R5,#0
  1393. LDMFD R13!,{R1-R9,R14}
  1394. BIC R14,R14,#1<<29; carry flag
  1395. ORRNE R14,R14,#1<<29
  1396. MOVS PC,R14
  1397.  
  1398. .foundloadtable
  1399. STMFD R13!,{R1-R6,R14}
  1400. MOV R0,#4
  1401. MOV R1,R7
  1402. MOV R2,R10
  1403. MOV R3,R6
  1404. SWI XOS_GBPB
  1405. SUB R5,R5,#1
  1406. LDMFD R13!,{R1-R6,PC}
  1407.  
  1408. .savetableswi
  1409. STMFD R13!,{R1-R9,R14}
  1410. BL gettlistaddr
  1411. LDMVSFD R13!,{R1-R9,PC}
  1412. MOV R11,R0
  1413. LDR R11,[R11]
  1414. CMP R11,#0
  1415. LDMEQFD R13!,{R1-R9,R14}
  1416. BEQ notableerr
  1417. SUB R11,R11,#b.sizeof
  1418. ADD R10,R11,#t.sizeof
  1419. LDR R9,[R11,#t.objsize]
  1420. LDR R8,[R11,#t.number]
  1421. MOV R6,#0
  1422. BL openfile
  1423. LDMVSFD R13!,{R1-R9,PC}
  1424. CMP R0,#0
  1425. LDMEQFD R13!,{R1-R9,PC}
  1426. BEQ badsaveerr
  1427. MOV R7,R0; our file handle
  1428. MOV R0,#18
  1429. MOV R2,#&FFD
  1430. SWI XOS_File
  1431. BLVS closefile
  1432. LDMVSFD R13!,{R1-R9,PC}
  1433. BL makesavetablehdr
  1434. BLVS closefile
  1435. LDMVSFD R13!,{R1-R9,PC}
  1436. .loopg0
  1437. LDR R0,[R10]
  1438. CMP R0,#0
  1439. BEQ dontsave
  1440. LDR R0,[R10,#o.flags]
  1441. TST R0,#Amf_save
  1442. BEQ dontsave ;Don't save if this bit is clear
  1443. MOV R0,#2
  1444. MOV R1,R7
  1445. MOV R2,R10
  1446. LDR R3,[R11,#t.objsize]
  1447. SWI XOS_GBPB
  1448. BLVS closefile
  1449. LDMVSFD R13!,{R1-R9,PC}
  1450. ADD R6,R6,#1
  1451. .dontsave
  1452. LDR R0,[R11,#t.objsize]
  1453. ADD R10,R10,R0
  1454. SUBS R8,R8,#1
  1455. BGT loopg0
  1456. STR R6,[R12,#v.temp0]
  1457. MOV R0,#1
  1458. MOV R1,R7
  1459. ADD R2,R12,#v.temp0
  1460. MOV R3,#4
  1461. MOV R4,#save.number
  1462. SWI XOS_GBPB
  1463. BLVS closefile
  1464. LDMVSFD R13!,{PC}
  1465. BL closefile
  1466. LDMFD R13!,{R1-R9,PC}
  1467.  
  1468. .openloadfile
  1469. STMFD R13!,{R1-R3,R14}
  1470. MOV R0,#&46
  1471. CMP R2,#0
  1472. MOVEQ R0,#&44
  1473. SWI XOS_Find
  1474. LDMFD R13!,{R1-R3,PC}
  1475.  
  1476. .openfile
  1477. STMFD R13!,{R1-R3,R14}
  1478. MOV R0,#&80
  1479. SWI XOS_Find
  1480. LDMFD R13!,{R1-R3,PC}
  1481.  
  1482. .closefile
  1483. STMFD R13!,{R0-R3,R14}
  1484. MOV R0,#&0
  1485. MOV R1,R7
  1486. SWI XOS_Find
  1487. LDMFD R13!,{R0-R3,PC}^
  1488.  
  1489. .savetableid
  1490. DCB "AmTb"
  1491. ALIGN
  1492. .makesavetablehdr
  1493. STMFD R13!,{R14}
  1494. MOV R0,#1
  1495. MOV R1,R7
  1496. ADR R2,savetableid
  1497. MOV R3,#4
  1498. MOV R4,#save.id
  1499. SWI XOS_GBPB
  1500. LDMVSFD R13!,{PC}
  1501. MOV R0,#1
  1502. MOV R1,R7
  1503. ADD R2,R11,#t.name
  1504. MOV R3,#8
  1505. MOV R4,#save.name
  1506. SWI XOS_GBPB
  1507. LDMVSFD R13!,{PC}
  1508. MOV R0,#1
  1509. MOV R1,R7
  1510. ADD R2,R11,#t.objsize
  1511. MOV R3,#4
  1512. MOV R4,#save.objsize
  1513. SWI XOS_GBPB
  1514. LDMVSFD R13!,{PC}
  1515. MOV R0,#1
  1516. MOV R1,R7
  1517. ADR R2,savetableid
  1518. MOV R3,#4
  1519. MOV R4,#save.gap ;set up pointer
  1520. SWI XOS_GBPB
  1521. LDMFD R13!,{PC}
  1522.  
  1523. .selecttableswi
  1524. STMFD R13!,{R3-R9,R14}
  1525. MOV R4,R0
  1526. CMP R2,#0
  1527. ORREQ R4,R4,#PF_plot
  1528. CMP R1,#0
  1529. ORREQ R4,R4,#PF_process
  1530. CMP R1,#2
  1531. ORREQ R2,R2,#R_tst
  1532. BIC R0,R0,#&FF<<24
  1533. BL gettlistaddr
  1534. LDMVSFD R13!,{R3-R9,PC}
  1535. MOV R10,R0
  1536. LDR R1,[R10]
  1537. CMP R1,#0
  1538. LDMEQFD R13!,{R3-R9,R14}
  1539. MOVEQ R0,R4
  1540. BEQ notableerr
  1541. LDR R1,[R10,#4]; colchtab ptr
  1542. CMP R1,#0
  1543. TSTNE R4,#PF_process
  1544. MOVNE R2,#c.sizeof
  1545. STRNE R2,[R1,#c.writeofs-b.sizeof]; wipes colch table
  1546. LDR R0,[R10]
  1547. SUB R0,R0,#b.sizeof
  1548. ADD R1,R0,#t.sizeof    ; first object
  1549. TST R4,#PF_process
  1550. MOVNE R2,#0
  1551. ORR R2,R2,#R_skip_advance
  1552. ORR R0,R4,#PF_advance
  1553. LDMFD R13!,{R3-R9,PC}^
  1554.  
  1555. .scantable
  1556. TST R2,#R_skip_advance
  1557. ADDEQ R10,R10,R9
  1558. BIC R2,R2,#R_alive+R_skip_advance
  1559. BIC R5,R2,#3
  1560. TST R2,#R_tst
  1561. BNE scantst
  1562. .scancmp
  1563. ._loop
  1564. #rept 8
  1565. CMP R10,R8
  1566. BGE scanfordone
  1567. LDR R0,[R10,R5]
  1568. BIC R0,R0,R4
  1569. CMP R0,R3
  1570. BEQ scanfound
  1571. ADD R10,R10,R9
  1572. #endr
  1573. B _loop
  1574. .scantst
  1575. CMP R10,R8
  1576. BGE scanfordone
  1577. CMP R3,#0
  1578. BEQ scanfound
  1579. ._loop
  1580. LDR R0,[R10,R5]
  1581. BIC R0,R0,R4
  1582. TST R0,R3
  1583. BNE scanfound
  1584. ADD R10,R10,R9
  1585. #rept 7
  1586. CMP R10,R8
  1587. BGE scanfordone
  1588. LDR R0,[R10,R5]
  1589. BIC R0,R0,R4
  1590. TST R0,R3
  1591. BNE scanfound
  1592. ADD R10,R10,R9
  1593. #endr
  1594. B _loop
  1595.  
  1596. .scanfordone
  1597. MOV R2,#0
  1598. LDMFD R13!,{R3-R9,PC}^
  1599. .scanfound
  1600. MOV R0,R11
  1601. MOV R1,R10
  1602. ORR R2,R2,#R_alive
  1603. LDMFD R13!,{R3-R9,PC}^
  1604.  
  1605. .processtableswi
  1606. ; receives and returns
  1607. ; R0 = table handle+flags
  1608. ; R1 = current object pointer
  1609. ; R2 = reason code
  1610. STMFD R13!,{R3-R9,R14}
  1611. MOV R11,R0
  1612. MOV R10,R1
  1613. BIC R0,R0,#&FFFF<<16
  1614. BL gettlistaddr
  1615. LDMVSFD R13!,{R3-R9,PC}
  1616. STR R0,[R12,#v.temp0]
  1617. LDR R0,[R0]; get tableaddr
  1618. SUB R7,R0,#b.sizeof
  1619. LDR R0,[R7,#t.size]
  1620. ADD R8,R7,R0
  1621. CMP R7,R10
  1622. CMPLT R10,R8
  1623. MOVGT R0,R11; for error report
  1624. LDMGTFD R13!,{R3-R9,R14}
  1625. BGT objectoutsideerr
  1626. LDR R9,[R7,#t.objsize]
  1627. TST R11,#PF_process
  1628. BEQ scantable
  1629. CMP R2,#R_skip_advance
  1630. BEQ skipadvance
  1631. TST R11,#PF_advance
  1632. BEQ noadvance 
  1633. .lookforobj
  1634. ADD R10,R10,R9; advance
  1635. .skipadvance
  1636.  
  1637. ;R8  = end of table in memory
  1638. ;R9  = [t.objsize]
  1639. ;R10 = address of next object to test
  1640.  
  1641. ._loop
  1642. #rept 8
  1643. CMP R10,R8
  1644. BGE lookfordone
  1645. LDR R0,[R10],R9
  1646. CMP R0,#0
  1647. BNE objfound
  1648. #endr
  1649. B _loop
  1650. .lookfordone
  1651. MOV R2,#0
  1652. LDMFD R13!,{R3-R9,PC}^
  1653.  
  1654. .objfound
  1655. SUB R10,R10,R9; R10 now points to the found object
  1656. STMFD R13!,{R7-R9}
  1657. ; we need for later
  1658. ; R7 as pointer to t struct
  1659. ; R8 as end address
  1660. ; R9 as object length
  1661.  
  1662. LDMIA R10,{R1-R8}
  1663. TST R2,#Amf_remote
  1664. BNE doremote
  1665. .remoteins0
  1666. BIC R2,R2,#%1111<<20
  1667. STR R2,[R10,#4]
  1668. AND R9,R11,#&FF<<24; R9 = the trigger mask
  1669. ORR R9,R9,#Amf_colch+Amf_attn+Amf_anim
  1670. TST R11,#PF_plot
  1671. ORRNE R9,R9,#Amf_plot+Amf_user_plot; request user plot if plots requested
  1672. TST R2,#Amf_use_plot_ofs
  1673. ORRNE R9,R9,#Amf_use_plot_ofs
  1674. TST R2,#Amf_velocity + Amf_attn_timer + Amf_dest_timer + Amf_anim
  1675. TSTEQ R2,#Amf_zero_vec + Amf_timer2
  1676. BEQ skipvelocity
  1677. TST R2,#Amf_velocity
  1678. ADDNE R3,R3,R5
  1679. ADDNE R4,R4,R6
  1680. TST R2,#Amf_zero_vec
  1681. MOVNE R5,#0
  1682. MOVNE R6,#0
  1683. TST R2,#Amf_gravity
  1684. BLNE addgravity
  1685. TST R2,#Amf_attn_timer + Amf_dest_timer + Amf_anim
  1686. SUBNE R7,R7,R7,LSL #16
  1687. CMP R7,#0; test for timer expiry
  1688. ORRLT R9,R9,#Amf_attn_timer + Amf_dest_timer
  1689. STMIA R10,{R1-R7}
  1690. TST R2,#Amf_timer2
  1691. BLNE runtimer2
  1692. .skipvelocity
  1693.  
  1694. TST R2,#Amf_game_horiz + Amf_game_vert + Amf_plot_window + Amf_kill_window
  1695. BEQ nowindows
  1696. STMFD R13!,{R2,R7}
  1697. MOV R14,R2       ;NOTE
  1698. MOV R5,R8,LSR #16
  1699. MOV R6,R8,LSL #16; R1 is <<16 its real value
  1700. ;        and don't forget the <<12 from pixels to coords
  1701. MOV R5,R5,LSL #16
  1702. SUB R1,R3,R5,LSR #17-coordshift
  1703. ADD R3,R3,R5,LSR #17-coordshift
  1704.  
  1705. SUB R2,R4,R6,LSR #17-coordshift
  1706. ADD R4,R4,R6,LSR #17-coordshift
  1707. TST R14,#Amf_game_horiz + Amf_game_vert
  1708. BEQ nogamewindow
  1709. ADD R0,R12,#v.gamewindow  ;the game window triggers when any part of the
  1710. ;             object    is outside of it
  1711.  
  1712. LDMIA R0,{R5-R8}
  1713. CMP R1,R5
  1714. CMPGE R7,R3
  1715. ORRLT R9,R9,#Amf_game_horiz
  1716. CMP R2,R6
  1717. CMPGE R8,R4
  1718. ORRLT R9,R9,#Amf_game_vert
  1719. .nogamewindow
  1720.  
  1721. TST R14,#Amf_kill_window
  1722. BEQ nokillwindow
  1723. ADD R0,R12,#v.killwindow
  1724. LDMIA R0,{R5-R8}       ;the kill window triggers if an object is entirely
  1725. ;            outside of it.
  1726. CMP R1,R7
  1727. CMPLE R5,R3
  1728. CMPLE R2,R8
  1729. CMPLE R6,R4
  1730. ORRGT R9,R9,#Amf_kill_window
  1731. .nokillwindow
  1732. TST R14,#Amf_plot_window
  1733. BEQ noplotwindow
  1734. TST R9,#Amf_use_plot_ofs
  1735. LDRNE R5,[R12,#v.plotxofs]
  1736. LDRNE R6,[R12,#v.plotyofs]
  1737. ADDNE R1,R1,R5
  1738. ADDNE R3,R3,R5
  1739. ADDNE R2,R2,R6
  1740. ADDNE R4,R4,R6
  1741. ADD R0,R12,#v.plotwindow
  1742. LDMIA R0,{R5-R8}       ;the plot window triggers if an object is entirely
  1743. ;            outside of it.
  1744. CMP R1,R7
  1745. CMPLT R5,R3
  1746. CMPLT R2,R8
  1747. CMPLT R6,R4
  1748. ORRGE R9,R9,#Amf_plot_window
  1749. TST R9,#Amf_plot_window
  1750. TSTNE R2,#Amf_colch_window
  1751. ORRNE R9,R9,#Amf_colch_window
  1752. .noplotwindow
  1753. LDMFD R13!,{R2,R7}
  1754. .nowindows
  1755.  
  1756. ; reset regs to return
  1757. BIC R0,R11,#PF_advance; signal that we havn't finished
  1758. MOV R1,R10
  1759. AND R2,R9,R2
  1760. TST R2,#Amf_plot_window
  1761. BICNE R2,R2,#Amf_plot + Amf_user_plot
  1762. BICS R9,R2,#Amf_imask
  1763. LDMFD R13!,{R7-R9}
  1764. LDMNEFD R13!,{R3-R9,PC}^ ; return if attention required
  1765. .noadvance
  1766. MOV R0,#0
  1767. TST R2,#Amf_kill_window
  1768. STRNE R0,[R10,#o.type]
  1769.  
  1770. TST R2,#Amf_dest_timer
  1771. BEQ nodesttimer
  1772. LDR R1,[R10,#o.timer]
  1773. CMP R1,#0
  1774. STRLT R0,[R10,#o.type]
  1775. .nodesttimer
  1776.  
  1777. LDR R0,[R10,#o.type]
  1778. CMP R0,#0
  1779. BEQ objectdead
  1780. TST R2,#Amf_plot
  1781. BLNE plotobj     ;uses previous R0
  1782.                 
  1783. TST R2,#Amf_colch
  1784. BEQ objectskip
  1785. TST R2,#Amf_colch_window
  1786. BNE objectskip
  1787. BL colchadd
  1788. LDMVSFD R13!,{R3-R9,PC}
  1789. .objectskip
  1790. .objectdead
  1791. ;SWI OS_ReadEscapeState
  1792. ;BCC lookforobj
  1793. B lookforobj
  1794. LDMFD R13!,{R3-R9,PC}
  1795.  
  1796. .runtimer2
  1797. STMFD R13!,{R0}
  1798. LDR R0,[R10,#o.timer2]
  1799. SUB R0,R0,R0,LSL #16
  1800. STR R0,[R10,#o.timer2]
  1801. CMP R0,#0
  1802. ORRGT R9,R9,#Amf_timer2
  1803. LDMFD R13!,{R0}
  1804. MOV PC,R14
  1805.  
  1806. .addgravity
  1807. LDR R0,[R12,#v.gravx]
  1808. ADD R5,R5,R0
  1809. LDR R0,[R12,#v.gravy]
  1810. ADD R6,R6,R0
  1811. MOV PC,R14
  1812.  
  1813. .plotobj
  1814. STMFD R13!,{R0-R3,R14}
  1815. TST R2,#Amf_anim
  1816. BLNE fastspranim
  1817. TST R2,#Amf_use_plot_ofs
  1818. LDRNE R3,[R12,#v.plotxofs]
  1819. LDR R1,[R10,#o.x]
  1820. ADDNE R1,R1,R3
  1821. LDRNE R3,[R12,#v.plotyofs]
  1822. LDR R2,[R10,#o.y]
  1823. ADDNE R2,R2,R3
  1824. MOV R1,R1,ASR #coordshift
  1825. MOV R2,R2,ASR #coordshift
  1826. SWI FastSpr_Plot
  1827. LDMFD R13!,{R0-R3,PC}
  1828.  
  1829. .fastspranim
  1830. TST R2,#Amf_timer2
  1831. LDREQ R1,[R10,#o.timer]
  1832. LDRNE R1,[R10,#o.timer2]
  1833. AND R1,R1,#&FF<<24
  1834. ORR R0,R0,R1,LSR #8
  1835. MOV PC,R14
  1836.  
  1837. .doremote
  1838. LDR R0,[R12,#v.remote]
  1839. CMP R0,#0
  1840. BEQ remoteins0
  1841. LDR R14,[R0,#-4]
  1842. SUBS R14,R14,#remoteID
  1843. BNE remoteins0
  1844. STMFD R13!,{R9-R12}
  1845. LDR R12,[R12,#v.remoteR12]
  1846. MOV R14,PC
  1847. MOV PC,R0
  1848. LDMFD R13!,{R9-R12}
  1849. LDMIA R10,{R1-R8}
  1850. B remoteins0
  1851.  
  1852. .colchadd
  1853. STMFD R13!,{R1-R9,R14}
  1854. LDR R0,[R12,#v.temp0]
  1855. LDR R9,[R0,#4]; get colchtab addr
  1856. CMP R9,#0
  1857. BEQ colchnotable
  1858. SUB R9,R9,#b.sizeof
  1859. LDR R1,[R9,#c.writeofs]
  1860. LDR R2,[R9,#c.size]
  1861. CMP R1,R2
  1862. BGE colchnoroom
  1863. SUB R0,R10,R7;offset within table
  1864. ADD R7,R9,R1; position to write to
  1865. LDR R3,[R10,#o.x]
  1866. LDR R4,[R10,#o.y]
  1867. LDR R8,[R10,#o.size]
  1868. MOV R5,R8,LSR #16
  1869. MOV R6,R8,LSL #16; R6 is <<16 its real value
  1870. MOV R5,R5,LSL #16; now so is R5
  1871. SUB R1,R3,R5,LSR #17-coordshift
  1872. ADD R3,R3,R5,LSR #17-coordshift
  1873. SUB R2,R4,R6,LSR #17-coordshift
  1874. ADD R4,R4,R6,LSR #17-coordshift
  1875. STMIA R7!,{R0-R4}
  1876. SUB R1,R7,R9; restore writeofs
  1877. STR R1,[R9,#c.writeofs]
  1878. LDMFD R13!,{R1-R9,PC}^
  1879. .colchnotable
  1880. LDMFD R13!,{R1-R9,R14}
  1881. B colchnotableerr
  1882.  
  1883. .colchnoroom
  1884. LDMFD R13!,{R1-R9,R14}
  1885. B colchnoroomerr
  1886.  
  1887. .colchswi
  1888. STMFD R13!,{R4-R9,R14}
  1889. CMP R0,#&8000
  1890. BLGE nofirstcolch
  1891. BL firstcolch
  1892. LDMVSFD R13!,{R4-R9,PC}
  1893. .nofirstcolch
  1894. ADD R4,R12,#v.colchsave
  1895. LDMIA R4,{R0-R3}
  1896.  
  1897. .loop13
  1898. CMP R2,R0
  1899. BGE colchend2
  1900. LDMIA R2,{R4-R7}
  1901. ADD R2,R2,#cent.sizeof
  1902.  
  1903. .loop12
  1904. #rept 4
  1905. CMP R3,R1
  1906. BGE colchend1
  1907. LDMIA R3,{R8-R11}
  1908. ADD R3,R3,#cent.sizeof
  1909. CMP R4,R10
  1910. CMPLE R8,R6
  1911. CMPLE R5,R11
  1912. CMPLE R9,R7
  1913. BLE contact
  1914. #endr
  1915. B loop12
  1916.  
  1917. .colchend1
  1918. CMP R0,R1 ;are we checking a table with itself?
  1919. ADDEQ R3,R2,#cent.sizeof
  1920. LDRNE R3,[R12,#v.colch3]; wind R3 back to start of table
  1921. B loop13
  1922.  
  1923. .colchend2
  1924. MOV R0,#0
  1925. LDMFD R13!,{R4-R9,PC}^
  1926.  
  1927. .contact
  1928. ADD R14,R12,#v.colchboxes
  1929. STMIA R14,{R4-R11}      ;R4 minx1, R5 miny1, R6  maxx1, R7  maxy1
  1930.             ;R8 minx2, R9 miny2, R10 maxx2, R11 maxy2
  1931. ADD R4,R12,#v.colchsave
  1932. STMIA R4,{R0-R3}
  1933. LDR R2,[R2,#-cent.sizeof-4]
  1934. LDR R3,[R3,#-cent.sizeof-4]
  1935. LDR R0,[R12,#v.colch0]
  1936. ADD R0,R0,R2
  1937. LDR R1,[R12,#v.colch1]
  1938. ADD R1,R1,R3
  1939. LDMFD R13!,{R4-R9,PC}^
  1940. ;returns object addresses in R0,R1
  1941.  
  1942. .firstcolch
  1943. STMFD R13!,{R14}
  1944. BL gettlistaddr
  1945. LDMVSFD R13!,{PC}
  1946. LDR R4,[R0,#4]
  1947. CMP R4,#0
  1948. SUB R4,R4,#b.sizeof
  1949. LDR R5,[R0]
  1950. SUB R5,R5,#b.sizeof
  1951. STR R5,[R12,#v.colch0]
  1952. LDMEQFD R13!,{R14}
  1953. BEQ colchnotableerr
  1954.  
  1955. MOV R0,R1
  1956. BL gettlistaddr
  1957. LDMVSFD R13!,{PC}
  1958. LDR R1,[R0,#4]
  1959. CMP R1,#0
  1960. SUB R1,R1,#b.sizeof
  1961. LDR R5,[R0]
  1962. SUB R5,R5,#b.sizeof
  1963. STR R5,[R12,#v.colch1]
  1964. LDMEQFD R13!,{R14}
  1965. BEQ colchnotableerr
  1966. MOV R0,R4
  1967. ADD R2,R0,#c.sizeof+4
  1968. ADD R3,R1,#c.sizeof+4
  1969. CMP R0,R1
  1970. ADDEQ R3,R3,#cent.sizeof; skip first object if R0=R1
  1971. LDR R4,[R0,#c.writeofs]
  1972. ADD R0,R0,R4
  1973. LDR R4,[R1,#c.writeofs]
  1974. ADD R1,R1,R4
  1975. STR R3,[R12,#v.colch3]
  1976. ADD R4,R12,#v.colchsave
  1977. STMIA R4,{R0-R3}
  1978. LDMFD R13!,{PC}^
  1979.  
  1980. .colchboxesswi
  1981. STMFD R13!,{R14}
  1982. ADD R14,R12,#v.colchboxes
  1983. LDMIA R14,{R0-R7}
  1984. LDMFD R13!,{PC}
  1985. ;R0 minx1, R1 miny1, R2 maxx1, R3 maxy2
  1986. ;R4 minx2, R5 miny2, R6 maxx2, R7 maxy2
  1987.  
  1988. .makeobjectswi
  1989. STMFD R13!,{R2-R8,R14}
  1990. BL makeobjectspaceswi
  1991. MOVCS R1,#0
  1992. MOVVS R1,#0
  1993. LDMVSFD R13!,{R2-R8,PC}
  1994. LDMCSFD R13!,{R2-R8,PC}
  1995. TST R2,#Amf_make_objsize
  1996. BLNE makeupsize
  1997. CMP R0,#&8000
  1998. LDMLTFD R13!,{R2-R8,R14}
  1999. BLT fatalerr
  2000. STMIA R0,{R1-R8}
  2001. MOV R1,R0
  2002. LDMFD R13!,{R2-R8,PC}
  2003.  
  2004. .makeupsize
  2005. STMFD R13!,{R0-R1,R14}
  2006. MOV R0,R1
  2007. SWI FastSpr_ReadSize
  2008. ORR R8,R1,R0,LSL #16
  2009. LDMFD R13!,{R0-R1,PC}
  2010.  
  2011. .makeobjectspaceswi
  2012. STMFD R13!,{R1-R9,R14}
  2013. BL gettableaddr
  2014. LDMVSFD R13!,{R1-R9,PC}
  2015. SUB R11,R0,#b.sizeof
  2016.  
  2017. LDR R0,[R11,#t.next]
  2018. LDR R1,[R11,#t.number]
  2019. BL scantablespace
  2020. BEQ objspacefound
  2021. MOV R0,#0
  2022. LDR R1,[R11,#t.next]
  2023. BL scantablespace
  2024. BEQ objspacefound
  2025. LDMFD R13!,{R1-R9,R14}
  2026. MOV R1,#0
  2027. MOV R0,#0
  2028. ORR R14,R14,#1<<29; set carry flag
  2029. MOVS PC,R14
  2030.  
  2031. .objspacefound
  2032. STR R0,[R11,#t.next]
  2033. LDMFD R13!,{R1-R9,R14}
  2034. MOV R0,R10
  2035. BIC R14,R14,#3<<28
  2036. MOVS PC,R14
  2037.  
  2038. .deleteobjectswi
  2039. STMFD R13!,{R0,R14}
  2040. MOV R0,#0
  2041. STR R0,[R1]
  2042. LDMFD R13!,{R0,PC}
  2043.  
  2044. .countobjectsswi
  2045. STMFD R13!,{R1-R9,R14}
  2046. BL gettableaddr
  2047. LDMVSFD R13!,{R1-R9,PC}
  2048. SUB R11,R0,#b.sizeof
  2049. ADD R10,R11,#t.sizeof
  2050. LDR R2,[R11,#t.objsize]
  2051. LDR R1,[R11,#t.number]
  2052. MOV R3,#0;counter
  2053. CMP R1,#8
  2054. BLT slowcount
  2055. .fastcountloop
  2056. #rept 8
  2057. LDR R4,[R10],R2
  2058. CMP R4,#0
  2059. ADDNE R3,R3,#1
  2060. #endr
  2061. SUB R1,R1,#8
  2062. CMP R1,#8
  2063. BGE fastcountloop
  2064. .slowcount
  2065. CMP R1,#0
  2066. BLE countskip
  2067. .slowcountloop
  2068. LDR R4,[R10],R2
  2069. CMP R4,#0
  2070. ADDNE R3,R3,#1
  2071. SUBS R1,R1,#1
  2072. BGT slowcountloop
  2073. .countskip
  2074. MOV R0,R3
  2075. LDMFD R13!,{R1-R9,PC}
  2076.  
  2077. .scantablespace
  2078. ADD R10,R11,#t.sizeof
  2079. LDR R2,[R11,#t.objsize]
  2080. MUL R3,R2,R0; R2 is considered smallest
  2081. ADD R10,R10,R3; R10 points to our object.
  2082. SUB R4,R1,R0
  2083. CMP R4,#8
  2084. BLT nofastscan
  2085. .fastscan
  2086. LDR R4,[R10],R2
  2087. CMP R4,#0
  2088. BEQ scanfoundspace
  2089. LDR R4,[R10],R2
  2090. CMP R4,#0
  2091. BEQ scanfoundspace
  2092. LDR R4,[R10],R2
  2093. CMP R4,#0
  2094. BEQ scanfoundspace
  2095. LDR R4,[R10],R2
  2096. CMP R4,#0
  2097. BEQ scanfoundspace
  2098. LDR R4,[R10],R2
  2099. CMP R4,#0
  2100. BEQ scanfoundspace
  2101. LDR R4,[R10],R2
  2102. CMP R4,#0
  2103. BEQ scanfoundspace
  2104. LDR R4,[R10],R2
  2105. CMP R4,#0
  2106. BEQ scanfoundspace
  2107. LDR R4,[R10],R2
  2108. CMP R4,#0
  2109. BEQ scanfoundspace
  2110. ADD R0,R0,#8
  2111. SUB R4,R1,R0
  2112. CMP R4,#8
  2113. BGE fastscan
  2114. .nofastscan
  2115. ._loop
  2116. CMP R0,R1
  2117. BGE scannospace
  2118. LDR R4,[R10],R2
  2119. CMP R4,#0
  2120. ADD R0,R0,#1
  2121. BNE _loop
  2122. .scanfoundspace
  2123. SUB R10,R10,R2; correct for overshoot
  2124. MOV PC,R14; EQ is already set
  2125. .scannospace
  2126. BIC R14,R14,#1<<30; flag non-zero
  2127. MOVS PC,R14
  2128.  
  2129. .setgravityswi
  2130. STR R0,[R12,#v.gravx]
  2131. STR R1,[R12,#v.gravy]
  2132. MOV PC,R14
  2133. .readgravityswi
  2134. LDR R0,[R12,#v.gravx]
  2135. LDR R1,[R12,#v.gravy]
  2136. MOV PC,R14
  2137.  
  2138. .remoteswi
  2139. STMFD R13!,{R1-R2,R14}
  2140. MOV R2,R1
  2141. CMP R0,#0
  2142. BEQ remoteok
  2143. MOV R1,R0
  2144. SWI OS_ValidateAddress
  2145. LDMCSFD R13!,{R1-R2,R14}
  2146. BCS badptrerr
  2147. LDR R1,[R0,#-4]
  2148. SUBS R1,R1,#remoteID
  2149. LDMNEFD R13!,{R1-R2,R14}
  2150. BNE remoteerr
  2151. .remoteok
  2152. STR R0,[R12,#v.remote]
  2153. STR R2,[R12,#v.remoteR12]
  2154. LDMFD R13!,{R1-R2,PC}
  2155.  
  2156. .claimblockswi
  2157. STMFD R13!,{R1-R11,R14}
  2158. ADD R1,R1,#3
  2159. BIC R1,R1,#3
  2160. ADD R1,R1,#b.sizeof
  2161. ADD R4,R12,#v.buffer
  2162. STMIA R4,{R0-R3} ;avoiding stack
  2163. CMP R0,#0
  2164. BEQ nomemcheck
  2165. MOV R1,R0
  2166. SWI OS_ValidateAddress
  2167. LDMCSFD R13!,{R1-R11,R14}
  2168. BCS badptrerr
  2169.  
  2170. .nomemcheck
  2171. ADD R4,R12,#v.buffer
  2172. LDMIA R4,{R0-R3}; No writeback
  2173. BL getavailablespace
  2174. LDMVSFD R13!,{R1-R11,PC}
  2175.  
  2176. ADD R8,R1,#b.sizeof+16; for block table entry
  2177. CMP R0,R8
  2178. BGE claimisok
  2179. LDR R0,[R12,#v.areatype]
  2180. AND R0,R0,#&FF
  2181. CMP R0,#A_type_messy
  2182. LDMNEFD R13!,{R1-R11,R14}
  2183. BNE noroomerr
  2184. BL tidyswi
  2185. LDMVSFD R13!,{R1-R11,PC}
  2186. ADD R4,R12,#v.buffer
  2187. LDMIA R4,{R0-R3}; No writeback
  2188. BL getavailablespace
  2189. LDMVSFD R13!,{R1-R11,PC}
  2190. ADD R8,R1,#b.sizeof+16; for block table entry including possible qwa
  2191. CMP R0,R8
  2192. LDMLTFD R13!,{R1-R11,R14}
  2193. BLT noroomerr
  2194.                    ;drops through
  2195. .claimisok
  2196. LDMIA R4,{R0-R3}
  2197. BL scanblocktable
  2198. LDMVSFD R13!,{R1-R11,PC}
  2199. TST R3,#BF_qwa
  2200. ADDNE R1,R1,#16
  2201. BICNE R1,R1,#15
  2202. SUBNE R1,R1,#4
  2203. MOV R10,R0
  2204. STR R1,[R10]
  2205. MVN R8,#0
  2206. STR R8,[R10,#-4]
  2207. ADD R4,R12,#v.buffer
  2208. LDMIA R4,{R0-R3}
  2209. BL initblock
  2210. LDR R4,[R10]
  2211. ADD R5,R4,#b.sizeof
  2212. CMP R0,#0
  2213. STRNE R5,[R0]
  2214. MOV R0,R4
  2215. BL wipeblock
  2216. MOV R0,R5
  2217. LDMFD R13!,{R1-R11,PC}^
  2218.  
  2219. .extendblockswi
  2220. STMFD R13!,{R1-R9,R14}
  2221. MOV R8,R1
  2222. CMP R0,#&8000
  2223. ADDGE R0,R0,#b.sizeof
  2224. BL findblockentry
  2225. LDMVSFD R13!,{R1-R9,PC}
  2226. LDR R10,[R0]
  2227. LDR R9,[R10,#b.size]
  2228. CMP R1,R9
  2229. BGT blockextend
  2230. STR R1,[R10,#b.size]
  2231. LDR R0,[R12,#v.areatype]
  2232. CMP R0,#A_type_tidy
  2233. BLEQ tidyswi
  2234. LDMFD R13!,{R1-R9,PC}
  2235.  
  2236. .blockextend
  2237. LDR R0,[R10,#b.ptr]
  2238. MOV R1,R8
  2239. ADD R2,R10,#b.name
  2240. LDR R3,[R10,#b.flags]
  2241. BL claimblockswi
  2242. LDMVSFD R13!,{R1-R9,PC}
  2243. ADD R1,R10,#b.sizeof
  2244. MOV R2,R8
  2245. BL copyblock
  2246. MOV R0,R10
  2247. BL releaseblockinternal
  2248. LDMVSFD R13!,{R1-R9,PC}
  2249. LDR R0,[R12,#v.areatype]
  2250. CMP R0,#A_type_tidy
  2251. BLEQ tidyswi
  2252. LDMFD R13!,{R1-R9,PC}
  2253.  
  2254. .copyblock
  2255. STMFD R13!,{R0-R3,R14}
  2256. .loop14
  2257. LDR R3,[R1],#4
  2258. STR R3,[R0],#4
  2259. SUBS R2,R2,#4
  2260. BGT loop14
  2261. LDMFD R13!,{R0-R3,PC}
  2262.  
  2263.  
  2264.  
  2265.  
  2266. .releaseblockinternal
  2267. STMFD R13!,{R1-R4,R14}
  2268. B releaseblockins
  2269.  
  2270.  
  2271. .releaseblockswi
  2272. STMFD R13!,{R1-R4,R14}
  2273. CMP R0,#0
  2274. LDMEQFD R13!,{R1-R4,R14}
  2275. BEQ discardarea
  2276.  
  2277. CMP R0,#&8000
  2278. SUBGE R0,R0,#b.sizeof
  2279. .releaseblockins
  2280. MOV R4,R0
  2281. BL findblockentry
  2282. BVS releasenofind
  2283. MOV R3,R0
  2284. LDR R2,[R3]
  2285. CMP R2,#0
  2286. BEQ releasenonblock
  2287. LDR R0,blockid
  2288. LDR R1,[R2,#b.id]
  2289. CMP R0,R1
  2290. BNE releasecorruptblock
  2291. LDR R1,[R2,#b.ptr]
  2292. CMP R1,#0
  2293. MOV R0,#0
  2294. STRNE R0,[R1]; set pointer to null
  2295. STR R0,[R2,#b.id]  ; delete ID word
  2296. .releasecorruptins
  2297. MOV R0,#0
  2298. STR R0,[R3]  ; zero entry in block list
  2299. .releasenofindins
  2300. LDR R0,[R12,#v.areatype]
  2301. AND R0,R0,#&FF
  2302. CMP R0,#A_type_tidy
  2303. BNE donttidy
  2304. BL tidyswi
  2305. LDMVSFD R13!,{R1-R4,PC}
  2306. .donttidy
  2307.  
  2308. LDMFD R13!,{R1-R4,PC}^
  2309.  
  2310. .releasenofind
  2311. STR R4,[R12,#v.errorblock]
  2312. SWI OS_WriteS
  2313. DCB "Amnesia : Release of non-existent block (failed to find) - continuing...",10,13,0
  2314. ALIGN
  2315. B releasenofindins
  2316.  
  2317. .releasecorruptblock
  2318. STR R4,[R12,#v.errorblock]
  2319. SWI OS_WriteS
  2320. DCB "Amnesia : Release of corrupt block (incorrect guard word) - continuing...",10,13,0
  2321. ALIGN
  2322. B releasecorruptins
  2323.  
  2324. .releasenonblock
  2325. STR R4,[R12,#v.errorblock]
  2326. SWI OS_WriteS
  2327. DCB "Amnesia : Release of non-existent block (zero entry) - continuing...",10,13,0
  2328. ALIGN
  2329. B releasecorruptins
  2330.  
  2331. .initblock
  2332. STMFD R13!,{R0-R4,R14}
  2333. LDR R4,[R10]
  2334. STR R0,[R4,#b.ptr]
  2335. STR R1,[R4,#b.size]
  2336. STR R3,[R4,#b.flags]
  2337. ADD R0,R4,#b.name
  2338. MOV R1,R2
  2339. CMP R1,#0
  2340. ADREQ R1,defaultname
  2341. MOV R2,#8
  2342. BL strncpy
  2343. LDR R0,blockid
  2344. STR R0,[R4,#b.id]
  2345. LDMFD R13!,{R0-R4,PC}^
  2346.  
  2347.  
  2348. .defaultname
  2349. DCB "None",0
  2350. ALIGN
  2351.  
  2352. .describeblockswi
  2353. STMFD R13!,{R7-R11,R14}
  2354. CMP R0,#&8000
  2355. SUBGE R0,R0,#b.sizeof
  2356. BL xfindblockentry
  2357. LDMVSFD R13!,{R7-R11,R14}
  2358. BVS err
  2359. LDR R0,[R0]
  2360. ;MOV R0,R0;block addr
  2361. LDR R1,[R0,#b.size];block size
  2362. ADD R2,R0,#b.sizeof;data addr
  2363. SUB R3,R1,#b.sizeof;data size
  2364. ADD R4,R0,#b.name;ptr to name
  2365. LDR R5,[R0,#b.ptr];ptr to ptr
  2366. LDR R6,[R0,#b.flags]
  2367. LDMFD R13!,{R7-R11,PC}
  2368.  
  2369. .scanblocktable
  2370. ;returns R0 pointing to the end marker of the block table
  2371. ;R1 pointing to the start of free space
  2372. ;R2 the number of blocks
  2373. STMFD R13!,{R3-R11,R14}
  2374. LDR R11,[R12,#v.areastart]
  2375. LDR R0,[R11,#h.areasize]
  2376. ADD R10,R11,R0 ;scan the blocks
  2377. LDR R7,blockid
  2378. MOV R5,#0; space counter
  2379. MOV R6,R11; header - last valid entry
  2380. .loopB
  2381. LDR R9,[R10,#-4]!
  2382. CMP R9,#0
  2383. BEQ loopB
  2384. CMP R9,#-1
  2385. BEQ scanblocktableend
  2386. MOV R6,R10
  2387. LDR R0,[R9]
  2388. CMP R0,R7
  2389. LDMNEFD R13!,{R3-R11,R14}
  2390. BNE scanbadblockerr
  2391. ADD R5,R5,#1
  2392. B loopB
  2393. .scanblocktableend
  2394. MOV R0,R10
  2395. LDR R2,[R6]
  2396. LDR R1,[R2,#b.size]
  2397. ADD R1,R2,R1
  2398. MOV R2,R5
  2399. LDMFD R13!,{R3-R11,PC}^
  2400.  
  2401. .xfindblockentry
  2402. STMFD R13!,{R7-R11,R14}
  2403. MOV R8,R0
  2404. LDR R11,[R12,#v.areastart]
  2405. LDR R10,[R11,#h.areasize]
  2406. ADD R10,R11,R10
  2407. CMP R8,#&8000
  2408. BLT xfindblockno
  2409. .loopE
  2410. LDR R9,[R10,#-4]!
  2411. CMP R9,#0
  2412. BEQ loopE
  2413. CMP R9,R8
  2414. BEQ foundblock
  2415. CMP R9,#-1
  2416. BEQ notfoundblock
  2417.  
  2418. B loopE
  2419.  
  2420.  
  2421. .findblockentry
  2422. STMFD R13!,{R7-R11,R14}
  2423. MOV R8,R0
  2424. LDR R11,[R12,#v.areastart]
  2425. LDR R10,[R11,#h.areasize]
  2426. ADD R10,R11,R10
  2427. LDR R7,blockid
  2428. CMP R8,#&8000
  2429. BLT findblockno
  2430. .loopC
  2431. LDR R9,[R10,#-4]!
  2432. CMP R9,#0
  2433. BEQ loopC
  2434. CMP R9,R8
  2435. BEQ foundblock
  2436. CMP R9,#-1
  2437. BEQ notfoundblock
  2438.  
  2439. LDR R0,[R9]
  2440. CMP R0,R7
  2441. LDMNEFD R13!,{R7-R11,R14}
  2442. BNE scanbadblockerr
  2443. B loopC
  2444. .foundblock
  2445. MOV R0,R10
  2446. LDMFD R13!,{R7-R11,PC}
  2447. .notfoundblock
  2448. MOV R0,R8
  2449. LDMFD R13!,{R7-R11,R14}
  2450. B notfoundblockerr
  2451.  
  2452. .xfindblockno
  2453. .loopF
  2454. LDR R9,[R10,#-4]!
  2455. CMP R9,#-1
  2456. BEQ notfoundblock
  2457. MOV R0,R9             ;check for amnesia block
  2458. MOV R1,R0
  2459. SWI OS_ValidateAddress
  2460. LDMCSFD R13!,{R7-R11,R14}
  2461. BCS areacorrupterr
  2462. SUBS R8,R8,#1
  2463. BPL loopF
  2464. B foundblock
  2465.  
  2466. .findblockno
  2467. .loopD
  2468. LDR R9,[R10,#-4]!
  2469. CMP R9,#-1
  2470. BEQ notfoundblock
  2471. CMP R9,#0
  2472. BEQ findblocknoskip
  2473. LDR R0,[R9]
  2474. CMP R0,R7
  2475. LDMNEFD R13!,{R7-R11,R14}
  2476. BNE scanbadblockerr
  2477. .findblocknoskip
  2478. SUBS R8,R8,#1
  2479. BPL loopD
  2480. B foundblock
  2481.  
  2482.  
  2483. .getfreespace
  2484. STMFD R13!,{R1-R2,R14}
  2485. BL getusedspace
  2486. LDMVSFD R13!,{R1-R2,PC}
  2487. LDR R1,[R12,#v.areastart]
  2488. LDR R1,[R1,#h.areasize]
  2489. SUB R0,R1,R0
  2490. LDMFD R13!,{R1-R2,PC}
  2491.  
  2492. .getavailablespace
  2493. STMFD R13!,{R1-R2,R14}
  2494. BL getusedspace
  2495. LDMVSFD R13!,{R1-R2,PC}
  2496. MOV R0,R1
  2497. LDMFD R13!,{R1-R2,PC}
  2498.  
  2499.  
  2500. .getusedspace
  2501. STMFD R13!,{R2-R11,R14}
  2502. LDR R11,[R12,#v.areastart]
  2503. LDR R0,[R11,#h.areasize]
  2504. ADD R10,R11,R0 ;let's count up the blocks
  2505. LDR R7,blockid
  2506. MOV R5,#0; space counter
  2507. MOV R4,R11
  2508. MOV R3,R10
  2509. .loopA
  2510. LDR R9,[R10,#-4]!
  2511. CMP R9,#-1
  2512. BEQ usedspaceend
  2513. MOV R0,R9
  2514. MOV R1,R0
  2515. SWI OS_ValidateAddress
  2516. LDMCSFD R13!,{R2-R11,R14}
  2517. BCS areacorrupterr
  2518. SUB R3,R3,#4
  2519. ADD R5,R5,#4;for block table entries
  2520. CMP R9,#0
  2521. BEQ loopA
  2522. LDR R0,[R9]
  2523. CMP R0,R7
  2524. LDMNEFD R13!,{R2-R11,R14}
  2525. BNE usedbadblockerr
  2526. LDR R2,[R9,#b.size]
  2527. ADD R5,R5,R2
  2528. ADD R4,R9,R2
  2529. B loopA
  2530. .usedspaceend
  2531. MOV R0,R5
  2532. SUB R1,R3,R4
  2533. LDMFD R13!,{R2-R11,PC}
  2534.  
  2535. .discardarea
  2536. STMFD R13!,{R0-R11,R14}
  2537. LDR R0,[R12,#v.areastart]
  2538. CMP R0,#0
  2539. LDMEQFD R13!,{R0-R11,PC}
  2540. STMFD R13!,{R0-R3}
  2541. ADR R0,start
  2542. MOV R1,#Service_Amnesia
  2543. MOV R2,R12
  2544. MOV R3,#0
  2545. SWI OS_ServiceCall
  2546. LDMFD R13!,{R0-R3}
  2547. LDR R0,[R12,#v.areatype]
  2548. TST R0,#1<<31
  2549. MOV R2,#v.areastart
  2550. BLNE releaserma
  2551. MOV R0,#0
  2552. STR R0,[R12,#v.areastart]
  2553. LDMFD R13!,{R0-R11,PC}
  2554.  
  2555. .newapplication
  2556. STMFD R13!,{R0,R14}
  2557. LDR R0,[R12,#v.areatype]
  2558. TST R0,#1<<31
  2559. BLEQ discardarea
  2560. LDMFD R13!,{R0,PC}
  2561.  
  2562. .getarearma
  2563. STMFD R13!,{R14}
  2564. LDR R0,[R12,#v.areatype]
  2565. ORR R0,R0,#1<<31        ;flag as 'in RMA'
  2566. STR R0,[R12,#v.areatype]
  2567. MOV R2,#v.areastart
  2568. LDR R3,[R12,#v.areasize]
  2569. BL claimrma
  2570. LDMFD R13!,{PC}
  2571.  
  2572. .setplotofsswi
  2573. STR R0,[R12,#v.plotxofs]
  2574. STR R1,[R12,#v.plotyofs]
  2575. MOV PC,R14
  2576.  
  2577. .readplotofsswi
  2578. LDR R0,[R12,#v.plotxofs]
  2579. LDR R1,[R12,#v.plotyofs]
  2580. MOV PC,R14
  2581.  
  2582. .defaultpath
  2583. DCB "File$Path",0
  2584. ALIGN
  2585.  
  2586. .loadfileswi
  2587. STMFD R13!,{R1-R9,R14}
  2588.          ; R1 = filename
  2589. MOV R3,R0; R3 = pointer address as supplied
  2590. MOV R4,R2; R4 = pathname
  2591. CMP R4,#0
  2592. ADREQ R4,defaultpath
  2593. MOV R0,#15
  2594. STMFD R13!,{R1-R4}
  2595. SWI XOS_File
  2596. MOV R6,R4; R6 = file length
  2597. LDMFD R13!,{R1-R4}
  2598. LDMVSFD R13!,{R1-R9,PC}
  2599. CMP R0,#1
  2600. LDMNEFD R13!,{R2-R10,R14} 
  2601. MOVNE R2,R0;for error report
  2602. BNE notafileerr
  2603.  
  2604. STMFD R13!,{R1-R4}
  2605. MOV R5,R1
  2606. ._loop
  2607. LDRB R0,[R5]
  2608. CMP R0,#32
  2609. ADDGT R5,R5,#1
  2610. BGT _loop
  2611. SUB R2,R5,#8
  2612. CMP R2,R1
  2613. MOVLT R2,R1
  2614. MOV R0,R3
  2615. MOV R1,R6
  2616. MOV R3,#2
  2617. BL claimblockswi
  2618. MOV R5,R0; R5 = block address
  2619. LDMFD R13!,{R1-R4}
  2620. LDMVSFD R13!,{R1-R9,PC}
  2621. STMFD R13!,{R1-R5}
  2622. MOV R0,#14
  2623. MOV R2,R5
  2624. MOV R3,#0 ; and R4 as preserved
  2625. SWI XOS_File
  2626. LDMFD R13!,{R1-R5}
  2627. LDMVSFD R13!,{R1-R9,PC}
  2628. MOV R0,R5
  2629. LDMFD R13!,{R1-R9,PC}^
  2630.  
  2631. .savefileswi
  2632. STMFD R13!,{R1-R9,R14}
  2633. STMFD R13!,{R1-R2}
  2634. BL describeblockswi
  2635. MOV R4,R2
  2636. ADD R5,R2,R3; end address
  2637. LDMFD R13!,{R1-R2}
  2638. LDMVSFD R13!,{R1-R9,PC}
  2639. MOV R0,#10
  2640. SWI XOS_File
  2641. LDMFD R13!,{R1-R9,PC} ;returns possible error from SWI
  2642.  
  2643. .loadhammeredswi
  2644. STMFD R13!,{R1-R9,R14}
  2645.         ; R1 = filename
  2646. MOV R7,R0; R7 = pointer address as supplied
  2647. CMP R2,#0
  2648. ADREQ R2,defaultpath
  2649. MOV R4,R2; R4 = pathname
  2650. MOV R0,#0
  2651. SWI XBlitz_HammerOp
  2652. LDMVSFD R13!,{R1-R9,PC}
  2653. MOV R6,R3
  2654. CMP R3,#0
  2655. MOVEQ R0,R7
  2656. LDMEQFD R13!,{R1-R9,R14}
  2657. BEQ loadfileswi
  2658.  
  2659. STMFD R13!,{R1-R4}
  2660. MOV R5,R1
  2661. ._loop
  2662. LDRB R0,[R5]
  2663. CMP R0,#32
  2664. ADDGT R5,R5,#1
  2665. BGT _loop
  2666. SUB R2,R5,#8
  2667. CMP R2,R1
  2668. MOVLT R2,R1
  2669. MOV R0,R7
  2670. MOV R1,R6
  2671. MOV R3,#2
  2672. BL claimblockswi
  2673. MOV R8,R0; R8 = block address
  2674. LDMFD R13!,{R1-R4}
  2675. LDMVSFD R13!,{R1-R9,PC}
  2676. MOV R0,#1
  2677. MOV R2,R4
  2678. MOV R3,R8
  2679. SWI XBlitz_HammerOp
  2680. LDMVSFD R13!,{R1-R9,PC}
  2681. MOV R0,R8
  2682. LDMFD R13!,{R1-R9,PC}^
  2683.  
  2684.  
  2685. .claimrma
  2686.  
  2687. ;on entry    r2=pointer to block is at r12+r2 block
  2688. ;        r3=requested size
  2689. ;sets V if error
  2690.  
  2691. STMFD R13!,{R0-R4,R14}
  2692. MOV R0,#6
  2693. MOV R4,R2
  2694. SWI XOS_Module
  2695. MOVVS R2,#0
  2696. STR R2,[R12,R4]
  2697. LDMFD R13!,{R0-R4,PC}
  2698.  
  2699. .releaserma
  2700. STMFD R13!,{R0-R4,R14}
  2701. MOV R0,#7
  2702. MOV R4,R2
  2703. LDR R2,[R12,R2]
  2704. SWI XOS_Module
  2705. BLVS releaseerr
  2706. MOV R2,#0
  2707. STR R2,[R12,R4]
  2708. LDMFD R13!,{R0-R4,PC}
  2709. .releaseerr
  2710. STMFD R13!,{R14}
  2711. ADD R0,R0,#4
  2712. SWI OS_Write0
  2713. SWI OS_NewLine
  2714. LDMFD R13!,{PC}
  2715.  
  2716. .strncpy
  2717. STMFD R13!,{R0-R4,R14}
  2718. MOV R4,#0
  2719. MOV R3,#1; ie not zero
  2720. .loop6
  2721. CMP R3,#0
  2722. LDRNEB R3,[R1],#1
  2723. CMP R3,#"'"
  2724. BLEQ strnquote
  2725. STRB R3,[R0],#1
  2726. SUBS R2,R2,#1
  2727. BGT loop6
  2728. LDMFD R13!,{R0-R4,PC}
  2729. .strnquote
  2730. CMP R4,#"'"
  2731. MOVEQ R3,#0
  2732. MOVEQ PC,R14
  2733. MOV R4,#"'"
  2734. LDRB R3,[R1],#1
  2735. CMP R3,#"'"
  2736. MOVEQ R3,#0
  2737. MOV PC,R14
  2738.  
  2739. .service
  2740. CMP R1,#&4E
  2741. MOVNES PC,R14
  2742. STMFD R13!,{R0-R12,R14}
  2743. LDR R12,[R12]
  2744. BL newapplication
  2745. LDMFD R13!,{R0-R12,PC}
  2746.  
  2747. .init
  2748. STMFD R13!,{R7-R12,R14}
  2749. MOV R0,#6
  2750. MOV R3,#v.sizeof
  2751. SWI XOS_Module
  2752. STR R2,[R12]
  2753. LDR R12,[R12]
  2754. BVS initabort
  2755. MOV R0,#0
  2756. STR R0,[R12,#v.areastart]
  2757. STR R0,[R12,#v.gravx]
  2758. STR R0,[R12,#v.gravy]
  2759. LDMFD R13!,{R7-R12,PC}
  2760.  
  2761. .final
  2762. STMFD R13!,{R7-R12,R14}
  2763. LDR R12,[R12]
  2764. BL discardarea
  2765. .initabort
  2766. MOV R0,#7
  2767. MOV R2,R12
  2768. SWI XOS_Module
  2769. LDMFD R13!,{R7-R12,PC}^
  2770.  
  2771. .badnumber
  2772. STMFD R13!,{R0}
  2773. ._loop
  2774. LDRB R0,[R1],#1
  2775. CMP R0,#" "
  2776. SWIGE OS_WriteC
  2777. BLGE _loop
  2778. SWI OS_WriteS
  2779. DCB 10,13,"!",10,13,0
  2780. ALIGN
  2781. LDMFD R13!,{R0}
  2782. SWI OS_GenerateError
  2783.  
  2784.  
  2785. .err
  2786. ORR R14,R14,#1<<28
  2787. MOVS PC,R14
  2788. .unknownswi
  2789. ADR R0,unknownswitext
  2790. B err
  2791. .unknownswitext
  2792. DCD &80C901
  2793. DCB "Amnesia : Unrecognised SWI",0
  2794. ALIGN
  2795. .amsnomatcherr
  2796. ADR R0,nomatcherrblock
  2797. B err
  2798. .nomatcherrblock
  2799. DCD &80C902
  2800. DCB "Amnesia : Unrecognised SWI tail",0
  2801. ALIGN
  2802. .badblockerr
  2803. ADR R0,badblocktext
  2804. B err
  2805. .badblocktext
  2806. DCD &80C903
  2807. DCB "Amnesia : Invalid memory block",0
  2808. ALIGN
  2809. .noroomrmaerr
  2810. ADR R0,noroomrmatext
  2811. B err
  2812. .noroomrmatext
  2813. DCD &80C904
  2814. DCB "Amnesia : Not enough memory in module area",0
  2815. ALIGN
  2816. .noroomerr
  2817. ADR R0,noroomtext
  2818. B err
  2819. .noroomtext
  2820. DCD &80C905
  2821. DCB "Amnesia : Not enough memory in Amnesia area",0
  2822. ALIGN
  2823. .notiniterr
  2824. ADR R0,notinittext
  2825. B err
  2826. .notinittext
  2827. DCD &80C906
  2828. DCB "Amnesia : Cannot perform operation - no area initialised",0
  2829. ALIGN
  2830. .toomanyerr
  2831. ADR R0,toomanytext
  2832. B err
  2833. .toomanytext
  2834. DCD &80C907
  2835. DCB "Amnesia : *** Aborting - Too many errors",0
  2836. ALIGN
  2837. .usedbadblockerr
  2838. ADR R0,usedbadblocktext
  2839. B err
  2840. .usedbadblocktext
  2841. DCD &80C908
  2842. DCB "Amnesia : Bad block detected when calculating used space",0
  2843. ALIGN
  2844. .scanbadblockerr
  2845. MOV R1,R0
  2846. ADR R0,scanbadblocktext
  2847. B err
  2848. .scanbadblocktext
  2849. DCD &80C909
  2850. DCB "Amnesia : Bad block detected when scanning block table",0
  2851. ALIGN
  2852. .badptrerr
  2853. ADR R0,badptrtext
  2854. B err
  2855. .badptrtext
  2856. DCD &80C90A
  2857. DCB "Amnesia : Supplied pointer address is not in valid memory",0
  2858. ALIGN
  2859. .tlisterr
  2860. STMFD R13!,{R14}
  2861. ADD R0,R0,#4
  2862. MOV R1,#0
  2863. MOV R2,#0
  2864. SWI OS_PrettyPrint
  2865. SWI OS_NewLine
  2866. LDMFD R13!,{R14}
  2867. ADR R0,tlisterrtext
  2868. B err
  2869. .tlisterrtext
  2870. DCD &80C90B
  2871. DCB "Amnesia : Failed to make a table list",0
  2872. ALIGN
  2873. .errbuf
  2874. DCD 0
  2875. .getblockerr
  2876. STR R0,[R12,#v.errorblock]
  2877. ADR R0,getblockerrtext
  2878. B err
  2879. .getblockerrtext
  2880. DCD &80C90C
  2881. DCB "Amnesia : Block does not exist",0
  2882. ALIGN
  2883. .notlisterr
  2884. ADR R0,notlisterrtext
  2885. B err
  2886. .notlisterrtext
  2887. DCD &80C90D
  2888. DCB "Amnesia : Cannot produce table - no internal table list",0
  2889. ALIGN
  2890. .tabletoohigherr
  2891. STR R0,[R12,#v.errortable]
  2892. ADR R0,tabletoohigherrtext
  2893. B err
  2894. .tabletoohigherrtext
  2895. DCD &80C90E
  2896. DCB "Amnesia : Table number is too high",0
  2897. ALIGN
  2898. .notableerr
  2899. STR R0,[R12,#v.errortable]
  2900. ADR R0,notableerrtext
  2901. B err
  2902. .notableerrtext
  2903. DCD &80C90F
  2904. DCB "Amnesia : Reference to table which does not exist",0
  2905. ALIGN
  2906. .notfoundblockerr
  2907. STR R0,[R12,#v.errorblock]
  2908. ADR R0,notfoundblockerrtext
  2909. B err
  2910. .notfoundblockerrtext
  2911. DCD &80C910
  2912. DCB "Amnesia : Cannot find requested block",0
  2913. ALIGN
  2914. .areacorrupterr
  2915. ADR R0,areacorrupterrtext
  2916. B err
  2917. .areacorrupterrtext
  2918. DCD &80C911
  2919. DCB "Amnesia : Area is corrupted.  Use *Ams Blocks",0
  2920. ALIGN
  2921. .badareaerr
  2922. STMFD R13!,{R14}
  2923. SWI OS_NewLine
  2924. LDMFD R13!,{R14}
  2925. ADR R0,badareaerrtext
  2926. B err
  2927. .badareaerrtext
  2928. DCD &80C912
  2929. DCB "Amnesia : Amnesia area is not consistent with normal operation",0
  2930. ALIGN
  2931. .movenonblockerr
  2932. STR R0,[R12,#v.errorblock]
  2933. ADR R0,movenonblockerrtext
  2934. B err
  2935. .movenonblockerrtext
  2936. DCD &80C913
  2937. DCB "Amnesia : Attempt to move a bad block",0
  2938. ALIGN
  2939.  
  2940. .inconblockerr
  2941. ADR R0,inconblockerrtext
  2942. B err
  2943. .inconblockerrtext
  2944. DCD &80C914
  2945. DCB "Amnesia : Block position and pointer to position do not agree",0
  2946. ALIGN
  2947. .needspaceerr
  2948. ADR R0,needspaceerrtext
  2949. B err
  2950. .needspaceerrtext
  2951. DCD &80C915
  2952. DCB "Amnesia : Abbreviated SWI tails with parameters must be followed by a space",0
  2953. ALIGN
  2954. .objectoutsideerr
  2955. STR R0,[R12,#v.errortable]
  2956. ADR R0,objectoutsideerrtext
  2957. B err
  2958. .objectoutsideerrtext
  2959. DCD &80C916
  2960. DCB "Amnesia : ProcessTable has received an object address outside of the table",0
  2961. ALIGN
  2962. .windownonerr
  2963. ADR R0,windownonerrtext
  2964. B err
  2965. .windownonerrtext
  2966. DCD &80C917
  2967. DCB "Amnesia : Bad window number - must be 0-2",0
  2968. ALIGN
  2969. .windowdodgyerr
  2970. ADR R0,windowdodgyerrtext
  2971. B err
  2972. .windowdodgyerrtext
  2973. DCD &80C918
  2974. DCB "Amnesia : Bad window - minimum greater than maximum",0
  2975. ALIGN
  2976. .colchnotableerr
  2977. ADR R0,colchnotableerrtext
  2978. B err
  2979. .colchnotableerrtext
  2980. DCD &80C919
  2981. DCB "Amnesia : Collision checking not requested when claiming table",0
  2982. ALIGN
  2983. .colchnoroomerr
  2984. ADR R0,colchnoroomerrtext
  2985. B err
  2986. .colchnoroomerrtext
  2987. DCD &80C920
  2988. DCB "Amnesia : No room in collision checking block",0
  2989. ALIGN
  2990. .notafileerr
  2991. STMFD R13!,{R14}
  2992. MOV R0,#19
  2993. SWI XOS_File
  2994. LDMFD R13!,{R14}
  2995. B err
  2996. .fatalerr
  2997. ADR R0,fatalerrtext
  2998. B err
  2999. .fatalerrtext
  3000. DCD &80C921
  3001. DCB "Amnesia : ***** Internal error ***** - please report any appearance of this error to the author, together with the circumstances in which the error occured.",0
  3002. ALIGN
  3003. .qwaerr
  3004. STR R0,[R12,#v.errorblock]
  3005. ADR R0,qwaerrtext
  3006. B err
  3007. .qwaerrtext
  3008. DCD &80C922
  3009. DCB "Amnesia : Area tidy would require a forward block shift.  Area corrupt?",0
  3010. ALIGN
  3011. .notyeterr
  3012. ADR R0,notyeterrtext
  3013. B err
  3014. .notyeterrtext
  3015. DCD &80C924
  3016. DCB "Amnesia : SWI not supported by this version",0
  3017. ALIGN
  3018. .badsaveerr
  3019. ADR R0,badsaveerrtext
  3020. B err
  3021. .badsaveerrtext
  3022. DCD &80C925
  3023. DCB "Amnesia : Failed to save",0
  3024. ALIGN
  3025.  
  3026. .remoteerr
  3027. ADR R0,remoteerrtext
  3028. B err
  3029. .remoteerrtext
  3030. DCD &80C926
  3031. DCB "Amnesia : Remote routine guard ID not present.  The word before the routine must be &006E0000.",0
  3032. ALIGN
  3033.  
  3034. .namematchwarn
  3035. STMFD R13!,{R14}
  3036. SWI OS_WriteS
  3037. DCB "Amnesia : LoadTable warning - The table name does not match that in the file",10,13,0
  3038. ALIGN
  3039. LDMFD R13!,{PC}
  3040.  
  3041. .objsizewarn
  3042. STMFD R13!,{R14}
  3043. SWI OS_WriteS
  3044. DCB "Amnesia : LoadTable warning - Object length does not match that in the file",10,13,0
  3045. ALIGN
  3046. LDMFD R13!,{PC}
  3047.