ftp.tcs3.com/ftp.tcs3.com.tar/ftp.tcs3.com/DRIVERS/Audio/Office2010/InfoPath.en-us/InfLR.cab/IPDSINTL.DLL_1033/HTML/INSPECTORALLFIELDS.XSL

Extensible Markup Language | 2010-03-29 | 29KB | 553 lines

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<!-- _lcid="1033" _version="" -->
<!-- _LocalBinding -->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" xmlns:my="http://schemas.microsoft.com/office/infopath/2006/inspec" version="1.0">
    <xsl:output encoding="UTF-8" method="xml"/>

    <xsl:template match="/">
        <table width="100%"><tr><td><div height="100%" width="100%">
            <xsl:variable name="numberOfCalculations" select="count(my:Inspector/my:Calculation)"/>
            <xsl:variable name="numberOfValidations" select="count(my:Inspector/my:DataValidation)"/>
            <xsl:variable name="numberOfBusinessLogic" select="count(my:Inspector/my:BusinessLogic)"/>
            <xsl:variable name="numberOfRules" select="count(my:Inspector/my:Rule)"/>

            <div class="overallFrameHeading">
                <table><tr><td width="18px" valign="top" style="padding-top:3px">
                <xsl:call-template name="OutputPlusMinus">
                    <xsl:with-param name="label">ValidationOverall</xsl:with-param>
                </xsl:call-template></td>
                <td valign="top"><span class="overallFramePrimaryTitle"><!-- _locID_text="InspectorOverallValidation" _locComment="{StringCategory=TXT}The Rule on this field that ensures that the entered data is valid" -->Validation</span>
                    <xsl:if test="/my:Inspector/@DataValidationsErrored='true'">
                        <span class="errorProcessing"><!-- _locID_text="InspectorOverallProcessingError1" _locComment="{StringCategory=TXT}There was an error processing these constructs" --> - Processing error</span>
                    </xsl:if>
                </td></tr></table>
            </div>
            <div></div>
            <div class="indentBar" id="ValidationOverall">
                <table width="100%">
                    <xsl:if test="$numberOfValidations=0">
                        <tr>
                            <td class="overallFrameIndentBar" />
                            <td class="overallFrameBar" />
                            <td class="overallFrameBackground">
                                <div class="indent"><span class="none"><!-- _locID_text="InspectorOverallNone1" _locComment="{StringCategory=TXT}There is no Rule associated with this node." -->None</span></div>
                            </td>
                        </tr>
                    </xsl:if>
                    <xsl:if test="not($numberOfValidations=0)">
                        <xsl:apply-templates select="my:Inspector/my:DataValidation">
                            <xsl:sort select="/my:Inspector/my:Field[my:Source/*=current()/@ID]/@ShortName"/>
                        </xsl:apply-templates>
                    </xsl:if>
                </table>
            </div>

            <div class="overallFrameHeading">
                <table><tr><td width="18px" valign="top" style="padding-top:3px">
                <xsl:call-template name="OutputPlusMinus">
                    <xsl:with-param name="label">CalcsOverall</xsl:with-param>
                </xsl:call-template>
                </td>
                <td valign="top"><span class="overallFramePrimaryTitle"><!-- _locID_text="InspectorOverallDefault" _locComment="{StringCategory=TXT}The default value for the field" -->Calculated Default Values</span>
                    <xsl:if test="/my:Inspector/@CalculationsErrored='true'">
                        <span class="errorProcessing"><!-- _locID_text="InspectorOverallProcessingError2" _locComment="{StringCategory=TXT}There was an error processing these constructs" --> - Processing error</span>
                    </xsl:if>
                </td></tr></table>
            </div>
            <div></div>
            <div class="indentBar" id="CalcsOverall">
                <table width="100%">
                    <tr>
                        <td class="overallFrameIndentBar" />
                        <td class="overallFrameBar" />
                        <td class="overallFrameBackground">
                            <xsl:if test="$numberOfCalculations=0">
                                <div class="indent"><span class="none"><!-- _locID_text="InspectorOverallNone2" _locComment="{StringCategory=TXT}There is no Rule associated with this node." -->None</span></div>
                            </xsl:if>
                            <xsl:if test="not($numberOfCalculations=0)">
                                <xsl:apply-templates select="my:Inspector/my:Calculation">
                                    <xsl:sort select="/my:Inspector/my:Field[@ID=current()/@Target]/@ShortName"/>
                                </xsl:apply-templates>
                            </xsl:if>
                        </td>
                    </tr>
                </table>
            </div>

            <div class="overallFrameHeading">
                <table><tr><td width="18px" valign="top" style="padding-top:3px">
                <xsl:call-template name="OutputPlusMinus">
                    <xsl:with-param name="label">RulesOverall</xsl:with-param>
                </xsl:call-template></td>
                <td valign="top"><span class="overallFramePrimaryTitle"><!-- _locID_text="InspectorOverallRules" _locComment="{StringCategory=TXT}The Rule that is triggered on this field (eg. sets a field value, displays a message, etc)" -->Actions</span>
                    <xsl:if test="/my:Inspector/@RulesErrored='true'">
                        <span class="errorProcessing"><!-- _locID_text="InspectorOverallProcessingError3" _locComment="{StringCategory=TXT}There was an error processing these constructs" --> - Processing error</span>
                    </xsl:if>
                </td></tr></table>
            </div>
            <div></div>
            <div class="indentBar" id="RulesOverall">
                <table width="100%">
                    <xsl:if test="$numberOfRules=0">
                        <tr>
                            <td class="overallFrameIndentBar" />
                            <td class="overallFrameBar" />
                            <td class="overallFrameBackground">
                                <div class="indent"><span class="none"><!-- _locID_text="InspectorOverallNone3" _locComment="{StringCategory=TXT}There is no Rule associated with this node." -->None</span></div>
                            </td>
                        </tr>
                    </xsl:if>
                    <xsl:if test="not($numberOfRules=0)">
                        <xsl:apply-templates select="my:Inspector/my:Rule">
                            <xsl:sort select="/my:Inspector/*[my:Source/*=current()/@ID]/@Group"/>
                            <xsl:sort select="/my:Inspector/*[my:Source/*=current()/@ID]/@ShortName"/>
                        </xsl:apply-templates>
                    </xsl:if>
                </table>
            </div>

            <div class="overallFrameHeading">
                <table><tr><td width="18px" valign="top" style="padding-top:3px">
                    <xsl:call-template name="OutputPlusMinus">
                        <xsl:with-param name="label">BusinessOverall</xsl:with-param>
                    </xsl:call-template>
                </td>
                <td valign="top">
                    <span class="overallFramePrimaryTitle"><!-- _locID_text="InspectorOverallLogic" _locComment="{StringCategory=TXT}The user-written functionality (C# / VB / Jscript)" -->Programming</span>
                    <xsl:if test="/my:Inspector/@BusinessLogicErrored='true'">
                        <span class="errorProcessing"><!-- _locID_text="InspectorOverallProcessingError4" _locComment="{StringCategory=TXT}There was an error processing these constructs" --> - Processing error</span>
                    </xsl:if>
                    <xsl:if test="/my:Inspector/@LogicNeedConversion='true'">
                        <span class="errorProcessing"><!-- _locID_text="InspectorOverallVersionMigrationRequired" _locComment="{StringCategory=TXT}This Rule requires migration to a newer version" --> - Version migration required</span>
                    </xsl:if>
                </td></tr></table>
            </div>
            <div></div>
            <div class="indentBar" id="BusinessOverall">
                <table width="100%">
                    <tr>
                        <td class="overallFrameIndentBar" />
                        <td class="overallFrameBar" />
                        <td class="overallFrameBackground">
                            <xsl:if test="$numberOfBusinessLogic=0">
                                <div class="indent"><span class="none"><!-- _locID_text="InspectorOverallNone4" _locComment="{StringCategory=TXT}There is no Rule associated with this node." -->None</span></div>
                            </xsl:if>
                            <xsl:if test="not($numberOfBusinessLogic=0)">
                                <xsl:apply-templates select="my:Inspector/my:BusinessLogic">
                                    <xsl:sort select="/my:Inspector/*[my:Source/*=current()/@ID]/@Group"/>
                                    <xsl:sort select="/my:Inspector/*[my:Source/*=current()/@ID]/@ShortName"/>
                                </xsl:apply-templates>
                            </xsl:if>
                        </td>
                    </tr>
                </table>
            </div>
        </div></td></tr></table>
    </xsl:template>

    <xsl:template name="EscapeWhiteSpace">
        <xsl:param name="TextWithWhiteSpace"></xsl:param>
        <xsl:choose>
            <!-- we're checking for double space as well as tab-->
            <xsl:when test="contains($TextWithWhiteSpace, '  ') or contains($TextWithWhiteSpace, '    ')">
                <xsl:variable name="thisValue" select="translate($TextWithWhiteSpace, ' ', ' ')" />
                <xsl:value-of select="translate($thisValue, '    ', ' ')" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$TextWithWhiteSpace" />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="my:InvalidField" mode="ComplexExpression">
        <span class="actionError"><!-- _locID_text="InspectorOverallInvalidField" _locComment="{StringCategory=TXT}The field is invalid." -->Invalid Field</span>
    </xsl:template>

    <xsl:template name="UnknownField">
        <span class="normalText" title="This field cannot be identified by the Rule Inspector. Certain XPath expressions cause this error, although they might work when filling out the form. Preview the form to verify that the rule works as expected."><!-- _locID@title="InspectorUnknownFieldTitle"  _locComment="{StringCategory=TXT}This field could not be determined by the Rule Inspector when designing the form template. When designing, certain XPaths cannot be resolved although they may work when filling out the form. Preview the form to verify that the field works as expected." --><!-- _locID_text="InspectorUnknownField" _locComment="{StringCategory=TXT}We couldn't find the node that this maps to." -->[Not Found]</span>
    </xsl:template>

    <xsl:template name="Filtered">
        <span class="normalText"><!-- _locID_text="InspectorFieldFiltered" _locComment="{StringCategory=TXT}There is a filter applied on this node." -->[Filtered]</span>
    </xsl:template>

    <xsl:template match="my:ID" mode="ComplexExpression">
        <xsl:call-template name="PrintFieldLink">
            <xsl:with-param name="Primary">
                <xsl:value-of select="'false'"/>
            </xsl:with-param>
            <xsl:with-param name="ComplexID">
                <xsl:value-of select="."/>
            </xsl:with-param>
            <xsl:with-param name="Filtered">
                <xsl:value-of select="@Filtered"/>
            </xsl:with-param>
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="PrintFieldLink">
        <xsl:param name="Primary"/>
        <xsl:param name="ComplexID"></xsl:param>
        <xsl:param name="Filtered" select="'false'"/>
        <xsl:variable name="linkClass">
            <xsl:choose>
                <xsl:when test="$Primary = 'true'">linkPrimary</xsl:when>
                <xsl:otherwise>linkSecondary</xsl:otherwise>
            </xsl:choose>
        </xsl:variable>
        <xsl:variable name="ComplexFullName" select="/my:Inspector/my:Field[@ID=$ComplexID]/@Name"/>
        <span class="$linkClass">
            <xsl:choose>
                <xsl:when test="$ComplexID='0'">
                    <xsl:call-template name="UnknownField"/>
                </xsl:when>
                <xsl:otherwise>
                    <a href="" onClick="ShowField('{$ComplexID}', event); return false;" title="{$ComplexFullName}"><xsl:value-of select="/my:Inspector/my:Field[@ID=$ComplexID]/@ShortName"/></a>
                    <xsl:if test="$Filtered='true'">
                        <xsl:call-template name="Filtered"/>
                    </xsl:if>
                </xsl:otherwise>
            </xsl:choose>
        </span>
    </xsl:template>

    <xsl:template name="PrintFieldLinkOfSourceID">
        <xsl:param name="SourceID"></xsl:param>
        <xsl:param name="Filtered" select="'false'"/>
        <xsl:call-template name="PrintFieldLink">
            <xsl:with-param name="Primary">
                <xsl:value-of select="'true'"/>
            </xsl:with-param>
            <xsl:with-param name="ComplexID"><xsl:value-of select="/my:Inspector/my:Field[my:Source/*=$SourceID]/@ID"/></xsl:with-param>
            <xsl:with-param name="Filtered">
                <xsl:value-of select="$Filtered"/>
            </xsl:with-param>
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="PrintButtonLinkPrimary">
        <xsl:param name="ComplexID"></xsl:param>
        <xsl:variable name="ComplexFullName" select="/my:Inspector/my:Button[@ID=$ComplexID]/@ID"/>
        <span class="linkPrimary">
            <xsl:if test="$ComplexFullName">
                <a href="" onClick="ShowField('{$ComplexID}', event); return false;" title="{$ComplexFullName}"><!-- _locID_text="InspectorOverallButtonLinkPrimary" _locComment="{StringCategory=TXT}A button on the form" -->Button <xsl:value-of select="/my:Inspector/my:Button[@ID=$ComplexID]/@ID" /></a>
            </xsl:if>
        </span>
    </xsl:template>

    <xsl:template name="PrintButtonLinkOfSourceID">
        <xsl:param name="SourceID"></xsl:param>
        <xsl:call-template name="PrintButtonLinkPrimary">
            <xsl:with-param name="ComplexID"><xsl:value-of select="/my:Inspector/my:Button[my:Source/*=$SourceID]/@ID"/></xsl:with-param>
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="PrintDocumentLink">
        <xsl:param name="SourceID"></xsl:param>
        <xsl:if test="count(/my:Inspector/my:XDocument[my:Source/*=$SourceID]) != 0">
            <span class="linkPrimary">
                <a href="" onClick="ShowField('XDocument', event); return false;" title="Document">
                    <!-- _locID_text="InspectorOverallDocumentLinkPrimary" _locComment="{StringCategory=TXT}" -->Document<xsl:if test="@DocumentRuleType='1'">
                        <xsl:text> </xsl:text><!-- _locID_text="InspectorOverallDocumentLinkPrimaryOnLoad" _locComment="{StringCategory=TXT}The Rule will be executed when the document loads" -->On Load</xsl:if><xsl:if test="@DocumentRuleType='2'">
                        <xsl:text> </xsl:text><!-- _locID_text="InspectorOverallDocumentLinkPrimaryOnSubmit" _locComment="{StringCategory=TXT}The Rule will be executed when the document loads" -->On Submit</xsl:if></a>
            </span>
        </xsl:if>
    </xsl:template>

    <xsl:template name="PrintFieldLinkOfTargetID">
        <xsl:param name="SourceID"></xsl:param>
        <xsl:call-template name="PrintFieldLink">
            <xsl:with-param name="Primary">
                <xsl:value-of select="'true'"/>
            </xsl:with-param>
            <xsl:with-param name="ComplexID"><xsl:value-of select="/my:Inspector/my:Field[my:Target/*=$SourceID]/@ID"/></xsl:with-param>
        </xsl:call-template>
    </xsl:template>

    <xsl:template match="my:Expression" mode="ComplexExpression">
        <span class="normalText">
            <xsl:call-template name="EscapeWhiteSpace">
                <xsl:with-param name="TextWithWhiteSpace" select="."/>
            </xsl:call-template>
        </span>
    </xsl:template>

    <xsl:template name="PrintComplexExpression">
        <xsl:apply-templates select="*" mode="ComplexExpression"/>
    </xsl:template>

    <xsl:template name="OutputPlusMinus">
        <xsl:param name="label"></xsl:param>
        <span class="expandCollapse"><a href="#" onClick="HideShow('{$label}', event)"><img border="0" id="{$label}Minus" src="InspectorMinus.PNG"/><img border="0" id="{$label}Plus" onLoad='Hide("{$label}Plus")' src="InspectorPlus.PNG"/></a></span>
    </xsl:template>

    <xsl:template name="PrintConditionsRules">
        <xsl:variable name="NumConditions" select="count(my:RuleCondition)"/>
        <xsl:variable name="RuleID" select="@ID" />

        <span class="overallFrameTertiaryTitle"> <!-- _locID_text="InspectorOverallRuleConditions" _locComment="{StringCategory=TXT}The tests on the rule (for ex. if (. < 5)) for this rule to execute" -->Conditions</span>
        <xsl:if test="$NumConditions=0">
            <div class="indent">
                <span class="none"><!-- _locID_text="InspectorOverallNone5" _locComment="{StringCategory=TXT}There is no Rule associated with this node." -->None</span>
            </div>
        </xsl:if>
        <xsl:if test="not($NumConditions=0)">
            <div class="indent">
                <xsl:apply-templates select="my:RuleCondition/*" mode="ProcessCondition"/><br/>
            </div>
        </xsl:if>
    </xsl:template>

    <xsl:template name="PrintActionsRules">
        <xsl:variable name="NumActions" select="count(my:RuleAction)"/>
        <xsl:variable name="RuleID" select="@ID" />

        <span class="overallFrameTertiaryTitle"> <!-- _locID_text="InspectorOverallRuleActions" _locComment="{StringCategory=TXT}The resulting actions of this rule (set a value, display a message, etc)" -->Actions</span>
        <xsl:if test="$NumActions=0">
            <div class="indent">
                <span class="none"><!-- _locID_text="InspectorOverallNone6" _locComment="{StringCategory=TXT}There is no rule associated with this node." -->None</span>
            </div>
        </xsl:if>
        <xsl:if test="not($NumActions=0)">
            <div class="indent">
                <xsl:apply-templates select="my:RuleAction"/>
            </div>
        </xsl:if>
    </xsl:template>

    <xsl:template match="my:Rule">
        <xsl:param name="type"></xsl:param>
        <xsl:variable name="RuleID" select="@ID"/>
        <tr>
            <td class="overallFrameIndentBar" />
            <td class="overallFrameBar" />
            <td class="overallFrameBackground">
                <table><tr><td width="18px" valign="top" style="padding-top:3px">
                    <xsl:call-template name="OutputPlusMinus">
                        <xsl:with-param name="label"><xsl:value-of select="@ID"/><xsl:value-of select="$type"/>Overall</xsl:with-param>
                    </xsl:call-template>
                </td>
                <td valign="top">
                    <xsl:call-template name="PrintDocumentLink">
                        <xsl:with-param name="SourceID"><xsl:value-of select="@ID"/></xsl:with-param>
                    </xsl:call-template>
                    <xsl:call-template name="PrintButtonLinkOfSourceID">
                        <xsl:with-param name="SourceID"><xsl:value-of select="@ID"/></xsl:with-param>
                    </xsl:call-template>
                    <xsl:call-template name="PrintFieldLinkOfSourceID">
                        <xsl:with-param name="SourceID"><xsl:value-of select="@ID"/></xsl:with-param>
                    </xsl:call-template><span class="normalText">: </span>
                    <span class="ruleName">
                        <xsl:call-template name="EscapeWhiteSpace">
                            <xsl:with-param name="TextWithWhiteSpace" select="@Name"/>
                        </xsl:call-template>
                    </span>
                    <xsl:if test="count(my:RuleCondition)=0">
                        <span class="normalText"><xsl:text>  </xsl:text> <!-- _locID_text="InspectorOverallRuleAlwaysExecutes" _locComment="{StringCategory=TXT}States that the rule always executes" -->- Always Executes</span>
                        <xsl:if test="@RuleEnabled='false'">
                            <span class="normalText"><xsl:text><!-- _locID_text="InspectorOverallRuleComma" _locComment="{StringCategory=TXT}Separator" -->, </xsl:text></span>
                        </xsl:if>
                    </xsl:if>
                    <xsl:if test="@RuleEnabled='false'">
                        <span class="ruleDisabled"><xsl:text>  </xsl:text> <!-- _locID_text="InspectorOverallRuleDisabled" _locComment="{StringCategory=TXT}States that the rule is disabled and not used" -->DISABLED </span>
                    </xsl:if>
                </td></tr></table>
                <div></div>
                <div class="indent" id="{$RuleID}{$type}Overall">
                    <xsl:call-template name="PrintConditionsRules"/>
                    <xsl:call-template name="PrintActionsRules"/>
                </div>
            </td>
        </tr>
    </xsl:template>

    <xsl:template match="my:Condition" mode="ProcessCondition">
        <xsl:call-template name="PrintComplexExpression"/>
    </xsl:template>
    <xsl:template match="my:and" mode="ProcessCondition">
        <span class="connectorText"><xsl:text> </xsl:text><!-- _locID_text="InspectorOverallConditionAnd" _locComment="{StringCategory=TXT}Logical connector" -->and </span><br/>
    </xsl:template>
    <xsl:template match="my:or" mode="ProcessCondition">
        <span class="connectorText"><xsl:text> </xsl:text><!-- _locID_text="InspectorOverallConditionOr" _locComment="{StringCategory=TXT}Logical connector" -->or </span><br/>
    </xsl:template>

    <xsl:template match="my:RuleAction">
        <xsl:choose>
            <xsl:when test="@RuleActionType='1'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction1" _locComment="{StringCategory=TXT}" -->Show a dialog box message: </span>
                <span class="normalText">
                    <xsl:call-template name="EscapeWhiteSpace">
                        <xsl:with-param name="TextWithWhiteSpace" select="@RuleActionString"/>
                    </xsl:call-template>
                </span><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='2'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction2" _locComment="{StringCategory=TXT}Display a dialog box which is based on a calculated expression" -->Show a dialog box expression: </span><span class="normalText"><xsl:call-template name="PrintComplexExpression"/></span><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='3'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction3" _locComment="{StringCategory=TXT}Change the current view of InfoPath" -->Switch views: </span><span class="normalText"><xsl:value-of select="@RuleActionString"/></span><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='4'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction4" _locComment="{StringCategory=TXT}" -->Set a field's value: </span>
                <xsl:if test="@RuleActionTarget">
                    <xsl:call-template name="PrintFieldLink">
                        <xsl:with-param name="Primary">
                            <xsl:value-of select="'false'"/>
                        </xsl:with-param>
                        <xsl:with-param name="ComplexID">
                            <xsl:value-of select="@RuleActionTarget"/>
                        </xsl:with-param>
                    </xsl:call-template>
                </xsl:if>
                <xsl:if test="@RuleActionTargetShortName">
                    <span class="normal" style="color:#FF6600; font-weight:bold;" title="No details for this field or group. See Help for more information."><!-- _locID@title="InspectorFieldAmbiguous"  _locComment="{StringCategory=TXT}We're not sure which node this field maps to." -->
                        <xsl:value-of select="@RuleActionTargetShortName" />
                    </span>
                </xsl:if>
                <span class="normalText">
                 = </span>
                <xsl:call-template name="PrintComplexExpression"/><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='5'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction5" _locComment="{StringCategory=TXT}" -->Query using a data connection: </span><span class="normalText"><xsl:value-of select="@RuleActionString"/></span><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='6'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction6" _locComment="{StringCategory=TXT}" -->Submit using a data connection: </span><span class="normalText"><xsl:value-of select="@RuleActionString"/></span><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='7'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction7" _locComment="{StringCategory=TXT}" -->Open a new form to fill out: </span><span class="normalText"><xsl:value-of select="@RuleActionString"/></span><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='8'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction8" _locComment="{StringCategory=TXT}" -->Close the form</span><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='9'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction9" _locComment="{StringCategory=TXT}" -->Send data to Web Part</span><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='10'">
                <span class="actionType"><!-- _locID_text="InspectorOverallRuleAction10" _locComment="{StringCategory=TXT}" -->Change REST URL: </span><span class="normalText"><xsl:value-of select="@RuleActionString"/></span><br/>
            </xsl:when>
            <xsl:when test="@RuleActionType='11'">
                <span class="actionType">
                    <!-- _locID_text="InspectorOverallRuleAction11" _locComment="{StringCategory=TXT}" -->Sign a signature line:
                </span>
                <xsl:if test="@RuleActionTarget">
                    <xsl:call-template name="PrintFieldLink">
                        <xsl:with-param name="Primary">
                            <xsl:value-of select="'false'"/>
                        </xsl:with-param>
                        <xsl:with-param name="ComplexID">
                            <xsl:value-of select="@RuleActionTarget"/>
                        </xsl:with-param>
                    </xsl:call-template>
                </xsl:if>
                <xsl:if test="@RuleActionTargetShortName">
                    <span class="normal" style="color:#FF6600; font-weight:bold;" title="The type of data to match the signature control.">
                        <!-- _locID@title="InspectorFieldSignerMatchType"  _locComment="{StringCategory=TXT}It is one of the types - Name / Email / Unique ID." -->
                        <xsl:value-of select="@RuleActionTargetShortName" />
                    </span>
                </xsl:if>
                <span class="normalText">
                    =
                </span>
                <xsl:call-template name="PrintComplexExpression"/>
                <br/>
            </xsl:when>
            <xsl:otherwise>
                <span class="actionError"><!-- _locID_text="InspectorOverallRuleActionError" _locComment="{StringCategory=TXT}" -->Internal error.</span><br/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="my:Calculation">
        <xsl:param name="type"></xsl:param>
        <span class="expandCollapse"><img src="InspectorNode.PNG"/></span>
        <xsl:call-template name="PrintFieldLink">
            <xsl:with-param name="Primary">
                <xsl:value-of select="'true'"/>
            </xsl:with-param>
            <xsl:with-param name="ComplexID">
                <xsl:value-of select="@Target"/>
            </xsl:with-param>
        </xsl:call-template><span class="normalText">: <xsl:call-template name="PrintComplexExpression"/></span><br/>
    </xsl:template>

    <xsl:template match="my:DataValidation">
        <xsl:param name="type"></xsl:param>
        <tr>
            <td class="overallFrameIndentBar" />
            <td class="overallFrameBar" />
            <td class="overallFrameBackground">
                <xsl:variable name="DataValID" select="@ID"/>
                <table><tr><td width="18px" valign="top" style="padding-top:3px">
                    <xsl:call-template name="OutputPlusMinus">
                        <xsl:with-param name="label"><xsl:value-of select="@ID"/><xsl:value-of select="$type"/>Overall</xsl:with-param>
                    </xsl:call-template>
                </td>
                <td valign="top">
                    <xsl:call-template name="PrintFieldLinkOfSourceID">
                        <xsl:with-param name="SourceID"><xsl:value-of select="@ID"/></xsl:with-param>
                    </xsl:call-template>
                    <span class="normalText">
                        : "<xsl:call-template name="EscapeWhiteSpace">
                            <xsl:with-param name="TextWithWhiteSpace" select="@Caption"/>
                        </xsl:call-template>"
                        <xsl:if test="@ErrorType='modal'">
                            <xsl:text>  </xsl:text><!-- _locID_text="InspectorOverallDataValidationDialog" _locComment="{StringCategory=TXT}This indicates that a message box / dialog will pop up" -->(Show Dialog)
                        </xsl:if>
                    </span>
                </td></tr></table>
                <div></div>
                <div class="indent" id="{$DataValID}{$type}Overall">
                    <span class="overallFrameTertiaryTitle"> <!-- _locID_text="InspectorOverallDataValidationConditions" _locComment="{StringCategory=TXT}The conditions that are met for the data to be invalid (. > 5 or . < 0)" -->Conditions</span>
                    <div class="indent">
                        <xsl:apply-templates select="*" mode="ProcessCondition"/><br/>
                    </div>
                    <span class="overallFrameTertiaryTitle"> <!-- _locID_text="InspectorOverallDataValidationActions" _locComment="{StringCategory=TXT}The resulting actions if the conditions are met" -->Actions</span>
                    <div class="indent">
                        <span class="normalText">
                            <xsl:if test="not(@ScreenTip='')">
                                <!-- _locID_text="InspectorOverallDataValidationScreenTip" _locComment="{StringCategory=TXT}This is the screen tip that appears when hovering the mouse over a field" -->ScreenTip:
                                "<xsl:call-template name="EscapeWhiteSpace">
                                    <xsl:with-param name="TextWithWhiteSpace" select="@ScreenTip"/>
                                </xsl:call-template>"<br/>
                            </xsl:if>
                            <xsl:if test="not(@Message='')">
                                <!-- _locID_text="InspectorOverallDataValidationMessage" _locComment="{StringCategory=TXT}This is the message that pops up in a dialog box" -->Message:
                                "<xsl:call-template name="EscapeWhiteSpace">
                                    <xsl:with-param name="TextWithWhiteSpace" select="@Message"/>
                                </xsl:call-template>"<br/>
                            </xsl:if>
                        </span>
                    </div>
                </div>
            </td>
        </tr>
    </xsl:template>

    <xsl:template match="my:BusinessLogic">
        <table><tr><td width="18px" valign="top" style="padding-top:3px">
            <span class="expandCollapse"><img src="InspectorNode.PNG"/></span>
        </td>
        <td valign="top">
            <xsl:call-template name="PrintDocumentLink">
                <xsl:with-param name="SourceID"><xsl:value-of select="@ID"/></xsl:with-param>
            </xsl:call-template>
            <xsl:call-template name="PrintButtonLinkOfSourceID">
                <xsl:with-param name="SourceID"><xsl:value-of select="@ID"/></xsl:with-param>
            </xsl:call-template>
            <xsl:call-template name="PrintFieldLinkOfSourceID">
                <xsl:with-param name="SourceID"><xsl:value-of select="@ID"/></xsl:with-param>
                <xsl:with-param name="Filtered"><xsl:value-of select="@Filtered"/></xsl:with-param>
            </xsl:call-template><span class="normalText">:
                <xsl:if test="@LogicType=''">
                    <!-- _locID_text="InspectorOverallScripting" _locComment="{StringCategory=TXT}This indicates that there is a script." -->Scripting
                </xsl:if>
                <xsl:if test="not(@LogicType='')">
                    <xsl:value-of select="@LogicType"/>
                </xsl:if>
                - <xsl:value-of select="@LogicFunction"/></span><br/>
        </td></tr></table>
    </xsl:template>

</xsl:stylesheet>