home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / genie-commodore-file-library / C64Educational / 64-SPELLER (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  4.6 KB  |  155 lines
  1. 0 REM *** THE 64 SPELLER ***
  2. 10 POKE53281,1:POKE53280,1:PRINTCHR$(144);CHR$(14);CHR$(147)
  3. 15 CLR
  4. 20 S=54272:V=53248
  5. 25 RESTORE
  6. 49 REM *** TITLE ***
  7. 50 FORX=1TO6:PRINT:NEXTX
  8. 55 PRINTTAB(13)"[212]HE 64 [211]PELLER"
  9. 60 PRINT:PRINTTAB(13)"BY [199]ARY [198]IELDS"
  10. 70 PRINT:PRINT:PRINT:PRINT
  11. 75 PRINTCHR$(18)"   [206][207][212][197] TO PARENT/TEACHER               "
  12. 80 PRINT:PRINTTAB(4)"[212]O CHANGE [215][207][210][196][211]/[196][197][198][201][206][201][212][201][207][206][211] - [198]1"
  13. 85 FORX=1TO40:PRINTCHR$(183);:NEXTX:GOSUB2000
  14. 87 FOR PR=0TO62:READPQ:POKE832+PR,PQ:NEXTPR
  15. 90 FOR X=1TO100
  16. 92 GETF1$:IFF1$=""THEN95
  17. 93 IFF1$=CHR$(133)THEN2500
  18. 95 NEXTX
  19. 99 REM *** DISPLAY WORDS ***
  20. 100 PRINTCHR$(147)
  21. 105 PRINT:PRINTCHR$(18)"[200]ERE ARE THE WORDS YOU WILL BE SPELLING":PRINTCHR$(146)
  22. 110 READA1$
  23. 120 IFA1$="-1"THEN150
  24. 125 READB1$,A2$,B2$
  25. 130 PRINTA1$:GOSUB2000
  26. 135 PRINTCHR$(145);TAB(20)A2$:GOSUB2000
  27. 140 GOTO110
  28. 150 PRINT:PRINTCHR$(18)" [208][210][197][211][211] ANY KEY TO BEGIN                "
  29. 155 PRINT:PRINT:PRINTTAB(3)"[212]O CHANGE [215][207][210][196][211]/[196][197][198][201][206][201][212][201][207][206][211] - [198]1"
  30. 158 FORX=1TO40:PRINTCHR$(183);:NEXTX:GOSUB2000
  31. 160 GETF1$:IFF1$=""THEN160
  32. 165 IFF1$=CHR$(133)THEN2500
  33. 190 RESTORE:FORPR=0TO62:READPQ:NEXTPR
  34. 200 PRINTCHR$(147)
  35. 210 READ A$,B$:CC=0
  36. 215 IF A$="-1"GOTO 1500
  37. 219 REM *** DISPLAY OF B$ 220-245
  38. 225 FORX=1TO6:PRINT:NEXTX
  39. 227 PRINT:PRINT
  40. 229 PRINT"[212]HIS DEFINES A WORD YOU KNOW."
  41. 230 FORX=1TO40:PRINTCHR$(183);:NEXTX:PRINT:PRINT
  42. 232 FORI=0TOLEN(B$)
  43. 235 POKES+24,6:POKES+1,126:POKES,6:POKES+5,120:POKES+6,30:POKES+4,33
  44. 240 PRINTLEFT$(B$,I+1):POKES+24,0
  45. 245 PRINTCHR$(145);CHR$(145):FORX=1TO40:NEXTX
  46. 247 POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0:NEXTI
  47. 270 PRINT:PRINT:FORX=1TO100:NEXTX
  48. 280 INPUT"[195]AN YOU SPELL THE WORD";C$
  49. 290 FORX=1TO50:NEXTX
  50. 300 IFC$=A$GOTO600
  51. 310 IFC$<>A$GOTO800
  52. 599 REM *** WINNING ROUTINE ***
  53. 600 PRINTCHR$(147):FORX=1TO9:PRINT:NEXTX
  54. 605 SM=24:REM *** START SMOKE LOCATION **
  55. 610 POKEV+4,200:POKEV+21,4:POKE2042,13:POKEV+29,4:REM EXPAND AND POSITION SPRITE
  56. 612 POKEV+41,0:REM MAKES TRAIN (SPRITE 2)BLACK
  57. 620 PRINT;A$:FORX=1TO200:NEXTX
  58. 622 PRINTCHR$(152);:FORX=1TO7:PRINTCHR$(178);:NEXTX
  59. 623 PRINT"[217]OU'RE ON THE RIGHT TRACK";:FORX=1TO6:PRINTCHR$(178);:NEXTX
  60. 624 PRINTCHR$(144)
  61. 625 FORTN=200TO24STEP-8:REM SPRITE MOVEMENT COUNTER
  62. 644 POKES+24,15:POKES+1,145:POKES,0:POKES+5,0:POKES+6,240:POKES+4,129
  63. 645 POKEV+4,TN:POKEV+5,120:REM ** SPRITEMOVER X AND Y LOCATION
  64. 646 IFSM<1THENSM=1
  65. 647 SM=SM-1:REM *** MOVES SMOKE RIGHT TO LEFT
  66. 648 GOSUB750
  67. 650 FORPU=1TO40:NEXT PU
  68. 651 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0:NEXTTN
  69. 653 POKES+24,15:POKES+1,155:POKES,255:POKES+5,0:POKES+6,240:POKES+4,17:REM TOOT
  70. 655 PRINTCHR$(19):FORX=1TO6:PRINT:NEXTX:PRINTTAB(14)"[217]OU GOT IT!!"
  71. 657 FORX=1TO500:NEXTX
  72. 658 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
  73. 659 FORX=1TO300:NEXTX:REM PAUSE BETWEEN TOOTS
  74. 660 POKES+24,15:POKES+1,155:POKES,255:POKES+5,0:POKES+6,240:POKES+4,17:REM TOOT
  75. 661 FORX=1TO500:NEXTX
  76. 662 POKEV+21,0:REM *** TURNS SPRITE OFF
  77. 663 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
  78. 664 PRINTCHR$(147):FORX=1TO6:PRINT:NEXTX
  79. 670 PRINTCHR$(18)A$;CHR$(146);" IS THE CORRECT SPELLING"
  80. 675 GOSUB2000
  81. 680 FORX=1TO1000:NEXTX:PRINTCHR$(147):FORX=1TO6:PRINT:NEXT
  82. 700 GOTO200
  83. 730 REM **** SMOKE ROUTINE ***
  84. 750 PRINTCHR$(19);:FORX=1TO8:PRINT:NEXTX:REM MOVES SMOKE DOWN 6 LINES
  85. 760 PRINTTAB(SM);CHR$(31);CHR$(42);CHR$(32);CHR$(42):REM PRINTS SMOKE
  86. 780 PRINTCHR$(144)
  87. 790 RETURN
  88. 799 REM *** INCORRECT ROUTINE ***
  89. 800 PRINTCHR$(147)
  90. 801 FORX=1TO6:PRINT:NEXTX
  91. 802 PRINT"[217]OUR ANSWER ";CHR$(18);C$;CHR$(146);" IS INCORRECT."
  92. 805 REM *** BUZZ SOUND ***
  93. 810 POKES+24,15:POKES+1,3:POKES,255:POKES+5,0:POKES+6,240:POKES+4,33
  94. 820 FORX=1TO600:NEXTX
  95. 825 POKES+24,15:POKES+1,34:POKES,75:POKES+5,128:POKES+6,128:POKES+4,39
  96. 830 FORX=1TO600:NEXTX
  97. 840 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
  98. 865 PRINT:PRINT"[212]RY AGAIN"
  99. 870 FORX=1TO800:NEXTX
  100. 880 PRINTCHR$(147):FORX=1TO6:PRINT:NEXTX
  101. 890 PRINTB$:PRINT:FORX=1TO500:NEXTX
  102. 892 PRINTCHR$(18);"[215]OULD YOU LIKE A CLUE? [208]RESS [198]1 "
  103. 893 GETCL$:IFCL$=""THEN893
  104. 894 IFCL$<>CHR$(133)THEN900
  105. 895 CC=CC+1:PRINT:PRINT:PRINTTAB(15);LEFT$(A$,CC):FORX=1TO500:NEXTX
  106. 896 PRINTCHR$(147):FORX=1TO6:PRINT:NEXTX
  107. 898 PRINTB$:PRINT:PRINT
  108. 900 INPUT"[208]LEASE SPELL THE WORD ";C$
  109. 910 GOTO290
  110. 1499 REM *** END ROUTINE ***
  111. 1500 FORX=1TO500:NEXT:C=0
  112. 1510 PRINTCHR$(147):FORX=1TO6:PRINT:NEXTX
  113. 1790 POKES+24,15:POKES+1,130:POKES,0:POKES+5,9:POKES+6,240:POKES+4,21
  114. 1795 PRINT"[199][210][197][193][212] YOU GOT THEM ALL [210][201][199][200][212]!!":C=C+1
  115. 1797 FORX=1TO600:NEXTX:PRINTCHR$(147)
  116. 1800 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
  117. 1810 FORX=1TO6:PRINT:NEXTX
  118. 1820 IFC<4GOTO1790
  119. 1830 PRINTCHR$(147):RESTORE:FORPR=0TO62:READPQ:NEXTPR
  120. 1840 PRINTCHR$(18)" [200]ERE ARE YOUR SPELLING WORDS AGAIN. "
  121. 1850 READA1$
  122. 1855 IFA1$="-1"THENEND
  123. 1860 READB1$,A2$,B2$
  124. 1880 PRINTA1$;:PRINTTAB(20)A2$
  125. 1890 GOTO1850
  126. 1999 REM **** BEEP SOUND ****
  127. 2000 POKES+24,15:POKES+1,45:POKES,0:POKES+5,9:POKES+6,0:POKES+4,17
  128. 2010 FORX=1TO400:NEXTX
  129. 2020 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
  130. 2030 RETURN
  131. 2499 REM **** ADD DATA ROUTINE ***
  132. 2500 PRINTCHR$(147)
  133. 2510 PRINT:PRINT:PRINT
  134. 2520 PRINT"[215]ORDS AND DEFINITIONS ARE STORED IN     [196]ATA LINES"
  135. 2525 PRINT"[212]HESE ARE LINES 2999-4999"
  136. 2530 PRINT:PRINT"[215]HEN REPLACING, BE SURE TO ENTER:"
  137. 2540 PRINT:PRINT" [196][193][212][193] LINE FOLLOWED BY 'DATA'"
  138. 2545 PRINT" THEN THE [215][207][210][196] FOLLOWED BY ACOMMA"
  139. 2550 PRINT" THEN THE [196][197][198][201][206][201][212][201][207][206] NO COMMA"
  140. 2555 PRINT:PRINT"[210]EMEMBER- THE DEFINITON CAN NOT BE OVER 39 CHARACTERS LONG"
  141. 2600 PRINT:PRINTCHR$(18)"[208]RESS [210]ETURN TO LIST DATA LINES";:INPUTF2$
  142. 2900 LIST2999-4999
  143. 2950 DATA0,0,0,25,191,255,31,191,255,31,156,6,15,12,244, 15
  144. 2951 DATA45,244,95,252,180,127,252,116,255,252,52,255,255,252,127, 255
  145. 2952 DATA254,95,255,255,3,255,255,3,255,255,15,254,0,31,252, 254
  146. 2953 DATA63,253,131,120,61,57,243,157,57,246,193,131,3,128,254
  147. 2999 REM *** DATA LINES ***
  148. 3000 DATA "DOG","[193] FOUR LEGGED PET THAT BARKS"
  149. 3002 DATA "PENCIL","[217]OU USE IT TO WRITE AT SCHOOL"
  150. 3004 DATA "ELEPHANT","[212]HE BIGGEST ANIMAL ON LAND"
  151. 3006 DATA "ALPHABET","[215]HAT ALL THE A,B,C'S ARE CALLED"
  152. 3024 DATA "MORNING","[212]IME OF DAY WHEN YOU FIRST WAKE UP"
  153. 3028 DATA "FRIEND","[211]OMEONE YOU LIKE VERY MUCH"
  154. 5000 DATA "-1","-1","-1","-1"
  155.