home *** CD-ROM | disk | FTP | other *** search
/ kermit.columbia.edu / kermit.columbia.edu.tar / kermit.columbia.edu / scripts / ckermit / linksys < prev    next >
Text File  |  2001-11-23  |  2KB  |  60 lines
  1. # get-linksys-addr.ksc
  2. # This script can be used with a Linksys Ethernet Cable/DSL Router 
  3. # to retrieve the IP address for use with Kerberos 5 authentication
  4. # when Network Address Translation (NAT) is enabled.
  5. # 
  6. #  by Frank da Cruz and Jeffrey Altman
  7. #
  8. # Version 1.0
  9.  
  10. if < \v(version) 800200 {
  11.   end 99 This script requires C-Kermit or Kermit 95 version 800200 or higher
  12. }
  13.  
  14. # define some default 
  15. local firewall fwuser fwpwd tempfile \%x addr
  16. define firewall 192.168.1.1             ; default value
  17. define fwuser                           ; default value
  18. define fwpwd    admin                   ; default value
  19. define tempfile \v(tempdir)linksys.htm
  20.  
  21. # Perform HTTP GET and place the Status HTML page into the tempfile
  22. http open \m(firewall)
  23. if failure end 1 Unable to connect to firewall
  24. http /user:\m(fwuser) /password:\m(fwpwd) get /Status.htm \m(tempfile)
  25. if failure end 2 Unable to access Status.htm: \v(http_code): \v(http_message)
  26. http close
  27.  
  28. # Read the contents of the tempfile into the data variable
  29. file open /binary /read \%x \m(tempfile)
  30. if failure end 3 FOPEN \m(tempfile): \f_errmsg()
  31. file read /size:\fsize(\m(tempfile)) \%x data
  32. file close \%x
  33.  
  34. # Delete the tempfile
  35. delete \m(tempfile)
  36.  
  37. # The IP Address of the Router is located in the HTML file
  38. # within a block defined by tags: <!--WAN head--> and <!--WAN tail-->
  39. # We extract the substr defined by the block
  40. .\%x := \findex(<!--WAN head-->,\m(data))
  41. if not \%x end 4 Header <!--WAN head--> not found
  42. .\%y := \findex(<!--WAN tail-->,\m(data),\%x)
  43. if not \%y end 5 Header <!--WAN tail--> not found
  44. .data := \fsubstr(\m(data),\%x,\%y-\%x+15)
  45.  
  46. # The IP Address is located after the string "IP Address:".
  47. # Find its location in the WAN block
  48. .\%x := \findex(IP Address:,\m(data))
  49. if not \%x end 6 IP Address tag not found
  50.  
  51. # Extract the IP Address
  52. .addr := \fipaddress(\m(data),\%x)
  53. if failure end 7 No ip address found
  54.  
  55. # Set the IP address of the Router to be used in Kerberos 5 tickets
  56. set auth k5 addresses \m(addr)
  57.  
  58. # Done
  59. end 0 Kerberos 5 address list set to: \m(addr)
  60.