home *** CD-ROM | disk | FTP | other *** search
/ Acorn User 10 / AU_CD10.iso / Updates / Perl / Non-RPC / !Perl / lib / zip / File / Copy.pm < prev    next >
Text File  |  1999-04-02  |  11KB  |  347 lines
  1. # File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
  2. # source code has been placed in the public domain by the author.
  3. # Please be kind and preserve the documentation.
  4. #
  5. # Additions copyright 1996 by Charles Bailey.  Permission is granted
  6. # to distribute the revised code under the same terms as Perl itself.
  7.  
  8. package File::Copy;
  9.  
  10. use strict;
  11. use Carp;
  12. use vars qw(@ISA @EXPORT @EXPORT_OK $VERSION $Too_Big
  13.         © &syscopy &cp &mv);
  14.  
  15. # Note that this module implements only *part* of the API defined by
  16. # the File/Copy.pm module of the File-Tools-2.0 package.  However, that
  17. # package has not yet been updated to work with Perl 5.004, and so it
  18. # would be a Bad Thing for the CPAN module to grab it and replace this
  19. # module.  Therefore, we set this module's version higher than 2.0.
  20. $VERSION = '2.02';
  21.  
  22. require Exporter;
  23. @ISA = qw(Exporter);
  24. @EXPORT = qw(copy move);
  25. @EXPORT_OK = qw(cp mv);
  26.  
  27. $Too_Big = 1024 * 1024 * 2;
  28.  
  29. sub _catname { #  Will be replaced by File::Spec when it arrives
  30.     my($from, $to) = @_;
  31.     if (not defined &basename) {
  32.     require File::Basename;
  33.     import  File::Basename 'basename';
  34.     }
  35.     if ($^O eq 'VMS')  { $to = VMS::Filespec::vmspath($to) . basename($from); }
  36.     elsif ($^O eq 'MacOS') { $to .= ':' . basename($from); }
  37.     elsif ($^O eq 'riscos' &&
  38.        (!defined &RISCOS::Filespec::convert
  39.         || !&RISCOS::Filespec::convert()))
  40.        { $to .= '.' . basename($from); }
  41.     elsif ($to =~ m|\\|)   { $to .= '\\' . basename($from); }
  42.     else                   { $to .= '/' . basename($from); }
  43. }
  44.  
  45. sub copy {
  46.     croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
  47.       unless(@_ == 2 || @_ == 3);
  48.  
  49.     my $from = shift;
  50.     my $to = shift;
  51.  
  52.     my $from_a_handle = (ref($from)
  53.              ? (ref($from) eq 'GLOB'
  54.                 || UNIVERSAL::isa($from, 'GLOB')
  55.                             || UNIVERSAL::isa($from, 'IO::Handle'))
  56.              : (ref(\$from) eq 'GLOB'));
  57.     my $to_a_handle =   (ref($to)
  58.              ? (ref($to) eq 'GLOB'
  59.                 || UNIVERSAL::isa($to, 'GLOB')
  60.                             || UNIVERSAL::isa($to, 'IO::Handle'))
  61.              : (ref(\$to) eq 'GLOB'));
  62.  
  63.     if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
  64.     $to = _catname($from, $to);
  65.     }
  66.  
  67.     if (defined &syscopy && \&syscopy != \©
  68.     && !$to_a_handle
  69.     && !($from_a_handle && $^O eq 'os2' )    # OS/2 cannot handle handles
  70.     && !($from_a_handle && $^O eq 'mpeix')    # and neither can MPE/iX.
  71.        )    
  72.     {
  73.     return syscopy($from, $to);
  74.     }
  75.  
  76.     my $closefrom = 0;
  77.     my $closeto = 0;
  78.     my ($size, $status, $r, $buf);
  79.     local(*FROM, *TO);
  80.     local($\) = '';
  81.  
  82.     if ($from_a_handle) {
  83.     *FROM = *$from{FILEHANDLE};
  84.     } else {
  85.     $from = "./$from" if $from =~ /^\s/;
  86.     open(FROM, "< $from\0") or goto fail_open1;
  87.     binmode FROM or die "($!,$^E)";
  88.     $closefrom = 1;
  89.     } 
  90.  
  91.     if ($to_a_handle) {
  92.     *TO = *$to{FILEHANDLE};
  93.     } else {        
  94.     $to = "./$to" if $to =~ /^\s/;
  95.     open(TO,"> $to\0") or goto fail_open2;
  96.     binmode TO or die "($!,$^E)";
  97.     $closeto = 1;
  98.     }  
  99.  
  100.     if (@_) {
  101.     $size = shift(@_) + 0;
  102.     croak("Bad buffer size for copy: $size\n") unless ($size > 0);
  103.     } else {
  104.     $size = -s FROM;
  105.     $size = 1024 if ($size < 512);
  106.     $size = $Too_Big if ($size > $Too_Big);
  107.     }
  108.  
  109.     $! = 0;
  110.     for (;;) {
  111.     my ($r, $w, $t);
  112.     defined($r = sysread(FROM, $buf, $size))
  113.         or goto fail_inner;
  114.     last unless $r;
  115.     for ($w = 0; $w < $r; $w += $t) {
  116.         $t = syswrite(TO, $buf, $r - $w, $w)
  117.         or goto fail_inner;
  118.     }
  119.     }
  120.  
  121.     close(TO) || goto fail_open2 if $closeto;
  122.     close(FROM) || goto fail_open1 if $closefrom;
  123.  
  124.     # Use this idiom to avoid uninitialized value warning.
  125.     return 1;
  126.     
  127.     # All of these contortions try to preserve error messages...
  128.   fail_inner:
  129.     if ($closeto) {
  130.     $status = $!;
  131.     $! = 0;
  132.     close TO;
  133.     $! = $status unless $!;
  134.     }
  135.   fail_open2:
  136.     if ($closefrom) {
  137.     $status = $!;
  138.     $! = 0;
  139.     close FROM;
  140.     $! = $status unless $!;
  141.     }
  142.   fail_open1:
  143.     return 0;
  144. }
  145.  
  146. sub move {
  147.     my($from,$to) = @_;
  148.     my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
  149.  
  150.     if (-d $to && ! -d $from) {
  151.     $to = _catname($from, $to);
  152.     }
  153.  
  154.     ($tosz1,$tomt1) = (stat($to))[7,9];
  155.     $fromsz = -s $from;
  156.     if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
  157.       # will not rename with overwrite
  158.       unlink $to;
  159.     }
  160.     return 1 if rename $from, $to;
  161.  
  162.     ($sts,$ossts) = ($! + 0, $^E + 0);
  163.     # Did rename return an error even though it succeeded, because $to
  164.     # is on a remote NFS file system, and NFS lost the server's ack?
  165.     return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
  166.                 (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
  167.                 ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
  168.                 $tosz2 == $fromsz;                         # it's all there
  169.  
  170.     ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
  171.     return 1 if ($copied = copy($from,$to)) && unlink($from);
  172.   
  173.     ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
  174.     unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
  175.     ($!,$^E) = ($sts,$ossts);
  176.     return 0;
  177. }
  178.  
  179. *cp = \©
  180. *mv = \&move;
  181.  
  182. # &syscopy is an XSUB under OS/2
  183. unless (defined &syscopy) {
  184.     if ($^O eq 'VMS') {
  185.     *syscopy = \&rmscopy;
  186.     } elsif ($^O eq 'mpeix') {
  187.     *syscopy = sub {
  188.         return 0 unless @_ == 2;
  189.         # Use the MPE cp program in order to
  190.         # preserve MPE file attributes.
  191.         return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
  192.     };
  193.     } else {
  194.     *syscopy = \©
  195.     }
  196. }
  197.  
  198. 1;
  199.  
  200. __END__
  201.  
  202. =head1 NAME
  203.  
  204. File::Copy - Copy files or filehandles
  205.  
  206. =head1 SYNOPSIS
  207.  
  208.       use File::Copy;
  209.  
  210.     copy("file1","file2");
  211.       copy("Copy.pm",\*STDOUT);'
  212.     move("/dev1/fileA","/dev2/fileB");
  213.  
  214.       use POSIX;
  215.     use File::Copy cp;
  216.  
  217.     $n=FileHandle->new("/dev/null","r");
  218.     cp($n,"x");'
  219.  
  220. =head1 DESCRIPTION
  221.  
  222. The File::Copy module provides two basic functions, C<copy> and
  223. C<move>, which are useful for getting the contents of a file from
  224. one place to another.
  225.  
  226. =over 4
  227.  
  228. =item *
  229.  
  230. The C<copy> function takes two
  231. parameters: a file to copy from and a file to copy to. Either
  232. argument may be a string, a FileHandle reference or a FileHandle
  233. glob. Obviously, if the first argument is a filehandle of some
  234. sort, it will be read from, and if it is a file I<name> it will
  235. be opened for reading. Likewise, the second argument will be
  236. written to (and created if need be).
  237.  
  238. B<Note that passing in
  239. files as handles instead of names may lead to loss of information
  240. on some operating systems; it is recommended that you use file
  241. names whenever possible.>  Files are opened in binary mode where
  242. applicable.  To get a consistent behaviour when copying from a
  243. filehandle to a file, use C<binmode> on the filehandle.
  244.  
  245. An optional third parameter can be used to specify the buffer
  246. size used for copying. This is the number of bytes from the
  247. first file, that wil be held in memory at any given time, before
  248. being written to the second file. The default buffer size depends
  249. upon the file, but will generally be the whole file (up to 2Mb), or
  250. 1k for filehandles that do not reference files (eg. sockets).
  251.  
  252. You may use the syntax C<use File::Copy "cp"> to get at the
  253. "cp" alias for this function. The syntax is I<exactly> the same.
  254.  
  255. =item *
  256.  
  257. The C<move> function also takes two parameters: the current name
  258. and the intended name of the file to be moved.  If the destination
  259. already exists and is a directory, and the source is not a
  260. directory, then the source file will be renamed into the directory
  261. specified by the destination.
  262.  
  263. If possible, move() will simply rename the file.  Otherwise, it copies
  264. the file to the new location and deletes the original.  If an error occurs
  265. during this copy-and-delete process, you may be left with a (possibly partial)
  266. copy of the file under the destination name.
  267.  
  268. You may use the "mv" alias for this function in the same way that
  269. you may use the "cp" alias for C<copy>.
  270.  
  271. =back
  272.  
  273. File::Copy also provides the C<syscopy> routine, which copies the
  274. file specified in the first parameter to the file specified in the
  275. second parameter, preserving OS-specific attributes and file
  276. structure.  For Unix systems, this is equivalent to the simple
  277. C<copy> routine.  For VMS systems, this calls the C<rmscopy>
  278. routine (see below).  For OS/2 systems, this calls the C<syscopy>
  279. XSUB directly.
  280.  
  281. =head2 Special behaviour if C<syscopy> is defined (VMS and OS/2)
  282.  
  283. If both arguments to C<copy> are not file handles,
  284. then C<copy> will perform a "system copy" of
  285. the input file to a new output file, in order to preserve file
  286. attributes, indexed file structure, I<etc.>  The buffer size
  287. parameter is ignored.  If either argument to C<copy> is a
  288. handle to an opened file, then data is copied using Perl
  289. operators, and no effort is made to preserve file attributes
  290. or record structure.
  291.  
  292. The system copy routine may also be called directly under VMS and OS/2
  293. as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
  294. is the routine that does the actual work for syscopy).
  295.  
  296. =over 4
  297.  
  298. =item rmscopy($from,$to[,$date_flag])
  299.  
  300. The first and second arguments may be strings, typeglobs, typeglob
  301. references, or objects inheriting from IO::Handle;
  302. they are used in all cases to obtain the
  303. I<filespec> of the input and output files, respectively.  The
  304. name and type of the input file are used as defaults for the
  305. output file, if necessary.
  306.  
  307. A new version of the output file is always created, which
  308. inherits the structure and RMS attributes of the input file,
  309. except for owner and protections (and possibly timestamps;
  310. see below).  All data from the input file is copied to the
  311. output file; if either of the first two parameters to C<rmscopy>
  312. is a file handle, its position is unchanged.  (Note that this
  313. means a file handle pointing to the output file will be
  314. associated with an old version of that file after C<rmscopy>
  315. returns, not the newly created version.)
  316.  
  317. The third parameter is an integer flag, which tells C<rmscopy>
  318. how to handle timestamps.  If it is E<lt> 0, none of the input file's
  319. timestamps are propagated to the output file.  If it is E<gt> 0, then
  320. it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
  321. timestamps other than the revision date are propagated; if bit 1
  322. is set, the revision date is propagated.  If the third parameter
  323. to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
  324. if the name or type of the output file was explicitly specified,
  325. then no timestamps are propagated, but if they were taken implicitly
  326. from the input filespec, then all timestamps other than the
  327. revision date are propagated.  If this parameter is not supplied,
  328. it defaults to 0.
  329.  
  330. Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
  331. it sets C<$!>, deletes the output file, and returns 0.
  332.  
  333. =back
  334.  
  335. =head1 RETURN
  336.  
  337. All functions return 1 on success, 0 on failure.
  338. $! will be set if an error was encountered.
  339.  
  340. =head1 AUTHOR
  341.  
  342. File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
  343. and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
  344.  
  345. =cut
  346.  
  347.