home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / pub / scripts / ckermit / remoteaccess < prev    next >
Encoding:
Text File  |  2020-01-01  |  7.0 KB  |  192 lines
  1. #!/usr/local/bin/kermit
  2.  
  3. ; r e m o t e a c c e s s
  4. ; 
  5. ; How to conduct a dialog with a user when Kermit does not have a controlling
  6. ; terminal; for example, when Kermit has accepted an incoming Internet ("set
  7. ; host *") or modem ("answer") connection, or when a Kermit script is started
  8. ; under inetd.  This script shows how to handle echoing and rudimentary
  9. ; keyboard editing:
  10. ;
  11. ; . Prints a prompt and waits for a line of text.
  12. ; . Ordinary characters echo.
  13. ; . Rubout, Delete, or Backspace removes the rightmost character from the line.
  14. ; . Ctrl-U removes the current line, if any.
  15. ; . Ctrl-R repaints the current line.
  16. ; . The prompt is protected.
  17. ;
  18. ; To make it more interesting, lines are interpreted as commands, validated,
  19. ; and executed.
  20. ;
  21. ; Note that when printing lines to the user's screen, both carriage (\13)
  22. ; and linefeed (\10) are included for when there is no terminal driver
  23. ; to supply them.  In case there IS a terminal driver, the SET INPUT ECHO OFF
  24. ; command allows the script to work there too.
  25. ;
  26. ; F. da Cruz, Columbia University, January 2003
  27.  
  28. ; First make a command keyword table and then sort it for \tablelook().
  29. ;
  30. declare \&k[] = exit:5 quit:5 help:2 ?:2 echo:1 send:3 list:4 directory:4
  31. sort &k
  32.  
  33. ; Make an array of help strings keyed on keyword value.
  34. ;
  35. dcl \&h[5]
  36. .\&h[1] = ECHO [text] echos its arguments.
  37. .\&h[2] = HELP prints this message; Synonym: "?".
  38. .\&h[3] = SEND filename [as-name] sends the given file under the given name.
  39. .\&h[4] = LIST [filespec] lists files; Synonym: DIRECTORY.
  40. .\&h[5] = EXIT exits; Synonym: QUIT.
  41.  
  42. ; Define command service routines
  43.  
  44. define DOEXIT {                        ; Service routine for EXIT command
  45.     output "\13\10Bye.\13\10"
  46.     sleep 1
  47.     exit
  48. }
  49.  
  50. define DOSEND {                        ; Service routine for SEND command
  51.     if not defined \%1 {
  52.         output "Filename required\13\10"
  53.         end 1
  54.     } else if not exist \%1 {
  55.         output "File not found: "\%1"\13\10"
  56.         end 1
  57.     }
  58.     send \%1 \%2
  59. }
  60.  
  61. define DOLIST {                        ; Service routine for LIST command
  62.     local \&d[] \%i \%f \%m
  63.     directory /array:&d \%1            ; Get filenames into array &d[]
  64.     output "\13\10"
  65.     if not \fdim(&d) {
  66.         output "(No files match)\13\10"
  67.     } else {
  68.         .\%m := 0                      ; Quickly get length of longest name
  69.         for \%i 1 \fdim(&d) 1 {
  70.             .\%m := \fmax(\%m,\flen(\&d[\%i]))
  71.         }
  72.         incr \%m
  73.         for \%i 1 \fdim(&d) 1 {        ; Print listing
  74.             .\%f := \&d[\%i]
  75.             if not readable \%f continue
  76.             output "  \frpad(\%f,\%m) \flpad(\fsize(\%f),9)  \fdate(\%f)\13\10"
  77.         }
  78.     }
  79.     output "\13\10"
  80. }
  81.  
  82. define DOHELP {                        ; Service routine for HELP command
  83.     local \%i
  84.     output "\13\10"
  85.     output "Commands are:\13\10\13\10"
  86.     for \%i 1 \fdim(&h) 1 {
  87.         output "  \&h[\%i]\13\10"
  88.     }
  89.     output "\13\{10}Commands may be abbreviated.\13\10"
  90.     output "\13\10"
  91. }
  92.  
  93. ; Command parser and dispatcher
  94.  
  95. define DOCOMMAND {
  96.     if not def \%1 return              ; Ignore blank lines
  97.     void \fsplit(\%1,&a,\32)           ; Split line into words
  98.     .\%k := \ftablelook(\&a[1],&k)     ; Look up first word
  99.     switch \%k {                       ; Handle lookup error
  100.       :-1
  101.         output "Command not found: "\&a[1]"\13\10"
  102.         output "Type HELP for help\13\10"
  103.         continue
  104.       :-2
  105.         output "Ambiguous: "\&a[1]"\13\10"
  106.         output "Type HELP for help\13\10"
  107.         continue
  108.     }
  109.     switch \fword(\&k[\%k],2,:) {      ; Dispatch on keyword value
  110.       :1                               ; ECHO prints its arguments
  111.         output "\fjoin(&a[2:])\13\10"
  112.         break
  113.       :2                               ; HELP prints help text
  114.         dohelp
  115.         break
  116.       :3                               ; SEND sends a file
  117.         dosend \&a[2] \&a[3]           ; with an optional as-name
  118.         output "\13\10"
  119.         break
  120.       :4                               ; LIST prints a file list
  121.         dolist \&a[2]
  122.         break
  123.       :5                               ; QUIT and EXIT quit
  124.         doexit
  125.     }
  126. }
  127.  
  128. set case off                           ; Commands are case-independent
  129. set input echo off                     ; In case there is a controlling tty
  130. set root .                             ; Restrict users to this directory tree
  131.  
  132. define prompt "Command: "              ; Define prompt
  133. output "\13\10"                        ; Start on a new line
  134. output "Type HELP for help.\13\10"     ; Greet
  135.  
  136. ; Loop to read lines and pass them to the command interpreter.
  137. ; This is where we handle echoing and editing.
  138.  
  139. while true {                           ; Outer loop for lines
  140.     undef buf                          ; Line buffer
  141.     .\%n = 0                           ; Line length
  142.     output "\m(prompt)"                ; Prompt
  143.     set flag off                       ; Inner loop control
  144.     while not flag {                   ; Inner loop for characters
  145.         input -1                       ; Get a character
  146.         if fail stop 1 INPUT Error     ; Make sure we did
  147.         .\%c := \v(inchar)             ; This is the character
  148.         .\%x := \fcode(\%c)            ; This is its code
  149.         switch \%x {                   ; switch on its code
  150.           :3                           ; Ctrl-C
  151.             doexit                     ; Exit immediately
  152.           :13                          ; Carriage Return
  153.           :10                          ; or Line Feed
  154.           :12                          ; or Form Feed
  155.             output "\13\10"            ; Echo CRLF
  156.             set flag on                ; Set inner-loop exit flag
  157.             docommand "\m(buf)"        ; Process the user's command
  158.             continue
  159.           :8                           ; Backspace
  160.           :127                         ; or Rubout
  161.             if not def buf {           ; Nothing to delete
  162.                 output "\7"            ; just beep
  163.                 continue
  164.             }
  165.             output "\8 \8"             ; Erase char from user's screen
  166.             decr \%n                   ; And from line buffer
  167.             .buf := \s(buf[1:\%n])
  168.             continue
  169.           :18                          ; Ctrl-R
  170.             output "\13\10"            ; Refresh line
  171.             output "\m(prompt)\m(buf)"
  172.             continue            
  173.           :21                          ; Ctrl-U
  174.             for \%i 1 \%n 1 {          ; Erase line from screen
  175.                 output "\8 \8"
  176.             }
  177.             .\%n = 0
  178.             undef buf
  179.             continue
  180.           :9                           ; Ctrl-I (Tab)
  181.             .\%c := \32                ; Convert to space
  182.             .\%x := 32                 ; and fall thru.
  183.           :default                     ; Anything else
  184.             if > \%x 31 {              ; If char is printable
  185.                 output \%c             ; echo it
  186.                 .buf := \m(buf)\%c     ; add it to line buffer
  187.                 incr \%n               ; and count it
  188.             } else output "\7"         ; Beep for nonprintables
  189.         }          
  190.     }
  191. }
  192.