home *** CD-ROM | disk | FTP | other *** search
/ Netrunner 2004 October / NETRUNNER0410.ISO / regular / ActivePerl-5.8.4.810-MSWin32-x86.msi / _aac972778f19b8806fcc937bb76f73c7 < prev    next >
Text File  |  2004-06-01  |  9KB  |  346 lines
  1. package Encode::Guess;
  2. use strict;
  3.  
  4. use Encode qw(:fallbacks find_encoding);
  5. our $VERSION = do { my @r = (q$Revision: 1.9 $ =~ /\d+/g); sprintf "%d."."%02d" x $#r, @r };
  6.  
  7. my $Canon = 'Guess';
  8. sub DEBUG () { 0 }
  9. our %DEF_SUSPECTS = map { $_ => find_encoding($_) } qw(ascii utf8);
  10. $Encode::Encoding{$Canon} = 
  11.     bless { 
  12.        Name       => $Canon,
  13.        Suspects => { %DEF_SUSPECTS },
  14.       } => __PACKAGE__;
  15.  
  16. use base qw(Encode::Encoding);
  17. sub needs_lines { 1 }
  18. sub perlio_ok { 0 }
  19.  
  20. our @EXPORT = qw(guess_encoding);
  21. our $NoUTFAutoGuess = 0;
  22.  
  23. sub import { # Exporter not used so we do it on our own
  24.     my $callpkg = caller;
  25.     for my $item (@EXPORT){
  26.     no strict 'refs';
  27.     *{"$callpkg\::$item"} = \&{"$item"};
  28.     }
  29.     set_suspects(@_);
  30. }
  31.  
  32. sub set_suspects{
  33.     my $class = shift;
  34.     my $self = ref($class) ? $class : $Encode::Encoding{$Canon};
  35.     $self->{Suspects} = { %DEF_SUSPECTS };
  36.     $self->add_suspects(@_);
  37. }
  38.  
  39. sub add_suspects{
  40.     my $class = shift;
  41.     my $self = ref($class) ? $class : $Encode::Encoding{$Canon};
  42.     for my $c (@_){
  43.     my $e = find_encoding($c) or die "Unknown encoding: $c";
  44.     $self->{Suspects}{$e->name} = $e;
  45.     DEBUG and warn "Added: ", $e->name;
  46.     }
  47. }
  48.  
  49. sub decode($$;$){
  50.     my ($obj, $octet, $chk) = @_;
  51.     my $guessed = guess($obj, $octet);
  52.     unless (ref($guessed)){
  53.     require Carp;
  54.     Carp::croak($guessed);
  55.     }
  56.     my $utf8 = $guessed->decode($octet, $chk);
  57.     $_[1] = $octet if $chk;
  58.     return $utf8;
  59. }
  60.  
  61. sub guess_encoding{
  62.     guess($Encode::Encoding{$Canon}, @_);
  63. }
  64.  
  65. sub guess {
  66.     my $class = shift;
  67.     my $obj   = ref($class) ? $class : $Encode::Encoding{$Canon};
  68.     my $octet = shift;
  69.  
  70.     # sanity check
  71.     return unless defined $octet and length $octet;
  72.  
  73.     # cheat 0: utf8 flag;
  74.     if ( Encode::is_utf8($octet) ) {
  75.     return find_encoding('utf8') unless $NoUTFAutoGuess;
  76.     Encode::_utf8_off($octet);
  77.     }
  78.     # cheat 1: BOM
  79.     use Encode::Unicode;
  80.     unless ($NoUTFAutoGuess) {
  81.     my $BOM = unpack('n', $octet);
  82.     return find_encoding('UTF-16')
  83.         if (defined $BOM and ($BOM == 0xFeFF or $BOM == 0xFFFe));
  84.     $BOM = unpack('N', $octet);
  85.     return find_encoding('UTF-32')
  86.         if (defined $BOM and ($BOM == 0xFeFF or $BOM == 0xFFFe0000));
  87.     if ($octet =~ /\x00/o){ # if \x00 found, we assume UTF-(16|32)(BE|LE)
  88.         my $utf;
  89.         my ($be, $le) = (0, 0);
  90.         if ($octet =~ /\x00\x00/o){ # UTF-32(BE|LE) assumed
  91.         $utf = "UTF-32";
  92.         for my $char (unpack('N*', $octet)){
  93.             $char & 0x0000ffff and $be++;
  94.             $char & 0xffff0000 and $le++;
  95.         }
  96.         }else{ # UTF-16(BE|LE) assumed
  97.         $utf = "UTF-16";
  98.         for my $char (unpack('n*', $octet)){
  99.             $char & 0x00ff and $be++;
  100.             $char & 0xff00 and $le++;
  101.         }
  102.         }
  103.         DEBUG and warn "$utf, be == $be, le == $le";
  104.         $be == $le 
  105.         and return
  106.             "Encodings ambiguous between $utf BE and LE ($be, $le)";
  107.         $utf .= ($be > $le) ? 'BE' : 'LE';
  108.         return find_encoding($utf);
  109.     }
  110.     }
  111.     my %try =  %{$obj->{Suspects}};
  112.     for my $c (@_){
  113.     my $e = find_encoding($c) or die "Unknown encoding: $c";
  114.     $try{$e->name} = $e;
  115.     DEBUG and warn "Added: ", $e->name;
  116.     }
  117.     my $nline = 1;
  118.     for my $line (split /\r\n?|\n/, $octet){
  119.     # cheat 2 -- \e in the string
  120.     if ($line =~ /\e/o){
  121.         my @keys = keys %try;
  122.         delete @try{qw/utf8 ascii/};
  123.         for my $k (@keys){
  124.         ref($try{$k}) eq 'Encode::XS' and delete $try{$k};
  125.         }
  126.     }
  127.     my %ok = %try;
  128.     # warn join(",", keys %try);
  129.     for my $k (keys %try){
  130.         my $scratch = $line;
  131.         $try{$k}->decode($scratch, FB_QUIET);
  132.         if ($scratch eq ''){
  133.         DEBUG and warn sprintf("%4d:%-24s ok\n", $nline, $k);
  134.         }else{
  135.         use bytes ();
  136.         DEBUG and 
  137.             warn sprintf("%4d:%-24s not ok; %d bytes left\n", 
  138.                  $nline, $k, bytes::length($scratch));
  139.         delete $ok{$k};
  140.         }
  141.     }
  142.     %ok or return "No appropriate encodings found!";
  143.     if (scalar(keys(%ok)) == 1){
  144.         my ($retval) = values(%ok);
  145.         return $retval;
  146.     }
  147.     %try = %ok; $nline++;
  148.     }
  149.     $try{ascii} or 
  150.     return  "Encodings too ambiguous: ", join(" or ", keys %try);
  151.     return $try{ascii};
  152. }
  153.  
  154.  
  155.  
  156. 1;
  157. __END__
  158.  
  159. =head1 NAME
  160.  
  161. Encode::Guess -- Guesses encoding from data
  162.  
  163. =head1 SYNOPSIS
  164.  
  165.   # if you are sure $data won't contain anything bogus
  166.  
  167.   use Encode;
  168.   use Encode::Guess qw/euc-jp shiftjis 7bit-jis/;
  169.   my $utf8 = decode("Guess", $data);
  170.   my $data = encode("Guess", $utf8);   # this doesn't work!
  171.  
  172.   # more elaborate way
  173.   use Encode::Guess;
  174.   my $enc = guess_encoding($data, qw/euc-jp shiftjis 7bit-jis/);
  175.   ref($enc) or die "Can't guess: $enc"; # trap error this way
  176.   $utf8 = $enc->decode($data);
  177.   # or
  178.   $utf8 = decode($enc->name, $data)
  179.  
  180. =head1 ABSTRACT
  181.  
  182. Encode::Guess enables you to guess in what encoding a given data is
  183. encoded, or at least tries to.  
  184.  
  185. =head1 DESCRIPTION
  186.  
  187. By default, it checks only ascii, utf8 and UTF-16/32 with BOM.
  188.  
  189.   use Encode::Guess; # ascii/utf8/BOMed UTF
  190.  
  191. To use it more practically, you have to give the names of encodings to
  192. check (I<suspects> as follows).  The name of suspects can either be
  193. canonical names or aliases.
  194.  
  195.  # tries all major Japanese Encodings as well
  196.   use Encode::Guess qw/euc-jp shiftjis 7bit-jis/;
  197.  
  198. If the C<$Encode::Guess::NoUTFAutoGuess> variable is set to a true
  199. value, no heuristics will be applied to UTF8/16/32, and the result
  200. will be limited to the suspects and C<ascii>.
  201.  
  202. =over 4
  203.  
  204. =item Encode::Guess->set_suspects
  205.  
  206. You can also change the internal suspects list via C<set_suspects>
  207. method. 
  208.  
  209.   use Encode::Guess;
  210.   Encode::Guess->set_suspects(qw/euc-jp shiftjis 7bit-jis/);
  211.  
  212. =item Encode::Guess->add_suspects
  213.  
  214. Or you can use C<add_suspects> method.  The difference is that
  215. C<set_suspects> flushes the current suspects list while
  216. C<add_suspects> adds.
  217.  
  218.   use Encode::Guess;
  219.   Encode::Guess->add_suspects(qw/euc-jp shiftjis 7bit-jis/);
  220.   # now the suspects are euc-jp,shiftjis,7bit-jis, AND
  221.   # euc-kr,euc-cn, and big5-eten
  222.   Encode::Guess->add_suspects(qw/euc-kr euc-cn big5-eten/);
  223.  
  224. =item Encode::decode("Guess" ...)
  225.  
  226. When you are content with suspects list, you can now
  227.  
  228.   my $utf8 = Encode::decode("Guess", $data);
  229.  
  230. =item Encode::Guess->guess($data)
  231.  
  232. But it will croak if:
  233.  
  234. =over
  235.  
  236. =item *
  237.  
  238. Two or more suspects remain
  239.  
  240. =item *
  241.  
  242. No suspects left
  243.  
  244. =back
  245.  
  246. So you should instead try this;
  247.  
  248.   my $decoder = Encode::Guess->guess($data);
  249.  
  250. On success, $decoder is an object that is documented in
  251. L<Encode::Encoding>.  So you can now do this;
  252.  
  253.   my $utf8 = $decoder->decode($data);
  254.  
  255. On failure, $decoder now contains an error message so the whole thing
  256. would be as follows;
  257.  
  258.   my $decoder = Encode::Guess->guess($data);
  259.   die $decoder unless ref($decoder);
  260.   my $utf8 = $decoder->decode($data);
  261.  
  262. =item guess_encoding($data, [, I<list of suspects>])
  263.  
  264. You can also try C<guess_encoding> function which is exported by
  265. default.  It takes $data to check and it also takes the list of
  266. suspects by option.  The optional suspect list is I<not reflected> to
  267. the internal suspects list.
  268.  
  269.   my $decoder = guess_encoding($data, qw/euc-jp euc-kr euc-cn/);
  270.   die $decoder unless ref($decoder);
  271.   my $utf8 = $decoder->decode($data);
  272.   # check only ascii and utf8
  273.   my $decoder = guess_encoding($data);
  274.  
  275. =back
  276.  
  277. =head1 CAVEATS
  278.  
  279. =over 4
  280.  
  281. =item *
  282.  
  283. Because of the algorithm used, ISO-8859 series and other single-byte
  284. encodings do not work well unless either one of ISO-8859 is the only
  285. one suspect (besides ascii and utf8).
  286.  
  287.   use Encode::Guess;
  288.   # perhaps ok
  289.   my $decoder = guess_encoding($data, 'latin1');
  290.   # definitely NOT ok
  291.   my $decoder = guess_encoding($data, qw/latin1 greek/);
  292.  
  293. The reason is that Encode::Guess guesses encoding by trial and error.
  294. It first splits $data into lines and tries to decode the line for each
  295. suspect.  It keeps it going until all but one encoding is eliminated
  296. out of suspects list.  ISO-8859 series is just too successful for most
  297. cases (because it fills almost all code points in \x00-\xff).
  298.  
  299. =item *
  300.  
  301. Do not mix national standard encodings and the corresponding vendor
  302. encodings.
  303.  
  304.   # a very bad idea
  305.   my $decoder
  306.      = guess_encoding($data, qw/shiftjis MacJapanese cp932/);
  307.  
  308. The reason is that vendor encoding is usually a superset of national
  309. standard so it becomes too ambiguous for most cases.
  310.  
  311. =item *
  312.  
  313. On the other hand, mixing various national standard encodings
  314. automagically works unless $data is too short to allow for guessing.
  315.  
  316.  # This is ok if $data is long enough
  317.  my $decoder =  
  318.   guess_encoding($data, qw/euc-cn
  319.                            euc-jp shiftjis 7bit-jis
  320.                            euc-kr
  321.                            big5-eten/);
  322.  
  323. =item *
  324.  
  325. DO NOT PUT TOO MANY SUSPECTS!  Don't you try something like this!
  326.  
  327.   my $decoder = guess_encoding($data, 
  328.                                Encode->encodings(":all"));
  329.  
  330. =back
  331.  
  332. It is, after all, just a guess.  You should alway be explicit when it
  333. comes to encodings.  But there are some, especially Japanese,
  334. environment that guess-coding is a must.  Use this module with care. 
  335.  
  336. =head1 TO DO
  337.  
  338. Encode::Guess does not work on EBCDIC platforms.
  339.  
  340. =head1 SEE ALSO
  341.  
  342. L<Encode>, L<Encode::Encoding>
  343.  
  344. =cut
  345.  
  346.