home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / pub / scripts / ckermit / malphapage < prev    next >
Encoding:
Text File  |  2020-01-01  |  10.8 KB  |  361 lines
  1. #!/usr/local/bin/kermit8
  2. ; --------------------------------------------------------------------
  3. ;
  4. ; cook2.ksc
  5. ;
  6. ;
  7. ; Author
  8. ; ------
  9. ; R. M. Almeria, Anteon Corp., 2003
  10. ;
  11. ;
  12. ; Purpose
  13. ; -------
  14. ; This kermit script is designed to take 1 to N times two arguments 
  15. ; (a pager-id and a message) and to connect to Arch's paging service 
  16. ; via a modem using their special service number.
  17. ;
  18. ; So you can basically connect to the service and issue several pages 
  19. ; or just one.  You could send a message to someone's pager like so:
  20. ;
  21. ;    cook2.ksc 4441111 "hello world"
  22. ;
  23. ; or you could send multiple messages to multiple pagers like so:
  24. ;
  25. ;    cook2.ksc 4441111 "test1" 4442222 "test2" 4443333 "test3"
  26. ;
  27. ;
  28. ; Special Remarks
  29. ; ---------------
  30. ; This program implements the TAP (Telocator Alphanumeric Protocol)
  31. ; for pagers.
  32. ;
  33. ;
  34. ; Language
  35. ; --------
  36. ; This program is written in Kermit script.  Please read the book
  37. ; "Using C-KERMIT" by Frank da Cruz et al., for more details.
  38. ; 
  39. ;
  40. ; Revision History
  41. ; ----------------
  42. ; v1.1 -- February 5, 2003 @ 3:48 PM 
  43. ;    Added copious debug statements that are toggled (0/1) via
  44. ;    the DEBUG constant (it is defined in the initialization section).
  45. ;
  46. ; v1.0 -- January 28, 2003 @ 5:55 PM 
  47. ;    Initial revision.
  48. ;
  49. ; --------------------------------------------------------------------
  50.  
  51. ; --------------------------------------------------------------------
  52. ; Check the number of command line arguments and exit if insufficient. 
  53. ; --------------------------------------------------------------------
  54.   xif < \v(args) 4 {
  55.     echo \10This kermit8 paging script accepts unlimited alphanumeric-
  56.  pager-id/message pairs.\10
  57.     echo {SYNTAX:\10\9cook2.ksc pagerid1 message1 pagerid2 message2-
  58.  pagerid3 message3 . . . \10}
  59.     echo {    EX:\10\9./cook2.ksc 9992322 "Hello World!"\10}
  60.     exit
  61.   }
  62.  
  63. ; --------------------------------------------------------------------
  64. ; Define the SendBlock function which sends a message (block) to the
  65. ; paging service.  This function is also called initially to send the
  66. ; first message.
  67. ; --------------------------------------------------------------------
  68. def SENDBLOCK {
  69.   local \%b \%c \%s blk
  70.  
  71.   ; Create a string composed of the pager-id and message with
  72.   ; appropriate control chars.
  73.   assign \%b \2\&p[\%m]\13\&m[\%m]\13\3
  74.  
  75.   ; Calculate the checksum required for TAP and add to the final
  76.   ; message string that will be sent to the paging service.
  77.   assign \%c \fchecksum(\%b)
  78.   assign blk \%b\fchar(\fmod(\%c/256,16)+48)\fchar(\fmod(\%c/16,16)+48)\fchar(\fmod(\%c,16)+48)\13
  79.  
  80.   assign \%s \flength(blk)
  81.  
  82.   ; Make sure that the size of the block is less than MaxBlockSize.
  83.   xif < \%s \%y {
  84.     if \m(DEBUG) echo {DEBUG: {SENDBLOCK}  Sending '\&m[\%m]' to '\&p[\%m]'}
  85.     output \m(blk)
  86.     return 1 
  87.   } else {
  88.     return 0
  89.   }
  90.  
  91. }
  92.  
  93. ; --------------------------------------------------------------------
  94. ; Define the SendNextBlock function which sends the second thru last 
  95. ; messages (blocks) to the paging service (one block sent per 
  96. ; function call).  This function calls SendBlock to send its messages.
  97. ; --------------------------------------------------------------------
  98. def SENDNEXTBLOCK {
  99.  
  100.   xif < \%m+1 \%n {
  101.  
  102.     ; There are still messages to send so send them.
  103.  
  104.     assign \%q 0    ; Reset the retries counter.
  105.     assign \%m \feval(\%m + 1)
  106.    
  107.     sendblock
  108.     return \v(return)
  109.  
  110.   } else {
  111.  
  112.     ; We are done with the paging service so disconnect.
  113.  
  114.     output \4\13    ; Send <EOT><CR>
  115.     if \m(DEBUG) echo {DEBUG: {SENDNEXTBLOCK} Sending <EOT><CR>.}
  116.     input 3 {\27\4\13}    ; Look for <ESC><EOT><CR>
  117.     assign \%f 1    ; Set Finished to true.
  118.     return 0
  119.   }
  120.  
  121. }
  122.  
  123. ; --------------------------------------------------------------------
  124. ; Define the TAP (Telocator Alphanumeric Protocol) function.
  125. ; --------------------------------------------------------------------
  126. def SENDTAPMSG {
  127.  
  128.   assign \%o \6\13    ; OK         = <ACK><CR>
  129.   assign \%t \21\13    ; TRY AGAIN    = <NAK><CR>
  130.   assign \%a \30\13    ; ABANDON    = <RS><CR>
  131.   assign \%d \27\4\13    ; DISCONNECT    = <ESC><EOT><CR>
  132.   
  133.   assign \%x 0        ; Initialize the loop variable.
  134.  
  135.   assign \%f 0        ; Initialize Finished flag to false.
  136.   assign \%w 5        ; Initialize MaxIDAttempts.
  137.  
  138. :dowhile
  139.  
  140.   ; Look for 'ID=' string for at least MaxIDAttempts before exiting.
  141.   xif = \%f 0 {
  142.     xif < \%x \%w {
  143.       output \13
  144.       input 3 {ID=}
  145.       xif success {
  146.         assign \%f 1
  147.       } else {
  148.         assign \%x \feval(\%x + 1)
  149.       }
  150.       goto dowhile
  151.     }
  152.   } 
  153.  
  154.   ; Exit if we didn't get the 'ID=' string.
  155.   xif = \%f 0 {
  156.     assign \%e 0  
  157.     end
  158.   }
  159.  
  160.   assign \%q 0        ; Initialize protocol Retries and NOT dialing retries.
  161.   assign \%u 1        ; Initialize First to true.
  162.   assign \%f 0        ; Reset Finished to false.
  163.   assign \%v 0        ; Initialize SentBlock to false.
  164.   assign \%y 233    ; Define MaxBlockSize.  Typically 256 according to the
  165.             ; protocol but Cook limits this to 233.
  166.   assign \%z 3        ; Define MaxRetries.
  167.  
  168.   while = \%f 0 {
  169.     xif = \%u 1 {
  170.       xif < \%q \%z {
  171.         if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} Sending <ESC>PG1<CR>.}
  172.  
  173.     ; Tell the paging service that we want to send an
  174.         ; alphanumeric page.
  175.         output {\27PG1\13}    ; Sending <ESC>PG1<CR>    
  176.  
  177.         ; Wait for a response from the paging service...
  178.         ; either OK, TRY AGAIN, DISCONNECT, 'ID=' or
  179.         ; TIMEOUT.
  180.         minput 3 {\%o} {\%t} {\%d} {ID=}
  181.  
  182.         switch \v(minput) {
  183.           :0, break        ; TIMEOUT 
  184.           :1,                   ; OK         = <ACK><CR> 
  185.               if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} Received OK.}
  186.               if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} Waiting for <ESC>[p<CR>.}
  187.  
  188.               ; Wait for the go-ahead from the paging service.
  189.               input 3 {\27[p\13}
  190.               xif success {
  191.                 msleep 500
  192.                 xif < \%m \%n {
  193.                   if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} Calling SENDBLOCK.}
  194.                   sendblock    ; Send first block.
  195.                   assign \%v \v(return)
  196.                   assign \%u 0
  197.                 } else {
  198.                   assign \%f 1    ; Set Finished to true.
  199.                 }
  200.               } else {
  201.                 assign \%f 1    ; Set Finished to true.
  202.               }
  203.               break        
  204.           :2,                   ; TRY AGAIN  = <NAK><CR> 
  205.               if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} Received TRY AGAIN.}
  206.               break
  207.           :3,                   ; DISCONNECT = <ESC><EOT><CR> 
  208.               if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} Received DISCONNECT.}
  209.               assign \%f 1    ; Set Finished to true.
  210.               break        
  211.           :4, break        ; Received 'ID=' send <ESC>PG1<CR> again
  212.         }
  213.  
  214.         ; Increment the Retries counter.
  215.         assign \%q \feval(\%q + 1)
  216.  
  217.       } else {
  218.         assign \%f 1        ; Set Finished to true.
  219.       }
  220.     } else {
  221.  
  222.       ; Look for the response to the first and succeeding blocks that
  223.       ; were sent to the paging service.  We are waiting for an OK,
  224.       ; ABANDON, TRY AGAIN, DISCONNECT or TIMEOUT response.
  225.       minput 3 {\%o} {\%a} {\%t} {\%d}
  226.       switch \v(minput) {
  227.         :0, break        ; TIMEOUT 
  228.         :1,                     ; OK         = <ACK><CR> 
  229.             if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} - Received OK.}
  230.             msleep 500   
  231.             if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} - Calling SENDNEXTBLOCK.}
  232.             sendnextblock
  233.             assign \%v \v(return)
  234.             break
  235.         :2,                     ; ABANDON    = <RS><CR> 
  236.             if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} - Received ABANDON.}
  237.             msleep 500   
  238.             if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} - Calling SENDNEXTBLOCK.}
  239.             sendnextblock
  240.             assign \%v \v(return)
  241.             break
  242.         :3,                     ; TRY AGAIN  = <NAK><CR>
  243.             if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} - Received TRY AGAIN.}
  244.             msleep 500
  245.             xif = \%v 1 {
  246.               xif < \%q \%z {
  247.                 sendblock
  248.                 assign \%v \v(return)
  249.  
  250.         ; Increment the retries counter.
  251.                 assign \%q \feval(\%q + 1) 
  252.               } else {
  253.                 sendnextblock
  254.                 assign \%v \v(return)
  255.               }
  256.             } else {
  257.               sendnextblock
  258.               assign \%v \v(return)
  259.             }
  260.             break
  261.         :4,                     ; DISCONNECT = <ESC><EOT><CR>
  262.             if \m(DEBUG) echo {DEBUG: {SENDTAPMSG} - Received DISCONNECT.}
  263.             assign \%f 1    ; Set Finished to true.
  264.             break
  265.       }
  266.     }
  267.   }
  268.   
  269.   xif < \%m+1 \%n {
  270.     assign \%e 0        ; Return false (Didn't send all messages due to errors).
  271.   } else {
  272.     assign \%e 1        ; Return true (We sent all of the messages).
  273.   }
  274. }
  275.  
  276.  
  277. ; --------------------------------------------------------------------
  278. ; Initialization.
  279. ; --------------------------------------------------------------------
  280.  
  281.   assign DEBUG 1
  282.  
  283.   ; Calculate the number of messages to send.
  284.   assign \%n \feval( (\v(args) - 2)/2)    
  285.  
  286.   declare \&p[\%n]        ; Declare the pager-id array.
  287.   declare \&m[\%n]        ; Declare the message array.
  288.  
  289.   ; Populate the pager-id and message arrays with the args.
  290.   for \%x 0 \%n-1 1 {
  291.     assign \%i \feval(2 + (\%x * 2))    ; Compute the pager-id index.
  292.     assign \%j \feval(3 + (\%x * 2))    ; Compute the message index.
  293.  
  294.     assign \&p[\%x] \&@[\%i]        ; Add pager-id to pager-id array.
  295.     assign \&m[\%x] \&@[\%j]        ; Add message to message array.
  296.   }
  297.  
  298.   assign \%m 0            ; Initialize message index (MIndex).
  299.  
  300.   assign \%r 0            ; Initialize the Reconnects counter.
  301.   assign \%s 3            ; Define MaxReconnects.
  302.  
  303.   assign COOKPDX 9,5031234567   ; Set to local paging service phone number.
  304.  
  305.   assign \%e 0            ; Initialize TAP Error Flag to false.
  306.  
  307. ; --------------------------------------------------------------------
  308. ; Try to connect to the paging service.
  309. ; --------------------------------------------------------------------
  310. :restart
  311.  
  312.   if \m(DEBUG) echo {\10DEBUG: RESTART NO. \%r}
  313.   set modem hangup-method modem-command 
  314.   if \m(DEBUG) echo {DEBUG: Issuing initial HANGUP.}
  315.   hangup
  316.  
  317.   if \m(DEBUG) echo {DEBUG: Setting modem type}
  318.   set modem type att-dataport
  319.   if \m(DEBUG) echo {DEBUG: Setting the port to '/dev/cua/4'}
  320.   set port /dev/cua/4
  321.   xif failure {
  322.     echo {ERROR: I could not connect to /dev/cua/4}
  323.     goto terminate 
  324.   } 
  325.  
  326.   if \m(DEBUG) echo {DEBUG: Setting up the terminal.}
  327.   set speed 2400
  328.   set parity even
  329.   set stop-bits 1
  330.   set flow-control xon/xoff
  331.   set modem flow none
  332.   set modem error-correction off
  333.   set modem data-compression off
  334.   set modem speed-matching off
  335.   ;set carrier-watch off
  336.   set output pacing 200
  337.   set dial retries 5
  338.   set dial interval 1
  339.  
  340.   if \m(DEBUG) echo {DEBUG: DIALING....}
  341.   dial \m(COOKPDX)
  342.   xif success {
  343.     if \m(DEBUG) echo {DEBUG: Calling SENDTAPMSG.}
  344.     sendtapmsg
  345.     xif = \%e 0 {
  346.       xif < \%r \%s {
  347.         xif < \%m \%n {
  348.           assign \%r \feval(\%r + 1)
  349.           goto restart
  350.         }
  351.       }
  352.     } 
  353.   }
  354.  
  355. :terminate
  356.  
  357.   if \m(DEBUG) echo {DEBUG: Hanging up.}
  358.   hangup
  359.   if \m(DEBUG) echo {DEBUG: Exiting.}
  360.   exit
  361.