home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 4 / AACD04.ISO / AACD / Programming / Python / Source / Amiga / CRC32.ASM < prev    next >
Encoding:
Assembly Source File  |  1999-10-19  |  6.0 KB  |  203 lines
  1.  
  2. ; $VER: CRC32 2.0 (17.10.99) ©1999 Irmen de Jong
  3.  
  4. ;****************************************************************
  5. ;*                                                              *
  6. ;*  CALCCRC32 - Calculates 32 bits CRC checksum                 *
  7. ;*                                *
  8. ;*  ULONG CRC32(ULONG startcrc, void* data, ULONG size)        *
  9. ;*  d0              d0           a0          d1        *
  10. ;*                                                              *
  11. ;* INPUT: d0.l=start crc value (usually 0)                        *
  12. ;*        a0=DataBuffer, d1.l=ByteSize                          *
  13. ;* OUTPUT: d0.l=CRC32 value                                     *
  14. ;*                                                              *
  15. ;****************************************************************
  16.     SECTION CRC32,CODE
  17.  
  18.     XDEF    _CalcCRC32
  19.  
  20.     SECTION CALCCRC32,CODE
  21.     
  22. _CalcCRC32:
  23.     movem.l    d1/d2/d3/d4/a2,-(sp)
  24.     move.l    d0,d2        ; keep crc in d2
  25.     lea.l    _crc_table,a2    ; crc table in a2
  26.   IFND M68000
  27.     tst.l    a0        ; buffer == 0?
  28.   ELSE
  29.     cmp.l    #0,a0
  30.   ENDC
  31.     bne.s    .L3
  32.     moveq.l    #0,d0        ; yes --> crc=0
  33.     bra.w    .exit
  34.  
  35.     ; -- buffer is not 0, so we have to work:
  36. .L3:
  37.     not.l    d2        ; invert crc
  38.     moveq.l    #3,d4
  39.     cmp.l    d1,d4        ; is length <=3 (less than 4?)
  40.     bcc.s    .endloop    ; yep, exit this loop
  41.     moveq.l    #0,d3
  42.     bra.s    .loop
  43.     
  44.     CNOP 0,4        ; align loop on longword (faster on 32 bit CPUs)
  45.  
  46. .loop:
  47.     moveq.l    #0,d0
  48.     move.b    (a0)+,d0    ; fetch data byte 2
  49.     eor.b    d2,d0
  50.     lsr.l    #8,d2
  51.   IFND M68000
  52.     move.l    (a2,d0.w*4),d0    ; crc table lookup
  53.   ELSE
  54.     add.w    d0,d0
  55.     add.w    d0,d0
  56.     move.l    0(a2,d0.w),d0
  57.   ENDC
  58.     eor.l    d0,d2
  59.  
  60.     moveq.l    #0,d0
  61.     move.b    (a0)+,d0    ; fetch data byte 2
  62.     eor.b    d2,d0
  63.     lsr.l    #8,d2
  64.   IFND M68000
  65.     move.l    (a2,d0.w*4),d0    ; crc table lookup
  66.   ELSE
  67.     add.w    d0,d0
  68.     add.w    d0,d0
  69.     move.l    0(a2,d0.w),d0
  70.   ENDC
  71.     eor.l    d0,d2
  72.  
  73.     moveq.l    #0,d0
  74.     move.b    (a0)+,d0    ; fetch data byte 3
  75.     eor.b    d2,d0
  76.     lsr.l    #8,d2
  77.   IFND M68000
  78.     move.l    (a2,d0.w*4),d0    ; crc table lookup
  79.   ELSE
  80.     add.w    d0,d0
  81.     add.w    d0,d0
  82.     move.l    0(a2,d0.w),d0
  83.   ENDC
  84.     eor.l    d0,d2
  85.  
  86.     moveq.l    #0,d0
  87.     move.b    (a0)+,d0    ; fetch data byte 4
  88.     eor.b    d2,d0
  89.     lsr.l    #8,d2
  90.   IFND M68000
  91.     move.l    (a2,d0.w*4),d0    ; crc table lookup
  92.   ELSE
  93.     add.w    d0,d0
  94.     add.w    d0,d0
  95.     move.l    0(a2,d0.w),d0
  96.   ENDC
  97.     eor.l    d0,d2
  98.  
  99.     subq.l    #4,d1
  100.     ;; moveq.l    #3,d4    ; (d4 still contains 3)
  101.     cmp.l    d1,d4        ; is length <=3 (less than 4)?
  102.     bcs.s    .loop        ; nope, continue loop
  103.  
  104. .endloop:
  105.     tst.w    d1        ; do we have some bytes left?
  106.     beq.s    .done        ; nope, done
  107.  
  108.     subq.w    #1,d1        ; compensate 1 for dbra
  109. .restloop:
  110.     moveq.l    #0,d0
  111.     move.b    (a0)+,d0    ; fetch data byte
  112.     eor.b    d2,d0
  113.     lsr.l    #8,d2
  114.   IFND M68000
  115.     move.l    (a2,d0.w*4),d0    ; crc table lookup
  116.   ELSE
  117.     add.w    d0,d0
  118.     add.w    d0,d0
  119.     move.l    0(a2,d0.w),d0
  120.   ENDC
  121.     eor.l    d0,d2
  122.     dbra    d1,.restloop    ; again if we have more bytes left
  123.  
  124. .done:
  125.     move.l    d2,d0
  126.     not.l    d0        ; invert crc
  127.  
  128. .exit:
  129.     movem.l    (sp)+,d1/d2/d3/d4/a2
  130.     rts
  131.  
  132.     SECTION CRC32TAB,DATA
  133.  
  134.  
  135. _crc_table
  136.     dc.l    $00000000,$77073096,$EE0E612C,$990951BA
  137.     dc.l    $076DC419,$706AF48F,$E963A535,$9E6495A3
  138.     dc.l    $0EDB8832,$79DCB8A4,$E0D5E91E,$97D2D988
  139.     dc.l    $09B64C2B,$7EB17CBD,$E7B82D07,$90BF1D91
  140.     dc.l    $1DB71064,$6AB020F2,$F3B97148,$84BE41DE
  141.     dc.l    $1ADAD47D,$6DDDE4EB,$F4D4B551,$83D385C7
  142.     dc.l    $136C9856,$646BA8C0,$FD62F97A,$8A65C9EC
  143.     dc.l    $14015C4F,$63066CD9,$FA0F3D63,$8D080DF5
  144.     dc.l    $3B6E20C8,$4C69105E,$D56041E4,$A2677172
  145.     dc.l    $3C03E4D1,$4B04D447,$D20D85FD,$A50AB56B
  146.     dc.l    $35B5A8FA,$42B2986C,$DBBBC9D6,$ACBCF940
  147.     dc.l    $32D86CE3,$45DF5C75,$DCD60DCF,$ABD13D59
  148.     dc.l    $26D930AC,$51DE003A,$C8D75180,$BFD06116
  149.     dc.l    $21B4F4B5,$56B3C423,$CFBA9599,$B8BDA50F
  150.     dc.l    $2802B89E,$5F058808,$C60CD9B2,$B10BE924
  151.     dc.l    $2F6F7C87,$58684C11,$C1611DAB,$B6662D3D
  152.     dc.l    $76DC4190,$01DB7106,$98D220BC,$EFD5102A
  153.     dc.l    $71B18589,$06B6B51F,$9FBFE4A5,$E8B8D433
  154.     dc.l    $7807C9A2,$0F00F934,$9609A88E,$E10E9818
  155.     dc.l    $7F6A0DBB,$086D3D2D,$91646C97,$E6635C01
  156.     dc.l    $6B6B51F4,$1C6C6162,$856530D8,$F262004E
  157.     dc.l    $6C0695ED,$1B01A57B,$8208F4C1,$F50FC457
  158.     dc.l    $65B0D9C6,$12B7E950,$8BBEB8EA,$FCB9887C
  159.     dc.l    $62DD1DDF,$15DA2D49,$8CD37CF3,$FBD44C65
  160.     dc.l    $4DB26158,$3AB551CE,$A3BC0074,$D4BB30E2
  161.     dc.l    $4ADFA541,$3DD895D7,$A4D1C46D,$D3D6F4FB
  162.     dc.l    $4369E96A,$346ED9FC,$AD678846,$DA60B8D0
  163.     dc.l    $44042D73,$33031DE5,$AA0A4C5F,$DD0D7CC9
  164.     dc.l    $5005713C,$270241AA,$BE0B1010,$C90C2086
  165.     dc.l    $5768B525,$206F85B3,$B966D409,$CE61E49F
  166.     dc.l    $5EDEF90E,$29D9C998,$B0D09822,$C7D7A8B4
  167.     dc.l    $59B33D17,$2EB40D81,$B7BD5C3B,$C0BA6CAD
  168.     dc.l    $EDB88320,$9ABFB3B6,$03B6E20C,$74B1D29A
  169.     dc.l    $EAD54739,$9DD277AF,$04DB2615,$73DC1683
  170.     dc.l    $E3630B12,$94643B84,$0D6D6A3E,$7A6A5AA8
  171.     dc.l    $E40ECF0B,$9309FF9D,$0A00AE27,$7D079EB1
  172.     dc.l    $F00F9344,$8708A3D2,$1E01F268,$6906C2FE
  173.     dc.l    $F762575D,$806567CB,$196C3671,$6E6B06E7
  174.     dc.l    $FED41B76,$89D32BE0,$10DA7A5A,$67DD4ACC
  175.     dc.l    $F9B9DF6F,$8EBEEFF9,$17B7BE43,$60B08ED5
  176.     dc.l    $D6D6A3E8,$A1D1937E,$38D8C2C4,$4FDFF252
  177.     dc.l    $D1BB67F1,$A6BC5767,$3FB506DD,$48B2364B
  178.     dc.l    $D80D2BDA,$AF0A1B4C,$36034AF6,$41047A60
  179.     dc.l    $DF60EFC3,$A867DF55,$316E8EEF,$4669BE79
  180.     dc.l    $CB61B38C,$BC66831A,$256FD2A0,$5268E236
  181.     dc.l    $CC0C7795,$BB0B4703,$220216B9,$5505262F
  182.     dc.l    $C5BA3BBE,$B2BD0B28,$2BB45A92,$5CB36A04
  183.     dc.l    $C2D7FFA7,$B5D0CF31,$2CD99E8B,$5BDEAE1D
  184.     dc.l    $9B64C2B0,$EC63F226,$756AA39C,$026D930A
  185.     dc.l    $9C0906A9,$EB0E363F,$72076785,$05005713
  186.     dc.l    $95BF4A82,$E2B87A14,$7BB12BAE,$0CB61B38
  187.     dc.l    $92D28E9B,$E5D5BE0D,$7CDCEFB7,$0BDBDF21
  188.     dc.l    $86D3D2D4,$F1D4E242,$68DDB3F8,$1FDA836E
  189.     dc.l    $81BE16CD,$F6B9265B,$6FB077E1,$18B74777
  190.     dc.l    $88085AE6,$FF0F6A70,$66063BCA,$11010B5C
  191.     dc.l    $8F659EFF,$F862AE69,$616BFFD3,$166CCF45
  192.     dc.l    $A00AE278,$D70DD2EE,$4E048354,$3903B3C2
  193.     dc.l    $A7672661,$D06016F7,$4969474D,$3E6E77DB
  194.     dc.l    $AED16A4A,$D9D65ADC,$40DF0B66,$37D83BF0
  195.     dc.l    $A9BCAE53,$DEBB9EC5,$47B2CF7F,$30B5FFE9
  196.     dc.l    $BDBDF21C,$CABAC28A,$53B39330,$24B4A3A6
  197.     dc.l    $BAD03605,$CDD70693,$54DE5729,$23D967BF
  198.     dc.l    $B3667A2E,$C4614AB8,$5D681B02,$2A6F2B94
  199.     dc.l    $B40BBE37,$C30C8EA1,$5A05DF1B,$2D02EF8D
  200.  
  201.     END
  202.  
  203.