home *** CD-ROM | disk | FTP | other *** search
/ Dream 52 / Amiga_Dream_52.iso / Linux / Divers / lynx2.8.1dev.10.tar.gz / lynx2.8.1dev.10.tar / lynx2-8 / configure.in < prev    next >
Text File  |  1998-05-10  |  17KB  |  614 lines
  1. dnl Process this file with autoconf to produce a configure script.
  2. dnl written jan/1997
  3. dnl by T.E.Dickey <dickey@clark.net>
  4. dnl and Jim Spath <jspath@mail.bcpl.lib.md.us>
  5.  
  6. AC_PREREQ(2.12)
  7. AC_INIT(userdefs.h)
  8. AC_CONFIG_HEADER(lynx_cfg.h:config.hin)
  9.  
  10. AC_PREFIX_DEFAULT(/usr/local)
  11. AC_CANONICAL_HOST
  12.  
  13. dnl --------------------------------------------------------------------------
  14. dnl Checks for location of programs
  15. dnl --------------------------------------------------------------------------
  16.  
  17. AC_PROG_CC
  18. AC_PROG_CPP
  19. AC_PROG_RANLIB
  20. AC_PROG_MAKE_SET
  21. CF_MAKE_INCLUDE
  22. AC_PROG_INSTALL
  23. AC_CHECK_PROGS(LINT, lint alint lclint tdlint, [])
  24.  
  25. dnl --------------------------------------------------------------------------
  26. dnl Debug/development/test
  27. dnl --------------------------------------------------------------------------
  28.  
  29. CF_HELP_MESSAGE(
  30. Development Options:)
  31.  
  32. CF_DISABLE_ECHO
  33.  
  34. AC_MSG_CHECKING(if you want to check memory-leaks)
  35. CF_ARG_ENABLE(find-leaks,
  36.     [  --enable-find-leaks     logic for testing memory leaks],
  37.     [with_leak_checks=yes],
  38.     [with_leak_checks=no])
  39. AC_MSG_RESULT($with_leak_checks)
  40. test "$with_leak_checks" = "yes" && AC_DEFINE(LY_FIND_LEAKS)
  41.  
  42. AC_MSG_CHECKING(if you want to enable debug-code)
  43. CF_ARG_ENABLE(debug,
  44.     [  --enable-debug          logic for traces/debugging],
  45.     [with_debug=yes],
  46.     [with_debug=no])
  47. AC_MSG_RESULT($with_debug)
  48. if test "$with_debug" = "yes" ; then
  49.     case $host_os in
  50.     ultrix*|osf*)
  51.         CF_STRIP_O_OPT(CFLAGS)
  52.         if test -z "$GCC" ; then
  53.             CFLAGS="$CFLAGS -g3"
  54.         fi
  55.         ;;
  56.     esac
  57. else
  58.     case $host_os in
  59.     osf*) #(vi
  60.         CFLAGS="$CFLAGS -std1"
  61.         CF_STRIP_G_OPT(CFLAGS)
  62.         ;;
  63.     *)
  64.         CF_STRIP_G_OPT(CFLAGS)
  65.         ;;
  66.     esac
  67. fi
  68.  
  69.  
  70. if test -n "$GCC"
  71. then
  72. AC_MSG_CHECKING(if you want to turn on gcc warnings)
  73. CF_ARG_ENABLE(warnings,
  74.     [  --enable-warnings       GCC compiler warnings],
  75.     [with_warnings=yes],
  76.     [with_warnings=no])
  77. AC_MSG_RESULT($with_warnings)
  78. if test "$with_warnings" = "yes"
  79. then
  80.     CF_GCC_ATTRIBUTES
  81.     CF_GCC_WARNINGS
  82. fi
  83. fi
  84.  
  85. dnl --------------------------------------------------------------------------
  86. dnl --------------------------------------------------------------------------
  87.  
  88. CF_HELP_MESSAGE(
  89. Basic Configuration Options:)
  90.  
  91. AC_MSG_CHECKING(if you want full utility pathnames)
  92. CF_ARG_DISABLE(full-paths,
  93.     [  --disable-full-paths    control whether full utility pathnames are used],
  94.     [with_full_paths=no],
  95.     [with_full_paths=yes])
  96. AC_MSG_RESULT($with_full_paths)
  97.  
  98. CF_DEFINE_PROG(system mailer, SYSTEM_MAIL,
  99.     /usr/mmdf/bin/submit \
  100.     /usr/sbin/sendmail \
  101.     /usr/lib/sendmail  \
  102.     )
  103. CF_SYSTEM_MAIL_FLAGS
  104.  
  105. CF_PATH_PROG(CHMOD,    chmod)
  106. CF_PATH_PROG(COMPRESS,    compress)
  107. CF_PATH_PROG(COPY,    cp)
  108. CF_PATH_PROG(GZIP,    gzip)
  109. CF_PATH_PROG(MKDIR,    mkdir)
  110. CF_PATH_PROG(MV,    mv)
  111. CF_PATH_PROG(RM,    rm)
  112. CF_PATH_PROG(TAR,    tar)
  113. CF_PATH_PROG(TOUCH,    touch)
  114. CF_PATH_PROG(UNCOMPRESS,gunzip)
  115. CF_PATH_PROG(UNZIP,    unzip)
  116. CF_PATH_PROG(UUDECODE,    uudecode)
  117. CF_PATH_PROG(ZCAT,    zcat)
  118. CF_PATH_PROG(ZIP,    zip)
  119.  
  120. dnl 'INSTALL' is a special case, since the configure script has to find a
  121. dnl BSD-compatible one so the build/install works properly.
  122. case "$INSTALL" in
  123. $srcdir*) # (vi
  124.     AC_DEFINE_UNQUOTED(INSTALL_PATH,"install")
  125.     ;;
  126. *) # (vi
  127.     AC_DEFINE_UNQUOTED(INSTALL_PATH,"$INSTALL")
  128.     ;;
  129. esac
  130.  
  131. dnl --------------------------------------------------------------------------
  132. dnl Checks for compiler & standard-library characteristics
  133. dnl --------------------------------------------------------------------------
  134.  
  135. dnl If we're able to run this script, this is true!
  136. AC_DEFINE(UNIX)
  137.  
  138. if test -z "$GCC" ; then
  139.     CF_ANSI_CC_CHECK
  140. fi
  141. AC_C_CONST
  142.  
  143. dnl Only add to this case statement things that we cannot design tests for.
  144. PROG_EXT=
  145. case $host_os in
  146. aix4*)
  147.     CFLAGS="$CFLAGS -DAIX4 -D_BSD=44" 
  148.     LIBS="$LIBS -lbsd"
  149.     ;;
  150. aix*)
  151.     LIBS="$LIBS -lbsd"
  152.     ;;
  153. apollo*)
  154.     CFLAGS="$CFLAGS -D_BUILTINS -W0,-opt,4"
  155.     ;;
  156. bsdi*)
  157.     CFLAGS="$CFLAGS -DBSDI" 
  158.     ;;
  159. clix*)
  160.     # Tested on CLIX 3.1 (T.Dickey).  The original makefile entry
  161.     # contributed by Alex Matulich (matuli_a@marlin.navsea.navy.mil) also
  162.     # references -lmalloc and -lbsd.
  163.     AC_CHECK_LIB(c_s,strcmp)
  164.     ;;
  165. convex*)
  166.     CFLAGS="$CFLAGS -D__STDC__ -Dunix"
  167.     ;;
  168. dgux*)
  169.     CFLAGS="$CFLAGS -DDGUX" 
  170.     ;;
  171. hpux*)
  172.     CFLAGS="$CFLAGS -DSNAKE" 
  173.     ;;
  174. isc*)
  175.     # -DPOSIX_JC is necessary, else LYBookmark.c never finds out what a mode_t is.
  176.     CFLAGS="$CFLAGS -DISC -DPOSIX_JC"
  177.     LIBS="$LIBS -linet -lnsl_s -lcposix"
  178.     ;;
  179. irix*)
  180.     # The original makefile used the $CFLAGS option -cckr for some form
  181.     # of K&R compatibility.  However, this causes compilation warnings for
  182.     # varargs on IRIX 5.2, and does not appear to be needed.
  183.     #removed: CFLAGS="$CFLAGS -cckr" 
  184.     ;;
  185. linux*)
  186.     CFLAGS="$CFLAGS -DLINUX" 
  187.     ;;
  188. next*)
  189.     CFLAGS="$CFLAGS -DNEXT -DXMOSAIC_HACK"
  190.     ;;
  191. openbsd*)
  192.     LIBS="$LIBS -lcompat"
  193.     ;;
  194. os2*)
  195.     # We make sure -Zexe is not used -- it would interfere with @PROG_EXT@
  196.     CFLAGS="$CFLAGS -Zmt -D__ST_MT_ERRNO__"
  197.     LDFLAGS=`echo "$LDFLAGS -Zmt -Zcrtdll" | sed "s/-Zexe//g"`
  198.     PROG_EXT=".exe"
  199.     ;;
  200. osf4*) 
  201.     # The -Olimit flag (see below) is no longer available with 
  202.     # Digital C 5.2, which is bundled with Digital UNIX 4.0. 
  203.     CFLAGS="$CFLAGS -DDSYS5" 
  204.     ;; 
  205. osf*)
  206.     # Increase the maximum size of functions that will be optimized.
  207.     test -z "$GCC" && CFLAGS="$CFLAGS -O -Olimit 4000"
  208.     CFLAGS="$CFLAGS -DDSYS5"
  209.     ;;
  210. sco3.2v5*)
  211.     test $ac_cv_prog_gcc != yes && CC="cc -belf"
  212.     ;;
  213. sco*)
  214.     LIBS="$LIBS -lmalloc"
  215.     # It's a little late to do much, but try to warn user if he's using
  216.     # SCO's cc (which is reported to have broken const/volatile).
  217.     case "$CC" in #(vi
  218.     cc|*/cc)
  219.         AC_MSG_WARN(You should consider using gcc or rcc if available)
  220.         unset ac_cv_prog_CC
  221.         AC_CHECK_PROGS(CC,gcc rcc,$CC)
  222.         ;;
  223.     esac
  224.     ;;
  225. sequent-ptx)
  226.     CFLAGS="$CFLAGS -DSVR4_BSDSELECT -DNO_IOCTL -DUSE_FCNTL"
  227.     ;;
  228. sequent-ptx2)
  229.     CFLAGS="$CFLAGS -DSVR4_BSDSELECT"
  230.     ;;
  231. sony-newsos*)
  232.     CFLAGS="$CFLAGS -I/usr/sony/include"
  233.     AC_CHECK_HEADERS(jcurses.h)
  234.     ;;
  235. svr4)
  236.     CFLAGS="$CFLAGS -DSVR4_BSDSELECT -DSVR4"
  237.     ;;
  238. sunos3*)
  239.     CFLAGS="$CFLAGS -DSUN"
  240.     ;;
  241. sunos4*)
  242.     CFLAGS="$CFLAGS -DSUN -DSUN4"
  243.     ;;
  244. ultrix*)
  245.     # Increase the maximum size of functions that will be optimized.
  246.     test -z "$GCC" && CFLAGS="$CFLAGS -O -Olimit 600 -G 7"
  247.     CFLAGS="$CFLAGS -DULTRIX" 
  248.     AC_CHECK_HEADERS(cursesX.h, cf_cv_ncurses_header=cursesX.h)
  249.     ;;
  250. esac
  251. AC_SUBST(PROG_EXT)
  252.  
  253. dnl --------------------------------------------------------------------------
  254. dnl Checks for library configuration (added right-to-left)
  255. dnl --------------------------------------------------------------------------
  256.  
  257. CF_NETLIBS
  258.  
  259. AC_MSG_CHECKING(for screen type)
  260. dnl This has to be cached, since there's a lot of interdependent tests.
  261. AC_CACHE_VAL(cf_cv_screen,[
  262. AC_ARG_WITH(screen,
  263. [  --with-screen=XXX       select screen type
  264.                           (XXX is curses (default), ncurses or slang)],
  265.     [
  266. case $withval in
  267. curses|ncurses|slang)
  268.     cf_cv_screen=$withval
  269.     ;;
  270. *)    AC_ERROR(Unexpected value)
  271.     ;;
  272. esac],
  273.     [cf_cv_screen=curses])])
  274. AC_MSG_RESULT($cf_cv_screen)
  275.  
  276. if test $cf_cv_screen != ncurses ; then
  277.     if eval "test \"`echo '$''{'cf_cv_ncurses_header'+set}'`\" != set"; then
  278.         cf_cv_ncurses_header=curses.h
  279.     fi
  280. fi
  281.  
  282. case $cf_cv_screen in
  283. curses)
  284.     CF_CURSES_LIBS
  285.     CF_CURS_PERFORMANCE
  286.     ;;
  287. ncurses)
  288.     CF_NCURSES_CPPFLAGS
  289.     CF_NCURSES_LIBS
  290.     ;;
  291. slang)
  292.     CF_SLANG_CPPFLAGS
  293.     CF_SLANG_LIBS
  294.     ;;
  295. esac
  296.  
  297. dnl Get the actual value for $libdir, which we will compile into Lynx as part of
  298. dnl the config pathnames.
  299. eval cf_libdir=$libdir
  300. cf_libdir=`echo $cf_libdir | sed -e s@'^NONE/'@$prefix/@ -e s@'^NONE/'@$ac_default_prefix/@`
  301.  
  302. AC_MSG_CHECKING(for location of config-file)
  303. LYNX_CFG_FILE=$cf_libdir/lynx.cfg
  304. AC_DEFINE_UNQUOTED(LYNX_CFG_FILE,"$LYNX_CFG_FILE")
  305. AC_MSG_RESULT($LYNX_CFG_FILE)
  306.  
  307. dnl --------------------------------------------------------------------------
  308. dnl Checks for standard headers
  309. dnl --------------------------------------------------------------------------
  310.  
  311. AC_HEADER_STDC
  312. AC_HEADER_TIME
  313. AC_HEADER_DIRENT
  314. dnl Don't check for sys/wait.h here since it is covered by another test.
  315. AC_CHECK_HEADERS( \
  316.     fcntl.h \
  317.     limits.h \
  318.     stdlib.h \
  319.     string.h \
  320.     sys/fcntl.h \
  321.     sys/filio.h \
  322.     sys/ioctl.h \
  323.     sys/param.h \
  324.     sys/time.h \
  325.     termio.h \
  326.     termios.h \
  327.     unistd.h \
  328. )
  329. CF_TERMIO_AND_TERMIOS
  330. CF_FUNC_WAIT
  331. AC_TYPE_MODE_T
  332.  
  333. dnl --------------------------------------------------------------------------
  334. dnl Checks for library units
  335. dnl --------------------------------------------------------------------------
  336.  
  337. AC_FUNC_VFORK
  338. CF_FIONBIO
  339. CF_REMOVE_BROKEN
  340. CF_FUNC_LSTAT
  341. AC_CHECK_FUNCS( \
  342.     cuserid \
  343.     getcwd \
  344.     getgroups \
  345.     putenv \
  346.     readdir \
  347.     strerror \
  348.     waitpid \
  349. )
  350. AC_REPLACE_FUNCS( \
  351.     mktime \
  352.     strstr \
  353. )
  354.  
  355. CF_CHECK_FUNCDECLS([#include <string.h>], strstr)
  356. CF_CHECK_FUNCDECLS([
  357. #include <stdio.h>
  358. #include <grp.h>], getgrgid getgrnam)
  359.  
  360. dnl --------------------------------------------------------------------------
  361. dnl Checks for external-data
  362. dnl --------------------------------------------------------------------------
  363.  
  364. CF_BOOL_DEFS
  365. CF_ERRNO
  366. CF_LOCALE
  367. CF_NGROUPS
  368. CF_SYS_ERRLIST
  369. CF_UTMP
  370.  
  371. ### These tests must be run after establishing the curses library.
  372. if test $cf_cv_screen != slang ; then
  373.     CF_ALT_CHAR_SET
  374.     CF_FANCY_CURSES
  375.     CF_NCURSES_VERSION
  376.     CF_NCURSES_BROKEN
  377.     CF_COLOR_CURSES
  378.     CF_SIZECHANGE
  379.     CF_TTYTYPE
  380.     AC_CHECK_FUNCS( \
  381.         cbreak \
  382.         keypad \
  383.         use_default_colors \
  384.         wborder \
  385.     )
  386. fi
  387.  
  388. dnl --------------------------------------------------------------------------
  389. dnl Miscellaneous options that don't need to test system features
  390. dnl --------------------------------------------------------------------------
  391.  
  392. CF_HELP_MESSAGE(
  393. Miscellaneous Options:)
  394.  
  395. AC_MSG_CHECKING(if experimental 8-bit case-conversion should be used)
  396. CF_ARG_ENABLE(8bit-toupper,
  397. [  --enable-8bit-toupper   use experimental 8-bit case-conversion],
  398.     [use_8bit_toupper=$enableval],
  399.     [use_8bit_toupper=no])
  400. AC_MSG_RESULT($use_8bit_toupper)
  401. test $use_8bit_toupper != no && AC_DEFINE(EXP_8BIT_TOUPPER)
  402.  
  403. AC_MSG_CHECKING(if color-style code should be used)
  404. CF_ARG_ENABLE(color-style,
  405. [  --enable-color-style    use optional/experimental color style],
  406.     [use_color_style=$enableval],
  407.     [use_color_style=no])
  408.  
  409. if test $use_color_style != no ; then
  410.     if test .$cf_cv_color_curses != .yes ; then
  411.         AC_ERROR(Configuration does not support color-styles)
  412.     fi
  413.     if test $cf_cv_screen = slang ; then
  414.         AC_ERROR(Configuration does not support color-styles)
  415.     fi
  416.     AC_DEFINE(USE_HASH)
  417.     AC_DEFINE(LINKEDSTYLES)
  418. fi
  419.  
  420. case $use_color_style in
  421. no)
  422.     AC_MSG_RESULT(no)
  423.     INSTALL_LSS=
  424.     ;;
  425. *)
  426.     AC_DEFINE(USE_COLOR_STYLE)
  427.     AC_MSG_RESULT(yes)
  428.  
  429.     AC_MSG_CHECKING(for location of style-sheet file)
  430.     LYNX_LSS_FILE=$cf_libdir/lynx.lss
  431.     AC_DEFINE_UNQUOTED(LYNX_LSS_FILE,"$LYNX_LSS_FILE")
  432.     AC_MSG_RESULT($LYNX_LSS_FILE)
  433.     INSTALL_LSS=install-lss
  434.     ;;
  435. esac
  436. AC_SUBST(INSTALL_LSS)
  437.  
  438. AC_MSG_CHECKING(if experimental partial-display should be used)
  439. CF_ARG_ENABLE(partial,
  440. [  --enable-partial        use experimental partial-display logic],
  441.     [use_partial_display=$enableval],
  442.     [use_partial_display=no])
  443. AC_MSG_RESULT($use_partial_display)
  444. test $use_partial_display != no && AC_DEFINE(DISP_PARTIAL)
  445.  
  446. use_dft_colors=no
  447. test ".$cf_cv_screen" = ".slang"                && use_dft_colors=maybe
  448. test ".$ac_cv_func_use_default_colors" = ".yes" && use_dft_colors=maybe
  449.  
  450. if test "$use_dft_colors" != no ; then
  451. AC_MSG_CHECKING(if you want to use default-colors)
  452. CF_ARG_ENABLE(default-colors,
  453. [  --enable-default-colors enable use of default-colors (ncurses/slang)],
  454.     [use_dft_colors=yes],
  455.     [use_dft_colors=no])
  456. AC_MSG_RESULT($use_dft_colors)
  457. test $use_dft_colors = "yes" && AC_DEFINE(USE_DEFAULT_COLORS)
  458. fi
  459.  
  460. AC_MSG_CHECKING(if you want to use extended HTML DTD logic)
  461. CF_ARG_DISABLE(extended-dtd,
  462. [  --disable-extended-dtd  disable extended HTML DTD logic],
  463.     [use_ext_htmldtd=no],
  464.     [use_ext_htmldtd=yes])
  465. AC_MSG_RESULT($use_ext_htmldtd)
  466. test $use_ext_htmldtd = "no" && AC_DEFINE(NO_EXTENDED_HTMLDTD)
  467.  
  468. AC_MSG_CHECKING(if you want to use external commands)
  469. CF_ARG_ENABLE(externs,
  470. [  --enable-externs        use external commands],
  471.     [use_externs=yes],
  472.     [use_externs=no])
  473. AC_MSG_RESULT($use_externs)
  474. test $use_externs != ".no" && AC_DEFINE(USE_EXTERNALS)
  475.  
  476. AC_MSG_CHECKING(if you want to use setfont support)
  477. CF_ARG_ENABLE(font-switch,
  478. [  --enable-font-switch    use Linux setfont for character-translation],
  479.     [use_setfont=yes],
  480.     [use_setfont=no])
  481. AC_MSG_RESULT($use_setfont)
  482. test $use_setfont = yes && AC_DEFINE(EXP_CHARTRANS_AUTOSWITCH)
  483.  
  484. AC_MSG_CHECKING(if you want internal-links feature)
  485. CF_ARG_ENABLE(internal-links,
  486. [  --enable-internal-links  handle following links to same doc differently],
  487.     [use_internal_links=yes],
  488.     [use_internal_links=no])
  489. AC_MSG_RESULT($use_internal_links)
  490. test $use_internal_links = no && AC_DEFINE(DONT_TRACK_INTERNAL_LINKS)
  491.  
  492. AC_MSG_CHECKING(if you want to fork NSL requests)
  493. CF_ARG_ENABLE(nsl-fork,
  494. [  --enable-nsl-fork       fork NSL requests, allowing them to be aborted],
  495.     [use_nsl_fork=yes],
  496.     [use_nsl_fork=no])
  497. AC_MSG_RESULT($use_nsl_fork)
  498. test $use_nsl_fork = yes && AC_DEFINE(NSL_FORK)
  499.  
  500. AC_MSG_CHECKING(if you want to underline links)
  501. CF_ARG_ENABLE(underlines,
  502. [  --enable-underlines     underline links rather than using boldface],
  503.     [use_underline=yes],
  504.     [use_underline=no])
  505. AC_MSG_RESULT($use_underline)
  506. test $use_underline = yes && AC_DEFINE(UNDERLINE_LINKS)
  507.  
  508. AC_MSG_CHECKING(if you want to use zlib for decompression of some gzip files)
  509. AC_ARG_WITH(zlib,
  510. [  --with-zlib             use zlib for decompression of some gzip files],
  511.     [use_zlib=$withval],
  512.     [use_zlib=no])
  513. AC_MSG_RESULT($use_zlib)
  514.  
  515. if test ".$use_zlib" != ".no" ; then
  516.     CF_FIND_LIBRARY(z,
  517.         [#include <zlib.h>],
  518.         [gzopen("name","mode")],
  519.         gzopen)
  520.     AC_DEFINE(USE_ZLIB)
  521. fi
  522.  
  523. dnl --------------------------------------------------------------------------
  524. dnl DirEd (directory-editor) options
  525. dnl --------------------------------------------------------------------------
  526.  
  527. CF_HELP_MESSAGE(
  528. Directory Editor Options:)
  529.  
  530. # All DirEd functions that were enabled on compilation can be disabled
  531. # or modified at run time via DIRED_MENU symbols in lynx.cfg.
  532. AC_MSG_CHECKING(if directory-editor code should be used)
  533. CF_ARG_DISABLE(dired,
  534. [  --disable-dired          enable optional directory-editor, DirEd],
  535.     [use_dired=$enableval],
  536.     [use_dired=yes])
  537. AC_MSG_RESULT($use_dired)
  538.  
  539. if test ".$use_dired" != ".no" ; then
  540.     AC_DEFINE(DIRED_SUPPORT)
  541.  
  542.     AC_MSG_CHECKING(if you wish to allow extracting from archives via DirEd)
  543.     CF_ARG_DISABLE(dired-archive,
  544.     [  --disable-dired-archive  disable dearchiving commands],[AC_DEFINE(ARCHIVE_ONLY)])
  545.     AC_MSG_RESULT($enableval)
  546.  
  547.     AC_MSG_CHECKING(if you wish to allow users to redefine DirEd keys)
  548.     CF_ARG_DISABLE(dired-override,
  549.     [  --disable-dired-override disable private keymaps],,[AC_DEFINE(OK_OVERRIDE)])
  550.     AC_MSG_RESULT($enableval)
  551.  
  552.     AC_MSG_CHECKING(if you wish to allow permissions commands via DirEd)
  553.     CF_ARG_DISABLE(dired-permit,
  554.     [  --disable-dired-permit  disable chmod/attrib commands],,[AC_DEFINE(OK_PERMIT)])
  555.     AC_MSG_RESULT($enableval)
  556.  
  557.     AC_MSG_CHECKING(if you wish to allow executable-permission commands via DirEd)
  558.     CF_ARG_DISABLE(dired-xpermit,
  559.     [  --disable-dired-xpermit disable chmod/attrib commands],[AC_DEFINE(NO_CHANGE_EXECUTE_PERMS)])
  560.     AC_MSG_RESULT($enableval)
  561.  
  562.     AC_MSG_CHECKING(if you wish to allow "tar" commands from DirEd)
  563.     CF_ARG_DISABLE(dired-tar,
  564.     [  --disable-dired-tar     disable "tar" command],,[AC_DEFINE(OK_TAR)])
  565.     AC_MSG_RESULT($enableval)
  566.  
  567.     AC_MSG_CHECKING(if you wish to allow "uudecode" commands from DirEd)
  568.     CF_ARG_DISABLE(dired-uudecode,
  569.     [  --disable-dired-uudecode disable "uudecode" command],,[AC_DEFINE(OK_UUDECODE)])
  570.     AC_MSG_RESULT($enableval)
  571.  
  572.     AC_MSG_CHECKING(if you wish to allow "zip" and "unzip" commands from DirEd)
  573.     CF_ARG_DISABLE(dired-zip,
  574.     [  --disable-dired-zip     disable "zip", "unzip"  commands],,[AC_DEFINE(OK_ZIP)])
  575.     AC_MSG_RESULT($enableval)
  576.  
  577.     AC_MSG_CHECKING(if you wish to allow "gzip" and "gunzip" commands from DirEd)
  578.     CF_ARG_DISABLE(dired-gzip,
  579.     [  --disable-dired-gzip    disable "gzip", "gunzip" commands],,[AC_DEFINE(OK_GZIP)])
  580.     AC_MSG_RESULT($enableval)
  581. fi
  582.  
  583. AC_MSG_CHECKING(if you want long-directory listings)
  584. CF_ARG_DISABLE(long-list,
  585. [  --disable-long-list     disable long "ls -l" directory listings],,
  586.     [AC_DEFINE(LONG_LIST)])
  587. AC_MSG_RESULT($enableval)
  588.  
  589. AC_MSG_CHECKING(if parent-directory references are permitted)
  590. CF_ARG_DISABLE(parent-dir-refs,
  591. [  --disable-parent-dir-refs
  592.                           disable "Up-to" links in directory listings],
  593.     [AC_DEFINE(NO_PARENT_DIR_REFERENCE)])
  594. AC_MSG_RESULT($enableval)
  595.  
  596. ### Finally, build config.h and the makefiles
  597. CFLAGS="$CFLAGS $EXTRA_CFLAGS"
  598. srcdir="$srcdir"
  599. SRCDIR_CLEAN="#"
  600. if test -n "$srcdir" ; then
  601.     echo srcdir is $srcdir
  602.     $srcdir/mkdirs.sh WWW/Library/unix
  603.     $srcdir/mkdirs.sh src/chrtrans
  604.     test "$srcdir" != "." && SRCDIR_CLEAN=""
  605. fi
  606.  
  607. AC_SUBST(SRCDIR_CLEAN)
  608. AC_OUTPUT(
  609.     makefile \
  610.     WWW/Library/unix/makefile \
  611.     src/makefile \
  612.     src/chrtrans/makefile \
  613. )
  614.