home *** CD-ROM | disk | FTP | other *** search
/ Netrunner 2004 October / NETRUNNER0410.ISO / regular / ActivePerl-5.8.4.810-MSWin32-x86.msi / _994c4bfef06e3340daee8acb1f689312 < prev    next >
Text File  |  2004-06-01  |  39KB  |  1,226 lines
  1. @rem = '--*-Perl-*--
  2. @echo off
  3. if "%OS%" == "Windows_NT" goto WinNT
  4. perl -x -S "%0" %1 %2 %3 %4 %5 %6 %7 %8 %9
  5. goto endofperl
  6. :WinNT
  7. perl -x -S %0 %*
  8. if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
  9. if %errorlevel% == 9009 echo You do not have Perl in your PATH.
  10. if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
  11. goto endofperl
  12. @rem ';
  13. #!perl
  14. #line 15
  15.     eval 'exec C:\TEMP\perl--------------------------------please-run-the-install-script--------------------------------\bin\perl.exe -S $0 ${1+"$@"}'
  16.     if $running_under_some_shell;
  17.  
  18. my $config_tag1 = 'v5.8.4 - Tue Jun  1 11:52:09 2004';
  19.  
  20. my $patchlevel_date = 1086115675;
  21. my $patch_tags = '+ACTIVEPERL_LOCAL_PATCHES_ENTRY +22751 +21540 ';
  22. my @patches = (
  23.     'ACTIVEPERL_LOCAL_PATCHES_ENTRY',
  24.     '22751 Update to Test.pm 1.25',
  25.     '21540 Fix backward-compatibility issues in if.pm'
  26. );
  27.  
  28. use Config;
  29. use File::Spec;        # keep perlbug Perl 5.005 compatible
  30. use Getopt::Std;
  31. use strict;
  32.  
  33. sub paraprint;
  34.  
  35. BEGIN {
  36.     eval "use Mail::Send;";
  37.     $::HaveSend = ($@ eq "");
  38.     eval "use Mail::Util;";
  39.     $::HaveUtil = ($@ eq "");
  40.     # use secure tempfiles wherever possible
  41.     eval "require File::Temp;";
  42.     $::HaveTemp = ($@ eq "");
  43. };
  44.  
  45. my $Version = "1.35";
  46.  
  47. # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
  48. # Changed in 1.07 to see more sendmail execs, and added pipe output.
  49. # Changed in 1.08 to use correct address for sendmail.
  50. # Changed in 1.09 to close the REP file before calling it up in the editor.
  51. #                 Also removed some old comments duplicated elsewhere.
  52. # Changed in 1.10 to run under VMS without Mail::Send; also fixed
  53. #                 temp filename generation.
  54. # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
  55. # Changed in 1.12 to check for editor errors, make save/send distinction
  56. #                 clearer and add $ENV{REPLYTO}.
  57. # Changed in 1.13 to hopefully make it more difficult to accidentally
  58. #                 send mail
  59. # Changed in 1.14 to make the prompts a little more clear on providing
  60. #                 helpful information. Also let file read fail gracefully.
  61. # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
  62. #                 Also report selected environment variables.
  63. # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
  64. # Changed in 1.17 Win32 support added.  GSAR 97-04-12
  65. # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
  66. # Changed in 1.19 '-ok' default not '-v'
  67. #                 add local patch information
  68. #                 warn on '-ok' if this is an old system; add '-okay'
  69. # Changed in 1.20 Added patchlevel.h reading and version/config checks
  70. # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
  71. # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
  72. # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
  73. # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
  74. # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
  75. # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
  76. # Changed in 1.27 Added Mac OS and File::Spec support CNANDOR 99-07-27
  77. # Changed in 1.28 Additional questions for Perlbugtron RFOLEY 20.03.2000
  78. # Changed in 1.29 Perlbug(tron): auto(-ok), short prompts RFOLEY 05-05-2000
  79. # Changed in 1.30 Added warnings on failure to open files MSTEVENS 13-07-2000
  80. # Changed in 1.31 Add checks on close().Fix my $var unless. TJENNESS 26-07-2000
  81. # Changed in 1.32 Use File::Spec->tmpdir TJENNESS 20-08-2000
  82. # Changed in 1.33 Don't require -t STDOUT for -ok.
  83. # Changed in 1.34 Added Message-Id RFOLEY 18-06-2002 
  84. # Changed in 1.35 Use File::Temp (patch from Solar Designer) NWCLARK 28-02-2004
  85.  
  86. # TODO: - Allow the user to re-name the file on mail failure, and
  87. #       make sure failure (transmission-wise) of Mail::Send is
  88. #       accounted for.
  89. #       - Test -b option
  90.  
  91. my( $file, $usefile, $cc, $address, $perlbug, $testaddress, $filename, $messageid, $domain,
  92.     $subject, $from, $verbose, $ed, $outfile, $Is_MacOS, $category, $severity,
  93.     $fh, $me, $Is_MSWin32, $Is_Linux, $Is_VMS, $msg, $body, $andcc, %REP, $ok,
  94.     $Is_OpenBSD);
  95.  
  96. my $perl_version = $^V ? sprintf("v%vd", $^V) : $];
  97.  
  98. my $config_tag2 = "$perl_version - $Config{cf_time}";
  99.  
  100. Init();
  101.  
  102. if ($::opt_h) { Help(); exit; }
  103. if ($::opt_d) { Dump(*STDOUT); exit; }
  104. if (!-t STDIN && !($ok and not $::opt_n)) {
  105.     paraprint <<EOF;
  106. Please use perlbug interactively. If you want to
  107. include a file, you can use the -f switch.
  108. EOF
  109.     die "\n";
  110. }
  111.  
  112. Query();
  113. Edit() unless $usefile || ($ok and not $::opt_n);
  114. NowWhat();
  115. Send();
  116.  
  117. exit;
  118.  
  119. sub ask_for_alternatives { # (category|severity)
  120.     my $name = shift;
  121.     my %alts = (
  122.     'category' => {
  123.         'default' => 'core',
  124.         'ok'      => 'install',
  125.         'opts'    => [qw(core docs install library utilities)], # patch, notabug
  126.     },
  127.     'severity' => {
  128.         'default' => 'low',
  129.         'ok'      => 'none',
  130.         'opts'    => [qw(critical high medium low wishlist none)], # zero
  131.     },
  132.     );
  133.     die "Invalid alternative($name) requested\n" unless grep(/^$name$/, keys %alts);
  134.     my $alt = "";
  135.     if ($ok) {
  136.     $alt = $alts{$name}{'ok'};
  137.     } else {
  138.      my @alts = @{$alts{$name}{'opts'}};
  139.     paraprint <<EOF;
  140. Please pick a \u$name from the following:
  141.  
  142.     @alts
  143.  
  144. EOF
  145.     my $err = 0;
  146.     do {
  147.         if ($err++ > 5) {
  148.         die "Invalid $name: aborting.\n";
  149.         }
  150.         print "Please enter a \u$name [$alts{$name}{'default'}]: ";
  151.         $alt = <>;
  152.         chomp $alt;
  153.         if ($alt =~ /^\s*$/) {
  154.         $alt = $alts{$name}{'default'};
  155.         }
  156.     } while !((($alt) = grep(/^$alt/i, @alts)));
  157.     }
  158.     lc $alt;
  159. }
  160.  
  161. sub Init {
  162.     # -------- Setup --------
  163.  
  164.     $Is_MSWin32 = $^O eq 'MSWin32';
  165.     $Is_VMS = $^O eq 'VMS';
  166.     $Is_Linux = lc($^O) eq 'linux';
  167.     $Is_OpenBSD = lc($^O) eq 'openbsd';
  168.     $Is_MacOS = $^O eq 'MacOS';
  169.  
  170.     @ARGV = split m/\s+/,
  171.         MacPerl::Ask('Provide command-line args here (-h for help):')
  172.         if $Is_MacOS && $MacPerl::Version =~ /App/;
  173.  
  174.     if (!getopts("Adhva:s:b:f:F:r:e:SCc:to:n:")) { Help(); exit; };
  175.  
  176.     # This comment is needed to notify metaconfig that we are
  177.     # using the $perladmin, $cf_by, and $cf_time definitions.
  178.  
  179.     # -------- Configuration ---------
  180.  
  181.     # perlbug address
  182.     $perlbug = 'perlbug@perl.org';
  183.  
  184.     # Test address
  185.     $testaddress = 'perlbug-test@perl.org';
  186.  
  187.     # Target address
  188.     $address = $::opt_a || ($::opt_t ? $testaddress : $perlbug);
  189.  
  190.     # Users address, used in message and in Reply-To header
  191.     $from = $::opt_r || "";
  192.  
  193.     # Include verbose configuration information
  194.     $verbose = $::opt_v || 0;
  195.  
  196.     # Subject of bug-report message
  197.     $subject = $::opt_s || "";
  198.  
  199.     # Send a file
  200.     $usefile = ($::opt_f || 0);
  201.  
  202.     # File to send as report
  203.     $file = $::opt_f || "";
  204.  
  205.     # File to output to
  206.     $outfile = $::opt_F || "";
  207.  
  208.     # Body of report
  209.     $body = $::opt_b || "";
  210.     
  211.     # Editor
  212.     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
  213.     || ($Is_VMS && "edit/tpu")
  214.     || ($Is_MSWin32 && "notepad")
  215.     || ($Is_MacOS && '')
  216.     || "vi";
  217.  
  218.     # Not OK - provide build failure template by finessing OK report
  219.     if ($::opt_n) {
  220.     if (substr($::opt_n, 0, 2) eq 'ok' )    {
  221.         $::opt_o = substr($::opt_n, 1);
  222.     } else {
  223.         Help();
  224.         exit();
  225.     }
  226.     }
  227.  
  228.     # OK - send "OK" report for build on this system
  229.     $ok = 0;
  230.     if ($::opt_o) {
  231.     if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
  232.         my $age = time - $patchlevel_date;
  233.         if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
  234.         my $date = localtime $patchlevel_date;
  235.         print <<"EOF";
  236. "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
  237. are more than 60 days old.  This Perl version was constructed on
  238. $date.  If you really want to report this, use
  239. "perlbug -okay" or "perlbug -nokay".
  240. EOF
  241.         exit();
  242.         }
  243.         # force these options
  244.         unless ($::opt_n) {
  245.         $::opt_S = 1; # don't prompt for send
  246.         $::opt_b = 1; # we have a body
  247.         $body = "Perl reported to build OK on this system.\n";
  248.         }
  249.         $::opt_C = 1; # don't send a copy to the local admin
  250.         $::opt_s = 1; # we have a subject line
  251.         $subject = ($::opt_n ? 'Not ' : '')
  252.             . "OK: perl $perl_version ${patch_tags}on"
  253.             ." $::Config{'archname'} $::Config{'osvers'} $subject";
  254.         $ok = 1;
  255.     } else {
  256.         Help();
  257.         exit();
  258.     }
  259.     }
  260.  
  261.     # Possible administrator addresses, in order of confidence
  262.     # (Note that cf_email is not mentioned to metaconfig, since
  263.     # we don't really want it. We'll just take it if we have to.)
  264.     #
  265.     # This has to be after the $ok stuff above because of the way
  266.     # that $::opt_C is forced.
  267.     $cc = $::opt_C ? "" : (
  268.     $::opt_c || $::Config{'perladmin'}
  269.     || $::Config{'cf_email'} || $::Config{'cf_by'}
  270.     );
  271.  
  272.     if ($::HaveUtil) {
  273.         $domain = Mail::Util::maildomain();
  274.     } elsif ($Is_MSWin32) {
  275.         $domain = $ENV{'USERDOMAIN'};
  276.     } else {
  277.         require Sys::Hostname;
  278.         $domain = Sys::Hostname::hostname();
  279.     }
  280.  
  281.     # Message-Id - rjsf
  282.     $messageid = "<$::Config{'version'}_${$}_".time."\@$domain>"; 
  283.  
  284.     # My username
  285.     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
  286.         : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
  287.         : $Is_MacOS ? $ENV{'USER'}
  288.         : eval { getpwuid($<) };    # May be missing
  289.  
  290.     $from = $::Config{'cf_email'}
  291.        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
  292.                ($me eq $::Config{'cf_by'});
  293. } # sub Init
  294.  
  295. sub Query {
  296.     # Explain what perlbug is
  297.     unless ($ok) {
  298.     paraprint <<EOF;
  299. This program provides an easy way to create a message reporting a bug
  300. in perl, and e-mail it to $address.  It is *NOT* intended for
  301. sending test messages or simply verifying that perl works, *NOR* is it
  302. intended for reporting bugs in third-party perl modules.  It is *ONLY*
  303. a means of reporting verifiable problems with the core perl distribution,
  304. and any solutions to such problems, to the people who maintain perl.
  305.  
  306. If you're just looking for help with perl, try posting to the Usenet
  307. newsgroup comp.lang.perl.misc.  If you're looking for help with using
  308. perl with CGI, try posting to comp.infosystems.www.programming.cgi.
  309. EOF
  310.     }
  311.  
  312.     # Prompt for subject of message, if needed
  313.     
  314.     if (TrivialSubject($subject)) {
  315.     $subject = '';
  316.     }
  317.  
  318.     unless ($subject) {
  319.     paraprint <<EOF;
  320. First of all, please provide a subject for the
  321. message. It should be a concise description of
  322. the bug or problem. "perl bug" or "perl problem"
  323. is not a concise description.
  324. EOF
  325.  
  326.     my $err = 0;
  327.     do {
  328.         print "Subject: ";
  329.         $subject = <>;
  330.         chomp $subject;
  331.         if ($err++ == 5) {
  332.         die "Aborting.\n";
  333.         }
  334.     } while (TrivialSubject($subject));
  335.     }
  336.  
  337.     # Prompt for return address, if needed
  338.     unless ($from) {
  339.     # Try and guess return address
  340.     my $guess;
  341.  
  342.     $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
  343.         if ($Is_MacOS) {
  344.             require Mac::InternetConfig;
  345.             $guess = $Mac::InternetConfig::InternetConfig{
  346.                 Mac::InternetConfig::kICEmail()
  347.             };
  348.         }
  349.  
  350.     unless ($guess) {
  351.         # move $domain to where we can use it elsewhere    
  352.         if ($domain) {
  353.         if ($Is_VMS && !$::Config{'d_socket'}) {
  354.             $guess = "$domain\:\:$me";
  355.         } else {
  356.             $guess = "$me\@$domain" if $domain;
  357.         }
  358.         }
  359.     }
  360.  
  361.     if ($guess) {
  362.         unless ($ok) {
  363.         paraprint <<EOF;
  364. Your e-mail address will be useful if you need to be contacted. If the
  365. default shown is not your full internet e-mail address, please correct it.
  366. EOF
  367.         }
  368.     } else {
  369.         paraprint <<EOF;
  370. So that you may be contacted if necessary, please enter
  371. your full internet e-mail address here.
  372. EOF
  373.     }
  374.  
  375.     if ($ok && $guess) {
  376.         # use it
  377.         $from = $guess;
  378.     } else {
  379.         # verify it
  380.         print "Your address [$guess]: ";
  381.         $from = <>;
  382.         chomp $from;
  383.         $from = $guess if $from eq '';
  384.     }
  385.     }
  386.  
  387.     if ($from eq $cc or $me eq $cc) {
  388.     # Try not to copy ourselves
  389.     $cc = "yourself";
  390.     }
  391.  
  392.     # Prompt for administrator address, unless an override was given
  393.     if( !$::opt_C and !$::opt_c ) {
  394.     paraprint <<EOF;
  395. A copy of this report can be sent to your local
  396. perl administrator. If the address is wrong, please
  397. correct it, or enter 'none' or 'yourself' to not send
  398. a copy.
  399. EOF
  400.     print "Local perl administrator [$cc]: ";
  401.     my $entry = scalar <>;
  402.     chomp $entry;
  403.  
  404.     if ($entry ne "") {
  405.         $cc = $entry;
  406.         $cc = '' if $me eq $cc;
  407.     }
  408.     }
  409.  
  410.     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
  411.     $andcc = " and $cc" if $cc;
  412.  
  413.     # Prompt for editor, if no override is given
  414. editor:
  415.     unless ($::opt_e || $::opt_f || $::opt_b) {
  416.     paraprint <<EOF;
  417. Now you need to supply the bug report. Try to make
  418. the report concise but descriptive. Include any
  419. relevant detail. If you are reporting something
  420. that does not work as you think it should, please
  421. try to include example of both the actual
  422. result, and what you expected.
  423.  
  424. Some information about your local
  425. perl configuration will automatically be included
  426. at the end of the report. If you are using any
  427. unusual version of perl, please try and confirm
  428. exactly which versions are relevant.
  429.  
  430. You will probably want to use an editor to enter
  431. the report. If "$ed" is the editor you want
  432. to use, then just press Enter, otherwise type in
  433. the name of the editor you would like to use.
  434.  
  435. If you would like to use a prepared file, type
  436. "file", and you will be asked for the filename.
  437. EOF
  438.     print "Editor [$ed]: ";
  439.     my $entry =scalar <>;
  440.     chomp $entry;
  441.  
  442.     $usefile = 0;
  443.     if ($entry eq "file") {
  444.         $usefile = 1;
  445.     } elsif ($entry ne "") {
  446.         $ed = $entry;
  447.     }
  448.     }
  449.  
  450.     # Prompt for category of bug
  451.     $category ||= ask_for_alternatives('category');
  452.  
  453.     # Prompt for severity of bug
  454.     $severity ||= ask_for_alternatives('severity');
  455.  
  456.     # Generate scratch file to edit report in
  457.     $filename = filename();
  458.  
  459.     # Prompt for file to read report from, if needed
  460.     if ($usefile and !$file) {
  461. filename:
  462.     paraprint <<EOF;
  463. What is the name of the file that contains your report?
  464. EOF
  465.     print "Filename: ";
  466.     my $entry = scalar <>;
  467.     chomp $entry;
  468.  
  469.     if ($entry eq "") {
  470.         paraprint <<EOF;
  471. No filename? I'll let you go back and choose an editor again.
  472. EOF
  473.         goto editor;
  474.     }
  475.  
  476.     unless (-f $entry and -r $entry) {
  477.         paraprint <<EOF;
  478. I'm sorry, but I can't read from `$entry'. Maybe you mistyped the name of
  479. the file? If you don't want to send a file, just enter a blank line and you
  480. can get back to the editor selection.
  481. EOF
  482.         goto filename;
  483.     }
  484.     $file = $entry;
  485.     }
  486.  
  487.     # Generate report
  488.     open(REP,">$filename") or die "Unable to create report file `$filename': $!\n";
  489.     my $reptype = !$ok ? "bug" : $::opt_n ? "build failure" : "success";
  490.  
  491.     print REP <<EOF;
  492. This is a $reptype report for perl from $from,
  493. generated with the help of perlbug $Version running under perl $perl_version.
  494.  
  495. EOF
  496.  
  497.     if ($body) {
  498.     print REP $body;
  499.     } elsif ($usefile) {
  500.     open(F, "<$file")
  501.         or die "Unable to read report file from `$file': $!\n";
  502.     while (<F>) {
  503.         print REP $_
  504.     }
  505.     close(F) or die "Error closing `$file': $!";
  506.     } else {
  507.     print REP <<EOF;
  508.  
  509. -----------------------------------------------------------------
  510. [Please enter your report here]
  511.  
  512.  
  513.  
  514. [Please do not change anything below this line]
  515. -----------------------------------------------------------------
  516. EOF
  517.     }
  518.     Dump(*REP);
  519.     close(REP) or die "Error closing report file: $!";
  520.  
  521.     # read in the report template once so that
  522.     # we can track whether the user does any editing.
  523.     # yes, *all* whitespace is ignored.
  524.     open(REP, "<$filename") or die "Unable to open report file `$filename': $!\n";
  525.     while (<REP>) {
  526.     s/\s+//g;
  527.     $REP{$_}++;
  528.     }
  529.     close(REP) or die "Error closing report file `$filename': $!";
  530. } # sub Query
  531.  
  532. sub Dump {
  533.     local(*OUT) = @_;
  534.  
  535.     print OUT <<EFF;
  536. ---
  537. Flags:
  538.     category=$category
  539.     severity=$severity
  540. EFF
  541.     if ($::opt_A) {
  542.     print OUT <<EFF;
  543.     ack=no
  544. EFF
  545.     }
  546.     print OUT <<EFF;
  547. ---
  548. EFF
  549.     print OUT "This perlbug was built using Perl $config_tag1\n",
  550.         "It is being executed now by  Perl $config_tag2.\n\n"
  551.     if $config_tag2 ne $config_tag1;
  552.  
  553.     print OUT <<EOF;
  554. Site configuration information for perl $perl_version:
  555.  
  556. EOF
  557.     if ($::Config{cf_by} and $::Config{cf_time}) {
  558.     print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
  559.     }
  560.     print OUT Config::myconfig;
  561.  
  562.     if (@patches) {
  563.     print OUT join "\n    ", "Locally applied patches:", @patches;
  564.     print OUT "\n";
  565.     };
  566.  
  567.     print OUT <<EOF;
  568.  
  569. ---
  570. \@INC for perl $perl_version:
  571. EOF
  572.     for my $i (@INC) {
  573.     print OUT "    $i\n";
  574.     }
  575.  
  576.     print OUT <<EOF;
  577.  
  578. ---
  579. Environment for perl $perl_version:
  580. EOF
  581.     my @env =
  582.         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
  583.     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
  584.     push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
  585.     my %env;
  586.     @env{@env} = @env;
  587.     for my $env (sort keys %env) {
  588.     print OUT "    $env",
  589.         exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
  590.         "\n";
  591.     }
  592.     if ($verbose) {
  593.     print OUT "\nComplete configuration data for perl $perl_version:\n\n";
  594.     my $value;
  595.     foreach (sort keys %::Config) {
  596.         $value = $::Config{$_};
  597.         $value =~ s/'/\\'/g;
  598.         print OUT "$_='$value'\n";
  599.     }
  600.     }
  601. } # sub Dump
  602.  
  603. sub Edit {
  604.     # Edit the report
  605.     if ($usefile || $body) {
  606.     paraprint <<EOF;
  607. Please make sure that the name of the editor you want to use is correct.
  608. EOF
  609.     print "Editor [$ed]: ";
  610.     my $entry =scalar <>;
  611.     chomp $entry;
  612.     $ed = $entry unless $entry eq '';
  613.     }
  614.  
  615. tryagain:
  616.     my $sts;
  617.     $sts = system("$ed $filename") unless $Is_MacOS;
  618.     if ($Is_MacOS) {
  619.         require ExtUtils::MakeMaker;
  620.         ExtUtils::MM_MacOS::launch_file($filename);
  621.         paraprint <<EOF;
  622. Press Enter when done.
  623. EOF
  624.         scalar <>;
  625.     }
  626.     if ($sts) {
  627.     paraprint <<EOF;
  628. The editor you chose (`$ed') could apparently not be run!
  629. Did you mistype the name of your editor? If so, please
  630. correct it here, otherwise just press Enter.
  631. EOF
  632.     print "Editor [$ed]: ";
  633.     my $entry =scalar <>;
  634.     chomp $entry;
  635.  
  636.     if ($entry ne "") {
  637.         $ed = $entry;
  638.         goto tryagain;
  639.     } else {
  640.         paraprint <<EOF;
  641. You may want to save your report to a file, so you can edit and mail it
  642. yourself.
  643. EOF
  644.     }
  645.     }
  646.  
  647.     return if ($ok and not $::opt_n) || $body;
  648.     # Check that we have a report that has some, eh, report in it.
  649.     my $unseen = 0;
  650.  
  651.     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
  652.     # a strange way to check whether any significant editing
  653.     # have been done: check whether any new non-empty lines
  654.     # have been added. Yes, the below code ignores *any* space
  655.     # in *any* line.
  656.     while (<REP>) {
  657.     s/\s+//g;
  658.     $unseen++ if $_ ne '' and not exists $REP{$_};
  659.     }
  660.  
  661.     while ($unseen == 0) {
  662.     paraprint <<EOF;
  663. I am sorry but it looks like you did not report anything.
  664. EOF
  665.     print "Action (Retry Edit/Cancel) ";
  666.     my ($action) = scalar(<>);
  667.     if ($action =~ /^[re]/i) { # <R>etry <E>dit
  668.         goto tryagain;
  669.     } elsif ($action =~ /^[cq]/i) { # <C>ancel, <Q>uit
  670.         Cancel();
  671.     }
  672.     }
  673. } # sub Edit
  674.  
  675. sub Cancel {
  676.     1 while unlink($filename);  # remove all versions under VMS
  677.     print "\nCancelling.\n";
  678.     exit(0);
  679. }
  680.  
  681. sub NowWhat {
  682.     # Report is done, prompt for further action
  683.     if( !$::opt_S ) {
  684.     while(1) {
  685.         paraprint <<EOF;
  686. Now that you have completed your report, would you like to send
  687. the message to $address$andcc, display the message on
  688. the screen, re-edit it, display/change the subject,
  689. or cancel without sending anything?
  690. You may also save the message as a file to mail at another time.
  691. EOF
  692.       retry:
  693.         print "Action (Send/Display/Edit/Subject/Save to File): ";
  694.         my $action = scalar <>;
  695.         chomp $action;
  696.  
  697.         if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
  698.         my $file_save = $outfile || "perlbug.rep";
  699.         print "\n\nName of file to save message in [$file_save]: ";
  700.         my $file = scalar <>;
  701.         chomp $file;
  702.         $file = $file_save if $file eq "";
  703.  
  704.         unless (open(FILE, ">$file")) {
  705.             print "\nError opening $file: $!\n\n";
  706.             goto retry;
  707.         }
  708.         open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
  709.         print FILE "To: $address\nSubject: $subject\n";
  710.         print FILE "Cc: $cc\n" if $cc;
  711.         print FILE "Reply-To: $from\n" if $from;
  712.         print FILE "Message-Id: $messageid\n" if $messageid;
  713.         print FILE "\n";
  714.         while (<REP>) { print FILE }
  715.         close(REP) or die "Error closing report file `$filename': $!";
  716.         close(FILE) or die "Error closing $file: $!";
  717.  
  718.         print "\nMessage saved in `$file'.\n";
  719.         exit;
  720.         } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
  721.         # Display the message
  722.         open(REP, "<$filename") or die "Couldn't open file `$filename': $!\n";
  723.         while (<REP>) { print $_ }
  724.         close(REP) or die "Error closing report file `$filename': $!";
  725.         } elsif ($action =~ /^su/i) { # <Su>bject
  726.         print "Subject: $subject\n";
  727.         print "If the above subject is fine, just press Enter.\n";
  728.         print "If not, type in the new subject.\n";
  729.         print "Subject: ";
  730.         my $reply = scalar <STDIN>;
  731.         chomp $reply;
  732.         if ($reply ne '') {
  733.             unless (TrivialSubject($reply)) {
  734.             $subject = $reply;
  735.             print "Subject: $subject\n";
  736.             }
  737.         }
  738.         } elsif ($action =~ /^se/i) { # <S>end
  739.         # Send the message
  740.         print "Are you certain you want to send this message?\n"
  741.             . 'Please type "yes" if you are: ';
  742.         my $reply = scalar <STDIN>;
  743.         chomp $reply;
  744.         if ($reply eq "yes") {
  745.             last;
  746.         } else {
  747.             paraprint <<EOF;
  748. That wasn't a clear "yes", so I won't send your message. If you are sure
  749. your message should be sent, type in "yes" (without the quotes) at the
  750. confirmation prompt.
  751. EOF
  752.         }
  753.         } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
  754.         # edit the message
  755.         Edit();
  756.         } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
  757.         Cancel();
  758.         } elsif ($action =~ /^s/i) {
  759.         paraprint <<EOF;
  760. I'm sorry, but I didn't understand that. Please type "send" or "save".
  761. EOF
  762.         }
  763.     }
  764.     }
  765. } # sub NowWhat
  766.  
  767. sub TrivialSubject {
  768.     my $subject = shift;
  769.     if ($subject =~
  770.     /^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
  771.     length($subject) < 4 ||
  772.     $subject !~ /\s/) {
  773.     print "\nThat doesn't look like a good subject.  Please be more verbose.\n\n";
  774.         return 1;
  775.     } else {
  776.     return 0;
  777.     }
  778. }
  779.  
  780. sub Send {
  781.     # Message has been accepted for transmission -- Send the message
  782.     if ($outfile) {
  783.     open SENDMAIL, ">$outfile" or die "Couldn't open '$outfile': $!\n";
  784.     goto sendout;
  785.     }
  786.  
  787.     # on linux certain mail implementations won't accept the subject
  788.     # as "~s subject" and thus the Subject header will be corrupted
  789.     # so don't use Mail::Send to be safe
  790.     if ($::HaveSend && !$Is_Linux && !$Is_OpenBSD) {
  791.     $msg = new Mail::Send Subject => $subject, To => $address;
  792.     $msg->cc($cc) if $cc;
  793.     $msg->add("Reply-To",$from) if $from;
  794.  
  795.     $fh = $msg->open;
  796.     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
  797.     while (<REP>) { print $fh $_ }
  798.     close(REP) or die "Error closing $filename: $!";
  799.     $fh->close;
  800.  
  801.     print "\nMessage sent.\n";
  802.     } elsif ($Is_VMS) {
  803.     if ( ($address =~ /@/ and $address !~ /^\w+%"/) or
  804.          ($cc      =~ /@/ and $cc      !~ /^\w+%"/) ) {
  805.         my $prefix;
  806.         foreach (qw[ IN MX SMTP UCX PONY WINS ], '') {
  807.         $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
  808.         }
  809.         $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
  810.         $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
  811.     }
  812.     $subject =~ s/"/""/g; $address =~ s/"/""/g; $cc =~ s/"/""/g;
  813.     my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
  814.     if ($sts) {
  815.         die <<EOF;
  816. Can't spawn off mail
  817.     (leaving bug report in $filename): $sts
  818. EOF
  819.     }
  820.     } else {
  821.     my $sendmail = "";
  822.     for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
  823.         $sendmail = $_, last if -e $_;
  824.     }
  825.     if ($^O eq 'os2' and $sendmail eq "") {
  826.         my $path = $ENV{PATH};
  827.         $path =~ s:\\:/: ;
  828.         my @path = split /$Config{'path_sep'}/, $path;
  829.         for (@path) {
  830.         $sendmail = "$_/sendmail", last if -e "$_/sendmail";
  831.         $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
  832.         }
  833.     }
  834.  
  835.     paraprint(<<"EOF"), die "\n" if $sendmail eq "";
  836. I am terribly sorry, but I cannot find sendmail, or a close equivalent, and
  837. the perl package Mail::Send has not been installed, so I can't send your bug
  838. report. We apologize for the inconvenience.
  839.  
  840. So you may attempt to find some way of sending your message, it has
  841. been left in the file `$filename'.
  842. EOF
  843.     open(SENDMAIL, "|$sendmail -t -oi") || die "'|$sendmail -t -oi' failed: $!";
  844. sendout:
  845.     print SENDMAIL "To: $address\n";
  846.     print SENDMAIL "Subject: $subject\n";
  847.     print SENDMAIL "Cc: $cc\n" if $cc;
  848.     print SENDMAIL "Reply-To: $from\n" if $from;
  849.     print SENDMAIL "Message-Id: $messageid\n" if $messageid;
  850.     print SENDMAIL "\n\n";
  851.     open(REP, "<$filename") or die "Couldn't open `$filename': $!\n";
  852.     while (<REP>) { print SENDMAIL $_ }
  853.     close(REP) or die "Error closing $filename: $!";
  854.  
  855.     if (close(SENDMAIL)) {
  856.         printf "\nMessage %s.\n", $outfile ? "saved" : "sent";
  857.     } else {
  858.         warn "\nSendmail returned status '", $? >> 8, "'\n";
  859.     }
  860.     }
  861.     1 while unlink($filename);  # remove all versions under VMS
  862. } # sub Send
  863.  
  864. sub Help {
  865.     print <<EOF;
  866.  
  867. A program to help generate bug reports about perl5, and mail them.
  868. It is designed to be used interactively. Normally no arguments will
  869. be needed.
  870.  
  871. Usage:
  872. $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
  873.     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
  874. $0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]
  875.  
  876. Simplest usage:  run "$0", and follow the prompts.
  877.  
  878. Options:
  879.  
  880.   -v    Include Verbose configuration data in the report
  881.   -f    File containing the body of the report. Use this to
  882.         quickly send a prepared message.
  883.   -F    File to output the resulting mail message to, instead of mailing.
  884.   -S    Send without asking for confirmation.
  885.   -a    Address to send the report to. Defaults to `$address'.
  886.   -c    Address to send copy of report to. Defaults to `$cc'.
  887.   -C    Don't send copy to administrator.
  888.   -s    Subject to include with the message. You will be prompted
  889.         if you don't supply one on the command line.
  890.   -b    Body of the report. If not included on the command line, or
  891.         in a file with -f, you will get a chance to edit the message.
  892.   -r    Your return address. The program will ask you to confirm
  893.         this if you don't give it here.
  894.   -e    Editor to use.
  895.   -t    Test mode. The target address defaults to `$testaddress'.
  896.   -d    Data mode.  This prints out your configuration data, without mailing
  897.         anything. You can use this with -v to get more complete data.
  898.   -A    Don't send a bug received acknowledgement to the return address.
  899.   -ok   Report successful build on this system to perl porters
  900.         (use alone or with -v). Only use -ok if *everything* was ok:
  901.         if there were *any* problems at all, use -nok.
  902.   -okay As -ok but allow report from old builds.
  903.   -nok  Report unsuccessful build on this system to perl porters
  904.         (use alone or with -v). You must describe what went wrong
  905.         in the body of the report which you will be asked to edit.
  906.   -nokay As -nok but allow report from old builds.
  907.   -h    Print this help message.
  908.  
  909. EOF
  910. }
  911.  
  912. sub filename {
  913.     if ($::HaveTemp) {
  914.     # Good. Use a secure temp file
  915.     my ($fh, $filename) = File::Temp::tempfile(UNLINK => 1);
  916.     close($fh);
  917.     return $filename;
  918.     } else {
  919.     # Bah. Fall back to doing things less securely.
  920.     my $dir = File::Spec->tmpdir();
  921.     $filename = "bugrep0$$";
  922.     $filename++ while -e File::Spec->catfile($dir, $filename);
  923.     $filename = File::Spec->catfile($dir, $filename);
  924.     }
  925. }
  926.  
  927. sub paraprint {
  928.     my @paragraphs = split /\n{2,}/, "@_";
  929.     print "\n\n";
  930.     for (@paragraphs) {   # implicit local $_
  931.     s/(\S)\s*\n/$1 /g;
  932.     write;
  933.     print "\n";
  934.     }
  935. }
  936.  
  937. format STDOUT =
  938. ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
  939. $_
  940. .
  941.  
  942. __END__
  943.  
  944. =head1 NAME
  945.  
  946. perlbug - how to submit bug reports on Perl
  947.  
  948. =head1 SYNOPSIS
  949.  
  950. B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
  951. S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
  952. S<[ B<-r> I<returnaddress> ]>
  953. S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
  954. S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-A> ]>  S<[ B<-h> ]>
  955.  
  956. B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
  957.  S<[ B<-A> ]> S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
  958.  
  959. =head1 DESCRIPTION
  960.  
  961. A program to help generate bug reports about perl or the modules that
  962. come with it, and mail them.
  963.  
  964. If you have found a bug with a non-standard port (one that was not part
  965. of the I<standard distribution>), a binary distribution, or a
  966. non-standard module (such as Tk, CGI, etc), then please see the
  967. documentation that came with that distribution to determine the correct
  968. place to report bugs.
  969.  
  970. C<perlbug> is designed to be used interactively. Normally no arguments
  971. will be needed.  Simply run it, and follow the prompts.
  972.  
  973. If you are unable to run B<perlbug> (most likely because you don't have
  974. a working setup to send mail that perlbug recognizes), you may have to
  975. compose your own report, and email it to B<perlbug@perl.org>.  You might
  976. find the B<-d> option useful to get summary information in that case.
  977.  
  978. In any case, when reporting a bug, please make sure you have run through
  979. this checklist:
  980.  
  981. =over 4
  982.  
  983. =item What version of Perl you are running?
  984.  
  985. Type C<perl -v> at the command line to find out.
  986.  
  987. =item Are you running the latest released version of perl?
  988.  
  989. Look at http://www.perl.com/ to find out.  If it is not the latest
  990. released version, get that one and see whether your bug has been
  991. fixed.  Note that bug reports about old versions of Perl, especially
  992. those prior to the 5.0 release, are likely to fall upon deaf ears.
  993. You are on your own if you continue to use perl1 .. perl4.
  994.  
  995. =item Are you sure what you have is a bug?
  996.  
  997. A significant number of the bug reports we get turn out to be documented
  998. features in Perl.  Make sure the behavior you are witnessing doesn't fall
  999. under that category, by glancing through the documentation that comes
  1000. with Perl (we'll admit this is no mean task, given the sheer volume of
  1001. it all, but at least have a look at the sections that I<seem> relevant).
  1002.  
  1003. Be aware of the familiar traps that perl programmers of various hues
  1004. fall into.  See L<perltrap>.
  1005.  
  1006. Check in L<perldiag> to see what any Perl error message(s) mean.
  1007. If message isn't in perldiag, it probably isn't generated by Perl.
  1008. Consult your operating system documentation instead.
  1009.  
  1010. If you are on a non-UNIX platform check also L<perlport>, as some
  1011. features may be unimplemented or work differently.
  1012.  
  1013. Try to study the problem under the Perl debugger, if necessary.
  1014. See L<perldebug>.
  1015.  
  1016. =item Do you have a proper test case?
  1017.  
  1018. The easier it is to reproduce your bug, the more likely it will be
  1019. fixed, because if no one can duplicate the problem, no one can fix it.
  1020. A good test case has most of these attributes: fewest possible number
  1021. of lines; few dependencies on external commands, modules, or
  1022. libraries; runs on most platforms unimpeded; and is self-documenting.
  1023.  
  1024. A good test case is almost always a good candidate to be on the perl
  1025. test suite.  If you have the time, consider making your test case so
  1026. that it will readily fit into the standard test suite.
  1027.  
  1028. Remember also to include the B<exact> error messages, if any.
  1029. "Perl complained something" is not an exact error message.
  1030.  
  1031. If you get a core dump (or equivalent), you may use a debugger
  1032. (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
  1033. report.  NOTE: unless your Perl has been compiled with debug info
  1034. (often B<-g>), the stack trace is likely to be somewhat hard to use
  1035. because it will most probably contain only the function names and not
  1036. their arguments.  If possible, recompile your Perl with debug info and
  1037. reproduce the dump and the stack trace.
  1038.  
  1039. =item Can you describe the bug in plain English?
  1040.  
  1041. The easier it is to understand a reproducible bug, the more likely it
  1042. will be fixed.  Anything you can provide by way of insight into the
  1043. problem helps a great deal.  In other words, try to analyze the
  1044. problem (to the extent you can) and report your discoveries.
  1045.  
  1046. =item Can you fix the bug yourself?
  1047.  
  1048. A bug report which I<includes a patch to fix it> will almost
  1049. definitely be fixed.  Use the C<diff> program to generate your patches
  1050. (C<diff> is being maintained by the GNU folks as part of the B<diffutils>
  1051. package, so you should be able to get it from any of the GNU software
  1052. repositories).  If you do submit a patch, the cool-dude counter at
  1053. perlbug@perl.org will register you as a savior of the world.  Your
  1054. patch may be returned with requests for changes, or requests for more
  1055. detailed explanations about your fix.
  1056.  
  1057. Here are some clues for creating quality patches: Use the B<-c> or
  1058. B<-u> switches to the diff program (to create a so-called context or
  1059. unified diff).  Make sure the patch is not reversed (the first
  1060. argument to diff is typically the original file, the second argument
  1061. your changed file).  Make sure you test your patch by applying it with
  1062. the C<patch> program before you send it on its way.  Try to follow the
  1063. same style as the code you are trying to patch.  Make sure your patch
  1064. really does work (C<make test>, if the thing you're patching supports
  1065. it).
  1066.  
  1067. =item Can you use C<perlbug> to submit the report?
  1068.  
  1069. B<perlbug> will, amongst other things, ensure your report includes
  1070. crucial information about your version of perl.  If C<perlbug> is unable
  1071. to mail your report after you have typed it in, you may have to compose
  1072. the message yourself, add the output produced by C<perlbug -d> and email
  1073. it to B<perlbug@perl.org>.  If, for some reason, you cannot run
  1074. C<perlbug> at all on your system, be sure to include the entire output
  1075. produced by running C<perl -V> (note the uppercase V).
  1076.  
  1077. Whether you use C<perlbug> or send the email manually, please make
  1078. your Subject line informative.  "a bug" not informative.  Neither is
  1079. "perl crashes" nor "HELP!!!".  These don't help.
  1080. A compact description of what's wrong is fine.
  1081.  
  1082. =back
  1083.  
  1084. Having done your bit, please be prepared to wait, to be told the bug
  1085. is in your code, or even to get no reply at all.  The Perl maintainers
  1086. are busy folks, so if your problem is a small one or if it is difficult
  1087. to understand or already known, they may not respond with a personal reply.
  1088. If it is important to you that your bug be fixed, do monitor the
  1089. C<Changes> file in any development releases since the time you submitted
  1090. the bug, and encourage the maintainers with kind words (but never any
  1091. flames!).  Feel free to resend your bug report if the next released
  1092. version of perl comes out and your bug is still present.
  1093.  
  1094. =head1 OPTIONS
  1095.  
  1096. =over 8
  1097.  
  1098. =item B<-a>
  1099.  
  1100. Address to send the report to.  Defaults to B<perlbug@perl.org>.
  1101.  
  1102. =item B<-A>
  1103.  
  1104. Don't send a bug received acknowledgement to the reply address.
  1105. Generally it is only a sensible to use this option if you are a
  1106. perl maintainer actively watching perl porters for your message to
  1107. arrive.
  1108.  
  1109. =item B<-b>
  1110.  
  1111. Body of the report.  If not included on the command line, or
  1112. in a file with B<-f>, you will get a chance to edit the message.
  1113.  
  1114. =item B<-C>
  1115.  
  1116. Don't send copy to administrator.
  1117.  
  1118. =item B<-c>
  1119.  
  1120. Address to send copy of report to.  Defaults to the address of the
  1121. local perl administrator (recorded when perl was built).
  1122.  
  1123. =item B<-d>
  1124.  
  1125. Data mode (the default if you redirect or pipe output).  This prints out
  1126. your configuration data, without mailing anything.  You can use this
  1127. with B<-v> to get more complete data.
  1128.  
  1129. =item B<-e>
  1130.  
  1131. Editor to use.
  1132.  
  1133. =item B<-f>
  1134.  
  1135. File containing the body of the report.  Use this to quickly send a
  1136. prepared message.
  1137.  
  1138. =item B<-F>
  1139.  
  1140. File to output the results to instead of sending as an email. Useful
  1141. particularly when running perlbug on a machine with no direct internet
  1142. connection.
  1143.  
  1144. =item B<-h>
  1145.  
  1146. Prints a brief summary of the options.
  1147.  
  1148. =item B<-ok>
  1149.  
  1150. Report successful build on this system to perl porters. Forces B<-S>
  1151. and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
  1152. prompts for a return address if it cannot guess it (for use with
  1153. B<make>). Honors return address specified with B<-r>.  You can use this
  1154. with B<-v> to get more complete data.   Only makes a report if this
  1155. system is less than 60 days old.
  1156.  
  1157. =item B<-okay>
  1158.  
  1159. As B<-ok> except it will report on older systems.
  1160.  
  1161. =item B<-nok>
  1162.  
  1163. Report unsuccessful build on this system.  Forces B<-C>.  Forces and
  1164. supplies a value for B<-s>, then requires you to edit the report
  1165. and say what went wrong.  Alternatively, a prepared report may be
  1166. supplied using B<-f>.  Only prompts for a return address if it
  1167. cannot guess it (for use with B<make>). Honors return address
  1168. specified with B<-r>.  You can use this with B<-v> to get more
  1169. complete data.  Only makes a report if this system is less than 60
  1170. days old.
  1171.  
  1172. =item B<-nokay>
  1173.  
  1174. As B<-nok> except it will report on older systems.
  1175.  
  1176. =item B<-r>
  1177.  
  1178. Your return address.  The program will ask you to confirm its default
  1179. if you don't use this option.
  1180.  
  1181. =item B<-S>
  1182.  
  1183. Send without asking for confirmation.
  1184.  
  1185. =item B<-s>
  1186.  
  1187. Subject to include with the message.  You will be prompted if you don't
  1188. supply one on the command line.
  1189.  
  1190. =item B<-t>
  1191.  
  1192. Test mode.  The target address defaults to B<perlbug-test@perl.org>.
  1193.  
  1194. =item B<-v>
  1195.  
  1196. Include verbose configuration data in the report.
  1197.  
  1198. =back
  1199.  
  1200. =head1 AUTHORS
  1201.  
  1202. Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently I<doc>tored
  1203. by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>), Tom Christiansen
  1204. (E<lt>tchrist@perl.comE<gt>), Nathan Torkington (E<lt>gnat@frii.comE<gt>),
  1205. Charles F. Randall (E<lt>cfr@pobox.comE<gt>), Mike Guy
  1206. (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop (E<lt>domo@computer.orgE<gt>),
  1207. Hugo van der Sanden (E<lt>hv@crypt.org<gt>),
  1208. Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
  1209. (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
  1210. and Richard Foley (E<lt>richard@rfi.netE<gt>).
  1211.  
  1212. =head1 SEE ALSO
  1213.  
  1214. perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
  1215. diff(1), patch(1), dbx(1), gdb(1)
  1216.  
  1217. =head1 BUGS
  1218.  
  1219. None known (guess what must have been used to report them?)
  1220.  
  1221. =cut
  1222.  
  1223.  
  1224. __END__
  1225. :endofperl
  1226.