home *** CD-ROM | disk | FTP | other *** search
- 0 POKE54296,15:FORL=1TO10:POKEL+54272,0:NEXT:SI=54272:W1=SI+4:W3=SI+18:V=SI+24:PW=SI+27
- 1 PRINT"[147]";:POKE53280,12:POKE53281,15:FORI=1024TO1063:POKEI,160:POKEI+54272,2:NEXT
- 2 PRINT"";:FORI=1TO22:PRINT"[145] [146]";SPC(38);" [146]":NEXT
- 3 POKE1944,160:POKE54272+1944,2:POKE1983,160:POKE54272+1983,2
- 4 FORI=1984TO2023:POKEI,160:POKEI+54272,2:NEXT:POKE54296,15
- 5 PRINT"TYPE IT!"
- 6 PRINT"[154] BY SYD BOLTON"
- 7 PRINT"[144]COPYRIGHT (C) 1985 BY"
- 8 PRINT"OSTON SOFTWARE":PRINT"HIT A KEY OR WAIT";
- 9 A$="":DIMA$(50):FORI=1TO50:READA$(I):NEXT:WM=20:PE=SI+28:HS=0
- 10 FORI=1TO3000:GETA$:IFA$=""THENNEXT
- 20 PRINT:PRINT"[147] WELCOME TO TYPE IT!"
- 30 PRINT"[144] I'LL GIVE YOU A SENTENCE AND YOU HAVE"
- 40 PRINT"TO TYPE IT AS FAST AS YOU CAN. I'LL TELL"
- 50 PRINT"YOU HOW MANY LETTERS PER MINUTE (LPM) &"
- 60 PRINT"HOW MANY WORDS PER MINUTE (WPM) THAT "
- 70 PRINT"YOU ARE TYPING AT."
- 80 PRINT" IF YOU ARE TYPING SLOW THEN I WILL LET"
- 90 PRINT"YOU QUIT. IF HOWEVER, YOU WANT TO "
- 100 PRINT"PRACTICE WITHOUT ME NAGGING AT YOU,"
- 110 PRINT"CHOOSE SKILL LEVEL #3"
- 120 PRINT" [156]HIT ANY KEY TO CONTINUE"
- 130 POKE198,0:WAIT198,1:POKE198,0
- 140 PRINT"[147] [144]LEVEL #2 WILL FLASH THE SENTENCE FOR"
- 150 PRINT"ABOUT 2 SECONDS AND THEN DISAPPEAR. YOU"
- 160 PRINT"MUST THEN TYPE THE SENTENCE IN."
- 170 PRINT" LEVEL #1 WILL DISPLAY THE SENTENCE "
- 180 PRINT"CONTINUALLY."
- 181 PRINT" PRESS THE COMMODORE LOGO KEY FOR A "
- 182 PRINT"REPORT CARD."
- 190 PRINT"ENTER SKILL LEVEL (1-3)?";
- 191 GETB$:IFB$=""THEN191
- 192 LV=1:Q=1
- 195 B=VAL(B$):IFB<1ORB>3THEN191
- 200 R=INT(RND(1)*50)+1:K=1:L=LEN(A$(R))
- 201 PRINT"[147][144][213][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][201]"
- 202 PRINT"[145][221] TYPE IT![144] [221]"
- 203 PRINT"[145][202][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][203]"
- 204 PRINT"[144]WPM:";WP
- 205 PRINT"[145]";TAB(31);"[144]LPM:";LP
- 210 PRINT"":T=(40-LEN(A$(R)))/2
- 230 PRINT:PRINT"[144][213][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][201]"
- 240 PRINT"[145][221] [221]"
- 250 PRINT"[145][202][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][203]":PRINT"[145][145][145]";
- 251 PRINT"[156] HIT ANY KEY WHEN READY":POKE198,0
- 252 WAIT198,1:PRINT"[145] ":POKE198,0
- 253 PRINT"[145][145][145][145][145][145][145][145][145][145]";TAB(T);"";A$(R):IFB=2THENGOSUB300
- 254 PRINT"";:FORWW=1TOT:PRINT"";:NEXT
- 255 Z=TI
- 260 FORI=1TOLEN(A$(R)):GOSUB8000:K=K+1:NEXT
- 266 LP=INT(L*60/((TI-Z)/60)):WP=INT(LP/5)
- 267 IFWP<WMANDB=1THEN400
- 268 IFWP<WMANDB=2THEN400
- 269 IFLP<0THENLP=0
- 270 IFWP<0THENWP=0
- 271 SC=SC+WP:Q=Q+1:IFQ=5THEN700
- 272 IFWP>HSTHENHS=WP
- 275 GOTO200
- 300 FORI=1TO2000:NEXT:PRINT"[145] ":POKE198,0:RETURN
- 400 PRINT"[147][144]IT APPEARS THAT YOU ARE FALLING BELOW":PRINT
- 410 PRINT"THE MINIMUM WPM. IF YOU WANT TO GO TO"
- 420 PRINT"LEVEL #3, HIT '3'. IF YOU WANT ME TO"
- 430 PRINT"REDUCE THE MINIMUM WPM, HIT 'R', AND IF"
- 440 PRINT"YOU WANT TO QUIT, HIT 'Q'"
- 450 PRINT"ENTER 3, R OR Q?"
- 460 GETA$:IFA$=""THEN460
- 470 IFA$="Q"THEN900
- 480 IFA$="R"THENWM=WM-10:LV=LV-2:IFLV<1THENLV=1:WM=20
- 490 IFA$="R"THENQ=0:GOTO200
- 500 IFA$="3"THENB=3:Q=0:GOTO200
- 510 GOTO460
- 700 POKE53280,0:POKE53281,0:PRINT"[147]":FORQQ=SITOPE:POKEQQ,0:NEXT
- 710 POKEW1+1,17:POKEW1+2,251:POKEW3+1,187:POKEW3+2,140:POKEV,143:POKEW3,17:POKEW3-3,15:POKEW1,19
- 720 POKEW3,129
- 730 FORQQ=1TO200:POKE54273,PEEK(54299):POKE646,QQ
- 735 PRINT"";TAB(6);"YOU HAVE COMPLETED LEVEL";LV
- 740 NEXT
- 750 POKEV,0:POKEW1,0:POKEW3,0
- 760 POKE53280,12:POKE53281,15:PRINT"[147][144]I AM NOW INCREASING THE SKILL LEVEL SO"
- 770 PRINT"THAT THE MINIMUN WPM WILL BE";WM+5
- 775 FORQQ=1TO2500:NEXT
- 776 PRINT" [144][213][195][195][195][195][195][195][201]"
- 780 PRINT"[144] [221]BONUS:[144][221]"
- 781 PRINT" [144] [202][195][195][195][195][195][195][203]"
- 785 POKE54296,15:POKE54277,0:POKE54278,247
- 790 FORQQ=1TOHS*LV:PRINT" ";QQ
- 792 :POKE54276,17:POKE54273,40:POKE54272,0:FORT=1TO20:NEXT
- 795 POKE54276,16:NEXT
- 800 Q=0:LV=LV+1:WM=WM+5:SC=SC+HS*LV:FORL=1TO2500:NEXT:GOTO200
- 900 PRINT"[147][156] REPORT CARD":PRINT" [183][183][183][183][183][183][183][183][183][183][183]"
- 905 PRINT"[144]YOUR FINAL SCORE IS: ";SC
- 910 PRINT"[144]YOU MADE IT TO LEVEL:";LV
- 920 PRINT"[144]YOUR BEST WPM WAS: ";HS
- 925 PRINT"[195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195]"
- 930 PRINT"ENTER [144]Y TO PLAY AGAIN, OR ANY OTHER KEY"
- 940 PRINT"TO QUIT"
- 950 PRINT"CHOICE?"
- 960 GETA$:IFA$=""THEN960
- 970 IFA$="Y"THENSC=0:Q=0:HS=0:WP=0:LP=0:LV=1:GOTO20
- 980 POKE53280,14:POKE53281,6:PRINT"[147][154]";:END
- 7999 STOP
- 8000 IN$="":PRINT" [157]";
- 8010 P=PEEK(209)+PEEK(210)*256+POS(0):CH=32:RC=128:TT=0
- 8020 POKEP,CH+RC:TT=TT+1:IFTT>5THENTT=0:RC=128-RC:GOTO8020
- 8025 IFPEEK(653)=2THENGOTO900
- 8030 GETX$:IFX$=""THEN8020
- 8071 IFX$=MID$(A$(R),K,1)THENGOTO8080
- 8072 POKE54296,15:POKE54277,45:POKE54278,165:POKE54276,33:POKE54273,6:POKE54272,5
- 8073 FORT=1TO200:NEXT:POKE54276,32:POKE54273,0:POKE54272,0:GOTO8010
- 8080 POKEP,CH:PRINTX$" [157]";:RETURN
- 60000 DATACOMPUTERS ARE ALOT OF FUN,XAVIER IS IN THE KITCHEN MAKING PIE
- 60010 DATAJOE IS BUILDING A HOUSE,CHUCK IS DRINKING A BEER
- 60020 DATASTEVE IS TAKING A SNOOZE,SOMEBODY IS TALKING ON THE PHONE
- 60030 DATAHER CAR WAS IN THE ACCIDENT,THE PICTURE FELL FROM THE WALL
- 60040 DATATHE TELEVISION WAS LEFT ON,I AM PLAYING TYPE IT
- 60050 DATAANSWER THE TELEPHONE,TURN OFF ALL THE LIGHTS PLEASE
- 60060 DATALET'S GO FOR A WALK,PAPER IS MADE FROM TREES
- 60070 DATATHAT IS NOT IN FASHION,TAKE THE DISK OUT OF THE DRIVE
- 60080 DATAYOU DON'T PLAY ENOUGH VIDEO GAMES,CHUCK WON BIG AT THE DOG TRACK
- 60090 DATAGARFIELD IS A FUNNY LITTLE CAT,I GOT HIGH SCORE ON PAC MAN
- 60100 DATASCHOOL WAS HARD WORK TODAY,CHARLIE BROWN EATS CHEERIOS
- 60110 DATAPITFALL IS A GREAT GAME,KITT IS A BONUS CAR
- 60120 DATAHAPPY DAYS IS ON THE TV,WE ARE GOING TO THE MOVIES
- 60130 DATAPLEASE GO DOWN AND GET ME A PAPER,WE SIGNED IN AT THE MOTEL
- 60140 DATAA FAKE BILL SURFACED AT THE STORE,JOE WENT TO KMART YESTERDAY
- 60150 DATAPLATINUM BLONDE ARE A GOOD GROUP,GHOSTBUSTERS WAS A GREAT MOVIE
- 60160 DATADINNER TASTED GOOD TONIGHT,TIME TO GO TO BED
- 60170 DATA7UP HAS NO CAFFEINE,THE DRAPES WEREN'T CLEANED
- 60180 DATATHE COMMODORE 64 IS A GREAT COMPUTER
- 60190 DATACHUCK OWES ALOT OF MONEY,I SUBSCRIBE TO COMPUTE! MAGAZINE
- 60200 DATATHE BED WAS MADE MESSILY,ARE YOU A MEMBER OF TPUG?
- 60210 DATATHE PROFESSOR ATE BAGELS FOR DINNER,STRONG WINDS WERE FORECAST
- 60220 DATATHE DOG TRACK IS OPEN TONIGHT,GO AND WAKE YOUR FATHER UP
- 60230 DATASHE ORDERED COFFEE AND A DOUGHNUT,SHARKY'S MACHINE IS ON TV NOW
- 60240 DATATHE ARCADE IS OPEN,I JUST PLAYED MS. PAC MAN
- 60250 DATATHIS IS THE LAST SENTENCE FOR TYPE IT
-