home *** CD-ROM | disk | FTP | other *** search
Text File | 1991-06-14 | 39.3 KB | 1,188 lines |
- C Vectors 1. Consequence of flagpole addition to vector boson masses.
- C Vectors 2. Vector-boson self-energies, infinite parts.
- C Vectors 3. Vector-boson self-energies. Comparison of various expressions.
- C Vectors 4. Photon-W0 ward identity.
- C Vectors 5. Neutral vector boson ward identity.
- C Vectors 6. Photon ward identity.
- C Vectors 7. Charged vector boson ward identity.
- C Vectors 8. Vector boson - vector boson scattering. Tree diagrams.
- C Vectors 9. Vector boson box diagram.
- C Vectors 10. Example of a gauge field theory. One loop poles.
- *end
-
- C Vectors 1. Consequence of flagpole addition to vector boson masses.
-
- C CONSEQUENCE OF FLAGPOLE ADDITION TO VECTOR BOSON MASSES,
- C AND NEUTRINo-ELECTRON SCATTERING CROSS SECTION AT ZERO ENERGY.
- C WCM2S IS THE SHIFT IN THE SQUARE OF THE CHARGED VECTOR BOSON MASS.
- C W0M2S SIMILARLY FOR THE NEUTRAL VECTOR BOSON.
- C WSG, WSZ, WSP AND WSGZ ARE THE SELF ENERGY ADDITIONS FOR PHOTON,
- C NEUTRAL W, CHARGED W, AND PHOTON-NEUTRAL W TRANSITION.
- P stat
- S MC,M0,MP,MU,MD,MT,MN
- F LOG
- F SGV,SZV,SWPV,SGZV
- B DDPI2,GG2,PI2
- Z WSG(AK2)=COUPW*SGV(AK2,TO2,BO2,HN2,TM2)
- Z WSZ(AK2)=COUPW*SZV(AK2,TO2,BO2,HN2,TM2)
- Z WSP(AK2)=COUPW*SECWV(AK2,TO2,BO2,HN2,TM2)
- Z WSGZ(AK2)=COUPW*SGZV(AK2,TO2,BO2,HN2,TM2)
- Id,SGV(AK2~,MU~,MD~,MN~,MT~) = AK2*SNT**2*(8.*B21(AK2,MT,MT)
- - 4.*B0(AK2,MT,MT)) + 4.*SNT**2*AK2/3.*(8.*B21(AK2,MU,MU)
- - 4.*B0(AK2,MU,MU)) + AK2*SNT**2/3.*(8.*B21(AK2,MD,MD)
- - 4.*B0(AK2,MD,MD))
- Al,SZV(AK2~,MU~,MD~,MN~,MT~)=AK2/16./CST**2*((4.*SNT**2-1.)**2+1)*
- (8.*B21(AK2,MT,MT)-4.*B0(AK2,MT,MT))
- + AK2/8./CST**2*(8.*B21(AK2,MN,MN)-4.*B0(AK2,MN,MN))
- + AK2*3./16./CST**2*((1.-8./3.*SNT**2)**2+1)*(8.*B21(AK2,MU,MU)
- - 4.*B0(AK2,MU,MU)) + 3.*AK2/16./CST**2*((4./3.*SNT**2-1.)**2+1)*
- (8.*B21(AK2,MD,MD)-4.*B0(AK2,MD,MD))
- -0.5/CST**2*(MT*B0(AK2,MT,MT)+3.*MU*B0(AK2,MU,MU)+
- 3.*MD*B0(AK2,MD,MD)+MN*B0(AK2,MN,MN))
- Al,SECWV(AK2~,MU~,MD~,MN~,MT~)=2.*AK2*(B21(AK2,MN,MT)+B1(AK2,MN,MT))
- - MN*B0(AK2,MN,MT) + (MT-MN)*
- B1(AK2,MN,MT)+6.*AK2*(B21(AK2,MU,MD)+B1(AK2,MU,MD))
- + 3.*(MD-MU)*B1(AK2,MU,MD)-3.*MU*B0(AK2,MU,MD)
- Al,SGZV(AK2~,MU~,MD~,MN~,MT~) = -AK2*SNT/CST*(4.*SNT**2-1.)*
- (2.*B21(AK2,MT,MT)-B0(AK2,MT,MT))
- + 2.*AK2*SNT/CST*(1.-8.*SNT**2/3.)*(2.*B21(AK2,MU,MU)
- - B0(AK2,MU,MU)) - AK2*SNT/CST*(4.*SNT**2/3.-1.)*
- (2.*B21(AK2,MD,MD)-B0(AK2,MD,MD))
- Id,COUPW=GG2/16./PI2
- Id,Multi,SNT**2=1.-CST**2
- Id,Multi,CST**2=1.-SNT**2
- Id,Multi,SNT**2=1.-CST**2
- Id,SNT**-2*CST**-2=1./SNT**2+1./CST**2
- Id,Multi,SNT**2=1.-CST**2
- Id,Multi,CST**2=1.-SNT**2
- Id,Multi,SNT**2=1.-CST**2
- Keeo WSG,WSZ,WSP,WSGZ
- *next
- B DDPI2,GG2,PI2
- Z DELMA=WSP(AK2)-MC*CST*WSGZ(AK2)/AK2/SNT-MC*WSG(AK2)/AK2
- Z W0AD=MC*SNT/CST**3*WSGZ(AK2)/AK2
- Z ELNEU=2.*WSZ(AK2)*CST**2/MC-2.*WSP(AK2)/MC
- Id,AK2=0.
- Al,B0(AK2,M1~,M2~)=B0(0,M1,M2)
- Al,B1(AK2,M1~,M2~)=B1(0,M1,M2)
- Al,B21(AK2,M1~,M2~)=B21(0,M1,M2)
- Id,B0(0,M1~,M1~)=DDPI2-LOG(M1)
- Al,B1(0,M1~,M1~)=-DDPI2/2+LOG(M1)/2.
- Al,B21(0,M1~,M1~)=DDPI2/3.-LOG(M1)/3.
- Al,B0(0,0,M1~)=DDPI2-LOG(M1)+1
- Al,B1(0,0,M1~)=-DDPI2/2.+LOG(M1)/2.-0.25
- Al,B21(0,0,M1~)=DDPI2/3.-LOG(M1)/3.+1./9.
- Id,B0(0,M1~,M2~)=DDPI2-LOG(M2)-F1(M1,M2)
- Al,B1(0,M1~,M2~)=-DDPI2/2.+LOG(M2)/2.+0.5*F2(M1,M2)
- Al,B21(0,M1~,M2~)=DDPI2/3.-LOG(M2)/3.-F3(M1,M2)/3.
- C F1(M1,M2) = FUNCTION F1 OF Y = M1**2/(M1**2-M2**2)
- C 1/Y = 1 - M2**2/M1**2
- Id,F1(M1~,M2~)=(1.-M2/M1)*(0.5+F2(M1,M2))
- Id,F2(M1~,M2~)=(1.-M2/M1)*(1./3.+F3(M1,M2))
- *yep
- Id,3,BO2**N~*F3(TO2,BO2)=(F3(TO2,BO2)*TO2+(TO2-BO2)/3.
- -TO2*F2(TO2,BO2))*BO2**N/BO2
- Al,3,TM2**N~*F3(HN2,TM2)=(F3(HN2,TM2)*HN2+(HN2-TM2)/3.
- -HN2*F2(HN2,TM2))*TM2**N/TM2
- Id,2,BO2**N~*F2(TO2,BO2)=(F2(TO2,BO2)*TO2+(TO2-BO2)/2.
- -TO2*F1(TO2,BO2))*BO2**N/BO2
- Al,2,TM2**N~*F2(HN2,TM2)=(F2(HN2,TM2)*HN2+(HN2-TM2)/2.
- -HN2*F1(HN2,TM2))*TM2**N/TM2
- *yep
- Id,Multi,SNT**2=1.-CST**2
- Id,Multi,CST**2=1.-SNT**2
- Id,Multi,SNT**2=1.-CST**2
- Id,SNT**-2*CST**-2=1./SNT**2+1./CST**2
- Id,Multi,SNT**2=1.-CST**2
- Id,Multi,CST**2=1.-SNT**2
- Id,Multi,SNT**2=1.-CST**2
- Keep WSG,WSP,WSGZ,WSZ,DELMA,W0AD
- *next
- F AA0
- Z WCM2S=DELMA-WSP(-MC)
- Z W0M2S=DELMA/CST**2+W0AD-WSZ(-M0)
- Id,Multi,M0=MC/CST**2
- Al,Multi,M0**-1=CST**2/MC
- Id,B21(AK2~,M1~,M2~)=-(-AA0(M2)-M1*B0(AK2,M1,M2)
- - 2.*(M1-M2-AK2)*B1(AK2,M1,M2) - 0.5*(M1+M2+AK2/3.))/3./AK2
- Id,B1(AK2~,M1~,M2~)=(0.5*AA0(M1)-0.5*AA0(M2)+0.5*(M1-M2-AK2)*
- B0(AK2,M1,M2))/AK2
- Id,AA0(M1~)=-M1*DDPI2+M1*LOG(M1)-M1
- Id,Multi,M0=MC/CST**2
- Al,Multi,M0**-1=CST**2/MC
- *yep
- B DDPI2,GG2,PI2
- Id,B0(AK2~,M1~,0)=B0(AK2,0,M1)
- Id,B0(AK2~,M1~,M2~)=DDPI2-LOG(M2)+B0R(AK2,M1,M2)
- Id,LOG(TO2)=LOG(TO2,BO2)+LOG(BO2)
- Al,LOG(HN2)=LOG(HN2,TM2)+LOG(TM2)
- Id,Multi,SNT**2=1.-CST**2
- Id,Multi,CST**2=1.-SNT**2
- Id,Multi,SNT**2=1.-CST**2
- Id,SNT**-2*CST**-2=1./SNT**2+1./CST**2
- Id,Multi,SNT**2=1.-CST**2
- Id,Multi,CST**2=1.-SNT**2
- Id,Multi,SNT**2=1.-CST**2
- Keep WCM2S,W0M2S
- *next
- B GG2,PI2
- Z CONTC=WCM2S-HAC
- Z CONT0=W0M2S-HA0
- Id,HAC=GG2/16./PI2*(4.*MC/9.-0.5*(TO2-BO2)**2/MC
- -1./6.*(TM2-HN2)**2/MC+3./4.*(TO2-BO2)
- +1./4.*(HN2-TM2)
- +(-2./3.*MC-TO2+0.5*TO2*(TO2-BO2)/MC)*LOG(TO2,BO2)
- +(-1./3.*HN2+1./6.*HN2*(HN2-TM2)/MC)*LOG(HN2,TM2)
- +3./2.*TO2*F1(TO2,BO2)+0.5*HN2*F1(HN2,TM2)
- +(-MC+0.5*(TO2-BO2)**2/MC+0.5*(TO2+BO2))*B0R(-MC,TO2,BO2)
- +(-1./3.*MC+1./6.*(HN2-TM2)**2/MC+1./6.*(HN2+TM2))*B0R(-MC,HN2,TM2))
- Al,HA0=GG2/PI2/CST**2*(MC/108./CST**2*(8.*CST**4-10.*CST**2+5.)
- +1./64.*(3.*(TO2-BO2)+HN2-TM2)
- +1./16.*(-1./6.*MC/CST**2-3./2.*TO2)*LOG(TO2,BO2)
- +1./16.*(1./6.*MC/CST**2-0.5*HN2)*LOG(HN2,TM2)
- +1./32.*(3.*TO2*F1(TO2,BO2)+HN2*F1(HN2,TM2))
- +(MC/288./CST**2*(-32.*CST**4+40.*CST**2-17.)
- +TO2/288.*(-64.*CST**4+80.*CST**2-7.))*B0R(-M0,TO2,TO2)
- +(MC/288./CST**2*(-8.*CST**4+4.*CST**2-5.)
- +BO2/288.*(-16.*CST**4+8.*CST**2+17.))*B0R(-M0,BO2,BO2)
- +1./96.*(-MC/CST**2+HN2)*B0R(-M0,HN2,HN2)
- +1./96.*(MC/CST**2*(-8.*CST**4+12.*CST**2-5.)
- +TM2*(-16.*CST**4+24.*CST**2-7.))*B0R(-M0,TM2,TM2))
- Keep WCM2S,W0M2S
- *next
- Z WHM2S=WCM2S
- Z WH0MS=W0M2S
- C LIMIT OF HIGH EQUAL MASSES OF THE FERMIONS.
- Id,B0R(AK2~,M1~,M2~)=-AK2/6./M2
- Id,BO2=TO2
- Al,TM2=HN2
- Id,M0=MC/CST**2
- Al,Multi,M0**-1=CST**2/MC
- Id,Multi,BO2**-1=TO2**-1
- Al,Multi,TM2**-1=HN2**-1
- Al,LOG(TM2)=LOG(HN2)
- Al,LOG(TO2,BO2)=0.
- Al,F1(HN2,TM2)=0.
- Al,F1(TO2,BO2)=0.
- Keep WCM2S,W0M2S
- *next
- B GG2,PI2,MC,M0
- Z WCM2L=WCM2S
- Id,B0R(AK2~,M1~,M2~)=LOG(M2,-AK2)+2.
- Id,LOG(M1~,M2~)=LOG(M1,MC)-LOG(M2,MC)
- Id,LOG(M1~)=LOG(M1,MC)+LOG(MC)
- Id,LOG(MC,MC)=0.
- Keep WCM2S,W0M2S,WCM2L
- *next
- B GG2,PI2,MC,M0
- Z W0M2L=W0M2S
- Id,B0R(AK2~,M1~,M2~)=LOG(M2,-AK2)+2.
- Id,LOG(M1~,M2~)=LOG(M1,M0)-LOG(M2,M0)
- Id,LOG(M1~)=LOG(M1,M0)+LOG(M0)
- Id,LOG(M0,M0)=0.
- Keep WCM2S,W0M2S,WCM2L,W0M2L
- *next
- N 10,R0
- B GG2,PI2,MC
- S LCST2
- Z WCM2N=WCM2L/2./MC1
- Z W0M2N=W0M2L/2./MC1*CST
- Id,GG2*PI2**-1=0.0390389874
- Id,LOG(M1~,M0)=LOG(M1,MC)+LCST2
- Id,LOG(TO2,MC)=-11.44717349
- Al,LOG(BO2,MC)=-11.44717349
- Al,LOG(TM2,MC)=-23.8328534
- Id,Numer,CST2,0.762,CST,0.8729261134,MC,5.852269263E9
- ,MC1,7.650012588851E4,LCST2,-0.2718087233
- Keep WCM2S,W0M2S,WCM2L,W0M2L
- *next
- N
- B GG2,PI2,MC
- Z CHECC=WCM2L-HANDC
- Z CHEC0=W0M2L-HAND0
- Id,HANDC=-GG2*MC*PI2**-1*(5./36.+1./48.*(2.*LOG(TO2,MC)
- +LOG(BO2,MC)+LOG(TM2,MC)) )
- Al,HAND0=-GG2*MC*PI2**-1*CST2**-2*(1./108.*(40.*CST2**2-50.*CST2+25.)
- +1./72.*(8.*CST2**2-10.*CST2+5.)*LOG(TO2,M0)
- +1./72.*(2.*CST2**2-CST2+0.5)*LOG(BO2,M0)
- +1./48.*(4.*CST2**2-6.*CST2+3.)*LOG(TM2,M0))
- Id,CST2=CST**2
- Al,Multi,CST2**-1=CST**-2
- Id,Numer,TO2,0.,BO2,0.,HN2,0.,TM2,0.
- Keep WCM2S,W0M2S
- *next
- B GG2,PI2
- Z WCM2H=WCM2S
- Z W0M2H=W0M2S
- Id,F1(HN2,TM2)=F1(TM2,HN2)+LOG(HN2,TM2)
- Al,B0R(AK2~,HN2,TM2)=B0R(AK2,TM2,HN2)-LOG(HN2,TM2)
- Id,LOG(HN2,TM2)=-LOG(TM2,HN2)
- Id,B0R(AK2~,M1~,M2~)=-F1(M1,M2)-AK2*INV(M1,M2)*(F1(M1,M2)-F2(M1,M2))
- Id,LOG(M1~,M2~)=(1.-M2/M1)*F1(M1,M2)+1.-M2/M1
- *yep
- Id,F1(M1~,M2~)=0.5*ANV(M1,M2)/M1+1./3.*(ANV(M1,M2)/M1)**2
- +1./4.*(ANV(M1,M2)/M1)**3
- Al,F2(M1~,M2~)=1./3.*ANV(M1,M2)/M1+1./4.*(ANV(M1,M2)/M1)**2
- +1./5.*(ANV(M1,M2)/M1)**3
- Id,Adiso,INV(M1~,M2~)*ANV(M1~,M2~)=1.
- Id,ANV(M1~,M2~)=M1-M2
- Id,LOG(HN2,TM2)=-LOG(TM2,HN2)
- Id,LOG(M1~,M2~)=1.-M2/M1+0.5*(1.-2.*M2/M1+M2**2/M1**2)
- Id,M0=MC/CST**2
- Al,Multi,M0**-1=CST**2/MC
- P output
- *yep
- B GG2,PI2,EQ2,EL2
- Id,BO2=TO2+EQ2
- Al,TM2=HN2+EL2
- Id,TO2=BO2-EQ2
- Al,HN2=TM2-EL2
- *end
-
- C Vectors 2. Vector-boson self-energies, infinite parts.
-
- C SELF-ENERGIES, INFINITE PARTS.
- C ALSO DM2, DMU, DE, DSNT2 CONSIDERATIONS.
- P stat
- F SGV,SZV,SWPV,SGZV
- B DDPI2,GG2,PI2
- Z WSG=COUPW*(SG
- +SGV(UP2,DO2,ELM2)+SGV(CH2,ST2,UM2)+SGV(TO2,BO2,TM2))
- Z WSZ=COUPW*(SZ
- +SZV(UP2,DO2,ELM2)+SZV(CH2,ST2,UM2)+SZV(TO2,BO2,TM2))
- Z WSP=COUPW*(SWP
- +SWPV(UP2,DO2,ELM2)+SWPV(CH2,ST2,UM2)+SWPV(TO2,BO2,TM2))
- Z WSGZ=COUPW*(SGZ
- +SGZV(UP2,DO2,ELM2)+SGZV(CH2,ST2,UM2)+SGZV(TO2,BO2,TM2))
- Id,SG=SNT2*S*(12.*(CB21+0.5*CB1)-4.*CB0-2./3.)
- Al,SZ=(12.*CST2-4.+CSTM2)*S*(CB21-0.25*CB0)
- + S*(HZB21+HZB1+0.25*HZB0)/CST2
- + (W0M2-HM2)*(0.5*HZB1+0.25*HZB0)/CST2 + W0M2*HZB0/CST2
- + WCM2*(2./CST2-4.)*CB0 - 2.*S*CST2/3.-4.*S*CB0*CST2
- Al,SGZ=CST*SNT*((12.-2./CST2)*S*(CB21-0.25*CB0)
- - (4.*S+2.*WCM2/CST2)*CB0 - 2.*S/3.)
- Al, SWP=(8.*CST2+1.)*(S*(CNB21+CNB1+0.25*CNB0)
- + (W0M2-WCM2)*(0.5*CNB1+0.25*CNB0))
- + 8.*SNT2*(S*(CPB21+CPB1+0.25*CPB0)-WCM2*(0.5*CPB1+0.25*CPB0))
- + S*(CHB21+CHB1+0.25*CHB0)+(WCM2-HM2)*(0.5*CHB1+0.25*CHB0)
- + CNB0*(WCM2*(CSTM2-3.)-4.*S*CST2) - CPB0*SNT2*4.*S
- + WCM2*CHB0-2.*S/3.
- Id,SGV(UP2~,DO2~,TM2~)=-S*SNT2*(8.*B21-4.*B0+32.*B21/3.-16.*B0/3.
- +8.*B21/3.-4.*B0/3.)
- Al,SZV(UP2~,DO2~,TM2~)=S*(-3.*((1.-8.*SNT**2/3.)**2+1.)*(8.*B21
- -4.*B0)/16/CST**2 - 3.*((4.*SNT**2/3.-1.)**2+1.)
- *(8.*B21-4.*B0)/16./CST**2) - 0.5*(3.*UP2*B0+3.*DO2*B0)/CST**2
- +S*(-(8.*B21-4.*B0)/8./CST**2
- - ((4.*SNT**2-1.)**2+1.)*(8.*B21-4.*B0)/16./CST**2)
- - 0.5*(HN2*B0+TM2*B0)/CST**2
- Al,SWPV(UP2~,DO2~,TM2~)=-2.*S*(3.*B21+3.*B1)+3.*(DO2-UP2)*B1-3.*UP2*B0
- -2.*S*(B21+B1)+(TM2-HN2)*B1-HN2*B0
- Al,SGZV(UP2~,DO2~,TM2~)=-S*SNT/CST*(2.*(1.-8.*SNT**2/3.)*(2.*B21-B0)
- -(4.*SNT**2/3.-1.)*(2.*B21-B0))
- -S*SNT/CST*(-(4.*SNT**2-1.)*(2.*B21-B0))
- Id,CB0=B0
- Al,CB1=B1
- Al,CB21=B21
- Al,HZB0=B0
- Al,HZB1=B1
- Al,HZB21=B21
- Al,CNB0=B0
- Al,CNB1=B1
- Al,CNB21=B21
- Al,CPB0=B0
- Al,CPB1=B1
- Al,CPB21=B21
- Id,CHB0=B0
- Al,CHB1=B1
- Al,CHB21=B21
- Al,W0M2=WCM2/CST**2
- Id,CSTM2=1./CST**2
- Al,COUPW=GG2/16./PI2
- Id,Multi,SNT**2=1.-CST**2
- Id,Multi,CST**2=1.-SNT**2
- Id,Multi,SNT**2=1.-CST**2
- Keep WSG,WSZ,WSP,WSGZ
- P output
- *next
- F WV,WA,WNV
- S ELM2,UM2
- B DDPI2,GG2,PI2,S
- Z DS2M=-(2.*DW0M*CST/WCM+DM2A)*CST**2/SNT**2
- Z DS2=-0.25*(AA1*DBB-BB1*DAA)/SNT**2
- Z WSGP=WSG
- Z WSZP=WSZ
- Z WSPP=WSP
- Z WSGZP=WSGZ
- Z DEWA=2.*DM2A-2.*DG2AF
- Z DEW=DEWV+DEVX+DEBX+PRCOT
- Id,DG2AF=-0.5*DEC-DS2A
- Id,DS2A=-(2.*DW0M*CST/WCM+DM2A)*CST**2/SNT**2
- Id,DEC=DEWVC+DEVXC+PRCC+W0GC
- Id,DEWVC=4.*WV(ELM2)+4.*WV(UM2)
- Al,DEVXC=-DDPI2*(SNT**2-5/8/CST**2-0.25)*4.*GG2/16/PI2
- +2.*GG2*0.375*DDPI2*(UM2+ELM2)/16/PI2/WCM2
- Al,PRCC=-2.*WSG *SYBS
- Al,W0GC=-VT*WSGZ*SABS*CST/SNT/WCM2
- Id,DEWV=2.*(WV(UM2)+WA(UM2)+WV(ELM2)+WA(ELM2)+2.*WNV(UM2)+2.*WNV(ELM2))
- Al,DEVX=-(1.25+0.125/CST**2)*DDPI2*COFF
- -(UM2+ELM2)*DDPI2/16/WCM2*COFF
- Al,DEBX=0.125*SNT**2*DDPI2*CFFF
- Al,PRCOT=2.*WSP *SIBS/WCM2
- Id,WV(ELM2~)=GG2*((VT**2+1.)*B1/8/CST**2+0.5*B1+0.75*ELM2*B1/WCM2)
- /32./PI2
- Al,WA(ELM2~)=GG2*(-VT*B1/4/CST**2+0.5*B1-0.25*ELM2*B1/WCM2)/32/PI2
- Al,WNV(ELM2~)=GG2*(0.25*B1/CST**2+0.5*B1+ELM2*B1/4/WCM2)/32/PI2
- Id,COFF=-8.*GG2/16/PI2
- Al,CFFF=-2.*8.*GG2/16/PI2
- Id,S**N~*SIBS=0.
- Al,S**N~*SABS=0.
- Al,S**N~*SYBS=1.
- Id,SIBS=1
- Al,SYBS=0
- Al,SABS=1
- Al,VT=4.*SNT**2-1
- Id,DAA=2.*BB1*WEA+RESA*COF+VTNG
- Al,DBB=2.*AA1*WEA+RESB*COF
- Id,RESA=CST*(SNT**2+0.5+9./16./CST**4 -7./4./CST**2)*ALDEL
- -(12.*SNT**2-2.)*ELM2/32./WCM2/CST*DDPI2
- Al,RESB=CST*(-1.5-7./16./CST**4+5./4./CST**2)*ALDEL
- -(-4.*SNT**2-2.)*ELM2/32./WCM2/CST*DDPI2
- Id,COF=-GG2*CST/4./PI2
- Id,WEA=GG2*(-(4.*SNT**2-1)*B1/4/CST**2+0.5*B1-0.25*ELM2/WCM2*B1)
- /32/PI2
- *yep
- Id,VTNG=(3.*C24-C24)*16.*WCM2*GG2/16./PI2/S*SNT**2
- + 4.*CST*SNT*(WSGZ+S*WSGZ*CST**2/WCM2)/S
- Id,AA1=4.*SNT**2-1.
- Al,BB1=-1.
- Al,C24=0.25*DDPI2
- Id,DM2A=-2.*DWCM/WCM
- Id,DWCM=-0.5*WSP*SUBS/WCM
- Al,DW0M=-0.5*WSZ*CST*SABS/WCM
- Id,S**N~*SUBS=WCM2**N
- Al,S**N~*SABS=WCM2**N/CST**N/CST**N
- Id,SUBS=1.
- Al,SABS=1.
- Id,Multi,WCM**-2=1./WCM2
- Al,Multi,WCM**2=WCM2
- Id,ALDEL=-DDPI2
- Id,B0=DDPI2
- Al,B1=-DDPI2/2.
- Al,B21=DDPI2/3.
- Al,CB0=DDPI2
- Al,CB1=-DDPI2/2.
- Al,CB21=DDPI2/3.
- Id,GG2*DDPI2=GG3
- Id,GG2=0.
- Id,GG3=GG2*DDPI2
- Id,Multi,SNT2=SNT**2
- Al,Multi,CST2=CST**2
- Al,Multi,SNT2**-1=SNT**-2
- Al,Multi,CST2**-1=CST**-2
- Id,SNT**-2*CST**-2=1./SNT**2+1./CST**2
- Id,Multi,SNT**2=1-CST**2
- Id,Multi,CST**2=1.-SNT**2
- Id,Multi,SNT**2=1-CST**2
- Id,SNT**-2*CST**-2=1./SNT**2+1./CST**2
- P output
- Keep DS2M,DS2,DEW,DEWA
- *next
- B DDPI2,GG2,PI2,S
- Z DS22=DS2-DS2M
- Id,Multi,SNT**2=1.-CST**2
- Id,Multi,CST**2=1.-SNT**2
- Id,Multi,SNT**2=1-CST**2
- Keep DEW,DEWA
- *next
- B DDPI2,GG2,PI2,S
- Z DEWX=DEW-DEWA
- *end
-
- C Vectors 3. Vector-boson self-energies. Comparison of various expressions.
-
- P stat
- S K2,M,M0,ME,MH,MN,MP
- F B21,B1,B0
- Z SG=SNT2*S*(12.*(CB21+0.5*CB1)-4.*CB0-2./3.)
- -S*SNT2*(8.*EB21+4.*EB1-2.*EB0)
- Z SGT = SNT2*( - K2*(12*B21(M,M) - 7*B0(M,M) - 2/3)
- + K2*(8*B21(ME,ME)-4*B0(ME,ME)) )
- Z SGP=SNT2*EA1C
- +2.*SNT2*CA2
- +2.*SNT2*WCM2*CB0
- +4.*SNT2*CB22
- -2.*SNT2*CB22
- -2.*SNT2*CA
- +SNT2*(4.*EA-8.*EB22+2.*S*EB0)
- Z SZ=(12.*CST2-4.+CSTM2)*S*(CB21-0.25*CB0)
- + S*(HZB21+HZB1+0.25*HZB0)/CST2
- + (W0M2-HM2)*(0.5*HZB1+0.25*HZB0)/CST2 + W0M2*HZB0/CST2
- + WCM2*(2./CST2-4.)*CB0 - 2.*S*CST2/3.-4.*S*CB0*CST2
- -S*((4.*SNT2-1.)**2+1.)*(8.*EB21+4.*EB1-2.*EB0)/16./CST2
- - 0.5*EM2*EB0/CST2-0.125*S*(8.*OB21+4.*OB1-2.*OB0)/CST2
- Z SZT = K2*(4-1/CST2 - 12*CST2)*B21(M,M) + 2*K2*CST2/3
- + (K2*(7*CST2-1+0.25/CST2) + WCM2*(2/CST2-4))*B0(M,M)
- - K2/CST2*B21(M0,MH)
- + 0.5*(W0M2-HM2-2*K2)/CST2*B1(M0,MH)
- + 0.25*(5*W0M2-HM2-K2)/CST2*B0(M0,MH)
- + K2/16/CST2*((4*SNT2-1)**2+1)*(8*B21(ME,ME)-4*B0(ME,ME))
- + K2/8/CST2*(8*B21(MN,MN)-4*B0(MN,MN))
- - EM2/2/CST2*B0(ME,ME)
- Z SZP=CST2*EA1C
- +2.*CST2*CA2
- +2.*SNT4*CSTM2*WCM2*CB0
- +CSTM4*WCM2*HNB0
- +CSTM2*HNB22
- +CSTM2*(CST2-SNT2)**2*CB22
- -2.*CST2*CB22
- -0.25*CSTM2*(HA+NA)+2.*(SNT2-0.25*CSTM2)*CA
- +1./16./CST2*(-16.*OB22+4.*S*OB0)
- + 0.25/CST2*( -2.*((4.*SNT2-1.)**2+1.)*EB22
- +EM2*((4.*SNT2-1.)**2-1.)*EB0+0.5*((4.*SNT2-1)**2+1.)
- *(2.*EA-(2.*EM2-S)*EB0) )
- Z SGZ=CST*SNT*((12.-2./CST2)*S*(CB21-0.25*CB0)
- - (4.*S+2.*WCM2/CST2)*CB0 - 2.*S/3.)
- + SNT*CST*(4.*SNT2-1.)*S*(8.*EB21+4.*EB1-2.*EB0) /4./CST2
- Z SGZT = K2*SNT*(2/CST - 12*CST)*B21(M,M)
- + SNT*(7*K2*CST - K2/2/CST - 2*WCM2/CST)*B0(M,M) + 2*K2/3*SNT*CST
- - K2*SNT/CST*(4*SNT2-1)*(2*B21(ME,ME) - B0(ME,ME))
- Z SGZP =CST*SNT*EA1C
- +2.*SNT*CST*CA2
- -2.*SNT3*CSTM1*WCM2*CB0
- +2.*SNT*CSTM1*(CST2-SNT2)*CB22
- -2.*SNT*CST*CB22
- +SNT*CSTM1*(SNT2-CST2)*CA
- +2.*SNT*CST/CST2*(4.*SNT2-1.)*EB22
- - SNT*CST/CST2*(4.*SNT2-1.)*EA
- - 0.5*SNT*CST/CST2*(4.*SNT2-1.)*S*EB0
- Z SWP=(8.*CST2+1.)*(S*(CNB21+CNB1+0.25*CNB0)
- + (W0M2-WCM2)*(0.5*CNB1+0.25*CNB0))
- + 8.*SNT2*(S*(CPB21+CPB1+0.25*CPB0)-WCM2*(0.5*CPB1+0.25*CPB0))
- + S*(CHB21+CHB1+0.25*CHB0)+(WCM2-HM2)*(0.5*CHB1+0.25*CHB0)
- + CNB0*(WCM2*(CSTM2-3.)-4.*S*CST2) - CPB0*SNT2*4.*S
- + WCM2*CHB0-2.*S/3.
- -2.*S*(ENB21+ENB1+0.25*ENB0) + 2.*EM2*(0.5*ENB1+0.25*ENB0)
- -0.5*(EM2-S)*ENB0
- Z SWT = (8*CST2+1)*(-K2*B21(M0,M) + 0.5*(W0M2-WCM2-2*K2)*(B1(M0,M)
- + 0.5*B0(M0,M))
- +0.25*K2*B0(M0,M)) + (WCM2*(1/CST2-3) + 4*K2*CST2)*B0(M0,M)
- + 2*K2/3
- - 8*SNT2*K2*(B21(MP,M) + B1(MP,M) - 0.25*B0(MP,M))
- - 2*SNT2*WCM2*(2*B1(MP,M) + B0(MP,M))
- - K2*B21(M,MH) + 0.5*(WCM2-HM2-2*K2)*B1(M,MH)
- + 0.25*(5*WCM2 - HM2 - K2)*B0(M,MH)
- + 2*K2*(B21(MN,ME) + B1(MN,ME)) + EM2*B1(MN,ME)
- Z SWPW = -CST2*((W0M2+WCM2+4.*S)*CNB0-ZA-CA-10.*CNB22
- -2.*(W0M2+WCM2-S/3.))
- -SNT2*((WCM2+4.*S)*CPB0-CA-10.*CPB22-2.*(WCM2-S/3.))
- -3.*CA-2.*WCM2 + CST2*(-3.*ZA-2.*W0M2)
- + WCM2*(SNT4*CNB0/CST2+SNT2*CPB0)
- + WCM2*CHB0
- + CHB22
- +CNB22
- -2.*(CST2*CNB22+SNT2*CPB22)
- -0.25*(ZA+HA+2.*CA)
- + 0.25*(-8.*ENB22+2.*EA-2.*(EM2-S)*ENB0)
- Id HNB21=HZB21
- Al HNB22=HZB22
- Al HNB1=HZB1
- Al HNB0=HZB0
- Al NA=ZA
- Id K2 = - S
- Id B21(M,M)=CB21
- Al B1(M,M) = CB1
- Al B0(M,M) = CB0
- Id B21(ME,ME) = EB21
- Al B1(ME,ME) = EB1
- Al B0(ME,ME) = EB0
- Id B21(M0,MH) = HZB21
- Al B1(M0,MH) = HZB1
- Al B0(M0,MH) = HZB0
- Id B21(MN,MN) = OB21
- Al B1(MN,MN) = OB1
- Al B0(MN,MN) = OB0
- Id B21(M0,M) = CNB21
- Al B1(M0,M) = CNB1
- Al B0(M0,M) = CNB0
- Id B21(MP,M) = CPB21
- Al B1(MP,M) = CPB1
- Al B0(MP,M) = CPB0
- Id B21(M,MH) = CHB21
- Al B1(M,MH) = CHB1
- Al B0(M,MH) = CHB0
- Id B21(MN,ME) = ENB21
- Al B1(MN,ME) = ENB1
- Al B0(MN,ME) = ENB0
- *yep
- Id ALF2=0.25*HM2/WCM2
- Id EA1C=-2.*((WCM2+2.*S)*CB0-CA-5.*CB22- (-1./3.*S+2.*WCM2))
- Al EB1C=-2.*(-5.*CB21-5.*CB1+CB0+1./3.)
- Al EH2NH=2.*NA-HA+(W0M2-2.*HM2-2.*S)*HNB0
- Id ER1C=CB1+2.*CB0
- Al ER1NH=HNB1+2.*HNB0
- Al ER3NH=HNB0+2.*HNB1
- Al CA2=-3.*CA-2.*WCM2
- Al W0M2=WCM2/CST2
- Id SNT2=1.-CST2
- Al SNT4=(1.-CST2)**2
- Al SNT3=SNT**3
- Id C2S22=(2.*CST2-1.)**2
- Al CSTM1=1./CST
- Al CSTM2=1./CST2
- Al CSTM3=1./CST**3
- Al CSTM4=1./CST2**2
- Id CST2=CST**2
- Al,Multi,CST2**-1=CST**-2
- Id,Multi,SNT**2=1-CST**2
- Id CB22=(0.5*CA-WCM2*CB0-0.5*S*CB1-0.5*(2.*WCM2-S/3))/3
- Al EB22=(0.5*EA-EM2*EB0-0.5*S*EB1-0.5*(2.*EM2-S/3.))/3.
- Al CNB22=(0.5*CA-W0M2*CNB0-0.5*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3
- Al CHB22=(0.5*HA-WCM2*CHB0-0.5*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3
- Al HZB22=(0.5*HA-W0M2*HZB0-0.5*(W0M2-HM2+S)*HZB1-0.5*(W0M2+HM2-S/3))/3
- Al CPB22=(0.5*CA-0.5*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3
- Al ENB22=(0.5*EA-0.5*(-EM2+S)*ENB1-0.5*(EM2-S/3.))/3.
- Al OB22=(-0.5*S*OB1+S/6.)/3.
- Id CB21=(-CA-WCM2*CB0-2.*S*CB1-0.5*(2.*WCM2-S/3.))/3/S
- Al EB21=(-EA-EM2*EB0-2.*S*EB1-0.5*(2.*EM2-S/3.))/3/S
- Al CNB21=(-CA-W0M2*CNB0-2*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3/S
- Al CPB21=(-CA-2.*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3/S
- Al ENB21=(-EA-2.*(-EM2+S)*ENB1-0.5*(EM2-S/3.))/3./S
- Al OB21=(-2.*S*OB1+S/6.)/3./S
- Al CHB21=(-HA-WCM2*CHB0-2.*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3/S
- Al HZB21=(-HA-W0M2*HZB0-2.*(W0M2-HM2+S)*HZB1-0.5*(W0M2+HM2-S/3))/3/S
- Id CB1= - 0.5*CB0
- Al EB1=-0.5*EB0
- Al CNB1=-(0.5*ZA-0.5*CA+0.5*(W0M2-WCM2+S)*CNB0)/S
- Al CHB1=-(0.5*CA-0.5*HA+0.5*(WCM2-HM2+S)*CHB0)/S
- Al HZB1=-(0.5*ZA-0.5*HA+0.5*(W0M2-HM2+S)*HZB0)/S
- Al CPB1=-(-0.5*CA+0.5*(-WCM2+S)*CPB0)/S
- Al ENB1=-(-0.5*EA+0.5*(-EM2+S)*ENB0)/S
- Al OB1=-0.5*OB0
- Id W0M2=WCM2/CST**2
- Keep SZ,SZT,SZP,SG,SGT,SGP,SGZ,SGZT,SGZP,SWP,SWT,SWPW
- P noutp
- *next
- P output
- Z SGG=SG-SGP
- Z SZZ=SZ-SZP
- Z SGZZ=SGZ-SGZP
- Z SWPP=SWP-SWPW
- Z VER1=SGT-SGP
- Z VER2=SZT-SZP
- Z VER3=SGZT-SGZP
- Z VER4=SWT-SWPW
- *end
-
- C Vectors 4. Photon-W0 ward identity.
-
- P stats
- C NOTATIONS ARE N=NEUTRAL,C=CHARGED,P=PHOTON,H=HIGGS,R=MIXING
- C S=-K**2
- Z EANP1=CST*SNT*EA1C
- Z EBNP1=CST*SNT*EB1C
- Z EANP2=2.*SNT*CST*CA2
- Z EANP3=-2.*SNT3*CSTM1*WCM2*CB0
- Z EANP6=2.*SNT*CSTM1*(CST2-SNT2)*CB22
- Z EBNP6=0.5*SNT*CSTM1*(CST2-SNT2)*(CB0+4.*CB1+4.*CB21)
- Z EANP7=-2.*SNT*CST*CB22
- Z EBNP7=-2.*CST*SNT*(CB1+CB21)
- Z EANP8=SNT*CSTM1*(SNT2-CST2)*CA
- Z ERP1=SNT*ER1C
- Z ERP4=-SNT*CB1
- Id ALF2=0.25*HM2/WCM2
- Id EA1C=-2.*((WCM2+2.*S)*CB0-CA-5.*CB22- (-1./3.*S+2.*WCM2))
- Id EB1C=-2.*(-5.*CB21-5.*CB1+CB0+1./3.)
- Id EH2NH=2.*NA-HA+(W0M2-2.*HM2-2.*S)*HNB0
- Id ER1C=CB1+2.*CB0
- Id ER1NH=HNB1+2.*HNB0
- Id ER3NH=HNB0+2.*HNB1
- Id CA2=-3.*CA-2.*WCM2
- Id W0M2=WCM2/CST2
- Id SNT2=1.-CST2
- Al SNT4=(1.-CST2)**2
- Id SNT3=SNT**3
- Id CSTM1=1./CST
- Id CSTM2=1./CST2
- Al CSTM4=1./CST2**2
- Id CSTM3=1./CST**3
- Id CST2=CST**2
- Id,Multi,CST2**-1=CST**-2
- Id CB22=(0.5*CA-WCM2*CB0-0.5*S*CB1-0.5*(2.*WCM2-S/3))/3
- Al CNB22=(0.5*CA-W0M2*CNB0-0.5*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3
- Al CHB22=(0.5*HA-WCM2*CHB0-0.5*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3
- Al HNB22=(0.5*HA-W0M2*HNB0-0.5*(W0M2-HM2+S)*HNB1-0.5*(W0M2+HM2-S/3))/3
- Al CPB22=(0.5*CA-0.5*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3
- Id CB21=(-CA-WCM2*CB0-2.*S*CB1-0.5*(2.*WCM2-S/3.))/3/S
- Al CNB21=(-CA-W0M2*CNB0-2*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3/S
- Al CPB21=(-CA-2.*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3/S
- Al CHB21=(-HA-WCM2*CHB0-2.*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3/S
- Al HNB21=(-HA-W0M2*HNB0-2.*(W0M2-HM2+S)*HNB1-0.5*(W0M2+HM2-S/3))/3/S
- Id CB1= - 0.5*CB0
- Al CNB1=-(0.5*NA-0.5*CA+0.5*(W0M2-WCM2+S)*CNB0)/S
- Al CHB1=-(0.5*CA-0.5*HA+0.5*(WCM2-HM2+S)*CHB0)/S
- Al HNB1=-(0.5*NA-0.5*HA+0.5*(W0M2-HM2+S)*HNB0)/S
- Al CPB1=-(-0.5*CA+0.5*(-WCM2+S)*CPB0)/S
- Id W0M2=WCM2/CST**2
- Keep EANP1,EBNP1,EANP2,EANP3,EANP6,EBNP6,EANP7,EBNP7,
- EANP8,ERP1,ERP4
- *next
- Z REANP=-S*(EANP1+EANP2+EANP3+EANP6+EANP7+EANP8)
- Z REBNP=S**2*(EBNP1+EBNP6+EBNP7)
- Z RERNP=-S*WCM2/CST*(ERP1+ERP4)
- Keep REANP,REBNP,RERNP
- *next
- Z RESNP=REANP+REBNP+RERNP
- Id SNT**3=SNT-SNT*CST**2
- *end
-
- C Vectors 5. Neutral vector boson ward identity.
-
- P stats
- C NOTATIONS ARE N=NEUTRAL,C=CHARGED,P=PHOTON,H=HIGGS,R=MIXING
- C S=-K**2
- Z EAN1=CST2*EA1C
- Z EBN1=CST2*EB1C
- Z EAN2=2.*CST2*CA2
- Z EAN3=2.*SNT4*CSTM2*WCM2*CB0
- Z EAN4=CSTM4*WCM2*HNB0
- Z EAN5=CSTM2*HNB22
- Z EBN5=0.25*CSTM2*(HNB0+4.*HNB1+4.*HNB21)
- Z EAN6=CSTM2*(CST2-SNT2)**2*CB22
- Z EBN6=0.25*CSTM2*(CST2-SNT2)**2*(CB0+4.*CB1+4.*CB21)
- Z EAN7=-2.*CST2*CB22
- Z EBN7=-2.*CST2*(CB1+CB21)
- Z EAN8=-0.25*CSTM2*(HA+NA)+2.*(SNT2-0.25*CSTM2)*CA
- Z EATA=-ALF2*(NA+2.*CA)+CA+0.5*CSTM2*NA-4.*CA
- -2.*CSTM2*NA-2.*WCM2-CSTM2*W0M2-3.*ALF2*HA
- Z EHN2=0.5*(CA-2.*(S+0.5*WCM2)*CB0)
- Z EHN3=0.25*CSTM2*EH2NH
- Z EHN5=4.*ALF2**2*WCM2*HNB0
- Z EHN6=0.5*WCM2*CB0
- Z EHN7=-CSTM2*(NA+0.5*W0M2)-2.*CA-WCM2
- Z EHN8=-0.5*ALF2*HA
- Z EHN9=-ALF2*CA-3./2.*ALF2*NA
- Z ERN1=-SNT2*CSTM1*ER1C
- Z ERN2=-0.5*CSTM3*ER1NH
- Z ERN3=ALF2*CSTM1*ER3NH
- Z ERN4=-CST*CB1
- Id ALF2=0.25*HM2/WCM2
- Id EA1C=-2.*((WCM2+2.*S)*CB0-CA-5.*CB22- (-1./3.*S+2.*WCM2))
- Id EB1C=-2.*(-5.*CB21-5.*CB1+CB0+1./3.)
- Id EH2NH=2.*NA-HA+(W0M2-2.*HM2-2.*S)*HNB0
- Id ER1C=CB1+2.*CB0
- Id ER1NH=HNB1+2.*HNB0
- Id ER3NH=HNB0+2.*HNB1
- Id CA2=-3.*CA-2.*WCM2
- Id W0M2=WCM2/CST2
- Id SNT2=1.-CST2
- Al SNT4=(1.-CST2)**2
- Id SNT3=SNT**3
- Id CSTM1=1./CST
- Id CSTM2=1./CST2
- Al CSTM4=1./CST2**2
- Id CSTM3=1./CST**3
- Id CST2=CST**2
- Id,Multi,CST2**-1=CST**-2
- Id CB22=(0.5*CA-WCM2*CB0-0.5*S*CB1-0.5*(2.*WCM2-S/3))/3
- Al CNB22=(0.5*CA-W0M2*CNB0-0.5*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3
- Al CHB22=(0.5*HA-WCM2*CHB0-0.5*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3
- Al HNB22=(0.5*HA-W0M2*HNB0-0.5*(W0M2-HM2+S)*HNB1-0.5*(W0M2+HM2-S/3))/3
- Al CPB22=(0.5*CA-0.5*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3
- Id CB21=(-CA-WCM2*CB0-2.*S*CB1-0.5*(2.*WCM2-S/3.))/3/S
- Al CNB21=(-CA-W0M2*CNB0-2*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3/S
- Al CPB21=(-CA-2.*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3/S
- Al CHB21=(-HA-WCM2*CHB0-2.*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3/S
- Al HNB21=(-HA-W0M2*HNB0-2.*(W0M2-HM2+S)*HNB1-0.5*(W0M2+HM2-S/3))/3/S
- Id CB1= - 0.5*CB0
- Al CNB1=-(0.5*NA-0.5*CA+0.5*(W0M2-WCM2+S)*CNB0)/S
- Al CHB1=-(0.5*CA-0.5*HA+0.5*(WCM2-HM2+S)*CHB0)/S
- Al HNB1=-(0.5*NA-0.5*HA+0.5*(W0M2-HM2+S)*HNB0)/S
- Al CPB1=-(-0.5*CA+0.5*(-WCM2+S)*CPB0)/S
- Id W0M2=WCM2/CST**2
- Keep EAN1,EBN1,EAN2,EAN3,EAN4,EAN5,EBN5,EAN6,EBN6,EAN7,
- EBN7,EAN8,EATA,EHN2,EHN3,EHN5,EHN6,EHN7,EHN8,EHN9,ERN1,
- ERN2,ERN3,ERN4
- *next
- Z RESAN=-S*(EAN1+EAN2+EAN3+EAN4+EAN5+EAN6+EAN7+EAN8)
- Z RESBN=S**2*(EBN1+EBN5+EBN6+EBN7)
- Z RESHN=W0M2*(EHN2+EHN3+EHN5+EHN6+EHN7+EHN8+EHN9)-0.5*W0M2*EATA
- Z RESRN=-2.*WCM2/CST*S*(ERN1+ERN2+ERN3+ERN4)
- Id W0M2=WCM2/CST**2
- Keep RESAN,RESBN,RESHN,RESRN
- *next
- Z RESN=RESAN+RESBN+RESHN+RESRN
- *end
-
- C Vectors 6. Photon ward identity.
-
- P stats
- C NOTATIONS ARE N=NEUTRAL,C=CHARGED,P=PHOTON,H=HIGGS,R=MIXING
- C S=-K**2
- Z EAP1=SNT2*EA1C
- Z EBP1=SNT2*EB1C
- Z EAP2=2.*SNT2*CA2
- Z EAP3=2.*SNT2*WCM2*CB0
- Z EAP6=4.*SNT2*CB22
- Z EBP6=SNT2*(CB0+4.*CB1+4.*CB21)
- Z EAP7=-2.*SNT2*CB22
- Z EBP7=-2.*SNT2*(CB1+CB21)
- Z EAP8=-2.*SNT2*CA
- Id ALF2=0.25*HM2/WCM2
- Id EA1C=-2.*((WCM2+2.*S)*CB0-CA-5.*CB22- (-1./3.*S+2.*WCM2))
- Id EB1C=-2.*(-5.*CB21-5.*CB1+CB0+1./3.)
- Id EH2NH=2.*NA-HA+(W0M2-2.*HM2-2.*S)*HNB0
- Id ER1C=CB1+2.*CB0
- Id ER1NH=HNB1+2.*HNB0
- Id ER3NH=HNB0+2.*HNB1
- Id CA2=-3.*CA-2.*WCM2
- Id W0M2=WCM2/CST2
- Id SNT2=1.-CST2
- Al SNT4=(1.-CST2)**2
- Id SNT3=SNT**3
- Id CSTM1=1./CST
- Id CSTM2=1./CST2
- Al CSTM4=1./CST2**2
- Id CSTM3=1./CST**3
- Id CST2=CST**2
- Id,Multi,CST2**-1=CST**-2
- Id CB22=(0.5*CA-WCM2*CB0-0.5*S*CB1-0.5*(2.*WCM2-S/3))/3
- Al CNB22=(0.5*CA-W0M2*CNB0-0.5*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3
- Al CHB22=(0.5*HA-WCM2*CHB0-0.5*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3
- Al HNB22=(0.5*HA-W0M2*HNB0-0.5*(W0M2-HM2+S)*HNB1-0.5*(W0M2+HM2-S/3))/3
- Al CPB22=(0.5*CA-0.5*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3
- Id CB21=(-CA-WCM2*CB0-2.*S*CB1-0.5*(2.*WCM2-S/3.))/3/S
- Al CNB21=(-CA-W0M2*CNB0-2*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3/S
- Al CPB21=(-CA-2.*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3/S
- Al CHB21=(-HA-WCM2*CHB0-2.*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3/S
- Al HNB21=(-HA-W0M2*HNB0-2.*(W0M2-HM2+S)*HNB1-0.5*(W0M2+HM2-S/3))/3/S
- Id CB1= - 0.5*CB0
- Al CNB1=-(0.5*NA-0.5*CA+0.5*(W0M2-WCM2+S)*CNB0)/S
- Al CHB1=-(0.5*CA-0.5*HA+0.5*(WCM2-HM2+S)*CHB0)/S
- Al HNB1=-(0.5*NA-0.5*HA+0.5*(W0M2-HM2+S)*HNB0)/S
- Al CPB1=-(-0.5*CA+0.5*(-WCM2+S)*CPB0)/S
- Id W0M2=WCM2/CST**2
- Keep EAP1,EBP1,EAP2,EAP3,EAP6,EAP7,EBP6,EBP7,EAP8
- *next
- Z RESAP=EAP1+EAP2+EAP3+EAP6+EAP7+EAP8
- Z RESBP=-S*(EBP1+EBP6+EBP7)
- Keep RESAP,RESBP
- *next
- Z RESP=RESAP+RESBP
- *end
-
- C Vectors 7. Charged vector boson ward identity.
-
- P stats
- B DEL
- Z EA1=
- -CST2*((W0M2+WCM2+4.*S)*CNB0-ZA-CA-10.*CNB22
- -2.*(W0M2+WCM2-S/3.))
- -SNT2*((WCM2+4.*S)*CPB0-CA-10.*CPB22-2.*(WCM2-S/3.))
- Z EB1=
- -CST2*(-10.*CNB21-10.*CNB1+2.*CNB0+2./3.)
- -SNT2*(-10.*CPB21-10.*CPB1+2.*CPB0+2./3.)
- Z EA2 =
- -3.*CA-2.*WCM2 + CST2*(-3.*ZA-2.*W0M2)
- Z EA3 =
- WCM2*(SNT4*CNB0/CST2+SNT2*CPB0)
- Z EA4 = WCM2*CHB0
- Z EA5 = CHB22
- Z EB5 = 0.25*CHB0+CHB1+CHB21
- Z EA6=CNB22
- Z EB6=0.25*CNB0+CNB1+CNB21
- Z EA7 = -2.*(CST2*CNB22+SNT2*CPB22)
- Z EB7 = -2.*(CST2*CNB1+SNT2*CPB1+CST2*CNB21+SNT2*CPB21)
- Z EA8 = -0.25*(ZA+HA+2.*CA)
- Z EATA=-ALF2*(ZA+2.*CA) + CA+0.5*ZA/CST2 -4.*CA-2.*ZA/CST2
- -2.*WCM2-W0M2/CST2
- -3.*ALF2*HA
- Z EH1 = WCM2*(4.*SNT4*CNB0/CST2+4.*SNT2*CPB0-2.*SNT4/CST2-2.*SNT2)
- Z EH2 = C2S22*0.25*(2.*ZA-CA+(W0M2-2.*WCM2-2.*S)*CNB0)/CST2
- +SNT2*(-CA-2.*(WCM2+S)*CPB0)
- +0.25*(2.*CA-ZA + (WCM2-2.*W0M2-2.*S)*CNB0)
- Z EH3 = 0.25*(2.*CA-HA+(WCM2-2.*HM2-2.*S)*CHB0)
- Z EH5 = 4.*ALF2**2*WCM2*CHB0
- Z EH6=0.5*(CST2-SNT2)*CNB0*WCM2/CST2
- Z EH7 = (SNT2-0.25/CST2)*(4.*ZA+2.*W0M2) -2.*CA - WCM2
- Z EH8 = -0.5*ALF2*HA
- Z EH9 = -ALF2*(0.5*ZA+2.*CA)
- Z ET1=0.5*SNT2*(CST2-SNT2)*(CNB1+2.*CNB0)/CST2-SNT2*(CPB1+2.*CPB0)
- Z ET2 = -(CHB0+0.5*CHB1)
- Z ET3 = ALF2*(CHB0+2.*CHB1)
- Z ET4 = CNB1+0.5*CNB0-CST2*CNB1-SNT2*CPB1
- Z ET5= - SNT2*(3.*CNB0+6.*CNB1)+SNT2*(3.*CPB0+6.*CPB1)
- Id SNT4=(1-CST2)**2
- Al CST4=CST2**2
- Id SNT2=1-CST2
- Id CSTM4=1./CST2**2
- Al CSTM2=1./CST2
- Id ALF2=0.25*HM2/WCM2
- Al C2S22=(2.*CST2-1.)**2
- Id CB22=(0.5*CA-WCM2*CB0-0.5*S*CB1-0.5*(2.*WCM2-S/3))/3
- Al CNB22=(0.5*CA-W0M2*CNB0-0.5*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3
- Al CHB22=(0.5*HA-WCM2*CHB0-0.5*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3
- Al HZB22=(0.5*HA-W0M2*HZB0-0.5*(W0M2-HM2+S)*HZB1-0.5*(W0M2+HM2-S/3))/3
- Al CPB22=(0.5*CA-0.5*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3
- Id CB21=(-CA-WCM2*CB0-2.*S*CB1-0.5*(2.*WCM2-S/3.))/3/S
- Al CNB21=(-CA-W0M2*CNB0-2*(W0M2-WCM2+S)*CNB1-0.5*(W0M2+WCM2-S/3))/3/S
- Al CPB21=(-CA-2.*(-WCM2+S)*CPB1-0.5*(WCM2-S/3))/3/S
- Al CHB21=(-HA-WCM2*CHB0-2.*(WCM2-HM2+S)*CHB1-0.5*(WCM2+HM2-S/3))/3/S
- Al HZB21=(-HA-W0M2*HZB0-2.*(W0M2-HM2+S)*HZB1-0.5*(W0M2+HM2-S/3))/3/S
- Id CB1= - 0.5*CB0
- Al CNB1=-(0.5*ZA-0.5*CA+0.5*(W0M2-WCM2+S)*CNB0)/S
- Al CHB1=-(0.5*CA-0.5*HA+0.5*(WCM2-HM2+S)*CHB0)/S
- Al HZB1=-(0.5*ZA-0.5*HA+0.5*(W0M2-HM2+S)*HZB0)/S
- Al CPB1=-(-0.5*CA+0.5*(-WCM2+S)*CPB0)/S
- Id W0M2=WCM2/CST2
- Keep EA1,EB1,EA2,EA3,EA4,EA5,EB5,EA6,EB6,EA7,EB7,EA8,EATA,EH1,
- EH2,EH3,EH5,EH6,EH7,EH8,EH9,ET1,ET2,ET3,ET4,ET5
- *next
- B DEL,CA
- Z RESA =- S*(EA1+EA2+EA3+EA4+EA5+EA6+EA7+EA8)
- Z RESB=
- + S**2*(EB1+EB5+EB6+EB7)
- Z RESH=
- + WCM2*(EH1+EH2+EH3+EH5+EH6+EH7+EH8+EH9)
- - 0.5*EATA *WCM2
- Z REST=
- - 2.*S*WCM2*(ET1+ET2+ET3+ET4+ET5)
- Keep RESA,RESB,RESH,REST
- *next
- B CA,DEL
- Z RESAL=RESA+RESB+RESH+REST
- *end
-
- C Vectors 8. Vector boson - vector boson scattering. Tree diagrams.
-
- P stat
- Oldnew,i=I
- S L,S,M,COS
- I IF
- I LA,AL,BE,GA,DE
- V K,P,KP,PP
- B L,PROP1,PROP2,PROP3
- Z DIA1 = AMPL(IA,IB,IC,ID,K,P,PP,KP)*PROP1
- Z DIA2 = AMPL(IA,IB,ID,IC,K,P,KP,PP)*PROP2
- Z DIA3 = AMPL(IC,IB,IA,ID,PP,P,K,KP)*PROP3
- Z DIA4 = ((Epf(IF,ID,IC)*Epf(IF,IB,IA))*
- (2*D(AL,GA)*D(BE,DE)-D(AL,DE)*D(BE,GA)-D(AL,BE)*D(GA,DE))
- + (Epf(IF,ID,IB)*Epf(IF,IC,IA))*
- (2*D(AL,BE)*D(GA,DE) - D(AL,DE)*D(GA,BE) - D(AL,GA)*D(BE,DE)))
- *E(K,AL)*E(KP,DE)*E(P,BE)*E(PP,GA)
- Z HDIA1 = M**2*D(AL,DE)*D(BE,GA)*D(IA,ID)*D(IB,IC)*PR1
- *E(K,AL)*E(KP,DE)*E(P,BE)*E(PP,GA)
- Z HDIA2 = M**2*D(AL,GA)*D(BE,DE)*D(IA,IC)*D(IB,ID)*PR2
- *E(K,AL)*E(KP,DE)*E(P,BE)*E(PP,GA)
- Z HDIA3 = M**2*D(AL,BE)*D(GA,DE)*D(IA,IB)*D(IC,ID)*PR3
- *E(K,AL)*E(KP,DE)*E(P,BE)*E(PP,GA)
- Id AMPL(IA~,IB~,IC~,ID~,K~,P~,PP~,KP~) =
- (Epf(IF,IA,ID)*Epf(IF,IB,IC))*
- (D(LA,GA)*(-2*PP(BE) - P(BE)) + D(BE,GA)*(PP(LA) - P(LA)) +
- D(LA,BE)*(2*P(GA) + PP(GA))) *
- (D(AL,LA)*(2*K(DE) + KP(DE)) + D(DE,LA)*(-2*KP(AL) - K(AL)) +
- D(AL,DE)*(KP(LA) - K(LA)) )
- *E(K,AL)*E(KP,DE)*E(P,BE)*E(PP,GA)
- C ALL MOMENTA INGOING
- Id E(K~,K~) = 0
- Id E(K,AL~) = K(AL)*K0/M/LK - I*M*D(AL,4)/LK
- Al E(P,AL~) = P(AL)*P0/M/LP - I*M*D(AL,4)/LP
- Al E(KP,AL~) = KP(AL)*KP0/M/LKP - I*M*D(AL,4)/LKP
- Al E(PP,AL~) = PP(AL)*PP0/M/LPP - I*M*D(AL,4)/LPP
- Id KDK = - M**2
- Al PDP = - M**2
- Al PPDPP = - M**2
- Al KPDKP = - M**2
- *yep
- Id KP(4) = I*KP0
- Id KP(AL~) = - K(AL) - P(AL) - PP(AL)
- Id,Dotpr,KP(AL~) = -K(AL) - P(AL) - PP(AL)
- Id KDK = - M**2
- Al PDP = - M**2
- Al PPDPP = - M**2
- Al KPDKP = - M**2
- Al KDPP = M**2 - PDK - PDPP
- Id K(4) = I*K0
- Al P(4) = I*P0
- Al PP(4) = I*PP0
- *yep
- C CENTRE OF MASS SYSTEM
- Id K0 = S
- Al LK**-1 = L**-1
- Al P0 = S
- Al LP**-1 = L**-1
- Al PP0 = - S
- Al LPP**-1 = L**-1
- Al KP0 = - S
- Al LKP**-1 = L**-1
- Al PDK = - 2*L**2 - M**2
- Al PDPP = L**2*COS + S**2
- Id,Multi,S**2 = L**2 + M**2
- *yep
- Id Trick
- *yep
- B COS
- Id COS = T**2/L**2/2 - 1
- C PROP1 = (T**2+ M**2)**-1
- C PROP2 = ( - T**2 + 4*L**2 + M**2)**-1
- C PROP3 = ( - 4*L**2 - 3*M**2)**-1
- C PR1 = (T**2 + M**2)**-1
- C PR2 = ( - T**2 + 4*L**2 + MM**2)**-1
- C PR3 = ( - 4*L**2 - 4*M**2 + MM**2)**-1
- Id,3,PROP1*T**IA~ = T**IA/T**2 - T**IA/T**2*M**2*PROP1
- Al,3,PROP2*T**IA~ = T**IA/T**2*4*L**2*PROP2 + T**IA/T**2*M**2*PROP2
- -T**IA/T**2
- Al,3,PROP3*L**IA~ = - 1/4*L**IA/L**2 - 3/4*L**IA/L**2*M**2*PROP3
- Id,3,PR1*T**IA~ = T**IA/T**2 - T**IA/T**2*MM**2*PR1
- Al,3,PR2*T**IA~ = - T**IA/T**2 + T**IA/T**2*4*L**2*PR2
- + MM**2*T**IA/T**2*PR2
- Al,3,PR3*L**IA~ = - 1/4*L**IA/L**2 - L**IA/L**2*M**2*PR3
- + 1/4*MM**2*L**IA/L**2*PR3
- Keep,DIA1,DIA2,DIA3,DIA4,HDIA1,HDIA2,HDIA3
- *next
- B GG
- Z DIAW = - GG**2*(DIA1 + DIA2 + DIA3 + DIA4)
- Z DIAH = GG**2*(HDIA1 + HDIA2 + HDIA3)
- Keep,DIAW,DIAH
- *next
- B GG
- Z DIA = DIAW + DIAH
- *end
-
- C Vectors 9. Vector boson box diagram.
-
- P stats
- B QDP1,QDP2,QDP3,QDP4,QDQ
- V Q,P1,P2,P3,P4
- Z BOX=(D(MU,LA)*(P1(KA)-Q(KA)) + D(KA,LA)*(2*Q(MU)+P1(MU))
- + D(MU,KA)*(-Q(LA)-2*P1(LA)))
- *(D(NU,KA)*(P2(JD)-P1(JD)-Q(JD))
- + D(JD,KA)*(2*Q(NU)+2*P1(NU)+P2(NU))
- + D(NU,JD)*(-Q(KA)-P1(KA)-2*P2(KA)))
- *(D(JA,JD)*(2*P3(JE)+P4(JE)-Q(JE))
- + D(JE,JD)*(2*Q(JA)-P3(JA)-2*P4(JA))
- + D(JA,JE)*(-Q(JD)+P4(JD)-P3(JD)))
- *(D(JB,JE)*(2*P4(LA)-Q(LA))
- + D(LA,JE)*(2*Q(JB)-P4(JB))
- + D(JB,LA)*(-Q(JE)-P4(JE)))
- Al,Multi,P2DP2=-M2
- Id,Multi,P1DP1=-M2
- Al,Multi,P3DP3=-M2
- Al,Multi,P4DP4=-M2
- *end
-
- C Vectors 10. Example of a gauge field theory. One loop poles.
-
- P stats
- Oldnew i=I
- S GG,AA,M,SM
- S GM,TP,TW1,TW2,LAM,KAP,DIV
- I A=3,B=3,C=3,E=3,AP=3,BP=3,CP=3,AL,BE,GA,EP
- I MU,NU,MU1,NU1,MU2,NU2,A1=3,A2=3,A3=3,A1P=3,A2P=3,A3P=3
- I AL1,AL2,AL3,AL1P,AL2P,AL3P
- I APP=3,BEP,GAP,ALP,ALQ,ALPP
- V K,P,Q,KP,KK,QP
- F NOM,BET,GAM
- F OUT1,OUT2,IN23,IN24,IN1,DUO2,SIN2,SIN1
- F QX,QY,X,F,OUT3,IN33,IN34A,IN34B,IN34C
- F DUO,TRIO
- F VER3,PROP,VER4
- X DVV(N)=DT(N+4)*DIV**N*DIV**5
- X NUM(M1,M2,M3,M4)=1-0.5*DK(M1,M4)*DK(M2,M3)
- X FOUR(M1,M2,M3,M4) = DT(Integ(- 1 +
- DK(M1,M2)*DK(M3,M4) + DK(M1,M3)*DK(M2,M4) + DK(M1,M4)*DK(M2,M3)) )
- T CHF(N)="W,"P,"Z,"P,"W
- T CHL(N)="W,"P,"Z,"W,"P
- X WW(A,AL,K,B,BE,P) = D(A,B)*D(AL,BE)*NOM(K,M)
- + D(A,B)*K(AL)*K(BE)*BET(K)
- X ZZ(A,AL,K,B,BE,P) = NOM(K,SM)
- X PP(A,AL,K,B,BE,P) = D(A,B)*GAM(K)
- X PW(A,AL,K,B,BE,P) = - I*M*TP*K(BE)*NOM(K,GM)*NOM(K,GM)*D(A,B)
- X XY(A,AL,K,B,BE,P) = D(A,B)*NOM(K,GM)/KAP
- X PPP=0
- X PWW=0
- X PZZ=0
- X WZZ=0
- X WWW(A,AL,K,B,BE,P,C,GA,Q) = - I*GG*EP3(A,B,C)*
- ( D(AL,GA)*(K(BE)-Q(BE)) + D(BE,GA)*(Q(AL)-P(AL))
- + D(AL,BE)*(P(GA) - K(GA)) )
- X WWWW(A,AL,B,BE,C,GA,E,EP) = - (D(E,B)*D(C,A) - D(E,A)*D(C,B))
- *GG**2*(2*D(AL,GA)*D(BE,EP) - D(AL,EP)*D(BE,GA) - D(AL,BE)
- *D(GA,EP)) - (D(E,C)*D(B,A) - D(E,A)*D(B,C))*GG**2
- *(2*D(AL,BE)*D(GA,EP) - D(AL,EP)*D(GA,BE) - D(AL,GA)*D(BE,EP))
- X PPW(B,BE,P,C,GA,Q,A,AL,K) = 0.5*I*GG*EP3(A,B,C)*(P(AL)-Q(AL))
- X PWZ(B,BE,P,A,AL,K,C,GA,Q) = 0.5*I*GG*D(A,B)*(P(AL)-Q(AL))
- X WWZ(A,AL,K,B,BE) = - GG*M*D(A,B)*D(AL,BE)
- X PPZ(A,AL,K,B) = - 2*AA*M*GG*D(A,B)
- X ZZZ = -6*AA*M*GG
- X WXY(A,AL,K,B,BE,P,C,GA,Q) = I*GG*EP3(A,B,C)*P(AL)*KAP
- X XYZ(A,AL,K,B) = - 0.5*M*GG*D(A,B)*LAM
- X PXY(A,AL,K,B,BE,P,C) = 0.5*M*GG*EP3(A,B,C)*LAM
- X PPWW(C,GA,E,EP,A,AL,B,BE) = - 0.5*GG**2*D(A,B)*D(C,E)*D(AL,BE)
- X WWZZ(A,AL,B,BE) = - 0.5*GG**2*D(A,B)*D(AL,BE)
- X PPPP(A,AL,B,BE,C,GA,E,EP) = -AA*GG**2*(D(A,B)*D(C,E)
- + D(A,C)*D(B,E) + D(A,E)*D(B,C))
- X PPZZ(A,AL,B,BE) = - AA*GG**2*D(A,B)
- X ZZZZ = - 3*AA*GG**2
- X EP3EP(A,B,C,AP,BP,CP) = D(A,AP)*(D(B,BP)*D(C,CP) - D(B,CP)
- *D(C,BP)) - D(A,BP)*(D(B,AP)*D(C,CP) - D(B,CP)*D(C,AP))
- - D(A,CP)*(D(B,BP)*D(C,AP) - D(B,AP)*D(C,BP))
- *fix
- BLOCK Subs{}
- P input
- B A123
- Id INTER =
- TRIO(5) + DUO(IN34A,5) + DUO(IN34B,5) + DUO(IN34C,5)
- - IN33("X,"Y,"X,"Y,"X,"Y)
- - IN33("Y,"X,"Y,"X,"Y,"X)
- Al INTE2 = DUO2(5) + SIN2(4) - IN23("X,"Y,"X,"Y)
- Id TRIO(N~) = DS(J1,1,N,(DS(J2,1,N,(DS(J3,1,N,(
- IN33(CHF(J1),CHL(J1),CHF(J2),CHL(J2),CHF(J3),CHL(J3) )
- ) ) ) ) ) )
- Al DUO(IN34A~,N~) = DS(J1,1,N,(DS(J2,J1,N,(
- IN34A(CHF(J1),CHL(J1),CHL(J2),CHF(J2) )
- ) ) ) )
- Al DUO2(N~) = DS(J1,1,N,(DS(J2,J1,N,(
- IN23(CHF(J1),CHL(J1),CHL(J2),CHF(J2) )
- ) ) ) )
- Al SIN2(N~) = DS(J1,1,N,(
- IN24(CHF(J1),CHL(J1) )
- ) )
- Al SIN1(N~) = DS(J1,1,N,(IN1(CHF(J1),CHL(J1) ) ) )
- Id OUT3(N1~,N2~,N3~)*IN33(M11~,M12~,M22~,M23~,M33~,M31~) =
- VER3(N1,M11,M31,*,A,AL,K,*,A1,AL1,Q,*,A3,AL3,P)*
- VER3(N2,M12,M22,*,AP,ALP,KP,*,A1P,AL1P,-Q,*,A2,AL2,-QP)*
- VER3(N3,M23,M33,*,APP,ALPP,KK,*,A2P,AL2P,QP,*,A3P,AL3P,-P)*
- PROP(M11,M12,*,A1,AL1,Q,*,A1P,AL1P,-Q)*
- PROP(M22,M23,*,A2,AL2,-QP,*,A2P,AL2P,QP)*
- PROP(M31,M33,*,A3,AL3,P,*,A3P,AL3P,-P)
- Al OUT3(N1~,N2~,N3~)*IN34A(M1~,M2~,M3~,M4~) =
- VER3(N1,M1,M4,*,A,AL,K,*,A1,AL1,Q,*,A2,AL2,P)*
- VER4(N2,N3,M2,M3,*,AP,ALP,*,APP,ALPP,*,A1P,AL1P,*,A2P,AL2P)*
- PROP(M1,M2,*,A1,AL1,Q,*,A1P,AL1P,-Q)*
- PROP(M4,M3,*,A2,AL2,P,*,A2P,AL2P,-P)*FOUR(N2,N3,M2,M3)*
- NUM(M1,M2,M3,M4)
- Al OUT3(N1~,N2~,N3~)*IN34B(M1~,M2~,M3~,M4~) =
- VER3(N2,M1,M4,*,AP,ALP,KP,*,A1,AL1,-Q,*,A2,AL2,-QP)*
- VER4(N1,N3,M2,M3,*,A,AL,*,APP,ALPP,*,A1P,AL1P,*,A2P,AL2P)*
- PROP(M1,M2,*,A1,AL1,-Q,*,A1P,AL1P,Q)*
- PROP(M4,M3,*,A2,AL2,-QP,*,A2P,AL2P,QP)*
- FOUR(N1,N3,M2,M3)*NUM(M1,M2,M3,M4)
- Al OUT3(N1~,N2~,N3~)*IN34C(M1~,M2~,M3~,M4~) =
- VER3(N3,M1,M4,*,APP,ALPP,KK,*,A1,AL1,QP,*,A2,AL2,-P)*
- VER4(N1,N2,M2,M3,*,A,AL,*,AP,ALP,*,A1P,AL1P,*,A2P,AL2P)*
- PROP(M1,M2,*,A1,AL1,QP,*,A1P,AL1P,-QP)*
- PROP(M4,M3,*,A2,AL2,-P,*,A2P,AL2P,P)*
- FOUR(N1,N2,M2,M3)*NUM(M1,M2,M3,M4)
- Al OUT2(N1~,N2~)*IN23(M1~,M2~,M3~,M4~) =
- VER3(N1,M1,M4,*,A,AL,K,*,C,GA,Q,*,B,BE,P)*
- PROP(M4,M3,*,B,BE,P,*,BP,BEP,-P)*
- PROP(M1,M2,*,C,GA,Q,*,CP,GAP,-Q)
- *VER3(N2,M2,M3,*,AP,ALP,-K,*,CP,GAP,-Q,*,BP,BEP,-P)
- *NUM(M1,M2,M3,M4)
- Al OUT2(N1~,N2~)*IN24(M1~,M2~) =
- VER4(N1,N2,M1,M2,*,A,AL,*,AP,ALP,*,C,GA,*,CP,GAP)
- *PROP(M1,M2,*,C,GA,P,*,CP,GAP,-P)
- *NUM(M1,M2,M1,M2)*FOUR(N1,N2,M1,M2)
- Al OUT1(N1~)*IN1(N2~,N3~) =
- VER3(N1,N2,N3,*,A,AL,K,*,B,BE,P,*,C,GA,-P)*
- PROP(N2,N3,*,B,BE,P,*,C,GA,-P)*NUM(N2,N3,N2,N3)
- Id Compo,<X>,VER3,VER4,PROP
- Id VER3(WWW~,A~,AL~,K~,B~,BE~,P~,C~,GA~,Q~) =
- WWW(A,AL,K,B,BE,P,C,GA,Q)
- Al VER4(WWWW~,A~,AL~,B~,BE~,C~,GA~,E~,EP~) =
- WWWW(A,AL,B,BE,C,GA,E,EP)
- Al PROP(WW~,A~,AL~,K~,B~,BE~,P~) = WW(A,AL,K,B,BE,P)
- Id Count,DVV,P,1,Q,1,QP,1,NOM,-2,BET,-4,GAM,-2
- Id,2 NOM(-P,M~) = NOM(P,M)
- Al,2 NOM(-Q,M~) = NOM(Q,M)
- Al,2 NOM(-QP,M~) = NOM(QP,M)
- Al,2 BET(-P) = BET(P)
- Al,2 BET(-Q) = BET(Q)
- Al,2 BET(-QP) = BET(QP)
- Al,2 GAM(-P)=GAM(P)
- Al,2 GAM(-Q) = GAM(Q)
- Al,2 GAM(-QP)=GAM(QP)
- Id EP3(A,A1,A3)*EP3(AP,A1,A2)*EP3(APP,A2,A3) = -A123
- Id,Adiso,EP3(A~,B~,C~)*EP3(AP~,BP~,CP~) = EP3EP(A,B,C,AP,BP,CP)
- Id Asymm,EP3,1,2,3
- Id EP3(APP,AP,A) = - A123
- *yep
- Id DIV**2*QDQ**2 = PDP**2*DIV**2 + 4*PDP*PDK*DIV
- Al DIV**3*QDQ**2 = PDP**2*DIV**3 + 4*PDP*PDK*DIV**2
- + 2*PDP*KDK*DIV + 4*PDK**2*DIV
- Al DIV*QDQ**2 = PDP**2*DIV
- Al DIV**2*QDQ = PDP*DIV**2 + 2*PDK*DIV
- Al DIV**3*QDQ = PDP*DIV**3 + 2*PDK*DIV**2 + KDK*DIV
- Al DIV*QDQ = PDP*DIV
- Id,Dotpr,Q(MU~) = QX(MU)
- Id Q(MU~) = QX(MU)
- Id,4 DIV**2*QX(MU~) = - DIV*K(MU) - DIV**2*P(MU)
- Al,4 DIV**3*QX(MU~) = - DIV**2*K(MU) - DIV**3*P(MU)
- Al,4 DIV*QX(MU~) = - P(MU)*DIV
- Id DIV**2*QPDQP**2 = PDP**2*DIV**2 - 4*PDP*PDKK*DIV
- Al DIV*QPDQP**2 = PDP**2*DIV
- Al DIV**2*QPDQP = PDP*DIV**2 - 2*PDKK*DIV
- Al DIV*QPDQP = DIV*PDP
- Id,Dotpr,QP(MU~) = QY(MU)
- Al QP(MU~) = QY(MU)
- Id,4 DIV**2*QY(MU~) = - DIV*KK(MU) + DIV**2*P(MU)
- Al,4 DIV*QY(MU~) = DIV*P(MU)
- Id,2 DIV**N~*BET(K~) = DIV**N*TW1*NOM(K,M)*NOM(K,GM)
- + DT(N-3)*DIV**N/DIV**2*TW2*M**2/PDP**3
- Id,3 DIV**N~*GAM(K~) = DIV**N*NOM(K,GM)
- + DT(N-3)*DIV**N/DIV**2*M**2*TP/PDP**2
- Id,2 DIV**3*NOM(Q,M~) = DIV**3/PDP - 2*PDK*PDP**-2*DIV**2
- - DIV*(KDK + M**2)/PDP**2 + 4*DIV*PDK**2/PDP**3
- Al,2 DIV**2*NOM(Q,M~) = DIV**2/PDP - 2*PDK*PDP**-2*DIV
- Id,2 DIV**2*NOM(QP,M~) = DIV**2/PDP + 2*PDKK*PDP**-2*DIV
- Id,4 DIV**3*NOM(P,M~) = DIV**3/PDP - DIV*M**2/PDP**2
- Al,4 DIV**2*NOM(P,M~) = DIV**2/PDP
- Al,6 DIV*NOM(Q~,M~) = DIV/PDP
- Id DIV**N~ = DK(N,1)*DIV
- Al Numer,PDP,1
- *yep
- Id,Dotpr,P(MU~) = X(MU)
- Al P(MU~) = X(MU)
- Id X(MU~)*X(M1~) = F(2,M1,MU)
- Id,Adiso,F(2,M1~,M2~)*X(MU~) = F(3,M1,M2,MU)
- Id,Adiso,F(3,M1~,M2~,M3~)*X(MU~) = F(4,M1,M2,M3,MU)
- Id X(MU~) = 0
- Al F(3,M1~,M2~,M3~) = 0
- C IN UNITS I*PI**2/(N-4)
- Id DIV**N~*F(2,M1~,M2~) = -DK(N,1)*0.5*D(M1,M2)
- Al DIV**N~*F(4,M1~,M2~,M3~,M4~) = - 1/12*DK(N,1)*
- (D(M1,M2)*D(M3,M4) + D(M1,M3)*D(M2,M4) + D(M1,M4)*D(M2,M3) )
- Al DIV**N~ = - 2*DK(N,1)
- *yep
- B I,GG
- Id SM**2=4*AA*M**2
- Id KP(MU~) = - K(MU) - KK(MU)
- Al,Dotpr,KP(MU~) = - K(MU) - KK(MU)
- Id TW1 = 1/KAP**2 - 1
- Al TW2 = (1+LAM**2 - LAM/KAP - LAM*KAP)/KAP**2
- Al TP = 1/KAP**2 - LAM/KAP
- Al,Multi,GM**2 = LAM*M**2/KAP
- Id EP3(A~,B~,C~)*EP3(AP~,BP~,CP~) = EP3EP(A,B,C,AP,BP,CP)
- Id A123=EP3(A,AP,APP)
- Id Asymm,EP3,1,2,3
- ENDBLOCK
- P input
- Z WSELF = OUT2("W,"W)*INTE2
- Subs{}
- *begin
- Z GHOST = OUT2("Y,"X)*(
- IN23("X,"Y,"Z,"Z) + IN23("X,"Y,"W,"W)
- + IN23("X,"Y,"P,"P) + IN23("X,"Y,"P,"W) + IN23("X,"Y,"W,"P) )
- Z TADP = OUT1("Z)*(SIN1(4) - IN1("X,"Y))
- Z PSELF = OUT2("P,"P)*INTE2
- Z PSWTR = OUT2("P,"W)*INTE2
- Z ZSELF = OUT2("Z,"Z)*INTE2
- Subs{}
- *begin
- Z WWWV = OUT3("W,"W,"W)*(
- TRIO(5) + DUO(IN34A,5) + DUO(IN34B,5) + DUO(IN34C,5)
- - IN33("X,"Y,"X,"Y,"X,"Y)
- - IN33("Y,"X,"Y,"X,"Y,"X) )
- Subs{}
- *end
-