home *** CD-ROM | disk | FTP | other *** search
/ World of Graphics / WOGRAPH.BIN / 575.MAKEQLB.BAT < prev    next >
DOS Batch File  |  1993-03-21  |  3KB  |  109 lines
  1. ECHO OFF
  2.  
  3. IF NOT "%1"=="" GOTO START
  4. ECHO  
  5. ECHO MAKEQLB takes TheDraw QuickBasic object files and incorporates them into a
  6. ECHO QuickBasic Library (for use in the integrated environment), plus a parallel
  7. ECHO link library (.LIB) file.  Non-TheDraw object files and libraries may also
  8. ECHO be included if you desire.
  9. ECHO  
  10. ECHO The following files must be present in the same directory:
  11. ECHO   LINK.EXE, LIB.EXE, BQLB40.LIB or BQLB45.LIB, QB4UTIL.LIB, and
  12. ECHO   the object files you want in the libraries.
  13. ECHO  
  14. ECHO ─────────────────────────────────────────────────────────────────────────── 
  15. ECHO  
  16. ECHO Usage:    MAKEQLB library [file1] [file2] [file3] etc...
  17. ECHO  
  18. ECHO           Do not put a file extension in the "library" parameter, as
  19. ECHO           the extensions .QLB and .LIB are assumed.
  20. ECHO  
  21. ECHO  
  22. ECHO Example:  MAKEQLB test image1.OBJ image2.OBJ image3.OBJ mycode.LIB
  23. ECHO  
  24. ECHO           Produces TEST.QLB -and- TEST.LIB containing the three object
  25. ECHO           files plus the contents of the library file MYCODE.LIB.
  26. ECHO  
  27. GOTO DONE
  28.  
  29. :START
  30. IF NOT EXIST LINK.EXE GOTO MISSINGFILE
  31. IF NOT EXIST LIB.EXE GOTO MISSINGFILE
  32. IF NOT EXIST QB4UTIL.LIB GOTO MISSINGFILE
  33. IF EXIST BQLB40.LIB GOTO GOTFILES
  34. IF EXIST BQLB45.LIB GOTO GOTFILES
  35.  
  36. :MISSINGFILE
  37. ECHO  
  38. ECHO Error!  MAKEQLB needs all of the following files in the current directory:
  39. ECHO   LINK.EXE
  40. ECHO   LIB.EXE
  41. ECHO   BQLB40.LIB (for QuickBasic v4.0) or BQLB45.LIB (for QuickBasic v4.5)
  42. ECHO   QB4UTIL.LIB
  43. ECHO   TheDraw object files (.OBJ) to include in libraries
  44. ECHO  
  45. ECHO Processing halted.
  46. GOTO DONE
  47.  
  48. :GOTFILES
  49. ECHO  
  50. ECHO Processing TheDraw Quick Library...
  51. SET libname=%1
  52. IF NOT EXIST %libname%.LIB GOTO NEWLIB
  53. ECHO Updating:  %libname%.LIB
  54. GOTO LIBLOOP
  55.  
  56. :NEWLIB
  57. ECHO Creating:  %libname%.LIB
  58. LIB %libname%.LIB+QB4UTIL.LIB; >ERRLOG
  59. IF ERRORLEVEL==1 GOTO LIBERROR
  60. GOTO LIBLOOP
  61.  
  62. :LIBOK
  63. SHIFT
  64. :LIBLOOP
  65. IF "%2"=="" GOTO QLBMAKE
  66. IF EXIST %2 GOTO LIBADD
  67. IF EXIST %2.OBJ GOTO LIBADD
  68. IF NOT EXIST %2.LIB GOTO INVALIDPARAM
  69.  
  70. :LIBADD
  71. ECHO   Adding:  %2
  72. LIB %libname%.LIB -%2; >ERRLOG
  73. LIB %libname%.LIB +%2; >ERRLOG
  74. IF NOT ERRORLEVEL==1 GOTO LIBOK
  75.  
  76. :LIBERROR
  77. ECHO  
  78. ECHO Fault occured while attempting to add "%2" to library "%libname%.LIB".
  79. TYPE ERRLOG
  80. IF EXIST ERRLOG DEL ERRLOG
  81. ECHO  
  82. ECHO To end processing, press [CTRL-C] or
  83. PAUSE
  84. GOTO LIBOK
  85.  
  86. :INVALIDPARAM
  87. ECHO  
  88. ECHO Aborting.  Unable to find any object file or library named: %2
  89. GOTO Done
  90.  
  91. :QLBMAKE
  92. IF EXIST %libname%.QLB ECHO Updating:  %libname%.QLB
  93. IF NOT EXIST %libname%.QLB ECHO Creating:  %libname%.QLB
  94. IF EXIST BQLB40.LIB LINK /Q /NOE /NOD %libname%.LIB, %libname%.QLB,ERRLOG.MAP,BQLB40.LIB; >ERRLOG
  95. IF EXIST BQLB45.LIB LINK /Q /NOE /NOD %libname%.LIB, %libname%.QLB,ERRLOG.MAP,BQLB45.LIB; >ERRLOG
  96. IF NOT ERRORLEVEL==1 GOTO QLBDONE
  97.  
  98. ECHO  
  99. ECHO Fault occured while creating quick library "%libname%.QLB".
  100. TYPE ERRLOG
  101.  
  102. :QLBDONE
  103. IF EXIST %libname%.BAK DEL %libname%.BAK
  104. SET LIBNAME=
  105.  
  106. :DONE
  107. IF EXIST ERRLOG DEL ERRLOG
  108. IF EXIST ERRLOG.MAP DEL ERRLOG.MAP
  109.