home *** CD-ROM | disk | FTP | other *** search
/ Dream 49 / Amiga_Dream_49.iso / atari / texte / 1857bin-d2.zoo / lisp / info.el < prev    next >
Lisp/Scheme  |  1991-12-02  |  24KB  |  702 lines
  1. ;; Info package for Emacs  -- could use a "create node" feature.
  2. ;; Copyright (C) 1985, 1986 Free Software Foundation, Inc.
  3.  
  4. ;; This file is part of GNU Emacs.
  5.  
  6. ;; GNU Emacs is free software; you can redistribute it and/or modify
  7. ;; it under the terms of the GNU General Public License as published by
  8. ;; the Free Software Foundation; either version 1, or (at your option)
  9. ;; any later version.
  10.  
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14. ;; GNU General Public License for more details.
  15.  
  16. ;; You should have received a copy of the GNU General Public License
  17. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  18. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  19.  
  20. (provide 'info)
  21.  
  22. (defvar Info-history nil
  23.   "List of info nodes user has visited.
  24. Each element of list is a list (FILENAME NODENAME BUFFERPOS).")
  25.  
  26. (defvar Info-enable-edit nil
  27.   "Non-nil means the \\[Info-edit] command in Info can edit the current node.")
  28.  
  29. (defvar Info-enable-active-nodes t
  30.   "Non-nil allows Info to execute Lisp code associated with nodes.
  31. The Lisp code is executed when the node is selected.")
  32.  
  33. (defvar Info-directory nil
  34.   "Default directory for Info documentation files.")
  35.  
  36. (defvar Info-current-file nil
  37.   "Info file that Info is now looking at, or nil.")
  38.  
  39. (defvar Info-current-subfile nil
  40.   "Info subfile that is actually in the *info* buffer now,
  41. or nil if current info file is not split into subfiles.")
  42.  
  43. (defvar Info-current-node nil
  44.   "Name of node that Info is now looking at, or nil.")
  45.  
  46. (defvar Info-tag-table-marker (make-marker)
  47.   "Marker pointing at beginning of current Info file's tag table.
  48. Marker points nowhere if file has no tag table.")
  49.  
  50. (defun info ()
  51.   "Enter Info, the documentation browser."
  52.   (interactive)
  53.   (if (get-buffer "*info*")
  54.       (switch-to-buffer "*info*")
  55.     (Info-directory)))
  56.  
  57. ;; Go to an info node specified as separate filename and nodename.
  58. ;; no-going-back is non-nil if recovering from an error in this function;
  59. ;; it says do not attempt further (recursive) error recovery.
  60. (defun Info-find-node (filename nodename &optional no-going-back)
  61.   ;; Convert filename to lower case if not found as specified.
  62.   ;; Expand it.
  63.   (if filename
  64.       (let (temp)
  65.     (setq filename (substitute-in-file-name filename))
  66.     (setq temp (expand-file-name filename
  67.                      ;; Use Info's default dir
  68.                      ;; unless the filename starts with `./'.
  69.                      (if (not (string-match "^\\./" filename))
  70.                      Info-directory)))
  71.     (if (file-exists-p temp)
  72.         (setq filename temp)
  73.       (setq temp (expand-file-name (downcase filename) Info-directory))
  74.       (if (file-exists-p temp)
  75.           (setq filename temp)
  76.         (error "Info file %s does not exist"
  77.            (expand-file-name filename Info-directory))))))
  78.   ;; Record the node we are leaving.
  79.   (if (and Info-current-file (not no-going-back))
  80.       (setq Info-history
  81.         (cons (list Info-current-file Info-current-node (point))
  82.           Info-history)))
  83.   ;; Go into info buffer.
  84.   (switch-to-buffer "*info*")
  85.   (or (eq major-mode 'Info-mode)
  86.       (Info-mode))
  87.   (widen)
  88.   (setq Info-current-node nil)
  89.   (unwind-protect
  90.       (progn
  91.     ;; Switch files if necessary
  92.     (or (null filename)
  93.         (equal Info-current-file filename)
  94.         (let ((buffer-read-only nil))
  95.           (setq Info-current-file nil
  96.             Info-current-subfile nil)
  97.           (erase-buffer)
  98.           (insert-file-contents filename t)
  99.           (set-buffer-modified-p nil)
  100.           (setq default-directory (file-name-directory filename))
  101.           ;; See whether file has a tag table.  Record the location if yes.
  102.           (set-marker Info-tag-table-marker nil)
  103.           (goto-char (point-max))
  104.           (forward-line -8)
  105.           (or (equal nodename "*")
  106.           (not (search-forward "\^_\nEnd tag table\n" nil t))
  107.           (let (pos)
  108.             ;; We have a tag table.  Find its beginning.
  109.             ;; Is this an indirect file?
  110.             (search-backward "\nTag table:\n")
  111.             (setq pos (point))
  112.             (if (save-excursion
  113.               (forward-line 2)
  114.               (looking-at "(Indirect)\n"))
  115.             ;; It is indirect.  Copy it to another buffer
  116.             ;; and record that the tag table is in that buffer.
  117.             (save-excursion
  118.               (let ((buf (current-buffer)))
  119.                 (set-buffer (get-buffer-create " *info tag table*"))
  120.                 (setq case-fold-search t)
  121.                 (erase-buffer)
  122.                 (insert-buffer-substring buf)
  123.                 (set-marker Info-tag-table-marker
  124.                     (match-end 0))))
  125.              (set-marker Info-tag-table-marker pos))))
  126.           (setq Info-current-file
  127.             (file-name-sans-versions buffer-file-name))))
  128.     (if (equal nodename "*")
  129.         (progn (setq Info-current-node nodename)
  130.            (Info-set-mode-line))
  131.       ;; Search file for a suitable node.
  132.       ;; First get advice from tag table if file has one.
  133.       ;; Also, if this is an indirect info file,
  134.       ;; read the proper subfile into this buffer.
  135.       (let ((guesspos (point-min)))
  136.         (if (marker-position Info-tag-table-marker)
  137.         (save-excursion
  138.           (set-buffer (marker-buffer Info-tag-table-marker))
  139.           (goto-char Info-tag-table-marker)
  140.           (if (search-forward (concat "Node: " nodename "\177") nil t)
  141.               (progn
  142.             (setq guesspos (read (current-buffer)))
  143.             ;; If this is an indirect file,
  144.             ;; determine which file really holds this node
  145.             ;; and read it in.
  146.             (if (not (eq (current-buffer) (get-buffer "*info*")))
  147.                 (setq guesspos
  148.                   (Info-read-subfile guesspos))))
  149.             (error "No such node: \"%s\"" nodename))))
  150.         (goto-char (max (point-min) (- guesspos 1000))))
  151.       ;; Now search from our advised position (or from beg of buffer)
  152.       ;; to find the actual node.
  153.       (let ((regexp (concat "Node: *" (regexp-quote nodename) " *[,\t\n]")))
  154.         (catch 'foo
  155.           (while (search-forward "\n\^_" nil t)
  156.         (forward-line 1)
  157.         (let ((beg (point)))
  158.           (forward-line 1)
  159.           (if (re-search-backward regexp beg t)
  160.               (throw 'foo t))))
  161.           (error "No such node: %s" nodename)))
  162.       (Info-select-node)))
  163.     ;; If we did not finish finding the specified node,
  164.     ;; go back to the previous one.
  165.     (or Info-current-node no-going-back
  166.     (let ((hist (car Info-history)))
  167.       (setq Info-history (cdr Info-history))
  168.       (Info-find-node (nth 0 hist) (nth 1 hist) t)
  169.       (goto-char (nth 2 hist)))))
  170.   (goto-char (point-min)))
  171.  
  172. (defun Info-read-subfile (nodepos)
  173.   (set-buffer (marker-buffer Info-tag-table-marker))
  174.   (goto-char (point-min))
  175.   (search-forward "\n\^_")
  176.   (let (lastfilepos
  177.     lastfilename)
  178.     (forward-line 2)
  179.     (catch 'foo
  180.       (while (not (looking-at "\^_"))
  181.     (if (not (eolp))
  182.         (let ((beg (point))
  183.           thisfilepos thisfilename)
  184.           (search-forward ": ")
  185.           (setq thisfilename  (buffer-substring beg (- (point) 2)))
  186.           (setq thisfilepos (read (current-buffer)))
  187.           (if (> thisfilepos nodepos)
  188.           (throw 'foo t))
  189.           (setq lastfilename thisfilename)
  190.           (setq lastfilepos thisfilepos)))))
  191.     (set-buffer (get-buffer "*info*"))
  192.     (or (equal Info-current-subfile lastfilename)
  193.     (let ((buffer-read-only nil))
  194.       (setq buffer-file-name nil)
  195.       (widen)
  196.       (erase-buffer)
  197.       (insert-file-contents lastfilename)
  198.       (set-buffer-modified-p nil)
  199.       (setq Info-current-subfile lastfilename)))
  200.     (goto-char (point-min))
  201.     (search-forward "\n\^_")
  202.     (+ (- nodepos lastfilepos) (point))))
  203.  
  204. ;; Select the info node that point is in.
  205. (defun Info-select-node ()
  206.   (save-excursion
  207.    ;; Find beginning of node.
  208.    (search-backward "\n\^_")
  209.    (forward-line 2)
  210.    ;; Get nodename spelled as it is in the node.
  211.    (re-search-forward "Node:[ \t]*")
  212.    (setq Info-current-node
  213.      (buffer-substring (point)
  214.                (progn
  215.                 (skip-chars-forward "^,\t\n")
  216.                 (point))))
  217.    (Info-set-mode-line)
  218.    ;; Find the end of it, and narrow.
  219.    (beginning-of-line)
  220.    (let (active-expression)
  221.      (narrow-to-region (point)
  222.                (if (re-search-forward "\n[\^_\f]" nil t)
  223.                (prog1
  224.                 (1- (point))
  225.                 (if (looking-at "[\n\^_\f]*execute: ")
  226.                 (progn
  227.                   (goto-char (match-end 0))
  228.                   (setq active-expression
  229.                     (read (current-buffer))))))
  230.              (point-max)))
  231.      (if Info-enable-active-nodes (eval active-expression)))))
  232.  
  233. (defun Info-set-mode-line ()
  234.   (setq mode-line-buffer-identification
  235.     (concat
  236.      "Info:  ("
  237.      (if Info-current-file
  238.          (file-name-nondirectory Info-current-file)
  239.        "")
  240.      ")"
  241.      (or Info-current-node ""))))
  242.  
  243. ;; Go to an info node specified with a filename-and-nodename string
  244. ;; of the sort that is found in pointers in nodes.
  245.  
  246. (defun Info-goto-node (nodename)
  247.   "Go to info node named NAME.  Give just NODENAME or (FILENAME)NODENAME."
  248.   (interactive "sGoto node: ")
  249.   (let (filename)
  250.     (string-match "\\s *\\((\\s *\\([^\t)]*\\)\\s *)\\s *\\|\\)\\(.*\\)"
  251.           nodename)
  252.     (setq filename (if (= (match-beginning 1) (match-end 1))
  253.                ""
  254.              (substring nodename (match-beginning 2) (match-end 2)))
  255.       nodename (substring nodename (match-beginning 3) (match-end 3)))
  256.     (let ((trim (string-match "\\s *\\'" filename)))
  257.       (if trim (setq filename (substring filename 0 trim))))
  258.     (let ((trim (string-match "\\s *\\'" nodename)))
  259.       (if trim (setq nodename (substring nodename 0 trim))))
  260.     (Info-find-node (if (equal filename "") nil filename)
  261.             (if (equal nodename "") "Top" nodename))))
  262.  
  263. (defvar Info-last-search nil
  264.   "Default regexp for Info S command to search for.")
  265.  
  266. (defun Info-search (regexp)
  267.   "Search for REGEXP, starting from point, and select node it's found in."
  268.   (interactive "sSearch (regexp): ")
  269.   (if (equal regexp "")
  270.       (setq regexp Info-last-search)
  271.     (setq Info-last-search regexp))
  272.   (let ((found ()) current
  273.     (onode Info-current-node)
  274.     (ofile Info-current-file)
  275.     (opoint (point))
  276.     (osubfile Info-current-subfile))
  277.     (save-excursion
  278.       (save-restriction
  279.     (widen)
  280.     (if (null Info-current-subfile)
  281.         (progn (re-search-forward regexp) (setq found (point)))
  282.       (condition-case err
  283.           (progn (re-search-forward regexp) (setq found (point)))
  284.         (search-failed nil)))))
  285.     (if (not found) ;can only happen in subfile case -- else would have erred
  286.     (unwind-protect
  287.         (let ((list ()))
  288.           (set-buffer (marker-buffer Info-tag-table-marker))
  289.           (goto-char (point-min))
  290.           (search-forward "\n\^_\nIndirect:")
  291.           (save-restriction
  292.         (narrow-to-region (point)
  293.                   (progn (search-forward "\n\^_")
  294.                      (1- (point))))
  295.         (goto-char (point-min))
  296.         (search-forward (concat "\n" osubfile ": "))
  297.         (beginning-of-line)
  298.         (while (not (eobp))
  299.           (re-search-forward "\\(^.*\\): [0-9]+$")
  300.           (goto-char (+ (match-end 1) 2))
  301.           (setq list (cons (cons (read (current-buffer))
  302.                      (buffer-substring (match-beginning 1)
  303.                                (match-end 1)))
  304.                    list))
  305.           (goto-char (1+ (match-end 0))))
  306.         (setq list (nreverse list)
  307.               current (car (car list))
  308.               list (cdr list)))
  309.           (while list
  310.         (message "Searching subfile %s..." (cdr (car list)))
  311.         (Info-read-subfile (car (car list)))
  312.         (setq list (cdr list))
  313.         (goto-char (point-min))
  314.         (if (re-search-forward regexp nil t)
  315.             (setq found (point) list ())))
  316.           (if found
  317.           (message "")
  318.         (signal 'search-failed (list regexp))))
  319.       (if (not found)
  320.           (progn (Info-read-subfile opoint)
  321.              (goto-char opoint)
  322.              (Info-select-node)))))
  323.     (widen)
  324.     (goto-char found)
  325.     (Info-select-node)
  326.     (or (and (equal onode Info-current-node)
  327.          (equal ofile Info-current-file))
  328.     (setq Info-history (cons (list ofile onode opoint)
  329.                  Info-history)))))
  330.  
  331. (defun Info-extract-pointer (name &optional errorname)
  332.   (save-excursion
  333.    (goto-char (point-min))
  334.    (forward-line 1)
  335.    (if (re-search-backward (concat name ":") nil t)
  336.        nil
  337.      (error (concat "Node has no " (capitalize (or errorname name)))))
  338.    (goto-char (match-end 0))
  339.    (Info-following-node-name)))
  340.  
  341. (defun Info-following-node-name (&optional allowedchars)
  342.   (skip-chars-forward " \t")
  343.   (buffer-substring
  344.    (point)
  345.    (progn
  346.      (while (looking-at (concat "[" (or allowedchars "^,\t\n") "]"))
  347.        (skip-chars-forward (concat (or allowedchars "^,\t\n") "("))
  348.        (if (looking-at "(")
  349.        (skip-chars-forward "^)")))
  350.      (skip-chars-backward " ")
  351.      (point))))
  352.  
  353. (defun Info-next ()
  354.   "Go to the next node of this node."
  355.   (interactive)
  356.   (Info-goto-node (Info-extract-pointer "next")))
  357.  
  358. (defun Info-prev ()
  359.   "Go to the previous node of this node."
  360.   (interactive)
  361.   (Info-goto-node (Info-extract-pointer "prev[ious]*" "previous")))
  362.  
  363. (defun Info-up ()
  364.   "Go to the superior node of this node."
  365.   (interactive)
  366.   (Info-goto-node (Info-extract-pointer "up")))
  367.  
  368. (defun Info-last ()
  369.   "Go back to the last node visited."
  370.   (interactive)
  371.   (or Info-history
  372.       (error "This is the first Info node you looked at"))
  373.   (let (filename nodename opoint)
  374.     (setq filename (car (car Info-history)))
  375.     (setq nodename (car (cdr (car Info-history))))
  376.     (setq opoint (car (cdr (cdr (car Info-history)))))
  377.     (setq Info-history (cdr Info-history))
  378.     (Info-find-node filename nodename)
  379.     (setq Info-history (cdr Info-history))
  380.     (goto-char opoint)))
  381.  
  382. (defun Info-directory ()
  383.   "Go to the Info directory node."
  384.   (interactive)
  385.   (Info-find-node "dir" "top"))
  386.  
  387. (defun Info-follow-reference (footnotename)
  388.   "Follow cross reference named NAME to the node it refers to.
  389. NAME may be an abbreviation of the reference name."
  390.   (interactive
  391.    (let ((completion-ignore-case t)
  392.      completions str i)
  393.      (save-excursion
  394.        (goto-char (point-min))
  395.        (while (re-search-forward "\\*note[ \n\t]*\\([^:]*\\):" nil t)
  396.      (setq str (buffer-substring
  397.             (match-beginning 1)
  398.             (1- (point))))
  399.      (setq i 0)
  400.      (while (setq i (string-match "[ \n\t]+" str i))
  401.        (setq str (concat (substring str 0 i) " "
  402.                  (substring str (match-end 0))))
  403.        (setq i (1+ i)))
  404.      (setq completions
  405.            (cons (cons str nil)
  406.              completions))))
  407.      (if completions
  408.      (list (completing-read "Follow reference named: " completions nil t))
  409.        (error "No cross-references in this node"))))
  410.   (let (target beg i (str (concat "\\*note " footnotename)))
  411.     (while (setq i (string-match " " str i))
  412.       (setq str (concat (substring str 0 i) "[ \t\n]+" (substring str (1+ i))))
  413.       (setq i (+ i 6)))
  414.     (save-excursion
  415.       (goto-char (point-min))
  416.       (or (re-search-forward str nil t)
  417.       (error "No cross-reference named %s" footnotename))
  418.       (goto-char (+ (match-beginning 0) 5))
  419.       (setq target (Info-extract-menu-node-name "Bad format cross reference")))
  420.     (while (setq i (string-match "[ \t\n]+" target i))
  421.       (setq target (concat (substring target 0 i) " "
  422.                (substring target (match-end 0))))
  423.       (setq i (+ i 1)))
  424.     (Info-goto-node target)))
  425.  
  426. (defun Info-extract-menu-node-name (&optional errmessage)
  427.   (skip-chars-forward " \t\n")
  428.   (let ((beg (point))
  429.     str i)
  430.     (skip-chars-forward "^:")
  431.     (forward-char 1)
  432.     (setq str
  433.       (if (looking-at ":")
  434.           (buffer-substring beg (1- (point)))
  435.         (skip-chars-forward " \t\n")
  436.         (Info-following-node-name "^.,\t\n")))
  437.     (while (setq i (string-match "\n" str i))
  438.       (aset str i ?\ ))
  439.     str))
  440.  
  441. (defun Info-menu-item-sequence (list)
  442.   (while list
  443.     (Info-menu-item (car list))
  444.     (setq list (cdr list))))
  445.  
  446. (defun Info-menu (menu-item)
  447.   "Go to node for menu item named (or abbreviated) NAME."
  448.   (interactive
  449.    (let ((completions '())
  450.      ;; If point is within a menu item, use that item as the default
  451.      (default nil)
  452.      (p (point))
  453.      (last nil))
  454.      (save-excursion
  455.        (goto-char (point-min))
  456.        (if (not (search-forward "\n* menu:" nil t))
  457.        (error "No menu in this node"))
  458.        (while (re-search-forward
  459.         "\n\\* \\([^:\t\n]*\\):" nil t)
  460.      (if (and (null default)
  461.           (prog1 (if last (< last p) nil)
  462.             (setq last (match-beginning 0)))
  463.           (<= p last))
  464.          (setq default (car (car completions))))
  465.      (setq completions (cons (cons (buffer-substring
  466.                      (match-beginning 1)
  467.                      (match-end 1))
  468.                        (match-beginning 1))
  469.                  completions)))
  470.        (if (and (null default) last
  471.         (< last p)
  472.         (<= p (progn (end-of-line) (point))))
  473.        (setq default (car (car completions)))))
  474.      (let ((item nil))
  475.        (while (null item)
  476.      (setq item (let ((completion-ignore-case t))
  477.               (completing-read (if default
  478.                        (format "Menu item (default %s): "
  479.                            default)
  480.                        "Menu item: ")
  481.                        completions nil t)))
  482.      ;; we rely on the bug (which RMS won't change for his own reasons)
  483.      ;; that ;; completing-read accepts an input of "" even when the
  484.      ;; require-match argument is true and "" is not a valid possibility
  485.      (if (string= item "")
  486.          (if default
  487.          (setq item default)
  488.              ;; ask again
  489.              (setq item nil))))
  490.        (list item))))
  491.   (Info-goto-node (Info-extract-menu-item menu-item)))
  492.   
  493. (defun Info-extract-menu-item (menu-item)
  494.   (save-excursion
  495.     (goto-char (point-min))
  496.     (or (search-forward "\n* menu:" nil t)
  497.     (error "No menu in this node"))
  498.     (or (search-forward (concat "\n* " menu-item ":") nil t)
  499.     (search-forward (concat "\n* " menu-item) nil t)
  500.     (error "No such item in menu"))
  501.     (beginning-of-line)
  502.     (forward-char 2)
  503.     (Info-extract-menu-node-name)))
  504.  
  505. (defun Info-extract-menu-counting (count)
  506.   (save-excursion
  507.     (goto-char (point-min))
  508.     (or (search-forward "\n* menu:" nil t)
  509.     (error "No menu in this node"))
  510.     (or (search-forward "\n* " nil t count)
  511.     (error "Too few items in menu"))
  512.     (Info-extract-menu-node-name)))
  513.  
  514. (defun Info-first-menu-item ()
  515.   "Go to the node of the first menu item."
  516.   (interactive)
  517.   (Info-goto-node (Info-extract-menu-counting 1)))
  518.  
  519. (defun Info-second-menu-item ()
  520.   "Go to the node of the second menu item."
  521.   (interactive)
  522.   (Info-goto-node (Info-extract-menu-counting 2)))
  523.  
  524. (defun Info-third-menu-item ()
  525.   "Go to the node of the third menu item."
  526.   (interactive)
  527.   (Info-goto-node (Info-extract-menu-counting 3)))
  528.  
  529. (defun Info-fourth-menu-item ()
  530.   "Go to the node of the fourth menu item."
  531.   (interactive)
  532.   (Info-goto-node (Info-extract-menu-counting 4)))
  533.  
  534. (defun Info-fifth-menu-item ()
  535.   "Go to the node of the fifth menu item."
  536.   (interactive)
  537.   (Info-goto-node (Info-extract-menu-counting 5)))
  538.  
  539. (defun Info-exit ()
  540.   "Exit Info by selecting some other buffer."
  541.   (interactive)
  542.   (switch-to-buffer (prog1 (other-buffer (current-buffer))
  543.                (bury-buffer (current-buffer)))))
  544.  
  545. (defun Info-undefined ()
  546.   "Make command be undefined in Info."
  547.   (interactive)
  548.   (ding))
  549.  
  550. (defun Info-help ()
  551.   "Enter the Info tutorial."
  552.   (interactive)
  553.   (Info-find-node "info"
  554.           (if (< (window-height) 23)
  555.               "Help-Small-Screen"
  556.             "Help")))
  557.  
  558. (defun Info-summary ()
  559.   "Display a brief summary of all Info commands."
  560.   (interactive)
  561.   (save-window-excursion
  562.     (switch-to-buffer "*Help*")
  563.     (erase-buffer)
  564.     (insert (documentation 'Info-mode))
  565.     (goto-char (point-min))
  566.     (let (ch flag)
  567.       (while (progn (setq flag (not (pos-visible-in-window-p (point-max))))
  568.             (message (if flag "Type Space to see more"
  569.                    "Type Space to return to Info"))
  570.             (if (/= ?\  (setq ch (read-char)))
  571.             (progn (setq unread-command-char ch) nil)
  572.               flag))
  573.     (scroll-up)))))
  574.  
  575. (defvar Info-mode-map nil
  576.   "Keymap containing Info commands.")
  577. (if Info-mode-map
  578.     nil
  579.   (setq Info-mode-map (make-keymap))
  580.   (suppress-keymap Info-mode-map)
  581.   (define-key Info-mode-map "." 'beginning-of-buffer)
  582.   (define-key Info-mode-map " " 'scroll-up)
  583.   (define-key Info-mode-map "1" 'Info-first-menu-item)
  584.   (define-key Info-mode-map "2" 'Info-second-menu-item)
  585.   (define-key Info-mode-map "3" 'Info-third-menu-item)
  586.   (define-key Info-mode-map "4" 'Info-fourth-menu-item)
  587.   (define-key Info-mode-map "5" 'Info-fifth-menu-item)
  588.   (define-key Info-mode-map "6" 'undefined)
  589.   (define-key Info-mode-map "7" 'undefined)
  590.   (define-key Info-mode-map "8" 'undefined)
  591.   (define-key Info-mode-map "9" 'undefined)
  592.   (define-key Info-mode-map "0" 'undefined)
  593.   (define-key Info-mode-map "?" 'Info-summary)
  594.   (define-key Info-mode-map "b" 'beginning-of-buffer)
  595.   (define-key Info-mode-map "d" 'Info-directory)
  596.   (define-key Info-mode-map "e" 'Info-edit)
  597.   (define-key Info-mode-map "f" 'Info-follow-reference)
  598.   (define-key Info-mode-map "g" 'Info-goto-node)
  599.   (define-key Info-mode-map "h" 'Info-help)
  600.   (define-key Info-mode-map "l" 'Info-last)
  601.   (define-key Info-mode-map "m" 'Info-menu)
  602.   (define-key Info-mode-map "n" 'Info-next)
  603.   (define-key Info-mode-map "p" 'Info-prev)
  604.   (define-key Info-mode-map "q" 'Info-exit)
  605.   (define-key Info-mode-map "s" 'Info-search)
  606.   (define-key Info-mode-map "u" 'Info-up)
  607.   (define-key Info-mode-map "\177" 'scroll-down))
  608.  
  609. (defun Info-mode ()
  610.   "Info mode provides commands for browsing through the Info documentation tree.
  611. Documentation in Info is divided into \"nodes\", each of which
  612. discusses one topic and contains references to other nodes
  613. which discuss related topics.  Info has commands to follow
  614. the references and show you other nodes.
  615.  
  616. h    Invoke the Info tutorial.
  617.  
  618. Selecting other nodes:
  619. n    Move to the \"next\" node of this node.
  620. p    Move to the \"previous\" node of this node.
  621. u    Move \"up\" from this node.
  622. m    Pick menu item specified by name (or abbreviation).
  623.     Picking a menu item causes another node to be selected.
  624. f    Follow a cross reference.  Reads name of reference.
  625. l    Move to the last node you were at.
  626.  
  627. Moving within a node:
  628. Space    scroll forward a page.     DEL  scroll backward.
  629. b    Go to beginning of node.
  630.  
  631. Advanced commands:
  632. q    Quit Info: reselect previously selected buffer.
  633. e    Edit contents of selected node.
  634. 1    Pick first item in node's menu.
  635. 2, 3, 4, 5   Pick second ... fifth item in node's menu.
  636. g    Move to node specified by name.
  637.     You may include a filename as well, as (FILENAME)NODENAME.
  638. s    Search through this Info file for specified regexp,
  639.     and select the node in which the next occurrence is found."
  640.   (kill-all-local-variables)
  641.   (setq major-mode 'Info-mode)
  642.   (setq mode-name "Info")
  643.   (use-local-map Info-mode-map)
  644.   (set-syntax-table text-mode-syntax-table)
  645.   (setq local-abbrev-table text-mode-abbrev-table)
  646.   (setq case-fold-search t)
  647.   (setq buffer-read-only t)
  648.   (make-local-variable 'Info-current-file)
  649.   (make-local-variable 'Info-current-subfile)
  650.   (make-local-variable 'Info-current-node)
  651.   (make-local-variable 'Info-tag-table-marker)
  652.   (make-local-variable 'Info-history)
  653.   (Info-set-mode-line))
  654.  
  655. (defvar Info-edit-map nil
  656.   "Local keymap used within `e' command of Info.")
  657. (if Info-edit-map
  658.     nil
  659.   (setq Info-edit-map (copy-keymap text-mode-map))
  660.   (define-key Info-edit-map "\C-c\C-c" 'Info-cease-edit))
  661.  
  662. (defun Info-edit-mode ()
  663.   "Major mode for editing the contents of an Info node.
  664. Like text mode with the addition of Info-cease-edit
  665. which returns to Info mode for browsing.
  666. \\{Info-edit-map}"
  667.   )
  668.  
  669. (defun Info-edit ()
  670.   "Edit the contents of this Info node.
  671. Allowed only if variable Info-enable-edit is non-nil."
  672.   (interactive)
  673.   (or Info-enable-edit
  674.       (error "Editing info nodes is not enabled"))
  675.   (use-local-map Info-edit-map)
  676.   (setq major-mode 'Info-edit-mode)
  677.   (setq mode-name "Info Edit")
  678.   (kill-local-variable 'mode-line-buffer-identification)
  679.   (setq buffer-read-only nil)
  680.   ;; Make mode line update.
  681.   (set-buffer-modified-p (buffer-modified-p))
  682.   (message (substitute-command-keys
  683.          "Editing: Type \\[Info-cease-edit] to return to info")))
  684.  
  685. (defun Info-cease-edit ()
  686.   "Finish editing Info node; switch back to Info proper."
  687.   (interactive)
  688.   ;; Do this first, so nothing has changed if user C-g's at query.
  689.   (and (buffer-modified-p)
  690.        (y-or-n-p "Save the file? ")
  691.        (save-buffer))
  692.   (use-local-map Info-mode-map)
  693.   (setq major-mode 'Info-mode)
  694.   (setq mode-name "Info")
  695.   (Info-set-mode-line)
  696.   (setq buffer-read-only t)
  697.   ;; Make mode line update.
  698.   (set-buffer-modified-p (buffer-modified-p))
  699.   (and (marker-position Info-tag-table-marker)
  700.        (buffer-modified-p)
  701.        (message "Tags may have changed.  Use Info-tagify if necessary")))
  702.