Amiga Format 104/af104sub.adf/MUIBank.LZX/MUIBank1.61/Installation

Text File | 1988-01-24 | 6KB | 227 lines

; $VER: Installation MUIBank 1.61 (18.09.97) by David PRESLE

(complete 0)

;####################################################################
; Création de quelques variables

(if (= @language "français")
(
;*** Choix du repertoire ***
(set MessChoixDir "Où voulez vous créer le répertoire MUIBank?")
(set AideChoixDir
    (cat "  Sélectionnez l'endroit où le repertoire MUIBank sera créé.\n"
         "  Ce répertoire servira à stocker tous les fichiers de MUIBank."
    )
)

;*** Choix du processeur ***
(set MessChoixProc "Quelle version compilée de MUIBank voulez-vous installer?")
(set AideChoixProc
    (cat "  Il existe deux versions compilées de MUIBank : une pour le processeur 68000 et une autre pour le 68020.\n"
         "  Si vous avez un 68000 ou 68010, choisissez \"68000\" sinon \"68020\"."
    )
)

;*** Choix des catalogues ***
(set MessChoixCat
    (cat "Quels catalogues voulez-vous installer?\n"
         "Si vous en installer aucun, MUIBank sera en français."
    )
)
(set AideChoixCat
    (cat "  Les catalogues permettent de localiser les applications.\n"
         "  Cochez les cases qui correspondent aux langues que vous voulez installer."
    )
)

;*** Choix Fichier Guide ***
(set MessChoixGuide "Voulez-vous installer la documentation française (\"MUIBank.guide\")?")
(set AideChoixGuide
    (cat "  Le fichier \"MUIBank.guide\" contient toute la documentation concernant MUIBank. De plus, ce fichier est nécessaire si vous voulez obtenir de l'aide en ligne.\n"
         "  Si vous choisissez de le copier, ce fichier sera stocké dans le même répertoire que MUIBank."
    )
)

;*** Choix Fichier Exemple ***
(set MessChoixExemple "Voulez-vous copier le fichier d'exemple \"Example.account\"?")
(set AideChoixExemple
    (cat "  Le fichier d'exemple permet d'avoir un aperçu des possibilités de MUIBank.\n"
         "  Si vous choisissez de le copier, ce fichier sera stocké dans le même répertoire que MUIBank."
    )
)
)
)

;*********************************************************************

(if (= @language "english")
(
;*** Choix du repertoire ***
(set MessChoixDir "Where do you want to create the MUIBank directory?")
(set AideChoixDir
    (cat "  Select the path where the MUIBank's directory will be created.\n"
         "  All MUIBank's files will be copied into this directory."
    )
)

;*** Choix du processeur ***
(set MessChoixProc "Which compiled version of MUIBank do you want to install?")
(set AideChoixProc
    (cat "  MUIbank exists in two compiled versions : one for the 68000 processor and an other for the 68020.\n"
         "  If you have got a 68000 or 68010, choose \"68000\" or else \"68020\"."
    )
)

;*** Choix des catalogues ***
(set MessChoixCat
    (cat "Please select catalogs to install.\n"
         "If you don't install any catalog, MUIBank's interface will be in French."
    )
)
(set AideChoixCat
    (cat "  Catalogs are used in order to localize an application.\n"
         "  Simply select the languages you want to install."
    )
)

;*** Choix Fichier Guide ***
(set MessChoixGuide "Do you want to install the french documentation (\"MUIBank.guide\")?")
(set AideChoixGuide
    (cat "  The \"MUIBank.guide\" file contents all the documentation about MUIBank. Moreover, this file is necessary if you want online help.\n"
         "  If you decide to copy this file, it will be saved in the MUIBank's directory."
    )
)

;*** Choix Fichier Exemple ***
(set MessChoixExemple "Do you want to copy the file \"Example.account\"?")
(set AideChoixExemple
    (cat "  This example will show you all MUIBank's capabilities and options.\n"
         "  If you decide to copy this file, it will be saved in the MUIBank's directory."
    )
)
)
)

(complete 15)

;####################################################################
;Choix et création du repertoire

(set DestDir
        (askdir
            (prompt MessChoixDir)
            (help AideChoixDir)
            (default ":")
        )
)

(set DestDir (expandpath DestDir))
(set @default-dest (tackon DestDir "MUIBank"))

(makedir @default-dest)
(set Icone (cat (expandpath "/") ".info"))
(if (= (exists Icone) 1)
    (copyfiles (source Icone) (dest DestDir) (newname "MUIBank.info") (noposition))
)

(complete 32)

;####################################################################
; Copie des fichiers

(if (patmatch "68000|68010" (database "cpu")) (set DefProc 0) (set DefProc 1))

(if (= @user-level 2)
    (set DefProc (askchoice
        (prompt MessChoixProc)
        (help AideChoixProc)
        (choices "68000" "68020")
        (default DefProc)
    ))
)

(if (= DefProc 0) (set Proc "/MUIBank.68000") (set Proc "/MUIBank.68020"))

(copyfiles
    (source Proc)
    (dest @default-dest)
    (newname "MUIBank")
    (infos)
    (noposition)
)

(copyfiles
    (source "")
    (dest @default-dest)
    (pattern "~(#?.info)")
    (infos)
    (noposition)
)

(complete 49)

;####################################################################
; Copie des catalogues

(if (= @language "français") (set #DefCat %0))
(if (= @language "english") (set #DefCat %1))

(if (= @user-level 2)
    (set #Rep
        (askoptions
            (prompt MessChoixcat)
            (help AideChoixCat)
            (choices "English")
            (default #DefCat)
        )
    )
    (set #Rep #DefCat)
)

(if (<> #Rep 0)
    (
    (set #DirCat (tackon @default-dest "catalogs"))
    (makedir #DirCat)
    )
)

(if (<> (IN #Rep 0) 0)
    (copyfiles (source "/catalogs/english/MUIBank.catalog")
               (dest (tackon @default-dest "catalogs/english"))
    )
)

(complete 66)

;####################################################################
; Copie du fichier MUIBank.guide?

(if (= @user-level 2)
    (
    if (askbool (prompt MessChoixGuide) (help AideChoixGuide))
        (
        copyfiles (source "/MUIBank.guide") (dest @default-dest) (infos) (noposition)
        )
    )
    (copyfiles (source "/MUIBank.guide") (dest @default-dest) (infos) (noposition))
)

(complete 73)

;####################################################################
; Copie du fichier Example.account?

(if (= @user-level 2)
    (
    if (askbool (prompt MessChoixExemple) (help AideChoixExemple))
        (
        copyfiles (source "/Example.account") (dest @default-dest)
        )
    )
    (copyfiles (source "/Example.account") (dest @default-dest))
)

(complete 100)

;####################################################################