home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
8bitfiles.net/archives
/
archives.tar
/
archives
/
genie-commodore-file-library
/
CMDGeneral
/
DESOTO14.1.SDA
/
EXIT.SMR
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2019-04-13
|
2KB
|
93 lines
50 POKE53280,11:POKE53281,0:POKE646,15
95 REM EXXIT V1.2
100 A$="^":REM PROGRAM TO LOAD WHEN DONE
105 AA$="PROGRAM.TITLE":REM:TARGET TITLE
110 RU$="RUN":REM OR "SYSXXXXX"
115 LD$=",1": REM "" FOR BASIC PROGRAMS
120 SP=254:REM PARTITION # FOR SYSTEMINFO
125 REM PRINTER COMMANDS
130 PR=1:REM PRINTER SWITCH:1=ON/0=OFF
135 P(1)=27:P(2)=64:P(3)= 0:P(4)= 0:P(5)= 0:P(6)= 0:P(7)= 0:P(8)= 0:P(9)= 0
137 JD=1:SR=0: REM JIFFY DOS?: SELF-RUN?
140 REM LIST 150- FOR ADDITIONAL OPTIONSREM(null)
145 GOTO190
150 P=1:REM OPTIONAL HD PARTITION NUMBER FOR A$
155 PA$=":81PART.NAME":REM OR HD DIR PATH FOR A$
160 REM:PRINT#15,"C[208]"+CHR$(P):REM HD PARTITION FOR A$
165 REM:PRINT#15,"/"+PA$:REM 81 PARTITIONFOR A$
170 REM:PRINT#15,"CD"+PA$:REM HD SUBDIR
175 REM(null)
180 RETURN
185 :
190 RD=22:REM DEVICE # TO BEGIN TEMPORARY CONFIGURATION
195 SI$="SYSTEMINFO.SMR"
200 :
205 PRINT"[147]RECONFIGURING...":RT=0
210 :
215 CM=1:REM CHECK DEV # & IF HD
220 DV=PEEK(186)
225 OPEN15,DV,15:PRINT#15,"G-P":GOSUB465:
230 :
235 SI$=":"+SI$:IFCM THEN SI$=STR$(SP)+SI$
240 OPEN5,DV,5,SI$+",S,R":GOSUB465:IFEXTHENCLOSE5:GOTO335
245 X=1
250 INPUT#5,A$(X):IFVAL(A$(X))=-1THENZ=X-1:GOTO265
255 OD(X)=VAL(LEFT$(A$(X),2)):ND(X)=VAL(RIGHT$(A$(X),2))
260 X=X+1:GOTO250
265 INPUT#5,G$,PN$:CLOSE5:PRINT#15,"S"+SI$:GOSUB465:CLOSE15
270 :
275 FORT=1TOZ
280 :OD=ND(T):ND=(RD-1)+T:GOSUB600:IFSTTHEN290
283 :GOSUB390
285 :ND(T)=ND:IFOD=DVTHENDV=ND
290 :NEXT
295 :
300 FORT=1TOZ
305 :OD=ND(T):ND=OD(T):GOSUB600:IFSTTHEN315
307 GOSUB390
310 :IFOD=DVTHENDV=ND
315 :NEXT
320 IFJDTHEN @#DV
325 OPEN15,DV,15
330 G=VAL(G$):PN=VAL(PN$):IFCMTHENPRINT#15,"C[208]"+CHR$(PN)
335 IF CM THEN PRINT#15,"CD/":GOSUB465
340 PRINT#15,"/":FORT=1TO700:NEXT:GOSUB465
345 IFRT=0THENRT=1:IFEXTHENEX=0:GOTO240
350 EX=0:GOSUB150:GOSUB465:IFEXTHEN495
355 CLOSE15:RT=0:IFPRTHENGOSUB515
360 :
365 IFG=1THEN405
370 IFA$<>"PROGRAMNAME....."THENGOTO415
375 PRINT"[147]":END
380 :
385 REM CHANGE DEV #
390 OPEN15,OD,15:PRINT#15,"M-W"CHR$(119)CHR$(0)CHR$(2)CHR$(ND+32)CHR$(ND+64)
395 CLOSE15:RETURN
400 :
405 LOAD"RBOOT",DV,1
410 :
415 PRINT"[147]":IFAA$="PROGRAM.TITLE"THEN430
420 PRINT" NOW LOADING"
425 PRINT:PRINT;:FORT=1TO((40-LEN(AA$))/2):PRINT" ";:NEXT:PRINTAA$
430 POKE251,PEEK(646):POKE646,PEEK(53281)
435 PRINT"LOAD"CHR$(34)A$CHR$(34)","+STR$(DV)+LD$+":"
440 PRINT:PRINT:PRINT:PRINT
445 PRINT"POKE646,"PEEK(251)":PRINT"CHR$(34)"[147]"RU$":"CHR$(34)
447 Z8=5:IFSRTHENZ8=2
450 POKE631,19:POKE632,13:POKE633,13:POKE634,19:POKE635,13:POKE198,Z8:NEW
455 :
460 REM ERROR CHANNEL
465 INPUT#15,EN$,EM$,ET$,ES$
470 EN=VAL(LEFT$(EN$,3))
475 IFEN<20THENRETURN
480 IFEN=31THENCM=0:RETURN
485 IFEN=30THENRETURN
490 IFEN=62THENEX=1:RETURN
495 PRINT"ERROR "EN:PRINTEM$:PRINT"TRACK"ET$" SECTOR "ES$:CLOSE15:STOP
500 RETURN
505 :
510 REM PRINTER
515 PRINT"PRINTER":OPEN5,4,0:CLOSE5:IFSTTHENRETURN
520 OPEN5,4,0:FORT=1TO9:PRINT#5,CHR$(P(T));:NEXT:CLOSE5:RETURN
600 OPEN15,OD,15:CLOSE15:RETURN