bombers.k12.ar.us/bombers.k12.ar.us.tar/bombers.k12.ar.us/survey_unconfigured/CopyItemAction.asp

Text File | 2006-10-25 | 14KB | 346 lines

<!--#Include File="Include/Top_inc.asp"-->
<%
'***********************************************************************
'   Application: SelectSurveyASP Advanced v8.1.11
'   Author: Aaron Baril for ClassApps.com
'   Page Description: This page works with CopyItem.asp, and process the
'                     form that allows users to create a new item by copying
'                      an existing item.  After creating the new item, the
'                      user is redirect to the page Item.asp to edit the item.
'
'   COPYRIGHT NOTICE
'
'   See attached Software License Agreement
'
'   (c) Copyright 2002 - 2006 by ClassApps.com.  All rights reserved.
'***********************************************************************
%>
<!--#Include File="Include/Config_inc.asp"-->
<!--#Include File="Include/Utility_inc.asp"-->
<!--#Include File="Include/adovbs_inc.asp"-->
<!--#Include File="Include/ID_inc.asp"-->
<!--#Include File="Include/CurrentUser_inc.asp"-->
<!--#Include File="Include/SurveySecurity_inc.asp"-->
<!--#Include File="Include/SurveyUtility_inc.asp"-->
<!--#Include File="Include/Constants_inc.asp"-->
<%
    Dim strSQL
    Dim conItem
    Dim rsOriginal
    Dim lngNewItemID
    Dim lngOriginalItemID
    Dim lngSurveyID
    Dim lngLibraryID
    Dim lngPageNumber
    Dim lngItemTypeID
    Dim strMinimumValue
    Dim strMaximumValue
    Dim lngMinimumNumberResponses
    Dim lngMaximumNumberResponses
    Dim lngRowTextWidth
    Dim lngMaximumLength
    Dim lngAnswerTotal
    Dim lngSubitemCount
    Dim strImageHeight
    Dim strItemAlias
    Dim strOtherText
    Dim strOtherDisplayType
    Dim lngNewAnswerID
    Dim lngNewSubitemID
    Dim lngAnswerValue
    Dim flgLibrary
    Dim flgHasResponses

    'Determine whether the item being copied is in a library or a survey
    If Len(Request.Form("LibraryID")) > 0 Then
        lngLibraryID = Request.Form("LibraryID")
        flgLibrary = True
        flgHasResponses = False
    ElseIf Len(Request.Form("cboLibrary")) > 0 Then
        'This is the case when inserting an item from a library
        lngSurveyID = Request.Form("OriginalSurveyID")
        flgLibrary = False
        flgHasResponses = HasResponses(lngSurveyID)
    Else
        'Get the survey ID
        If Len(Request.Form("OriginalSurveyID")) > 0 Then
            lngSurveyID = Request.Form("OriginalSurveyID")
        Else
            lngSurveyID = Request.Form("SurveyID")
        End If
        flgLibrary = False
        flgHasResponses = HasResponses(lngSurveyID)
    End If

    'Do not allow a user to copy an item in a survey that already has responses.  Instead, redirect the user back
    'to the modify survey page
    If flgHasResponses = True Then
        Response.Redirect "ModifySurvey.asp?SurveyID=" & lngSurveyID
    End If

    'Initialization
    Set rsOriginal = Server.CreateObject("ADODB.Recordset")
    Set conItem = Server.CreateObject("ADODB.Connection")
    conItem.Open SURVEY_APP_CONNECTION

    'If the survey is being copied from the ModifySurvey.asp page, the item ID will be in a form variable called ItemID.
    'Otherwise, the item was selected from a combo box.
    If Len(Request.Form("cboItem")) = 0 Then
        lngOriginalItemID = Request.Form("ItemID")
    Else
        lngOriginalItemID = Request.Form("cboItem")
    End If

    'Get ID for a new item
    lngNewItemID = ID_GetNextAvailableID("SurveyGenerationItem")

    'Copy all of the data from the item table (SUR_ITEM)
    strSQL = "SELECT * FROM sur_item WHERE item_id = " & lngOriginalItemID
    rsOriginal.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenDynamic, adLockReadOnly, adCmdText
    rsOriginal.MoveFirst
    lngItemTypeID = rsOriginal("item_type_id")
    strOtherText = rsOriginal("other_text")
    If IsNull(strOtherText) = True Then
        strOtherText = ""
    End If
    strOtherDisplayType = rsOriginal("other_display_type")
    If IsNull(strOtherDisplayType) = True Then
        strOtherDisplayType = ""
    End If

    If Len(rsOriginal("minimum_value")) = 0 Or IsNull(rsOriginal("minimum_value")) = True Then
        strMinimumValue = ""
    Else
        strMinimumValue = rsOriginal("minimum_value")
    End If

    If Len(rsOriginal("maximum_value")) = 0 Or IsNull(rsOriginal("maximum_value")) = True Then
        strMaximumValue = ""
    Else
        strMaximumValue = rsOriginal("maximum_value")
    End If

    If Len(rsOriginal("answer_total")) = 0 Or IsNull(rsOriginal("answer_total")) = True Then
        lngAnswerTotal = "Null"
    Else
        lngAnswerTotal = rsOriginal("answer_total")
    End If

    If Len(rsOriginal("subitem_count")) = 0 Or IsNull(rsOriginal("subitem_count")) = True Then
        lngSubitemCount = "Null"
    Else
        lngSubitemCount = rsOriginal("subitem_count")
    End If

    If Len(rsOriginal("minimum_number_responses")) = 0 Or IsNull(rsOriginal("minimum_number_responses")) = True Then
        lngMinimumNumberResponses = "Null"
    Else
        lngMinimumNumberResponses = rsOriginal("minimum_number_responses")
    End If

    If Len(rsOriginal("maximum_number_responses")) = 0 Or IsNull(rsOriginal("maximum_number_responses")) = True Then
        lngMaximumNumberResponses = "Null"
    Else
        lngMaximumNumberResponses = rsOriginal("maximum_number_responses")
    End If

    If Len(rsOriginal("row_text_width")) = 0 Or IsNull(rsOriginal("row_text_width")) = True Then
        lngRowTextWidth = "Null"
    Else
        lngRowTextWidth = rsOriginal("row_text_width")
    End If

    If Len(rsOriginal("maximum_length")) = 0 Or IsNull(rsOriginal("maximum_length")) = True Then
        lngMaximumLength = "Null"
    Else
        lngMaximumLength = rsOriginal("maximum_length")
    End If

    If Len(rsOriginal("image_height")) = 0 Or IsNull(rsOriginal("image_height")) = True Then
        strImageHeight = ""
    Else
        strImageHeight = rsOriginal("image_height")
    End If

    If Len(rsOriginal("item_alias")) = 0 Or IsNull(rsOriginal("item_alias")) = True Then
        strItemAlias = ""
    Else
        strItemAlias = rsOriginal("item_alias")
    End If

    'Create the item in the SUR_ITEM table
    strSQL = "INSERT INTO sur_item(item_id, item_type_id, item_alias, required_yn, random_answer_order_yn, " & _
                "email_address_yn, other_yn, other_text, other_display_type, minimum_value, maximum_value, " & _
                "answer_total, minimum_number_responses, maximum_number_responses, row_text_width, maximum_length, " & _
                "display_format, image_path, image_width, image_height, image_alignment, default_value, " & _
                "database_dsn, subitem_count, item_sub_text, database_sql, item_text) VALUES(" & _
                lngNewItemID & ", " & _
                rsOriginal("item_type_id") & ", " & _
                SQLEncode(strItemAlias) & ", " & _
                SQLEncode(rsOriginal("required_yn")) & ", " & _
                SQLEncode(rsOriginal("random_answer_order_yn")) & ", " & _
                SQLEncode(rsOriginal("email_address_yn")) & ", " & _
                SQLEncode(rsOriginal("other_yn")) & ", " & _
                SQLEncode(strOtherText) & ", " & _
                SQLEncode(strOtherDisplayType) & ", " & _
                SQLEncode(strMinimumValue) & ", " & _
                SQLEncode(strMaximumValue) & ", " & _
                lngAnswerTotal & ", " & _
                lngMinimumNumberResponses & ", " & _
                lngMaximumNumberResponses & ", " & _
                lngRowTextWidth & ", " & _
                lngMaximumLength & ", " & _
                SQLEncode(rsOriginal("display_format")) & ", " & _
                SQLEncode(rsOriginal("image_path")) & ", " & _
                SQLEncode(rsOriginal("image_width")) & ", " & _
                SQLEncode(strImageHeight) & ", " & _
                SQLEncode(rsOriginal("image_alignment")) & ", " & _
                SQLEncode(rsOriginal("default_value")) & ", " & _
                SQLEncode(rsOriginal("database_dsn")) & ", " & _
                lngSubitemCount & ", " & _
                SQLEncode(rsOriginal("item_sub_text")) & ", " & _
                SQLEncode(rsOriginal("database_sql")) & ", " & _
                SQLEncode(rsOriginal("item_text")) & ")"
    conItem.Execute ConvertSQL(strSQL), , adCmdText
    rsOriginal.Close

    'Move all the other items down one, so that we can insert the new item in the right location.  Note that
    'new items are always inserted AT the order number indicated, which means that all existing items
    'with that order number or higher have to have their order numbers incremented by 1.
    If flgLibrary = True Then
        strSQL = "UPDATE sur_library_to_item_mapping SET order_number = order_number + 1 WHERE order_number >= " & Request.Form("OrderNumber") & " AND library_id = " & lngLibraryID
    Else
        strSQL = "UPDATE sur_survey_to_item_mapping SET order_number = order_number + 1 WHERE order_number >= " & Request.Form("OrderNumber") & " AND survey_id = " & lngSurveyID
    End If
    conItem.Execute ConvertSQL(strSQL), , adCmdText

    'If the "NewPage" form value is set to "Yes", then the new item should be inserted on a new page.  The new page
    'number will be one greater than the page number passed in.  All pages after this page must be bumped down.
    If Request.Form("NewPage") = "Yes" Then
        strSQL = "UPDATE sur_survey_to_item_mapping " & _
                    "SET page_number = page_number + 1 " & _
                    "WHERE survey_id = " & lngSurveyID & _
                    " AND page_number > " & Request.Form("PageNumber")
        conItem.Execute ConvertSQL(strSQL), , adCmdText

        'Increment the page number for all page conditions for this survey that are greater than the page just created
        strSQL = "UPDATE sur_page_condition " & _
                    "SET page_number = page_number + 1 " & _
                    "WHERE survey_id = " & lngSurveyID & _
                    " AND page_number > " & Request.Form("PageNumber")
        conItem.Execute ConvertSQL(strSQL), , adCmdText

        'Increment the page number for all page properties for this survey that are greater than the page just created
        strSQL = "UPDATE sur_page " & _
                    "SET page_number = page_number + 1 " & _
                    "WHERE survey_id = " & lngSurveyID & _
                    " AND page_number > " & Request.Form("PageNumber")
        conItem.Execute ConvertSQL(strSQL), , adCmdText

        lngPageNumber = CLng(Request.Form("PageNumber")) + 1
    Else
        lngPageNumber = Request.Form("PageNumber")
    End If

    'Insert an entry into the mapping table (either SUR_SURVEY_TO_ITEM_MAPPING or SUR_LIBRARY_TO_ITEM_MAPPING).
    If flgLibrary = True Then
        strSQL = "INSERT INTO sur_library_to_item_mapping(library_id, item_id, order_number) VALUES(" & _
                    lngLibraryID & ", " & lngNewItemID & ", " & Request.Form("OrderNumber") & ")"
    Else
        strSQL = "INSERT INTO sur_survey_to_item_mapping(survey_id, item_id, order_number, page_number) VALUES(" & _
                    lngSurveyID & ", " & lngNewItemID & ", " & Request.Form("OrderNumber") & ", " & lngPageNumber & ")"
    End If
    conItem.Execute ConvertSQL(strSQL), , adCmdText

    'If the item type contains multiple answers, record the answers in the database.
    If CLng(lngItemTypeID) = SUR_ITEM_SINGLE_SELECT_DROPDOWN Or CLng(lngItemTypeID) = SUR_ITEM_MULTISELECT_CHECKBOXES Or CLng(lngItemTypeID) = SUR_ITEM_SINGLE_SELECT_OPTIONS Or CLng(lngItemTypeID) = SUR_ITEM_MATRIX_SINGLE_SELECT_OPTIONS Or CLng(lngItemTypeID) = SUR_ITEM_MATRIX_MULTISELECT_CHECKBOXES Or CLng(lngItemTypeID) = SUR_ITEM_MATRIX_TEXT_BOXES Then
        'Copy all of the answers from the item table (SUR_ITEM_ANSWER)
        strSQL = "SELECT * FROM sur_item_answer WHERE item_id = " & lngOriginalItemID
        rsOriginal.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenForwardOnly, adLockReadOnly, adCmdText
        rsOriginal.MoveFirst

        'Loop through the answers, and insert each into the SUR_ITEM_ANSWER table as answers to the new question
        Do While Not rsOriginal.EOF
            'Get the next available answer ID
            lngNewAnswerID = ID_GetNextAvailableID("SurveyGenerationAnswer")

            'Get the answer value
            If IsNull(rsOriginal("answer_value")) = True Then
                lngAnswerValue = "Null"
            Else
                lngAnswerValue = rsOriginal("answer_value")
            End If

            strSQL = "INSERT INTO sur_item_answer(item_id, answer_id, answer_text, answer_value, order_number, " & _
                        "default_yn) VALUES(" & _
                        lngNewItemID & ", " & _
                        lngNewAnswerID & ", " & _
                        SQLEncode(rsOriginal("answer_text")) & ", " & _
                        lngAnswerValue & ", " & _
                        rsOriginal("order_number") & ", " & _
                        SQLEncode(rsOriginal("default_yn")) & ")"
            conItem.Execute ConvertSQL(strSQL), , adCmdText
            rsOriginal.MoveNext
        Loop

        'Clean up
        rsOriginal.Close
    End If

    'If the item type contains subitems, record the subitems in the database.
    If CLng(lngItemTypeID) = SUR_ITEM_CONSTANT_SUM Or CLng(lngItemTypeID) = SUR_ITEM_RANKING Or CLng(lngItemTypeID) = SUR_ITEM_OPEN_ENDED_ONE_OR_MORE_LINES Or CLng(lngItemTypeID) = SUR_ITEM_MATRIX_SINGLE_SELECT_OPTIONS Or CLng(lngItemTypeID) = SUR_ITEM_MATRIX_RATING_SCALE Or CLng(lngItemTypeID) = SUR_ITEM_MATRIX_MULTISELECT_CHECKBOXES Or CLng(lngItemTypeID) = SUR_ITEM_MATRIX_TEXT_BOXES Then
        'Copy all of subitems from the submitem table (SUR_SUBITEM)
        strSQL = "SELECT * FROM sur_subitem WHERE item_id = " & lngOriginalItemID
        rsOriginal.Open ConvertSQL(strSQL), SURVEY_APP_CONNECTION, adOpenForwardOnly, adLockReadOnly, adCmdText
        rsOriginal.MoveFirst

        'Loop through the submitems, and insert each into the SUR_SUBITEM table as subitems for the new question
        Do While Not rsOriginal.EOF
            'Get the next available subitem ID
            lngNewSubitemID = ID_GetNextAvailableID("SurveyGenerationSubitem")

            strSQL = "INSERT INTO sur_subitem(subitem_id, item_id, subitem_text, order_number) VALUES(" & _
                        lngNewSubitemID & ", " & _
                        lngNewItemID & ", " & _
                        SQLEncode(rsOriginal("subitem_text")) & ", " & _
                        rsOriginal("order_number") & ")"
            conItem.Execute ConvertSQL(strSQL), , adCmdText
            rsOriginal.MoveNext
        Loop

        'Clean up
        rsOriginal.Close
    End If

    'Clean up
    conItem.Close
    Set conItem = Nothing
    Set rsOriginal = Nothing

    'For libraries, redirect back to the modify library page
    If flgLibrary = True Then
        Response.Redirect "ModifyLibrary.asp?LibraryID=" & lngLibraryID & "&#ItemID" & lngNewItemID
    Else
        'If the item was created by copying from the ModifySurvey.asp page, redirect back to that page; otherwise,
        'redirect to the new item so that it can be modified.
        If Len(Request.Form("ReturnToModifySurvey")) > 0 Then
            Response.Redirect "ModifySurvey.asp?SurveyID=" & lngSurveyID & "&#ItemID" & lngNewItemID
        Else
%>
            <html>
            <body onload="javascript:document.forms['frmItem'].submit();">
                <form name="frmItem" action="Item.asp" method="post">
                    <input type="hidden" name="State" value="<%=SUR_STATE_EDIT%>">
                    <input type="hidden" name="ItemID" value="<%=lngNewItemID%>">
                    <input type="hidden" name="SurveyID" value="<%=lngSurveyID%>">
                </form>
            </body>
            </html>
<%
        End If
    End If

    'Ensure that the web server returns the page
    Response.Flush
%>