8bitfiles.net/archives/archives.tar/archives/genie-commodore-file-library/Information/256KB.UTILS.SFX/routines.a

Text File | 1993-06-23 | 2.4 KB | 242 lines

;
;GET HEX DIGITS
;
GETHEX JSR CON
 ASL A
 ASL A
 ASL A
 ASL A
 STA BAD
 JSR CHRGET ;GET CHAR FROM BUFFER
 JSR CON
 ORA BAD
 SEC
 RTS
;
CON CMP #':'
 PHP
 AND #%00001111
 PLP
 BCC CON00
 ADC #8
CON00 RTS
;
;ACCEPT HEX BYTE
;IGNORE SPACES
;RESULT IS IN (TO)
;
CL0 DEC CHRPTR
ACCEPT LDA #0
 STA TO
 STA TO+1
 STA SYREG
ACCE00 JSR CHRGET ;GET CHAR FROM BUFFER
 BEQ ACCE05
 CMP #' '
 BEQ ACCE00
ACCE01 CMP #' '
 BEQ ACCE04
 CMP #','
 BEQ ACCE04
 JSR HCOMP
 BCS ACCE06
 CMP #':'
 BCC ACCE02
 SBC #8
ACCE02 SBC #'/'
 ASL A
 ASL A
 ASL A
 ASL A
 LDX #4
ACCE03 ASL A
 ROL TO
 ROL TO+1
 DEX
 BNE ACCE03
 INC SYREG
 JSR CHRGET ;GET CHAR FROM BUFFER
 BNE ACCE01
ACCE04 LDA TO
 CLC
ACCE05 RTS
ACCE06 SEC
 LDA #0
 RTS
;
;
;
ADDR LDA T2
 LDX T2+1
;
;
;
AXHEX PHA
 TXA
 JSR OUTHEX
 PLA
;
;
;
HEXSPC JSR OUTHEX ;OUTPUT ACC. IN HEX
SPACE LDA #' '
 .BYT $2C
QUEST LDA #'?'
 .BYT $2C
CRUP LDA #145
 .BYT $2C
CR LDA #13
 JMP CHROUT ;OUTPUT CHARACTER
;
;
;
OUTHEX STX SXREG
 JSR SNGHEX ;OUTPUT ACC. IN ASCII
 JSR CHROUT ;OUTPUT CHARACTER
 TXA
 LDX SXREG
 JMP CHROUT ;OUTPUT CHARACTER
;
;
;
SNGHEX PHA
 JSR CH
 TAX
 PLA
 LSR A
 LSR A
 LSR A
 LSR A
;
CH AND #%00001111
 CMP #10
 BCC SK259
 ADC #6
SK259 ADC #'0'
 RTS

CHRGET STX SXREG
 LDX CHRPTR
 CPX BUFEND
 BCS SK260
 LDA BUF,X
 CMP #':'
 BEQ SK260
 INC CHRPTR
LP069 PHP
 LDX SXREG
 PLP
 RTS
SK260 LDA #0
 BEQ LP069
BUFSTO STA KEYD
 LDA T2+1
 JSR SNGHEX ;OUTPUT ACC. IN ASCII
 STA KEYD+1
 STX KEYD+2
 LDA T2
 JSR SNGHEX ;OUTPUT ACC. IN ASCII
 STA KEYD+3
 STX KEYD+4
 LDA #' '
 STA KEYD+5
 LDA #6
 STA NDX
 RTS
;
;
;
MOVE LDA TO
 STA T2
 LDA TO+1
 STA T2+1
 RTS
;
;
;
SUBS SEC
 LDA TO
 SBC T2
 STA TO
 LDA TO+1
 SBC T2+1
 STA TO+1
 RTS
;
;
;
SM LDA #1
SUBST STA SXREG
 SEC
 LDA TO
 SBC SXREG
 STA TO
 LDA TO+1
 SBC #0
 STA TO+1
 RTS
;
;
;
SUB1 SEC
 LDA T1
 SBC #1
 STA T1
 LDA T1+1
 SBC #0
 STA T1+1
 RTS

ADD1 LDA #1

ADDACC CLC
 ADC T2
 STA T2
 BCC SK261
 INC T2+1
SK261 RTS
;
;
;
GETPRM BCS ACCE07
 JSR MOVE ;COPY (TO) TO (T2)
 JSR ACCEPT ;INPUT HEX NUMBER (TO)
 BCS ACCE07
 JSR SUBS
 LDA TO
 STA T1
 LDA TO+1
 STA T1+1
 CLC
ACCE07 RTS
;
;
;
PROW JSR CR ;PRINT CR
PROW0 LDA #'>'
 JSR CHROUT ;OUTPUT CHARACTER
 JSR ADDR ;PRINT (T2) IN ASCII
 LDY #0
PROW02 JSR BFET88 ;FETCH BYTE
 STA XCNT,Y
 JSR HEXSPC ;ACC. IN HEX & SPACE
 INY
 CPY #8
 BCC PROW02
 LDA #':'
 JSR CHROUT ;OUTPUT CHARACTER
 LDY #0
PROW03 LDA XCNT,Y
 AND #%01111111
 CMP #127
 BEQ PROW01
 CMP #' '
 BCS PROW04
PROW01 LDA #'.'
PROW04 JSR CHROUT ;OUTPUT CHARACTER
 INY
 CPY #8
 BCC PROW03
 RTS
.END