home *** CD-ROM | disk | FTP | other *** search
/ ftp.shrubbery.net / 2015-02-07.ftp.shrubbery.net.tar / ftp.shrubbery.net / pub / pc / unix / unx.arc / TOUCH.ASM < prev    next >
Assembly Source File  |  1985-11-16  |  4KB  |  187 lines
  1. page 66,132
  2. ;compressed mode on prn.
  3.  
  4. ;---- touch.com ---------------------------------------------------
  5. ; Usage: touch file [file...]
  6. ; Sets creation time of file to now
  7. ; Wildcards allowed in filename 
  8. ; Patterned after rm by MCN
  9. ; DRK 30 Oct 85
  10. ;---------------------------------------------------------------
  11.     extrn    _args:near,argc:word,argv:word,_shift:near
  12.     extrn    ffirst:near,fnext:near,fnam:byte,finder:word
  13.  
  14. stderr    equ    2
  15.  
  16. code    segment    public 'CODE'
  17. assume cs:code,ds:code,es:code
  18.  
  19. f_attrib    equ    21        ; offset from DTA of file attrib
  20.  
  21.     org    100h
  22.  
  23. ; This is a .COM program.
  24. ; It takes one or more arguments - the names of files (wildcards ok).
  25. ; 
  26. ; The argument is the first nonblank string of chars.
  27. ; Either backslashes or forward slashes may be used in a pathname.
  28.  
  29. exist    proc    near
  30.  
  31.     ; Get arguments.
  32.     call    _args
  33.  
  34.     ; Check # of arguments- if none, send usage message.
  35.     cmp    argc, 0
  36.     jnz    arglp
  37.         jmp    usage
  38.  
  39.                     
  40.     ; call DOS to see if file exists.
  41. arglp:    mov    dx, argv[2]    ; get pointer to first argument.
  42.     mov    cx, 0        ; no special attribute bits set
  43.     call    ffirst        ; FIND FIRST
  44.     jc    nofile        ; if carry set, no file found.
  45.  
  46. doit: 
  47.  
  48.     mov    ah, 3dh        ; open file for writing
  49.     mov    al, 1
  50.     lea    dx, fnam    ; 
  51.     int    21h
  52.     jnc    changem
  53.         call    denied        ; give whimpy access denied message
  54.         jmp    short next
  55. changem:
  56.     xchg    ax, bx
  57.  
  58.     ; Get current date/time
  59.     cli            ; stop system chronograph (no rollover, please)
  60.     mov    ah, 2ch
  61.     int    21h        ; hour=ch, min=cl, sec=dh
  62.     push    cx
  63.     push    dx
  64.     mov    ah, 2ah
  65.     int    21h        ; cx=year(1980..), dh=month(1-12), dl=day(1-31)
  66.     sti            ; restart chronograph, hope no serial I/O lost
  67.  
  68.     ; Convert to file timestamp format
  69.     ; dx=yyyyyyy mmmm ddddd (yyyyyyy = year-1980, mmmm=1..12, dddd=1..31)
  70.     sub    cx, 1980
  71.     shl    dh, 1
  72.     shl    dh, 1
  73.     shl    dh, 1
  74.     shl    dh, 1
  75.     shl    dh, 1        ; dh = mmm00000
  76.     rcl    cl, 1        ; cl = yyyyyyym
  77.     or    dl, dh        ; dl = mmmddddd
  78.     mov    dh, cl        ; dx = yyyyyyym mmmddddd
  79.     
  80.     ; cx=hhhhh mmmmmm sssss (sssss = seconds/2)
  81.     pop    ax        ; sec = ah
  82.     pop    cx        ; hour = ch, min=cl
  83.     shr    ah, 1        ; ah = 000sssss
  84.     shl    cl, 1
  85.     shl    cl, 1        ; cx = 000hhhhh mmmmmm00
  86.     shl    cx, 1
  87.     shl    cx, 1
  88.     shl    cx, 1
  89.     or    cl, ah        ; cx = hhhhhmmm mmmsssss
  90.  
  91.     ; Set file creation date/time
  92.     mov    ax, 5701h    ; cx=time, dx=date
  93.     int    21h
  94.     jnc    closem
  95.         call    denied        ; give whimpy access denied message
  96.         jmp    short next
  97. closem:
  98.     ; Close file
  99.     mov    ah, 3eh
  100.     int    21h
  101.  
  102. next:    mov    bx, finder
  103.     call    fnext        ; FIND NEXT
  104.     jnc    doit        ; again
  105.     
  106. narg:    call    _shift        ; more arguments?
  107.     dec    argc
  108.     jnz    arglp        ; nope
  109.  
  110.     mov    al, 0        ; errorlevel= 0 => file found
  111.     jmp    short exit
  112.  
  113. nlen    = 0
  114. nlen    = nend-noff
  115.  
  116. nofile:    mov    bx, stderr     ; error device
  117.     mov    cx,    nlen
  118.     mov    dx,    offset nmsg
  119.     mov    ah, 40h
  120.     int    21h
  121.     mov    al, 1        ; file not found error
  122.     jmp    short narg
  123.  
  124.     
  125.     
  126.  
  127. exit:    mov    ah, 4ch
  128.     int    21h        ; terminate process, return status in AL.
  129.  
  130. ulen    = 0
  131. ulen    =    uend-uoff
  132.  
  133. usage:    mov    bx, stderr    ; write to error device...
  134.     mov    cx, ulen
  135.     mov    dx, offset umsg
  136.     mov    ah, 40h
  137.     int    21h
  138.     mov    al, 2        ; error2 = syntax error
  139.     jmp    short exit
  140.  
  141. alen    = 0
  142. alen    =    aend-aoff
  143.  
  144. denied: cmp    ax, 5
  145.     jne    nfw        ; not access denied
  146.     mov    bx, stderr    ; error device
  147.     mov    cx, alen
  148.     mov    dx, offset amsg
  149.     mov    ah, 40h        ; write message
  150.     int    21h
  151.     mov    al, 1
  152.     ret
  153.  
  154. nfw:
  155.     mov    bx, stderr     ; error device
  156.     mov    cx,    nlen
  157.     mov    dx,    offset nmsg
  158.     mov    ah, 40h
  159.     int    21h
  160.     mov    al, 0ffh        ; file whiz error
  161.     jmp    short exit
  162.  
  163. exist    endp
  164.  
  165.  
  166. handle    dw    ?
  167.     
  168. umsg    db    'Usage: touch filespec [filespec ...]', 13, 10
  169. bugo    db    ?
  170. uoff    equ    offset umsg
  171. uend    equ    offset bugo
  172.  
  173. nmsg    db    "touch: Couldn't touch.", 13, 10
  174. nugo    db    ?
  175. noff    equ    offset nmsg
  176. nend    equ    offset nugo
  177.  
  178. amsg    db    'touch: access denied', 13, 10
  179. augo    db    ?
  180. aoff    equ    offset amsg
  181. aend    equ    offset augo
  182.  
  183.  
  184. code    ends
  185.  
  186.     end    exist
  187.