home *** CD-ROM | disk | FTP | other *** search
/ back2roots/filegate / filegate.zip / filegate / gamesnet / g_amiga / AE1CRTVC.ZIP / AE1CRTVC.LHA / DSPACE.BAS < prev    next >
BASIC Source File  |  1980-01-01  |  7KB  |  253 lines
  1. 100 PRINT CHR$(26);TAB(24);"DEEPSPACE"
  2. 110 PRINT TAB(20);"CREATIVE COMPUTING"
  3. 120 PRINT TAB(18);"MORRISTOWN, NEW JERSEY"
  4. 130 PRINT:PRINT
  5. 150 PRINT "THIS IS DEEPSPACE, A TACTICAL SIMULATION OF SHIP TO SHIP"
  6. 160 PRINT "COMBAT IN DEEP SPACE."
  7. 165 PRINT
  8. 170 PRINT "DO YOU WISH INSTRUCTIONS";:INPUT I$
  9. 180 IF LEFT$(I$,1)="N" THEN 610
  10. 190 PRINT CHR$(26)
  11. 200 PRINT "YOU ARE ONE OF A GROUP OF CAPTAINS ASSIGNED TO PATROL A"
  12. 210 PRINT "SECTION OF YOUR STAR EMPIRE'S BORDER AGAINST HOSTILE"
  13. 220 PRINT "ALIENS. ALL YOUR ENCOUNTERS HERE WILL BE AGAINST HOSTILE"
  14. 230 PRINT "VESSELS. YOU WILL FIRST BE REQUIRED TO SELECT A VESSEL"
  15. 240 PRINT "FROM ONE OF THREE TYPES, EACH WITH ITS OWN CHARACTERISTICS:"
  16. 260 PRINT:PRINT "    TYPE","SPEED","CARGO SPACE","PROTECTION"
  17. 265 PRINT "   ------","-----","-----------","----------"
  18. 270 PRINT "1- SCOUT"," 10X","     16","    1"
  19. 280 PRINT "2- CRUISER","  4X","     24","    2"
  20. 290 PRINT "3- BATTLESHIP","  2X","     30","    5"
  21. 310 PRINT:PRINT "SPEED IS GIVEN RELATIVE TO THE OTHER SHIPS."
  22. 320 PRINT "CARGO SPACE IS IN UNITS OF SPACE ABOARD SHIP WHICH CAN BE"
  23. 330 PRINT "FILLED WITH WEAPONS."
  24. 340 PRINT "PROTECTION IS THE RELATIVE STRENGTH OF THE SHIP'S ARMOR"
  25. 350 PRINT "AND FORCE FIELDS."
  26. 360 GOSUB 10000
  27. 370 PRINT:PRINT "ONCE A SHIP HAS BEEN SELECTED, YOU WILL BE INSTRUCTED TO ARM"
  28. 380 PRINT "IT WITH WEAPONRY FROM THE FOLLOWING LIST:"
  29. 390 PRINT
  30. 400 PRINT "     TYPE                    CARGO SPACE    REL. STRENGTH"
  31. 405 PRINT "    ------                   -----------    -------------"
  32. 410 PRINT "1- PHASER BANKS                   12                4"
  33. 420 PRINT "2- ANTI-MATTER MISSILE             4               20"
  34. 430 PRINT "3- HYPERSPACE LANCE                4               16"
  35. 440 PRINT "4- PHOTON TORPEDO                  2               10"
  36. 450 PRINT "5- HYPERON NEUTRALIZATION FIELD   20                6"
  37. 470 PRINT:PRINT "WEAPONS #1 & #5 CAN BE FIRED 100 TIMES EACH; ALL OTHERS CAN"
  38. 480 PRINT "BE FIRED ONCE FOR EACH ON BOARD."
  39. 485 PRINT
  40. 490 PRINT "A TYPICAL LOAD FOR A CRUISER MIGHT CONSIST OF:"
  41. 500 PRINT "          1-#1 PHASER BANK          = 12"
  42. 510 PRINT "          2-#3 HYPERSPACE LANCES    =  8"
  43. 520 PRINT "          2-#4 PHOTON TORPEDOES     =  4"
  44. 530 PRINT "                                  ---------"
  45. 540 PRINT "                              24 UNITS OF CARGO"
  46. 545 GOSUB 10000
  47. 550 PRINT " A WORD OF CAUTION: FIRING HIGH YIELD WEAPONS AT CLOSE (<100)"
  48. 560 PRINT "RANGE CAN BE DANGEROUS TO YOUR SHIP AND MINIMAL DAMAGE CAN"
  49. 570 PRINT "OCCUR AS FAR OUT AS 200 IN SOME CIRCUMSTANCES."
  50. 590 PRINT:PRINT "RANGE IS GIVEN IN THOUSANDS OF KILOMETERS."
  51. 600 GOTO 640
  52. 610 PRINT "DO YOU WISH A MANEUVER CHART";:INPUT M$
  53. 620 IF LEFT$(M$,1)="N" THEN 770
  54. 640 PRINT
  55. 650 PRINT "     MANEUVER CHART":PRINT "     --------------"
  56. 670 PRINT " 1      FIRE PHASERS"
  57. 680 PRINT " 2      FIRE ANTI-MATTER MISSILE"
  58. 690 PRINT " 3      FIRE HYPERSPACE LANCE"
  59. 700 PRINT " 4      FIRE PHOTON TORPEDO"
  60. 710 PRINT " 5      ACTIVE HYPERON NEUTRALIZATION FIELD"
  61. 720 PRINT " 6      SELF-DESTRUCT"
  62. 730 PRINT " 7      CHANGE VELOCITY"
  63. 740 PRINT " 8      DISENGAGE"
  64. 750 PRINT " 9      PROCEED"
  65. 770 PRINT:PRINT "YOU HAVE A CHOICE OF THREE SYSTEMS TO PATROL."
  66. 780 PRINT "1 - ORION"
  67. 790 PRINT "2 - DENEB"
  68. 800 PRINT "3 - ARCTURUS"
  69. 810 PRINT "SELECT A SYSTEM (1-3)";:INPUT S9
  70. 820 IF S9=1 THEN 2380
  71. 830 IF S9=2 THEN 2430
  72. 840 GOTO 2480
  73. 850 D0=0
  74. 860 D1=0
  75. 870 N1=0
  76. 880 N2=0
  77. 890 N3=0
  78. 900 N4=0
  79. 910 D=0
  80. 920 PRINT "WHICH SPACECRAFT WOULD YOU LIKE (1-3)";:INPUT S
  81. 930 ON S GOTO 1790,1830,1870
  82. 960 GOTO 920
  83. 970 C=C0
  84. 980 PRINT "YOU HAVE";C;"UNITS OF CARGO SPACE TO FILL WITH WEAPONRY."
  85. 990 PRINT "CHOOSE A WEAPON AND THE AMOUNT YOU WISH";:INPUT W,N
  86. 1000 ON W GOTO 1910,2010,2100,2190,2280
  87. 1050 GOTO 980
  88. 1060 IF N*C1>C THEN 2530
  89. 1070 C=C-N*C1
  90. 1080 ON W GOTO 1990,2080,2170,2260
  91. 1120 GOTO 2360
  92. 1130 IF C>1 THEN 980
  93. 1140 REM
  94. 1150 S1=S0*RND(0)
  95. 1160 R=(3*RND(0)+5)*100
  96. 1180 PRINT:PRINT "RANGE TO TARGET:";R
  97. 1190 PRINT "RELATIVE VELOCITY:";S1
  98. 1200 PRINT "ACTION";:INPUT M
  99. 1210 ON M GOTO 1940,2030,2120,2210,2310,1660,1390,2760
  100. 1290 IF R<500 THEN 1500
  101. 1300 IF S1>0 THEN 1330
  102. 1310 R=R+(S1*8.3)^1.25
  103. 1320 GOTO 1340
  104. 1330 R=R-(S1*8.3)^1.25
  105. 1340 IF R>1500 THEN 2590
  106. 1350 IF R>0 THEN 1370
  107. 1360 R=-R
  108. 1370 PRINT
  109. 1380 GOTO 1180
  110. 1390 PRINT "CHANGE TO BE EFFECTED";:INPUT S2
  111. 1400 IF (S1+S2)>S0 THEN 2550
  112. 1410 S1=S1+S2
  113. 1420 GOTO 1180
  114. 1430 F0=P1*(Z/R)^1.5
  115. 1440 REM
  116. 1450 D0=(2*F0+3*F0*RND(0))/5
  117. 1460 D=D+D0
  118. 1470 PRINT "SCANNERS REPORT ENEMY DAMAGE NOW:";D
  119. 1480 IF D>99 THEN 2720
  120. 1490 GOTO 1510
  121. 1500 D0=0
  122. 1510 REM
  123. 1520 K=E1+E2*RND(0)
  124. 1530 REM
  125. 1540 E=E3+E4*RND(0)+5/P0*RND(0)
  126. 1550 REM
  127. 1560 F3=E*(K/R)^1.85
  128. 1570 D2=(3*F3+3*F3*RND(0))/5.5
  129. 1580 D1=D1+D2
  130. 1590 IF (Z*D0)/(R*500)>2.2 THEN 1620
  131. 1600 D3=D0*2/(R^2*P0)
  132. 1610 D1=D1+D3
  133. 1620 PRINT "DAMAGE CONTROL REPORTS YOUR VESSEL DAMAGE AT:";D1
  134. 1630 IF D1>99 THEN 2740
  135. 1640 IF D>99 THEN 2760
  136. 1650 GOTO 1300
  137. 1660 PRINT "SELF DESTRUCT FAILSAFE ACTIVATED!!"
  138. 1670 PRINT "INPUT 1 TO RELEASE FAILSAFE";:INPUT U
  139. 1680 IF U=1 THEN 1700
  140. 1690 GOTO 1290
  141. 1700 PRINT "SELF DESTRUCT ACCOMPLISHED."
  142. 1710 IF R>60 THEN 1740
  143. 1720 PRINT "ENEMY VESSEL ALSO DESTROYED."
  144. 1730 GOTO 2760
  145. 1740 D4=3200/R
  146. 1750 D=D+D4
  147. 1760 IF D>99 THEN 1720
  148. 1770 PRINT "ENEMY VESSEL SURVIVES WITH";D;"DAMAGE."
  149. 1780 GOTO 2760
  150. 1790 S0=10
  151. 1800 C0=16
  152. 1810 P0=1
  153. 1820 GOTO 970
  154. 1830 S0=4
  155. 1840 C0=24
  156. 1850 P0=2
  157. 1860 GOTO 970
  158. 1870 S0=2
  159. 1880 C0=30
  160. 1890 P0=5
  161. 1900 GOTO 970
  162. 1910 C1=12
  163. 1930 GOTO 1060
  164. 1940 P1=4
  165. 1950 IF N1=0 THEN 2160
  166. 1960 N1=N1-1
  167. 1970 Z=200
  168. 1980 GOTO 1430
  169. 1990 N1=N1+N
  170. 2000 GOTO 1130
  171. 2010 C1=4
  172. 2020 GOTO 1060
  173. 2030 P1=20
  174. 2040 IF N2=0 THEN 2640
  175. 2050 N2=N2-1
  176. 2060 Z=500
  177. 2070 GOTO 1430
  178. 2080 N2=N2+N
  179. 2090 GOTO 1130
  180. 2100 C1=4
  181. 2110 GOTO 1060
  182. 2120 P1=16
  183. 2130 IF N3=0 THEN 2660
  184. 2140 N3=N3-1
  185. 2150 Z=550
  186. 2160 GOTO 1430
  187. 2170 N3=N3+N
  188. 2180 GOTO 1130
  189. 2190 C1=2
  190. 2200 GOTO 1060
  191. 2210 P1=10
  192. 2220 IF N4=O THEN 2680
  193. 2230 N4=N4-1
  194. 2240 Z=400
  195. 2250 GOTO 1430
  196. 2260 N4=N4+N
  197. 2270 GOTO 1130
  198. 2280 C1=.2
  199. 2290 N=100
  200. 2300 GOTO 1060
  201. 2310 P1=6
  202. 2320 IF N5=0 THEN 2700
  203. 2330 N5=N5-1
  204. 2340 Z=250
  205. 2350 GOTO 1430
  206. 2360 N5=N5+N
  207. 2370 GOTO 1130
  208. 2380 E1=150
  209. 2390 E2=500
  210. 2400 E3=3
  211. 2410 E4=4
  212. 2420 GOTO 850
  213. 2430 E1=200
  214. 2440 E2=350
  215. 2450 E3=4
  216. 2460 E4=3
  217. 2470 GOTO 850
  218. 2480 E1=150
  219. 2490 E2=400
  220. 2500 E3=5
  221. 2510 E4=2
  222. 2520 GOTO 850
  223. 2530 PRINT "NOT ENOUGH SPACE. RESELECT."
  224. 2540 GOTO 980
  225. 2550 PRINT "CHANGE BEYOND MAXIMUM POSSIBLE."
  226. 2560 PRINT "INCREASING TO MAXIMUM."
  227. 2570 S1=S0
  228. 2580 GOTO 1300
  229. 2590 PRINT "OUT OF SENSOR RANGE. AUTOMATIC DISENGAGE."
  230. 2600 GOTO 2760
  231. 2610 PRINT "PHASER BANKS DRAINED."
  232. 2620 PRINT "SELECT ANOTHER COURSE OF ACTION."
  233. 2630 GOTO 1200
  234. 2640 PRINT " ALL ANTI-MATTER MISSLES EXPENDED."
  235. 2650 GOTO 2620
  236. 2660 PRINT "ALL HYPERSPACE LANCES EXPENDED."
  237. 2670 GOTO 2620
  238. 2680 PRINT "ALL PHOTON TORPEDO TUBES EMPTY."
  239. 2690 GOTO 2620
  240. 2700 PRINT "HYPERON NEUTRALIZATION FIELD DRAINED."
  241. 2710 GOTO 2620
  242. 2720 PRINT "ENEMY VESSEL DESTROYED!"
  243. 2730 GOTO 1510
  244. 2740 PRINT "YOUR VESSEL HAS BEEN DESTROYED!"
  245. 2760 PRINT "ANOTHER BATTLE";:INPUT R$
  246. 2770 IF LEFT$(R$,1)="Y" THEN 810
  247. 2780 PRINT:PRINT "TRY AGAIN LATER!":PRINT
  248. 2790 GOTO 65000
  249. 10000 PRINT:LINE INPUT "ENTER 'RETURN' TO CONTINUE. ";XX$
  250. 10010 PRINT CHR$(26)
  251. 10020 RETURN
  252. 65000 END
  253.