home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / pub / scripts / ckermit / ftprename < prev    next >
Encoding:
Text File  |  2020-01-01  |  2.2 KB  |  44 lines
  1. ; Kermit FTP script to add ".old" suffix to all files in a server directory.
  2. ; 
  3. ; Requires C-Kermit 8.0 (Unix) or Kermit 95 2.0 (Windows):
  4. ; http://www.columbia.edu/kermit/
  5. ;
  6. ; F. da Cruz, Columbia University, July 2002
  7. ;
  8. ; Change these as appropriate or convert them to command-line parameters.
  9. ; See: http://www.columbia.edu/kermit/ckscripts.html for an explanation.
  10. ;
  11. define user olga                                ; Username
  12. define host ftp.xyzcorp.com                     ; Hostname
  13. define dir  invoices                            ; Remote directory name
  14. define rfs  *                                   ; Remote file specification
  15. define tmp  filelist                            ; Local temp file name
  16.  
  17. ; The rest of the script doesn't need to be changed
  18.  
  19. ftp \m(host) /user:\m(user)                     ; Open the connection
  20. if fail stop 1 ftp open \m(host) failed         ; Check for failure
  21. ftp cd \m(dir)                                  ; CD to remote directory
  22. if fail stop 1 ftp cd \m(dir) failed            ; Check for failure
  23. ftp mget /namelist:\m(tmp) \m(rfs)              ; Get list of filenames
  24. if fail stop 1 ftp mget /namelist failed        ; Check for failure
  25. fopen /read \%c \m(tmp)                         ; Open the namelist file
  26. if fail stop 1 Open \m(tmp) failed: \f_errmsg() ; Check for failure
  27.  
  28. .\%n = 0                                        ; Initialize file counter
  29. set flag off                                    ; Error indication
  30. while not flag {                                ; Loop through files
  31.     fread \%c filename                          ; Read next filename
  32.     if fail break                               ; Failure is EOF
  33.     increment \%n                               ; Count the file
  34.     echo \%n. \m(filename)                      ; Give feedback
  35.     ftp rename \m(filename) \m(filename).old    ; Rename this file
  36.     if fail set flag on                         ; Check for failure
  37. }
  38. ftp dir                                         ; Done - Show remote files
  39. ftp bye                                         ; Disconnect from server
  40.  
  41. if flag stop 1 ftp rename failed: \m(filename)  ; Report any failure
  42. echo Files renamed: \%n                         ; Or report success
  43. end
  44.