home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
8bitfiles.net/archives
/
archives.tar
/
archives
/
genie-commodore-file-library
/
C64Adventure
/
STONEVILLE
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2019-04-13
|
13KB
|
418 lines
5 REM ADAPTED TO COMMODORE COMPUTERS
7 REM BY DOUG YODER & NICHOLAS FIELDS
8 REM IN NORTHWOOD, ENGLAND, 1983
10 L=9
50 DIMI$(33),O$(33),O(33),L$(37),D$(3,37),D(3,37)
110 PRINT"[147]"TAB(10)"STONEVILLE MANOR"
400 FORX=1TO33:READI$(X),O$(X),O(X):NEXTX
430 FORX=1TO37:READL$(X):NEXTX
460 FORY=1TO37:FORX=1TO3:READD$(X,Y),D(X,Y):NEXTX:NEXTY
490 FORX=1TO3:READP$(X):NEXTX
520 FORX=1TO8:READVE(X):NEXTX
550 FORX=1TO3:Z=INT(89*RND(1))+11:N$(X)=STR$(Z):NEXTX
590 FORX=1TO3
600 Z=INT(3*RND(1))+1
610 IFS(Z)=ZTHEN600
620 S$(Z)=N$(X):S(Z)=Z:NEXTX
630 REM
650 PRINT:PRINT:PRINT:PRINT
670 INPUT"DO YOU WANT INSTRUCTIONS";C$
680 IFC$="Y"THENGOSUB7500
1000 PRINT"[147]"
1010 PRINT"LOCATION[146]:";:PRINTL$(L)
1020 PRINT"DIRECTION[146]:";
1030 FORX=1TO3:GOSUB5000:NEXTX
1060 PRINT"VISIBLE OBJECTS[146]:";
1070 IFL=30ANDO(13)THEN1190
1075 IFL=31ANDO(13)THEN1190
1085 FORX=1TO33:IFO(X)=LTHENPRINTO$(X)
1100 NEXTX
1110 GOSUB5200
1190 PRINT:INPUT"NOW WHAT";C$
1220 IFLEFT$(C$,3)="GET"THEN2030
1225 IFC$="DROP SNORKEL"THEN3640
1230 IFLEFT$(C$,4)="DROP"THEN2190
1240 IFLEFT$(C$,8)="TAKE INV"THEN2350
1260 IFC$="ENTER VENT"THEN2395
1270 IFC$="ENTER BALLOON"THEN2540
1280 IFC$="ENTER LAKE"THEN2600
1290 IFC$="ENTER DOOR"THEN2650
1300 IFC$="ENTER STORE"THEN2680
1320 IFLEFT$(C$,5)="ENTER"THEN2750
1340 IFLEFT$(C$,7)="EXAMINE"THEN2840
1350 IFLEFT$(C$,4)="LOOK"THEN2850
1360 IFLEFT$(C$,6)="GO JOG"THEN3000
1370 IFLEFT$(C$,4)="GO E"ANDL=32THEN3950
1380 IFLEFT$(C$,4)="GO O"THEN3030
1390 IFLEFT$(C$,2)="GO"THEN3080
1400 IFC$="PET SERVAL"THEN3130
1410 IFC$="FEED SERVAL"THEN3150
1420 IFC$="GIVE TROUT"THEN3150
1430 IFLEFT$(C$,8)="CUT TREE"THEN3190
1435 IFLEFT$(C$,10)="CLIMB TREE"THEN3800
1440 IFLEFT$(C$,9)="CHOP TREE"THEN3190
1450 IFLEFT$(C$,4)="DIVE"THEN3210
1460 IFC$="END GAME"THENPRINT"[147]":END
1470 IFLEFT$(C$,3)="BUY"ANDL=10THEN2060
1475 IFC$="REMOVE COVER"THEN3250
1480 IFLEFT$(C$,9)="OPEN VENT"THEN3250
1485 IFC$="OPEN BOOK"THEN2850
1490 IFC$="OPEN DOOR"THEN3295
1495 IFC$="OPEN CREDENZA"THEN2850
1500 IFC$="OPEN BAG"THEN2850
1510 IFC$="OPEN SAFE"THEN7000
1520 IFC$="UNLOCK DOOR"THEN3295
1540 IFC$="INFLATE RAFT"THEN3350
1550 IFC$="INFLATE BALLOON"THEN3380
1560 IFC$="BUILD BALLOON"THEN3380
1570 IFC$="FLY BALLOON"THEN3460
1580 IFC$="SAIL BALLOON"THEN3460
1590 IFC$="READ WILL"ANDF=1THEN7200
1600 IFC$="READ BOOK"THEN2850
1605 IFC$="READ SIGN"THEN3900
1610 IFC$="SAVE GAME"THEN8400
1620 IFC$="CLEAR SCREEN"THEN1000
1990 PRINT"DON'T UNDERSTAND":GOTO1190
2030 IFC$="GET TROUT"ANDL=29ANDO(10)THEN2032
2031 GOTO2035
2032 PRINT"IT SLIPPED OUT OF YOUR HANDS":GOTO1190
2035 IFC$="GET PICTURE"ANDL=16THENPRINT"TOO VALUABLE":GOTO1190
2040 IFL=10THENPRINT"CAN ONLY BUY FROM STORE":GOTO1190
2045 IFC$="GET TABLE"ANDL=37THENPRINT"IT'S NAILED DOWN":GOTO1190
2050 IFS=1THEN6000
2055 IFI=4THENPRINT"INVENTORY TOO HEAVY":GOTO1190
2060 IFC$="GET MASK"THEN6150
2065 IFC$="GET SNORKEL"THEN6100
2070 FORX=1TO19:G=LEN(I$(X))
2090 IFMID$(C$,5,G)=I$(X)ANDO(X)=0THENPRINT"ALREADY HAVE OBJECT":GOTO1190
2100 IFMID$(C$,5,G)=I$(X)ANDO(X)=LTHENO(X)=0:I=I+1:GOTO1000
2110 NEXTX
2120 IFC$="GET SERVAL"ANDO(30)=LTHEN6200
2130 IFC$="GET CREDENZA"ANDL=14THENPRINT"CAN'T LIFT IT":GOTO1190
2140 IFC$="GET CASE"ANDO(26)=LTHENPRINT"NOT THIRSTY":GOTO1190
2150 IFC$="GET SAFE"ANDO(25)=LTHENPRINT"SAFE IS SECURED TO WALL":GOTO1190
2170 GOTO1990
2190 FORX=1TO19:G=LEN(I$(X))
2210 IFMID$(C$,6,G)=I$(X)ANDO(X)=0THEN2240
2220 NEXTX
2230 GOTO1990
2240 IFX=8ANDL=28THENO(8)=5:I=I-1:PRINT"RAFT DRIFTS AWAY"
2241 IFX=8ANDL=28THENFORI=1TO2000:NEXTI:GOTO1000
2245 IFX=8ANDL=29THENO(8)=5:I=I-1:PRINT"RAFT DRIFTS AWAY"
2247 IFX=8ANDL=29THENFORI=1TO2000:NEXTI:GOTO1000
2270 I=I-1
2280 IFL=28THENO(X)=30:GOTO1000
2290 IFL=29THENO(X)=31:GOTO1000
2300 O(X)=L:GOTO1000
2350 FORX=1TO19:IFO(X)=0THENPRINTO$(X)
2370 NEXTX
2380 GOTO1190
2395 FORX=1TO8:IFVE(X)=LTHEN2415
2405 NEXTX
2410 GOTO1990
2415 IFO(8)=0ANDR=1THENPRINTP$(2):GOTO1190
2420 FORX=1TO4:IFO(X)=0THENPRINTP$(2):GOTO1190
2430 NEXTX
2450 IFL=13ANDC1=0THENPRINTP$(1):GOTO1190
2460 IFL=14ANDC2=0THENPRINTP$(1):GOTO1190
2470 IFL=17ANDC3=0THENPRINTP$(1):GOTO1190
2480 IFL=18ANDC4=0THENPRINTP$(1):GOTO1190
2485 IFW=0THENPRINT"YOU WEIGH TOO MUCH":GOTO1190
2490 IFL=13ANDC1=1THENL=21:GOTO1000
2500 IFL=14ANDC2=1THENL=24:GOTO1000
2510 IFL=17ANDC3=1THENL=26:GOTO1000
2520 IFL=18ANDC4=1THENL=27:GOTO1000
2530 GOTO1190
2540 IFH=0THENPRINT"NOT READY YET":GOTO1190
2550 IFL=8THENL=34:GOTO1000
2560 IFL=36THENL=35:GOTO1000
2570 PRINT"CAN'T FIND":GOTO1190
2600 IFL<>5THEN1190
2610 IFO(8)THENPRINT"NEED SOMETHING TO FLOAT ON":GOTO1190
2630 IFR=0THENPRINT"RAFT IS TOO FLAT":GOTO1190
2640 L=28:GOTO1000
2650 IFL=16ANDK=0THENPRINT"DOOR IS LOCKED":GOTO1190
2655 IFL=20THENL=16:K=1:GOTO1000
2660 IFL=16THENL=20:GOTO1000
2670 GOTO1990
2680 IFL<>9THENGOTO1990
2690 FORX=1TO19
2700 IFO(X)=0THENPRINT"CAN'T ENTER STORE WITH INVENTORY":GOTO1190
2710 NEXTX
2720 L=10:GOTO1000
2750 IFC$="ENTER MANOR"ANDL=9THENL=12:GOTO1000
2760 IFC$="ENTER MANOR"ANDL=1THENL=17:GOTO1000
2770 IFC$="ENTER HOSPITAL"ANDL=9THENL=11:GOTO1000
2780 IFC$="ENTER TUNNEL"ANDL=31ANDO(13)=0THENL=32:GOTO1000
2785 IFC$="ENTER SHACK"ANDL=36THENL=L+1:GOTO1000
2790 IFC$="ENTER CREEK"ANDL=4THENPRINT"YOU SLIPPED AND FELL"
2791 FORI=1TO2000:NEXTI:S=1:L=11:GOTO1000
2800 IFC$="ENTER GORGE"ANDL=8THENPRINT"TOO STEEP":GOTO1190
2810 IFC$="ENTER SHACK"ANDL=36THENL=37:GOTO1000
2820 GOTO1990
2840 G=LEN(C$)-8:Q$=MID$(C$,9,G):GOTO2860
2850 G=LEN(C$)-5:Q$=MID$(C$,6,G)
2860 FORX=1TO33:IFQ$=I$(X)ANDO(X)=LTHEN2900
2875 IFQ$=I$(X)ANDO(X)=0THEN2900
2880 NEXTX
2890 GOTO1990
2900 IFQ$="BOTTLE"THENPRINTP$(3);N$(1):GOTO1190
2910 IFQ$="GOBLET"THENPRINTP$(3);N$(2):GOTO1190
2920 IFQ$="TABLE"THENPRINT"ON TOP IS A NOTE WITH THE NUMBER"N$(3):GOTO1190
2930 IFQ$="CASE"THENPRINT"ONE BOTTLE IS MISSING":GOTO1190
2940 IFQ$="BOOK"THEN6550
2950 IFQ$="CREDENZA"ANDO(13)=40THENPRINT"INSIDE IS A SWIM MASK":GOTO1190
2960 IFQ$="BAG"ANDO(19)=40THENPRINT"INSIDE IS A SNORKEL":GOTO1190
2970 IFQ$="PICTURE"THENPRINT"BEHIND PICTURE IS A SAFE":E=1:GOTO1190
2980 PRINT"NOTHING UNUSUAL":GOTO1190
3000 IFO(11)THENPRINT"NEED SHOES":GOTO1190
3010 IFL>9THENPRINT"CAN'T JOG HERE":GOTO1190
3015 W=1:PRINT"WHEW!... DONE":GOTO1190
3020 IFL=28THENL=5:GOTO1000
3025 GOTO1990
3030 IFS=1THENPRINT"NOT WELL":GOTO1190
3040 IFL=21ANDC1=0THENPRINTP$(1):GOTO1190
3050 IFL=24ANDC2=0THENPRINTP$(1):GOTO1190
3060 IFL=26ANDC3=0THENPRINTP$(1):GOTO1190
3070 IFL=27ANDC4=0THENPRINTP$(1):GOTO1190
3080 IFLEFT$(C$,4)="GO E"ANDL=18THEN6300
3090 FORX=1TO3:IFMID$(C$,4,1)=D$(X,L)THENL=D(X,L):GOTO1000
3110 NEXTX
3120 PRINT"DIRECTION NOT CLEAR":GOTO1190
3130 IFV=0ANDL=18THEN6200
3140 GOTO1990
3150 IFV=1THEN1990
3160 IFL<>18THEN1990
3170 IFO(14)ORL<>18THENPRINT"NEED FOOD":GOTO1190
3180 PRINT"SERVAL TOOK TROUT AND ESCAPED":IFO(14)=0THENI=I-1
3185 V=1:O(14)=40:O(30)=40:FORI=1TO2000:NEXTI:GOTO1000
3190 IFL=2ANDO(12)=0ORO(12)=LTHENO(4)=2:GOTO1000
3200 GOTO1990
3210 IFL=28ANDO(8)=0ANDO(19)=0THENO(8)=5:I=I-1:L=30:PRINT"RAFT DRIFTS AWAY":GOTO1000
3215 IFL=29ANDO(8)=0ANDO(19)=0THENO(8)=5:I=I-1:L=31:PRINT"RAFT DRIFTS AWAY":GOTO1000
3220 IFL=28ANDO(19)=0THENL=30:GOTO1000
3225 IFL=29ANDO(19)=0THENL=31:GOTO1000
3230 IFL=28ORL=29THENPRINT"NEED SNORKEL":GOTO1190
3240 GOTO1990
3250 IFL=13THENC1=1:GOTO1000
3255 IFL=21THENC1=1:GOTO1000
3260 IFL=14THENC2=1:GOTO1000
3265 IFL=24THENC2=1:GOTO1000
3270 IFL=17THENC3=1:GOTO1000
3275 IFL=26THENC3=1:GOTO1000
3280 IFL=18THENC4=1:GOTO1000
3285 IFL=27THENC4=1:GOTO1000
3290 GOTO1990
3295 IFL=16ORL=20THEN3305
3300 GOTO1990
3305 IFL=16ANDK=0THENPRINT"CAN'T! DOOR IS LOCKED FROM OTHER SIDE":GOTO1190
3310 PRINT"OK":GOTO1190
3350 IFL<>5THENPRINT"NOT HERE":GOTO1190
3360 IFR=1THENPRINT"ALREADY INFLATED":GOTO1190
3370 PRINT"OK":R=1:GOTO1190
3380 IFL<>8THENPRINT"NOT HERE":GOTO1190
3390 FORX=1TO6:IFO(X)=0ORO(X)=8THENHB=HB+1
3400 NEXTX
3405 IFHB=6THEN3420
3410 PRINT"NOT READY":HB=0:GOTO1190
3420 FORX=1TO6:IFO(X)=0THENI=I-1
3430 O(X)=40:NEXTX
3450 H=1:GOTO1000
3460 IFH=0THENPRINT"NOT READY":GOTO1190
3470 IFL=8ORL=36THENPRINT"NEED TO GET IN FIRST":GOTO1190
3480 IFL=34THEN3500
3485 IFL=35THEN3570
3490 GOTO1990
3500 Z=13:Y=5:GOSUB6400
3510 Z=8:Y=11:GOSUB6400
3520 Z=3:Y=17:GOSUB6400
3530 Z=8:Y=23:GOSUB6400
3540 Z=13:Y=29:GOSUB6400
3550 PRINT"[147]"
3560 L=35:GOTO1000
3570 Z=13:Y=29:GOSUB6400
3580 Z=8:Y=23:GOSUB6400
3590 Z=3:Y=17:GOSUB6400
3600 Z=8:Y=11:GOSUB6400
3610 Z=13:Y=5:GOSUB6400
3620 PRINT"[147]"
3630 L=34:GOTO1000
3640 IFO(19)THENPRINT"DON'T HAVE":GOTO1190
3650 IFL>27ANDL<32THENPRINT"YOU QUICKLY GRAB IT BACK!":GOTO11900
3660 O(19)=L:I=I-1:GOTO1000
3800 IFL<>2THEN1990
3810 PRINT"YOU FELL OFF":S=1:L=11:FORZZ=1TO1000:NEXT:GOTO1000
3900 IFO(9)=0ORO(9)=LTHENPRINT"SIGN SAYS:AN APPROPRIATE PLACE":GOTO1190
3910 PRINT"CAN'T FIND":GOTO1190
3950 IFO(19)=0THEN3080
3960 PRINT"NEED SNORKEL"GOTO1190
5000 REM DIRECTION
5010 IFD$(X,L)="-"THENRETURN
5020 IFD$(X,L)="O"THENPRINT"OUT":RETURN
5030 IFD$(X,L)="N"THENPRINT"NORTH":RETURN
5040 IFD$(X,L)="E"THENPRINT"EAST":RETURN
5050 IFD$(X,L)="S"THENPRINT"SOUTH":RETURN
5060 IFD$(X,L)="W"THENPRINT"WEST":RETURN
5070 IFD$(X,L)="U"THENPRINT"UP":RETURN
5080 IFD$(X,L)="D"THENPRINT"DOWN":RETURN
5200 REM OBJECTS
5210 IFO(13)=0ANDL=31THENPRINT"AN UNDERWATER TUNNEL":RETURN
5220 IFL=13ORL=14ORL=17ORL=18THENPRINT"VENT"
5230 IFL=13ANDC1=1THENPRINT"VENT COVER":RETURN
5240 IFL=14ANDC2=1THENPRINT"VENT COVER":RETURN
5250 IFL=17ANDC3=1THENPRINT"VENT COVER":RETURN
5260 IFL=18ANDC4=1THENPRINT"VENT COVER":RETURN
5270 IFH=1ANDL=8ORL=36THENPRINT"HOT AIR BALLOON":RETURN
5280 Z=INT(10*RND(1))+1
5290 IFL=6ANDZ=1THENPRINT"THE BUTLER WITH TWO STICKS OF DYNAMITE":RETURN
5300 IFL=3ANDZ=3THENPRINT"THE MAID WITH A PACK OF BLOODHOUNDS":RETURN
5310 IFL=7ANDZ=5THENPRINT"THE GARDENER WITH A BULLDOZER":RETURN
5320 IFL=33ANDZ<5THENPRINT"A BAT PASSES CLOSERE BY":RETURN
5330 IFL=27ANDZ<3THENPRINT"YOU HAVE COBWEBS IN YOUR HAIR":RETURN
5340 IFL=25ANDZ<3THENPRINT"A RODENT BRUSHES YOUR LEG":RETURN
5350 IF L=4ANDZ=7THENPRINT"A TOAD JUMPS ACROSS THE CREEK":RETURN
5360 IFL=28ANDO(14)=0ANDZ<5THENPRINT"A HUNGRY GULL CIRCLES OVERHEAD":RETURN
5370 IFL=2ANDZ=8THENPRINT"A PRIMATE WATCHES FROM ABOVE":RETURN
5390 RETURN
6000 IF C$="GET WELL"THENS=0:PRINT"RECOVERED":GOTO 1190
6020 GOTO1990
6100 IFO(19)=0THENPRINT"ALREADY HAVE OBJECT":GOTO1190
6115 IFO(19)=40ANDO(7)=0THENO(19)=0:I=I+1:GOTO1000
6120 IFO(19)=40ANDO(7)=LTHENO(19)=0:I=I+1:GOTO1000
6130 IF0(19)=LTHENO(19)=0:I=I+1:GOTO1000
6140 GOTO1990
6150 IFO(13)=0THENPRINT"ALREADY HAVE":GOTO1190
6160 IFO(13)=40ANDL=14THENO(13)=0:I=I+1:GOTO1000
6170 IFO(13)=LTHENO(13)=0:I=I+1:GOTO1000
6180 GOTO1990
6200 REM
6210 PRINT"YOU HAD JUST ENOUGH STRENGTH TO GET AWAY"
6211 FORX=1TO3000:NEXTX:S=1:L=11:GOTO1000
6300 IFV=0THENPRINT"SERVAL WON'T LET YOU":GOTO1190
6310 L=19:GOTO1000
6400 REM
6410 PRINT"[147]":FORI=1TOZ:PRINT:NEXT
6420 PRINTTAB(Y)"- - -"
6425 PRINTTAB(Y-1)"- -"
6430 PRINTTAB(Y-2)"========="
6440 PRINTTAB(Y-1)"- -"
6445 PRINTTAB(Y)"- -"
6450 PRINTTAB(Y+1)".-."
6455 PRINTTAB(Y+1)". ."
6460 PRINTTAB(Y+1)"---"
6470 PRINTTAB(Y+1)"***"
6480 PRINTTAB(Y+1)"---"
6485 FORX=1TO1000:NEXTX
6490 RETURN
6500 REM
6510 RETURN
6550 PRINT"[147]"
6560 PRINT:PRINTTAB(5)"HOW TO BUILD A HOT AIR BALLOON"
6570 PRINT:PRINTTAB(8)"#1 BALLOON"
6575 PRINTTAB(8)"#2 HEAT SOURCE"
6580 PRINTTAB(8)"#3 FUEL"
6585 PRINTTAB(8)"#4 GONDOLA OR CONTAINER"
6590 PRINTTAB(8)"#5 CABLE OR TWINE"
6595 PRINTTAB(8)"#6 MATCHES OR LIGHTER"
6600 PRINT"BUILD A BALLOON AT AN APPROPRIATE PLACE"
6605 PRINTTAB(8)
6610 INPUT"PRESS RETURN TO CONTINUE";C$
6620 GOTO1000
7000 REM
7010 IFE=0THENPRINT"CAN'T FIND":GOTO1190
7030 IFL<>16THENPRINT"NOT HERE":GOTO1190
7040 PRINT"COMBINATION LOCK"
7050 INPUT"ENTER FIRST NUMBER";F$(1)
7055 GOSUB6500
7060 IFVAL(F$(1))<>VAL(N$(1))THENPRINT"NOT CORRECT":GOTO1190
7070 INPUT"ENTER SECOND NUMBER";F$(2)
7075 GOSUB6500
7080 IFVAL(F$(2))<>VAL(N$(2))THENPRINT"NOT CORRECT":GOTO1190
7090 INPUT"ENTER LAST NUMBER";F$(3)
7095 GOSUB6500
7100 IFVAL(F$(3))<>VAL(N$(3))THENPRINT"NOT CORRECT":GOTO1190
7105 F=1
7110 PRINT"CLICK!..........INSIDE IS A WILL":GOTO1190
7200 PRINT"[147]"
7210 FORI=1TO6:PRINT:NEXTI
7220 PRINT" **************************************"
7225 PRINT" *";SPC(36);"*"
7230 PRINT" * WILL *"
7235 PRINT" * *"
7240 PRINT" * I,MR STONE,LEAVE ALL MY WORLDLY *"
7245 PRINT" * POSSESSIONS TO WHOMEVER OPENS THIS *"
7250 PRINT" * SAFE. *"
7255 PRINT" *";SPC(36);"*"
7260 PRINT" **************************************"
7265 PRINT
7270 PRINT" <<<CONGRATULATIONS>>>":END
7500 PRINT"[147]":PRINT
7510 PRINT"WELCOME TO STONEVILLE. YOU HAVE RECENTLY"
7520 PRINT"LEARNED THAT THE WEALTHY MR. STONE DIED AND"
7530 PRINT"RUMOUR HAS IT THAT THE ECCENTRIC MISER"
7540 PRINT"HAS LEFT HIS ENTIRE ESTATE TO WHOMEVER"
7550 PRINT"FINDS AND OPENS HIS SAFE. "
7560 PRINT
7570 PRINT"TO PLAY,YOU MUST MANIPULATE OBJECTS AND"
7580 PRINT"EXPLORE YOUR SURROUNDINGS BY USING TWO"
7590 PRINT"WORD COMMANDS. FOR EXAMPLE,'GET BASKET'"
7600 PRINT"OR'GO SOUTH'. TO SPEED UP DIRECTIONAL"
7605 PRINT"MOVEMENT,'GO' COMMANDS MAY BE SHORTENED"
7610 PRINT"TO INCLUDE 1 LETTER SUCH AS 'GO S'.":PRINT
7615 PRINT"THE COMMAND 'SAVE GAME' WILL PRESERVE"
7620 PRINT"YOUR PROGRESS FOR PLAY AT A LATER TIME"
7625 PRINT"OR IF YOU PREFER TO JUST END THE GAME"
7630 PRINT"THEN ENTER 'END GAME'. AND IF NEEDED"
7640 PRINT"'CLEAR SCREEN'WILL RESET YOUR LOCATION."
7680 INPUT"PRESS RETURN TO CONTINUE";C$:RETURN
8000 DATABALLOON,FALLEN WEATHER BALLOON,3,STOVE,SMALL WOOD BURNING STOVE
8005 DATA1,BASKET,LARGE WICKER BASKET,12
8010 DATALOGS,LOGS,40,TWINE,ROLL OF TWINE,17,MATCHES,BOOK OF MATCHES,15
8020 DATABAG,BURLAP BAG,18,RAFT,INFLATABLE RAFT,1,SIGN,SIGN,8
8030 DATANET,FISH NET,7,SHOES,JOGGING SHOES,10,AXE,AXE,10
8040 DATAMASK,SWIM MASK,40,TROUT,TROUT,29,GOBLET,CRYSTAL GOBLET,19
8050 DATABOTTLE,EMPTY BOTTLE OF CHABLIS,33,BOOK,BOOK,14,PICTURE
8055 DATAPICTURE OF MR STONE,16
8060 DATASNORKEL,SNORKEL,40,MANOR,STONEVILLE MANOR,9,MANOR
8065 DATASTONEVILLE MANOR,1
8070 DATA SHACK,OLD ABANDONED SHACK,36,TABLE,WOODEN TABLE,37
8075 DATACREDENZA,WALNUT CREDENZA,14
8080 DATASAFE,SAFE,40,CASE,CASE OF CHABLIS,18,TREES,TREES,2
8090 DATADOOR,DOOR,20,DOOR,DOOR,16,SERVAL,AN IMPORTED SERVAL,18
8100 DATASTORE,GENERAL STORE,9,STAIRWAY,STAIRWAY,19,HOSPITAL,HOSPITAL,9
8110 DATAIN THE COURTYARD,IN A WOODED AREA,IN A MEADOW,ALONG A SLIPPERY CREEK
8115 DATAON THE BANK OF A LAKE,IN A BARREN FIELD,ON A ROCKY TRAIL
8120 DATAAT THE EDGE OF A GORGE,IN THE MAIN STREET,INSIDE THE GENERAL STORE
8125 DATAINSIDE THE HOSPITAL,IN THE FOYER,IN THE PARLOR
8130 DATA IN THE STUDY,IN AN ORIEL,IN THE GALLERY,IN THE ATRIUM
8135 DATAIN THE WEST WING OF THE WINE CELLER
8136 DATAIN THE EAST WING OF THE WINE CELLER
8140 DATAAT AN OUTLET IN THE DUCT
8141 DATAAT A FORK IN THE DUCT,AT A TURN IN THE DUCT
8142 DATA AT A FORK IN THE DUCT,AT A TURN IN THE DUCT
8143 DATA AT AN OUTLET IN THE DUCT
8150 DATAAT AN OUTLET IN THE DUCT,AT AN OUTLET IN THE DUCT
8151 DATAON THE LAKE,IN THE SOUTHERN BAY,UNDER THE SURFACE OF THE LAKE
8152 DATAUNDER THE SURFACE OF THE LAKE
8160 DATAALONG AN UNDERGROUND RIVER,INSIDE A CAVERN,IN A HOT AIR BALLOON
8161 DATAIN A HOT AIR BALLOON
8162 DATAON THE TOP OF A PLATEAU,INSIDE THE SHACK
8170 DATAW,2,S,4,-,0,E,1,S,3,N,9,N,2,E,4,-,0,W,3,E,5,N,1,W,4,-,0
8175 DATA-,0,S,9,E,7,-,0,W,6,E,8,-,0
8180 DATAW,7,-,0,-,0,S,2,N,6,-,0,O,9,-,0,-,0,O,9,-,0,-,0,O,9
8185 DATAS,13,-,0,N,12,E,14,S,17,W,13,E,15,S,16
8190 DATAW,14,-,0,-,0,N,14,W,17,-,0,O,1,N,13,E,16,E,19,-,0,-,0,W,18,U,20,-
8192 DATA0,D,19,-,0,-,0,O,13,S,22,-,0,N,21,E,23,-,0
8200 DATAW,22,N,24,S,25,O,14,S,23,-,0,N,23,W,26,-,0,O,17,D,27,E,25,O,18,U,26
8205 DATA-,0,O,5,S,29,-,0,N,28,-,0,-,0
8210 DATAU,28,S,31,-,0,U,29,N,30,-,0,E,31,W,33,-,0,E,32,-,0,-,0,O,8,-,0,-,0,O
8215 DATA36,-,0,-,0,-,0,-,0,-,0,O,36,-,0,-,0
8220 DATAVENT IS COVERED,SOMETHING IS TOO BIG
8225 DATAINSIDE IS A NOTE WITH THE NUMBER
8230 DATA13,14,17,18,21,24,26,27
8300 REM
8310 D$=CHR$(4)
8320 RETURN
8400 END
17746 PRINT