home *** CD-ROM | disk | FTP | other *** search
/ kermit.columbia.edu / kermit.columbia.edu.tar / kermit.columbia.edu / scripts / ckermit / twoscomplementv2.~1~ < prev    next >
Text File  |  2007-12-27  |  6KB  |  181 lines
  1. # Macros to convert signed decimal numbers to two's complement hexadecimal
  2. # notation.  This version does not use machine arithmetic; it does everything
  3. # with strings, so is able to handle integers of any size.  As written it
  4. # accommodates word sizes of 4, 8, 16, 32, 64, and 128 bits.  Other word
  5. # sizes can be added by changing the definitions at the top.
  6. # 
  7. # Because machine arithmetic is not used, this version is considerably slower
  8. # than the first one but it works for numbers that don't fit in 32 bits in
  9. # Kermit 95 and in 32-bit versions of C-Kermit.
  10. #
  11. # F. da Cruz, Columbia University, 28 December 2007
  12.  
  13. .legal = :4:8:16:32:64:128:             # Legal word sizes
  14.  
  15. # Largest positive integer for the supported word sizes
  16.  
  17. .maxint<4> = 7
  18. .maxint<8> = 127
  19. .maxint<16> = 32767
  20. .maxint<32> = 2147483647
  21. .maxint<64> = 9223372036854775807
  22. .maxint<128> = 340282366920938463463374607431768211455
  23.  
  24. # Ditto plus one (because we can't necessarily do arithmetic on big numbers)
  25.  
  26. .maxplusone<4> = 8
  27. .maxplusone<8> = 128
  28. .maxplusone<16> = 32768
  29. .maxplusone<32> = 2147483648
  30. .maxplusone<64> = 9223372036854775808
  31. .maxplusone<128> = 340282366920938463463374607431768211456
  32.  
  33. # Macro BINTOHEX converts a binary string to hex.
  34. #   \%1 = binary number (string)
  35. #   \%2 = word size in bits
  36. # 
  37. # \fradix() is constrained by machine integer word length
  38. # so we do it in pieces in case the number is too big.
  39. #
  40. define BINTOHEX {
  41.     undef \%6                                # Result accumulator
  42.     .\%1 := \flpad(\%1,\%2,0)                # Pad to size if necessary
  43.     for \%9 1 \%2 4 {                        # Do four bits at at a time
  44.         .\%8 := \fsubstr(\%1,\%9,4)          # Get chunk of 4
  45.         if not def \%8 break                 # Make sure we have one
  46.         .\%7 := \fradix(\%8,2,16)            # Convert to Hex digit
  47.         .\%6 := \%6\%7                       # Accumulate
  48.     }
  49.     return \%6
  50. }
  51.  
  52. def DIV2 {                                   # Divide decimal string by two
  53.     undef \%6 \%7 result
  54.     for \%i 1 \flen(\%1) 1 {                 # One digit at a time.
  55.         .\%9 := \%7\:(\%1[\%i:1])            # Get a digit.
  56.         .\%8 ::= \%9/2                       # Divide it by 2
  57.         .\%7 ::= \%9%2                       # Get remainder
  58.         .\%6 := \%6\%8                       # Accumulate result
  59.     }
  60.     .result := \%6                           # Make result 
  61.     .remainder := \%7                        # and remainder visible
  62. }
  63.  
  64. def DTOB {                                   # Convert decimal string to binary
  65.     while true {                             # without using machine 
  66.         div2 \%1                             # arithmetic.
  67.         .\%6 := \m(remainder)\%6
  68.         .\%1 := \m(result)                    
  69.         if not \fverify(0,\%1) break
  70.     }        
  71.     return \%6
  72. }
  73. # Macro DECTOHEX converts a signed decimal number to 2's complement hex,
  74. # using the macros defined above as workers.
  75. #   \%1 = decimal number string (default 0)
  76. #   \%2 = word size in bits
  77. #         (must be a power of two, 4 or greater, default 32, max 128)
  78. #   Returns result in \v(result) and/or as value of \fexec(dectohex arg arg).
  79. #
  80. define DECTOHEX {
  81.     local digits
  82.     if not def \%1 .\%1 = 0                  # Supply default if no arg given
  83.     if not numeric \%1 return NOT_A_NUMBER:\%1  # Check that arg is a number
  84.     if not def \%2 .\%2 := 32                   # Use 32 bits if no second arg
  85.     if not \findex(:\%2:,\m(legal)) end 1 "UNSUPPORTED WORD SIZE - \%2"
  86.     .digits := \flen(\m(maxint<\%2>))           # Number of digits in it
  87.  
  88.     if eq "\fsubstr(\%1,1,1)" "+" .\%1 := \fsubstr(\%1,2) # strip any + sign
  89.     if not eq "\fsubstr(\%1,1,1)" "-" {      # If argument is not signed...
  90.         if lgt \flpad(\%1,\m(digits),0) \m(maxint<\%2>) return OVERFLOW
  91.         dtob \%1                             # Convert from decimal to binary
  92.         bintohex \v(return) \%2              # And from binary to hex
  93.         return \flpad(\v(return),(\%2/4),0)  # Return padded result
  94.     }
  95.     .\%1 := \fsubstr(\%1,2)                  # Negative number - remove sign
  96.     .\%1 := \flpad(\%1,\flen(\m(maxint<\%2>)),0) # Must use lexical comparison
  97.     if llt \m(maxplusone<\%2>) \%1 return UNDERFLOW # Check magnitude
  98.     dtob \%1                                 # Convert to binary
  99.     .\%9 := \flpad(\v(return),\%2,0)         # and pad
  100.     .\%8 ::= \frindex(1,\%9) - 1             # Find first 1 on the right
  101.     if == \%8 -1 return \frepeat(0,\%2 / 4)  # Watch out for negative 0
  102.     .\%7 := \fsubstr(\%9,1,\%8)              # Split string here
  103.     .\%6 := \fsubstitute(\%7,01,10)          # Complement bits in left part
  104.     .\%5 := \%6\fsubstr(\%9,\%8+1)           # Put back with right part
  105.     .\%4 := \fexec(bintohex \%5 \%2)         # Convert to hex
  106.     return \%4
  107. }
  108. # Test the functions...
  109.  
  110. def try {
  111.     # Note \v(time) lacks the fractional part in Windows for some reason.
  112.     .t1 := \v(ftime)                    # Current time
  113.     .result := \fexec(dectohex \%1 \%2) # Do the conversion
  114.     .t2 := \v(ftime)                    # New time
  115.     (setq t3 (- t2 t1))                 # Difference
  116.     echo \%1[\%2] = \m(result) [\ffpround(\m(t3),2) sec] # Print
  117. }
  118. try 7          # No word size specified
  119.  
  120. try  7 4       # 4-bit word
  121. try  8 4
  122. try -8 4
  123. try -9 4
  124. try 99 4
  125.  
  126. try  0 8        # 8-bit word
  127. try -0 8
  128. try  1 8
  129. try +1 8
  130. try  2 8
  131. try  3 8
  132. try  4 8
  133. try  5 8
  134. try  6 8
  135. try  7 8
  136. try -1 8
  137. try -2 8
  138. try -3 8
  139. try -4 8
  140. try -5 8
  141. try -6 8
  142. try -7 8
  143. try -8 8
  144. try 64 8
  145. try 65 8
  146. try -128 8
  147.  
  148. try 0 16       # 16-bit word
  149. try 64 16
  150. try 65 16
  151. try -128 16
  152. try -32768 16
  153. try 99999 16
  154. try -99999 16
  155.  
  156. try 0 32       # 32-bit word
  157. try 1 32
  158. try 16383 32
  159. try 2147483647 32
  160. try -1 32
  161. try -2 32
  162. try -2147483647 32
  163. try -2147483648 32
  164.  
  165. try 0 64       # 64-bit word
  166. try 2147483647 64
  167. try -1 64
  168. try -2 64
  169. try  1234567890 64
  170. try -2147483647 64
  171. try -2147483648 64
  172. try  8224373093854475231 64
  173.  
  174. try 0 128      # 128-bit word
  175. try 1 128
  176. try -1 128
  177. try -2 128
  178. try 317282366902934863643347307341786875499 128
  179.  
  180. if c-kermit exit
  181.