home *** CD-ROM | disk | FTP | other *** search
/ Dream 57 / Amiga_Dream_57.iso / Amiga / Programmation / e / Exemples / Bezier.lha / bezier.e next >
Encoding:
Text File  |  1998-04-10  |  10.5 KB  |  350 lines
  1. /****** teaching/bezier *******************************************
  2. * 
  3. *   NAME
  4. *       bezier -- draw moving BΘzier spline.
  5. *
  6. *   SYNOPSIS
  7. *       bezier
  8. *
  9. *   FUNCTION
  10. *       Draws an animated BΘzier spline on the screen.
  11. *       Demonstrates with 4 rebounding points on screen, A B C and D.
  12. *       You should see that the spline runs from A to D, heading to B
  13. *       from point A, and ending facing away from C at point D. If that
  14. *       didn't make sense, just run it :)
  15. *
  16. *       Working example to accompany tutorial in Defy 4 from Cydonia :)
  17. *
  18. *   RESULT
  19. *       Demonstrates the following topics:
  20. *       - ASL ScreenMode requester
  21. *       - Intuition double-buffering
  22. *       - Use of fixed-point math. (fixed.m)
  23. *       - Basic 680x0 instructions
  24. *       - Recursive subdivision
  25. *
  26. *   EXAMPLES
  27. *       As an exercise for the reader, possible extensions include:
  28. *       - Multiple splines - trails, joined shapes, screen blankers
  29. *       - Automated decisions on how many subdivisions to make, and whether
  30. *         to use points or lines.
  31. *       - User influence on movement
  32. *
  33. *   NOTE
  34. *       You should be able to see two levels of abstraction here. The main
  35. *       loop is concerned with the screen buffering, timing and user input,
  36. *       whereas init()/done() and draw() only know of a 'virtual' screen
  37. *       whose boundaries are given in init, and they may only write using
  38. *       stdrast and graphics functions.
  39. *
  40. *       We use 'fixed point' arithmetic - basically, add 16 bits of extra
  41. *       significance, work with it, then take it away when finished
  42. *       calculating.
  43. *
  44. *       We use a very complicated line of code in the double-buffering code:
  45. *       IF sig THEN
  46. *         WHILE m:=GetMsg(port) DO status[1-Long(m+SIZEOF mn)]:=OK_REDRAW
  47. *
  48. *       Basically, on the first run we are allowed to draw into either buffer
  49. *       then 'swap it in'. When we swap it in, we ask the system to send us
  50. *       a message to say it has been swapped in, therefore the other buffer
  51. *       has been swapped out. We know that it will use the message in the
  52. *       DBufInfo structure, and right after this is the UserData1 long.
  53. *       So we can access the long directly after the message we get from
  54. *       GetMsg(), 'Long(m + SIZEOF mn)', and say that the other buffer
  55. *       '1-', is ok to redraw into: 'status[...]:=OK_REDRAW'
  56. *
  57. *   SEE ALSO
  58. *       bezier.txt
  59. *
  60. ****************************************************************************
  61. *
  62. *
  63. */
  64.  
  65. OPT PREPROCESS
  66. OPT OSVERSION=39
  67.  
  68. MODULE 'asl', 'exec/ports', 'graphics/displayinfo', 'graphics/rastport',
  69.        'graphics/view', 'intuition/intuition', 'intuition/screens',
  70.        'libraries/asl', 'utility/tagitem', '*fixed'
  71.  
  72. -> the left/top/right/bottom edges of our screen
  73. DEF lft, top, rgt, bot
  74.  
  75. ->--------------------------------------------------------------------------
  76.  
  77. -> A B C and D are vectors - points on the screen with a direction.
  78. OBJECT vector
  79.    x,  y
  80.    dx, dy
  81. ENDOBJECT
  82.  
  83. DEF a:PTR TO vector,
  84.     b:PTR TO vector,
  85.     c:PTR TO vector,
  86.     d:PTR TO vector
  87.  
  88. PROC rand() OF vector
  89.   -> create new vector with random position/movement (within screen limits)
  90.  
  91.   self.x  := Rnd(rgt-lft) + lft
  92.   self.y  := Rnd(bot-top) + top
  93.   self.dx := (Rnd(10)-5) OR 1  -> between -5 and 5 but not 0
  94.   self.dy := (Rnd(10)-5) OR 1
  95. ENDPROC
  96.  
  97. PROC move() OF vector
  98.   -> move and bounce around the limits of the screen (l/r/t/b)
  99.  
  100.   IF self.x <= lft THEN self.dx :=  (Rnd(5) OR 1)
  101.   IF self.x >= rgt THEN self.dx := -(Rnd(5) OR 1)
  102.   IF self.y <= top THEN self.dy :=  (Rnd(5) OR 1)
  103.   IF self.y >= bot THEN self.dy := -(Rnd(5) OR 1)
  104.  
  105.   self.x:=Bounds(self.x+self.dx, lft, rgt)
  106.   self.y:=Bounds(self.y+self.dy, top, bot)
  107. ENDPROC
  108.  
  109. ->--------------------------------------------------------------------------
  110.  
  111. PROC init(leftedge, topedge, width, height)
  112.   -> This is called once at the start from the main program, with
  113.   -> leftedge/topedge and width/height of the screen we'll be rendering on
  114.  
  115.   -> make a quite (!!) random seed
  116.   DEF bla; CurrentTime({bla},{bla}); Rnd(-Abs(Mul({arg},bla)))
  117.  
  118.   -> we set up the edges of our 'screen' appropriately
  119.   lft := leftedge
  120.   rgt := leftedge + width  - 1
  121.   top := topedge
  122.   bot := topedge  + height - 1
  123.  
  124.   -> create and give random positions and directions to our vectors
  125.   NEW a.rand()
  126.   NEW b.rand()
  127.   NEW c.rand()
  128.   NEW d.rand()
  129. ENDPROC
  130.  
  131. PROC done()
  132.   END a; END b; END c; END d
  133. ENDPROC
  134.  
  135. PROC draw()
  136.   -> called once per frame from the main loop. We should draw whatever to
  137.   -> stdrast.
  138.  
  139.   -> clear screen
  140.   SetAPen(stdrast, 0)
  141.   RectFill(stdrast, lft, top, rgt, bot)
  142.  
  143.   -> move vectors a, b, c and d.
  144.   a.move(); b.move(); c.move(); d.move()
  145.  
  146.   -> draw b to a to d to c in white
  147.   SetAPen(stdrast, 2)
  148.   Move(stdrast, b.x, b.y)
  149.   Draw(stdrast, a.x, a.y)
  150.   Draw(stdrast, d.x, d.y)
  151.   Draw(stdrast, c.x, c.y)
  152.  
  153.   -> draw bΘzier curve in black
  154.   SetAPen(stdrast, 1)
  155.   bezier(
  156.    inttofixed(a.x), inttofixed(a.y),
  157.    inttofixed(b.x), inttofixed(b.y),
  158.    inttofixed(c.x), inttofixed(c.y),
  159.    inttofixed(d.x), inttofixed(d.y)
  160.   )
  161. ENDPROC
  162.  
  163. ->--------------------------------------------------------------------------
  164.  
  165. PROC bezier(p1_x,p1_y, p2_x,p2_y, p3_x,p3_y, p4_x,p4_y, level=0)
  166.   ->  with thanks to Storm/Cydonia
  167.  
  168.   -> All  we  do  is  divide the curve into two seperate curves, and repeat
  169.   -> this  division  until we have many curves in which case we have enough
  170.   -> accuracy to get away with drawing these tiny curves as straight lines.
  171.  
  172.   -> P1  is  the start point of the curve (or curve segment). P4 is the end
  173.   -> point. P2 and P3 are the control points of it. We divide the 'P' curve
  174.   -> into  two  curves,  the  'L'  curve  (L1/L2/L3/L4)  and  the 'R' curve
  175.   -> (R1/R2/R3/R4).  The  L curve goes from the start point to the midpoint
  176.   -> of the P curve. The R curve goes from the midpoint to the end point of
  177.   -> the P curve.
  178.  
  179.   -> we do this 5 times, and end up with 2^5 parts = 32 line segments
  180.  
  181.   -> note that we take in and calculate with 'fixed point' coordinates
  182.   -> and turn them back into normal integers to draw the line segments.
  183.  
  184.   DEF l1_x,l1_y, l2_x,l2_y, l3_x,l3_y, l4_x,l4_y,
  185.       r1_x,r1_y, r2_x,r2_y, r3_x,r3_y, r4_x,r4_y,
  186.       h_x, h_y
  187.  
  188.   IF level>4
  189.     Move(stdrast, fixedtoint(p1_x), fixedtoint(p1_y))
  190.     Draw(stdrast, fixedtoint(p4_x), fixedtoint(p4_y))
  191.     RETURN
  192.   ENDIF
  193.  
  194.   -> register D1 = constant 1 (to speed up the LSR command)
  195.   MOVEQ   #1,D1
  196.  
  197.   -> L1 = P1
  198.   MOVE.L  p1_x,l1_x
  199.   MOVE.L  p1_y,l1_y
  200.  
  201.   -> R4 = P4
  202.   MOVE.L  p4_x,r4_x
  203.   MOVE.L  p4_y,r4_y
  204.  
  205.   -> L2 = average(P1, P2)
  206.   MOVE.L p1_x,D0; ADD.L p2_x,D0; LSR.L D1,D0; MOVE.L D0,l2_x
  207.   MOVE.L p1_y,D0; ADD.L p2_y,D0; LSR.L D1,D0; MOVE.L D0,l2_y
  208.  
  209.   -> R3 = average(P3, P4)
  210.   MOVE.L p3_x,D0; ADD.L p4_x,D0; LSR.L D1,D0; MOVE.L D0,r3_x
  211.   MOVE.L p3_y,D0; ADD.L p4_y,D0; LSR.L D1,D0; MOVE.L D0,r3_y
  212.  
  213.   -> H = average(P2, P3)
  214.   MOVE.L p2_x,D0; ADD.L p3_x,D0; LSR.L D1,D0; MOVE.L D0,h_x
  215.   MOVE.L p2_y,D0; ADD.L p3_y,D0; LSR.L D1,D0; MOVE.L D0,h_y
  216.  
  217.   -> L3 = average(L2, H)
  218.   MOVE.L l2_x,D0; ADD.L h_x,D0; LSR.L D1,D0; MOVE.L D0,l3_x
  219.   MOVE.L l2_y,D0; ADD.L h_y,D0; LSR.L D1,D0; MOVE.L D0,l3_y
  220.  
  221.   -> R2 = average(R3, H)
  222.   MOVE.L r3_x,D0; ADD.L h_x,D0; LSR.L D1,D0; MOVE.L D0,r2_x
  223.   MOVE.L r3_y,D0; ADD.L h_y,D0; LSR.L D1,D0; MOVE.L D0,r2_y
  224.  
  225.   -> L4 = average(L3, R2)
  226.   MOVE.L l3_x,D0; ADD.L r2_x,D0; LSR.L D1,D0; MOVE.L D0,l4_x
  227.   MOVE.L l3_y,D0; ADD.L r2_y,D0; LSR.L D1,D0; MOVE.L D0,l4_y
  228.  
  229.   -> R1 = L4
  230.   MOVE.L  l4_x,r1_x
  231.   MOVE.L  l4_y,r1_y
  232.  
  233.   -> and subdivide again...
  234.   bezier(l1_x,l1_y, l2_x,l2_y, l3_x,l3_y, l4_x,l4_y, level+1)
  235.   bezier(r1_x,r1_y, r2_x,r2_y, r3_x,r3_y, r4_x,r4_y, level+1)
  236. ENDPROC
  237.  
  238. ->--------------------------------------------------------------------------
  239.  
  240. ENUM OK_NONE,OK_REDRAW,OK_SWAPIN
  241.  
  242. PROC main() HANDLE
  243.   -> the main program - handle allocations, buffers, input, etc
  244.  
  245.   DEF s=NIL:PTR TO screen, w=NIL:PTR TO window, m:PTR TO intuimessage,
  246.  
  247.       sb:PTR TO screenbuffer, rp[2]:ARRAY OF rastport,
  248.       status[2]:ARRAY OF LONG, sbuf[2]:ARRAY OF LONG,
  249.       port=NIL:PTR TO mp,
  250.       held_off=FALSE, sigs=0, buf_current=0, buf_nextdraw=1, buf_nextswap=1
  251.  
  252.   sbuf:=[NIL, NIL]
  253.   status:=[OK_REDRAW, OK_REDRAW]
  254.   InitRastPort(rp[0])
  255.   InitRastPort(rp[1])
  256.  
  257.   IF (port:=CreateMsgPort())=NIL THEN Raise()
  258.  
  259.   -> open the screen
  260.   s := OpenScreenTagList(NIL, [
  261.     SA_DEPTH,     2,
  262.     SA_DISPLAYID, asl_modereq(),
  263.     SA_TITLE,     'BΘzier spline demo',
  264.     SA_PENS,      [-1]:INT,
  265.     TAG_DONE
  266.   ])
  267.   IF s=NIL THEN Raise()
  268.  
  269.   sbuf[0]:=AllocScreenBuffer(s, NIL, SB_SCREEN_BITMAP)
  270.   sbuf[1]:=AllocScreenBuffer(s, NIL, SB_COPY_BITMAP)
  271.  
  272.   IF (sbuf[0] AND sbuf[1])=NIL THEN Raise()
  273.  
  274.   sb:=sbuf[0]; sb.dbufinfo.userdata1:=0; rp[0].bitmap:=sb.bitmap
  275.   sb:=sbuf[1]; sb.dbufinfo.userdata1:=1; rp[1].bitmap:=sb.bitmap
  276.  
  277.   -> open a window to recieve input on the screen
  278.   w := OpenWindowTagList(NIL, [
  279.     WA_CUSTOMSCREEN, s,
  280.     WA_FLAGS,        WFLG_BORDERLESS OR WFLG_RMBTRAP,
  281.     WA_IDCMP,        IDCMP_VANILLAKEY OR IDCMP_MOUSEBUTTONS,
  282.     WA_BACKDROP,     TRUE,
  283.     WA_BORDERLESS,   TRUE,
  284.     WA_ACTIVATE,     TRUE,
  285.     TAG_DONE
  286.   ])
  287.   IF w=NIL THEN Raise()
  288.  
  289.   init(0, s.barheight+1, s.width, s.height-s.barheight-1)
  290.  
  291.   REPEAT
  292.     IF sigs THEN WHILE m:=GetMsg(port) DO status[1-Long(m+SIZEOF mn)]:=OK_REDRAW
  293.  
  294.     held_off:=FALSE
  295.  
  296.     IF status[buf_nextdraw]=OK_REDRAW
  297.       stdrast:=rp[buf_nextdraw]
  298.       draw()
  299.       WaitBlit()
  300.       status[buf_nextdraw]:=OK_SWAPIN
  301.       buf_nextdraw:=1-buf_nextdraw
  302.     ENDIF
  303.  
  304.     IF status[buf_nextswap]=OK_SWAPIN
  305.       sb:=sbuf[buf_nextswap]
  306.       sb.dbufinfo.safemessage.replyport:=port
  307.       IF ChangeScreenBuffer(s, sb)
  308.         status[buf_nextswap]:=OK_NONE
  309.         buf_current:=buf_nextswap
  310.         buf_nextswap:=1-buf_nextswap
  311.       ELSE
  312.         held_off:=TRUE
  313.       ENDIF
  314.     ENDIF
  315.  
  316.     IF held_off THEN WaitTOF() ELSE sigs:=Wait(Shl(1,port.sigbit))
  317.   UNTIL CtrlC() OR (IF m:=GetMsg(w.userport) THEN ReplyMsg(m) BUT 1 ELSE 0)
  318.  
  319.   done()
  320.  
  321. EXCEPT DO
  322.   IF w       THEN CloseWindow(w)
  323.   IF sbuf[1] THEN FreeScreenBuffer(s, sbuf[1])
  324.   IF sbuf[0] THEN FreeScreenBuffer(s, sbuf[0])
  325.   IF s       THEN CloseScreen(s)
  326.   IF port    THEN DeleteMsgPort(port)
  327. ENDPROC
  328.  
  329. ->--------------------------------------------------------------------------
  330.  
  331. PROC asl_modereq()
  332.   -> a little moderequester
  333.   -> will return modeid of chosen mode if user successfully
  334.   -> chose a screenmode, otherwise will Raise()
  335.  
  336.   DEF req:PTR TO screenmoderequester, modeid, result=0
  337.  
  338.   IF aslbase := OpenLibrary('asl.library',37)
  339.     IF req := AllocAslRequest(ASL_SCREENMODEREQUEST, NIL)
  340.       result := AslRequest(req, NIL)
  341.       modeid := req.displayid
  342.       FreeAslRequest(req)
  343.     ENDIF
  344.     CloseLibrary(aslbase)
  345.   ENDIF
  346.  
  347.   IF result=0 THEN Raise() -> if user actually chose 'Cancel'
  348.  
  349. ENDPROC modeid
  350.