Dream 52/Amiga_Dream_52.iso/Amiga/Internet/Mail/iris.lha/Iris/Install-Iris

Text File | 1998-03-18 | 8KB | 389 lines

(welcome)

(if
    (=
        (askchoice
            (prompt "Select disired action.")
            (choices "Install" "Update")
            (default 0)
            (help "'Update' will only copy the changed or new files. Installer will fail if you select 'Install' for an update.")
        )
    1)

;** UPDATE **********************************************************
(
(message (cat
    "Installing Iris V1.2\nNEW: POP3 progress indication improved - "
    "support for smtpd - user menu - reply to all - text buttons - "
    "bug fixes - new button installation procedure - etc."
))

(set #destdir
    (askdir
        (prompt "Where is the Iris program?")
        (default @default-dest)
        (help @askdir-help)
    )
)
(set #doc-dir
    (askdir
        (prompt "Where is the Iris documentation?")
        (default #destdir)
        (help @askdir-help)
    )
)
(set #smtpd
    (askbool
        (prompt "Should the script for smtpd be installed?")
        (default 1)
        (help "This script can be used to read messages from other sources into Iris. It is mainly interesting for use with smtpd.")
    )
)

(copyfiles
    (prompt "Copying documentation...")
    (source "Iris.guide")
    (dest #doc-dir)
    (all)
)
(copyfiles
    (prompt "Copying program...")
    (source "Iris")
    (dest #destdir)
    (noposition)
)
(copyfiles
    (prompt "Copying Poll.irx script...")
    (source "Poll.irx")
    (dest #destdir)
)
(copyfiles
    (prompt "Copying DelFolder.irx script...")
    (source "DelFolder.irx")
    (dest #destdir)
)
(if #smtpd
    (copyfiles
        (prompt "Copying IrisRMail.irx script...")
        (source "IrisRMail.irx")
        (dest #destdir)
    )
)
(copyfiles
    (prompt "Copying DelFolder.irx icon...")
    (source (tackon #destdir "Poll.irx.info"))
    (dest #destdir)
    (infos)
    (noposition)
    (newname "DelFolder.irx.info")
)
(set #storage-dir (tackon #destdir "Storage"))
(if (not (exists #storage-dir))
(
    (makedir #storage-dir)
    (copyfiles
        (prompt "Copying Storage icon...")
        (source (tackon #destdir "Buttons.info"))
        (dest #destdir)
        (newname "Storage.info")
    )
    (rename (tackon #destdir "Buttons") (tackon #storage-dir "Old_Buttons"))
    (rename (tackon #destdir "Buttons.info") (tackon #storage-dir "Old_Buttons.info"))
    (working "Making links...")
    (run "MakeLink" "HARD" "FORCE" (tackon #destdir "Buttons") (tackon #storage-dir "Old_Buttons"))
    (run "MakeLink" "HARD" "FORCE" (tackon #destdir "Buttons.info") (tackon #storage-dir "Old_Buttons.info"))
) ;endblock
) ;endif
(copyfiles
    (prompt "Copying buttons...")
    (source "Storage")
    (dest #storage-dir)
    (all)
    (infos)
    (noposition)
)
(copyfiles
    (prompt "Copying Install-Buttons...")
    (source "Install-Buttons")
    (dest #destdir)
    (infos)
    (noposition)
)
(set @default-dest #destdir)
(exit)
) ; endblock
) ; endif

;** INSTALL *********************************************************

(set #destdir
    (askdir
        (prompt "Where should the Iris drawer be created?")
        (default @default-dest)
        (help @askdir-help)
    )
)
(set @default-dest #destdir)
(set #parent-dir #destdir)
(set #doc-dir
    (askdir
        (prompt "Where do you want to install the documentation (AmigaGuide)?")
        (default (tackon #destdir "Iris"))
        (newpath)
        (help @askdir-help)
    )
)
(set #icons
    (askchoice
        (prompt "Which icons do you want to install?")
        (choices "Standard" "MagicWB")
        (default 0)
        (help @askchoice-help)
    )
)
(set #copycfg
    (askbool
        (prompt "Should the sample configuration file be copied?")
        (choices "Yes" "No")
        (default 1)
        (help "This config already contains some folders and filters.")
    )
)

(set #buttons
    (askchoice
        (prompt "Which buttons do you want to use?")
        (choices "Image (MWB)" "Text (MWB)" "GT (4 colour)")
        (default (if (= #icons 1) 0 2))
        (help
            (cat "Text buttons created by Karl Schon.\n"
            "Image buttons (Eudora like) created by Menno and Jilles Tjoelker.\n"
            "GT buttons created by Jilles Tjoelker.\n"
            @askchoice-help)
        )
    )
)
(select (+ #buttons 1)
    (set #buttons-dir "Image_Buttons")
    (set #buttons-dir "Text_Buttons")
    (set #buttons-dir "GT_Buttons")
)

(set #browsewww
    (askfile
        (prompt "Which WWW browser do you use?")
        (help @askfile-help)
        (default "BrowseWWWscripts/AWeb")
    )
)
(if (not (patmatch "#?AWeb#?" #browsewww))
    (message "Warning: the selected script has not been tested.")
)

(set #smtpd
    (askbool
        (prompt "Should the script for smtpd be installed?")
        (default 1)
                (help "This script can be used to read messages from other sources into Iris. It is mainly interesting for use with smtpd.")
    )
)

(set #ext
    (askchoice
        (prompt "Which version of the bgui.library do you want to install?")
        (choices "Standard" "Extended (AmigaOS 3.0 and 68020 required)")
        (default 0)
        (help @askchoice-help)
    )
)
(if (= #ext 0)
    (set #bgui-lib "libs/bgui.library")
    (set #bgui-lib "libs/bgui.library_e")
)
(set #lib-dest
    (askdir
        (prompt "Where should the bgui.library be installed?\nA version check will be performed.")
        (help @askdir-help)
        (default "LIBS:")
    )
)
(set #classes-dest
    (askdir
        (prompt "Where should the class 'bgui_popbutton.gadget be installed?")
        (help @askdir-help)
        (default "LIBS:Gadgets/")
        (newpath)
    )
)

(copylib
    (prompt "Copying bgui.library...")
    (confirm)
    (source #bgui-lib)
    (dest #lib-dest)
    (newname "bgui.library")
    (help @copylib-help)
)
(copylib
    (prompt "Copying bgui_popbutton.gadget")
    (confirm)
    (source "classes/gadgets/bgui_popbutton.gadget")
    (dest #classes-dest)
    (help @copylib-help)
)

(set #destdir (tackon #destdir "Iris"))
(set @default-dest #destdir)
(makedir #destdir)
(set #buttons-dest (tackon #destdir "Buttons"))
(set #sig-dest (tackon #destdir "Signatures"))
(makedir #sig-dest (infos))
(copyfiles
    (prompt "Copying signature...")
    (dest #sig-dest)
    (source "Signatures/Standard")
    (infos)
    (noposition)
)
(makedir (tackon #destdir "Mail"))
(copyfiles
    (prompt "Copying program...")
    (source "Iris")
    (dest #destdir)
    (infos)
    (noposition)
)
(set #storage-dir (tackon #destdir "Storage"))
(makedir #storage-dir (infos))
(copyfiles
    (prompt "Copying buttons...")
    (source "Storage")
    (dest #storage-dir)
    (all)
    (infos)
    (noposition)
)
(working "Making links...")
(run "MakeLink" "HARD" "FORCE" (tackon #destdir "Buttons") (tackon #storage-dir #buttons-dir))
(run "MakeLink" "HARD" "FORCE" (tackon #destdir "Buttons.info") (cat (tackon #storage-dir #buttons-dir) ".info"))
(copyfiles
    (prompt "Copying Install-Buttons...")
    (source "Install-Buttons")
    (dest #destdir)
    (infos)
    (noposition)
)
(if #copycfg
    (copyfiles
        (prompt "Copying sample configuration file...")
        (source "Iris.cfg")
        (dest #destdir)
    )
)
(copyfiles
    (prompt "Copying BrowseWWW.rexx script...")
    (source #browsewww)
    (dest #destdir)
    (newname "BrowseWWW.rexx")
)
(copyfiles
    (prompt "Copying Poll.irx script...")
    (source "Poll.irx")
    (dest #destdir)
    (infos)
    (noposition)
)
(copyfiles
    (prompt "Copying DelFolder.irx script...")
    (source "DelFolder.irx")
    (dest #destdir)
    (infos)
    (noposition)
)
(if #smtpd
    (copyfiles
        (prompt "Copying IrisRMail.irx script...")
        (source "IrisRMail.irx")
        (dest #destdir)
    )
)
(copyfiles
    (prompt "Copying documentation...")
    (source "Iris.guide")
    (dest #doc-dir)
    (infos)
    (all)
)

(if (= #icons 1)
    (
        (copyfiles
            (prompt "Copying MagicWB style drawer icon...")
            (source "MWB-Icons/Iris_drw.info")
            (dest #parent-dir)
            (newname "Iris.info")
            (infos)
            (noposition)
        )
        (copyfiles
            (prompt "Copying MagicWB style program icon...")
            (source "MWB-Icons/Iris.info")
            (dest #destdir)
            (infos)
            (noposition)
        )
        (copyfiles
            (prompt "Copying MagicWB style Buttons drawer icon...")
            (source "MWB-Icons/Buttons.info")
            (dest #destdir)
            (infos)
            (noposition)
        )
        (copyfiles
            (prompt "Copying MagicWB style guide icon...")
            (source "MWB-Icons/Iris.guide.info")
            (dest #doc-dir)
            (infos)
            (noposition)
        )
        (copyfiles
            (prompt "Copying MagicWB style Poll.irx icon...")
            (source "MWB-Icons/Poll.irx.info")
            (dest #destdir)
            (infos)
            (noposition)
        )
        (copyfiles
            (prompt "Copying MagicWB style DelFolder.irx icon...")
            (source "MWB-Icons/Poll.irx.info")
            (dest #destdir)
            (infos)
            (noposition)
            (newname "DelFolder.irx.info")
        )
        (copyfiles
            (prompt "Copying MagicWB style Signatures drawer icon...")
            (source "MWB-Icons/Signatures.info")
            (dest #destdir)
            (infos)
            (noposition)
        )
        (copyfiles
            (prompt "Copying MagicWB style signature icon...")
            (source "MWB-Icons/Standard.info")
            (dest #sig-dest)
            (infos)
            (noposition)
        )
    )
    (copyfiles
        (prompt "Copying drawer icon...")
        (source "/Iris.info")
        (dest #parent-dir)
        (infos)
        (noposition)
    )
)
(set @default-dest #destdir)