home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / genie-commodore-file-library / C64Adventure / STONEVILLE (.txt) < prev    next >
Commodore BASIC  |  2019-04-13  |  13KB  |  418 lines
  1. 5 REM ADAPTED TO COMMODORE COMPUTERS
  2. 7 REM BY DOUG YODER & NICHOLAS FIELDS
  3. 8 REM IN NORTHWOOD, ENGLAND, 1983
  4. 10 L=9
  5. 50 DIMI$(33),O$(33),O(33),L$(37),D$(3,37),D(3,37)
  6. 110 PRINT"[147]"TAB(10)"STONEVILLE MANOR"
  7. 400 FORX=1TO33:READI$(X),O$(X),O(X):NEXTX
  8. 430 FORX=1TO37:READL$(X):NEXTX
  9. 460 FORY=1TO37:FORX=1TO3:READD$(X,Y),D(X,Y):NEXTX:NEXTY
  10. 490 FORX=1TO3:READP$(X):NEXTX
  11. 520 FORX=1TO8:READVE(X):NEXTX
  12. 550 FORX=1TO3:Z=INT(89*RND(1))+11:N$(X)=STR$(Z):NEXTX
  13. 590 FORX=1TO3
  14. 600 Z=INT(3*RND(1))+1
  15. 610 IFS(Z)=ZTHEN600
  16. 620 S$(Z)=N$(X):S(Z)=Z:NEXTX
  17. 630 REM
  18. 650 PRINT:PRINT:PRINT:PRINT
  19. 670 INPUT"DO YOU WANT INSTRUCTIONS";C$
  20. 680 IFC$="Y"THENGOSUB7500
  21. 1000 PRINT"[147]"
  22. 1010 PRINT"LOCATION[146]:";:PRINTL$(L)
  23. 1020 PRINT"DIRECTION[146]:";
  24. 1030 FORX=1TO3:GOSUB5000:NEXTX
  25. 1060 PRINT"VISIBLE OBJECTS[146]:";
  26. 1070 IFL=30ANDO(13)THEN1190
  27. 1075 IFL=31ANDO(13)THEN1190
  28. 1085 FORX=1TO33:IFO(X)=LTHENPRINTO$(X)
  29. 1100 NEXTX
  30. 1110 GOSUB5200
  31. 1190 PRINT:INPUT"NOW WHAT";C$
  32. 1220 IFLEFT$(C$,3)="GET"THEN2030
  33. 1225 IFC$="DROP SNORKEL"THEN3640
  34. 1230 IFLEFT$(C$,4)="DROP"THEN2190
  35. 1240 IFLEFT$(C$,8)="TAKE INV"THEN2350
  36. 1260 IFC$="ENTER VENT"THEN2395
  37. 1270 IFC$="ENTER BALLOON"THEN2540
  38. 1280 IFC$="ENTER LAKE"THEN2600
  39. 1290 IFC$="ENTER DOOR"THEN2650
  40. 1300 IFC$="ENTER STORE"THEN2680
  41. 1320 IFLEFT$(C$,5)="ENTER"THEN2750
  42. 1340 IFLEFT$(C$,7)="EXAMINE"THEN2840
  43. 1350 IFLEFT$(C$,4)="LOOK"THEN2850
  44. 1360 IFLEFT$(C$,6)="GO JOG"THEN3000
  45. 1370 IFLEFT$(C$,4)="GO E"ANDL=32THEN3950
  46. 1380 IFLEFT$(C$,4)="GO O"THEN3030
  47. 1390 IFLEFT$(C$,2)="GO"THEN3080
  48. 1400 IFC$="PET SERVAL"THEN3130
  49. 1410 IFC$="FEED SERVAL"THEN3150
  50. 1420 IFC$="GIVE TROUT"THEN3150
  51. 1430 IFLEFT$(C$,8)="CUT TREE"THEN3190
  52. 1435 IFLEFT$(C$,10)="CLIMB TREE"THEN3800
  53. 1440 IFLEFT$(C$,9)="CHOP TREE"THEN3190
  54. 1450 IFLEFT$(C$,4)="DIVE"THEN3210
  55. 1460 IFC$="END GAME"THENPRINT"[147]":END
  56. 1470 IFLEFT$(C$,3)="BUY"ANDL=10THEN2060
  57. 1475 IFC$="REMOVE COVER"THEN3250
  58. 1480 IFLEFT$(C$,9)="OPEN VENT"THEN3250
  59. 1485 IFC$="OPEN BOOK"THEN2850
  60. 1490 IFC$="OPEN DOOR"THEN3295
  61. 1495 IFC$="OPEN CREDENZA"THEN2850
  62. 1500 IFC$="OPEN BAG"THEN2850
  63. 1510 IFC$="OPEN SAFE"THEN7000
  64. 1520 IFC$="UNLOCK DOOR"THEN3295
  65. 1540 IFC$="INFLATE RAFT"THEN3350
  66. 1550 IFC$="INFLATE BALLOON"THEN3380
  67. 1560 IFC$="BUILD BALLOON"THEN3380
  68. 1570 IFC$="FLY BALLOON"THEN3460
  69. 1580 IFC$="SAIL BALLOON"THEN3460
  70. 1590 IFC$="READ WILL"ANDF=1THEN7200
  71. 1600 IFC$="READ BOOK"THEN2850
  72. 1605 IFC$="READ SIGN"THEN3900
  73. 1610 IFC$="SAVE GAME"THEN8400
  74. 1620 IFC$="CLEAR SCREEN"THEN1000
  75. 1990 PRINT"DON'T UNDERSTAND":GOTO1190
  76. 2030 IFC$="GET TROUT"ANDL=29ANDO(10)THEN2032
  77. 2031 GOTO2035
  78. 2032 PRINT"IT SLIPPED OUT OF YOUR HANDS":GOTO1190
  79. 2035 IFC$="GET PICTURE"ANDL=16THENPRINT"TOO VALUABLE":GOTO1190
  80. 2040 IFL=10THENPRINT"CAN ONLY BUY FROM STORE":GOTO1190
  81. 2045 IFC$="GET TABLE"ANDL=37THENPRINT"IT'S NAILED DOWN":GOTO1190
  82. 2050 IFS=1THEN6000
  83. 2055 IFI=4THENPRINT"INVENTORY TOO HEAVY":GOTO1190
  84. 2060 IFC$="GET MASK"THEN6150
  85. 2065 IFC$="GET SNORKEL"THEN6100
  86. 2070 FORX=1TO19:G=LEN(I$(X))
  87. 2090 IFMID$(C$,5,G)=I$(X)ANDO(X)=0THENPRINT"ALREADY HAVE OBJECT":GOTO1190
  88. 2100 IFMID$(C$,5,G)=I$(X)ANDO(X)=LTHENO(X)=0:I=I+1:GOTO1000
  89. 2110 NEXTX
  90. 2120 IFC$="GET SERVAL"ANDO(30)=LTHEN6200
  91. 2130 IFC$="GET CREDENZA"ANDL=14THENPRINT"CAN'T LIFT IT":GOTO1190
  92. 2140 IFC$="GET CASE"ANDO(26)=LTHENPRINT"NOT THIRSTY":GOTO1190
  93. 2150 IFC$="GET SAFE"ANDO(25)=LTHENPRINT"SAFE IS SECURED TO WALL":GOTO1190
  94. 2170 GOTO1990
  95. 2190 FORX=1TO19:G=LEN(I$(X))
  96. 2210 IFMID$(C$,6,G)=I$(X)ANDO(X)=0THEN2240
  97. 2220 NEXTX
  98. 2230 GOTO1990
  99. 2240 IFX=8ANDL=28THENO(8)=5:I=I-1:PRINT"RAFT DRIFTS AWAY"
  100. 2241 IFX=8ANDL=28THENFORI=1TO2000:NEXTI:GOTO1000
  101. 2245 IFX=8ANDL=29THENO(8)=5:I=I-1:PRINT"RAFT DRIFTS AWAY"
  102. 2247 IFX=8ANDL=29THENFORI=1TO2000:NEXTI:GOTO1000
  103. 2270 I=I-1
  104. 2280 IFL=28THENO(X)=30:GOTO1000
  105. 2290 IFL=29THENO(X)=31:GOTO1000
  106. 2300 O(X)=L:GOTO1000
  107. 2350 FORX=1TO19:IFO(X)=0THENPRINTO$(X)
  108. 2370 NEXTX
  109. 2380 GOTO1190
  110. 2395 FORX=1TO8:IFVE(X)=LTHEN2415
  111. 2405 NEXTX
  112. 2410 GOTO1990
  113. 2415 IFO(8)=0ANDR=1THENPRINTP$(2):GOTO1190
  114. 2420 FORX=1TO4:IFO(X)=0THENPRINTP$(2):GOTO1190
  115. 2430 NEXTX
  116. 2450 IFL=13ANDC1=0THENPRINTP$(1):GOTO1190
  117. 2460 IFL=14ANDC2=0THENPRINTP$(1):GOTO1190
  118. 2470 IFL=17ANDC3=0THENPRINTP$(1):GOTO1190
  119. 2480 IFL=18ANDC4=0THENPRINTP$(1):GOTO1190
  120. 2485 IFW=0THENPRINT"YOU WEIGH TOO MUCH":GOTO1190
  121. 2490 IFL=13ANDC1=1THENL=21:GOTO1000
  122. 2500 IFL=14ANDC2=1THENL=24:GOTO1000
  123. 2510 IFL=17ANDC3=1THENL=26:GOTO1000
  124. 2520 IFL=18ANDC4=1THENL=27:GOTO1000
  125. 2530 GOTO1190
  126. 2540 IFH=0THENPRINT"NOT READY YET":GOTO1190
  127. 2550 IFL=8THENL=34:GOTO1000
  128. 2560 IFL=36THENL=35:GOTO1000
  129. 2570 PRINT"CAN'T FIND":GOTO1190
  130. 2600 IFL<>5THEN1190
  131. 2610 IFO(8)THENPRINT"NEED SOMETHING TO FLOAT ON":GOTO1190
  132. 2630 IFR=0THENPRINT"RAFT IS TOO FLAT":GOTO1190
  133. 2640 L=28:GOTO1000
  134. 2650 IFL=16ANDK=0THENPRINT"DOOR IS LOCKED":GOTO1190
  135. 2655 IFL=20THENL=16:K=1:GOTO1000
  136. 2660 IFL=16THENL=20:GOTO1000
  137. 2670 GOTO1990
  138. 2680 IFL<>9THENGOTO1990
  139. 2690 FORX=1TO19
  140. 2700 IFO(X)=0THENPRINT"CAN'T ENTER STORE WITH INVENTORY":GOTO1190
  141. 2710 NEXTX
  142. 2720 L=10:GOTO1000
  143. 2750 IFC$="ENTER MANOR"ANDL=9THENL=12:GOTO1000
  144. 2760 IFC$="ENTER MANOR"ANDL=1THENL=17:GOTO1000
  145. 2770 IFC$="ENTER HOSPITAL"ANDL=9THENL=11:GOTO1000
  146. 2780 IFC$="ENTER TUNNEL"ANDL=31ANDO(13)=0THENL=32:GOTO1000
  147. 2785 IFC$="ENTER SHACK"ANDL=36THENL=L+1:GOTO1000
  148. 2790 IFC$="ENTER CREEK"ANDL=4THENPRINT"YOU SLIPPED AND FELL"
  149. 2791 FORI=1TO2000:NEXTI:S=1:L=11:GOTO1000
  150. 2800 IFC$="ENTER GORGE"ANDL=8THENPRINT"TOO STEEP":GOTO1190
  151. 2810 IFC$="ENTER SHACK"ANDL=36THENL=37:GOTO1000
  152. 2820 GOTO1990
  153. 2840 G=LEN(C$)-8:Q$=MID$(C$,9,G):GOTO2860
  154. 2850 G=LEN(C$)-5:Q$=MID$(C$,6,G)
  155. 2860 FORX=1TO33:IFQ$=I$(X)ANDO(X)=LTHEN2900
  156. 2875 IFQ$=I$(X)ANDO(X)=0THEN2900
  157. 2880 NEXTX
  158. 2890 GOTO1990
  159. 2900 IFQ$="BOTTLE"THENPRINTP$(3);N$(1):GOTO1190
  160. 2910 IFQ$="GOBLET"THENPRINTP$(3);N$(2):GOTO1190
  161. 2920 IFQ$="TABLE"THENPRINT"ON TOP IS A NOTE WITH THE NUMBER"N$(3):GOTO1190
  162. 2930 IFQ$="CASE"THENPRINT"ONE BOTTLE IS MISSING":GOTO1190
  163. 2940 IFQ$="BOOK"THEN6550
  164. 2950 IFQ$="CREDENZA"ANDO(13)=40THENPRINT"INSIDE IS A SWIM MASK":GOTO1190
  165. 2960 IFQ$="BAG"ANDO(19)=40THENPRINT"INSIDE IS A SNORKEL":GOTO1190
  166. 2970 IFQ$="PICTURE"THENPRINT"BEHIND PICTURE IS A SAFE":E=1:GOTO1190
  167. 2980 PRINT"NOTHING UNUSUAL":GOTO1190
  168. 3000 IFO(11)THENPRINT"NEED SHOES":GOTO1190
  169. 3010 IFL>9THENPRINT"CAN'T JOG HERE":GOTO1190
  170. 3015 W=1:PRINT"WHEW!...  DONE":GOTO1190
  171. 3020 IFL=28THENL=5:GOTO1000
  172. 3025 GOTO1990
  173. 3030 IFS=1THENPRINT"NOT WELL":GOTO1190
  174. 3040 IFL=21ANDC1=0THENPRINTP$(1):GOTO1190
  175. 3050 IFL=24ANDC2=0THENPRINTP$(1):GOTO1190
  176. 3060 IFL=26ANDC3=0THENPRINTP$(1):GOTO1190
  177. 3070 IFL=27ANDC4=0THENPRINTP$(1):GOTO1190
  178. 3080 IFLEFT$(C$,4)="GO E"ANDL=18THEN6300
  179. 3090 FORX=1TO3:IFMID$(C$,4,1)=D$(X,L)THENL=D(X,L):GOTO1000
  180. 3110 NEXTX
  181. 3120 PRINT"DIRECTION NOT CLEAR":GOTO1190
  182. 3130 IFV=0ANDL=18THEN6200
  183. 3140 GOTO1990
  184. 3150 IFV=1THEN1990
  185. 3160 IFL<>18THEN1990
  186. 3170 IFO(14)ORL<>18THENPRINT"NEED FOOD":GOTO1190
  187. 3180 PRINT"SERVAL TOOK TROUT AND ESCAPED":IFO(14)=0THENI=I-1
  188. 3185 V=1:O(14)=40:O(30)=40:FORI=1TO2000:NEXTI:GOTO1000
  189. 3190 IFL=2ANDO(12)=0ORO(12)=LTHENO(4)=2:GOTO1000
  190. 3200 GOTO1990
  191. 3210 IFL=28ANDO(8)=0ANDO(19)=0THENO(8)=5:I=I-1:L=30:PRINT"RAFT DRIFTS AWAY":GOTO1000
  192. 3215 IFL=29ANDO(8)=0ANDO(19)=0THENO(8)=5:I=I-1:L=31:PRINT"RAFT DRIFTS AWAY":GOTO1000
  193. 3220 IFL=28ANDO(19)=0THENL=30:GOTO1000
  194. 3225 IFL=29ANDO(19)=0THENL=31:GOTO1000
  195. 3230 IFL=28ORL=29THENPRINT"NEED SNORKEL":GOTO1190
  196. 3240 GOTO1990
  197. 3250 IFL=13THENC1=1:GOTO1000
  198. 3255 IFL=21THENC1=1:GOTO1000
  199. 3260 IFL=14THENC2=1:GOTO1000
  200. 3265 IFL=24THENC2=1:GOTO1000
  201. 3270 IFL=17THENC3=1:GOTO1000
  202. 3275 IFL=26THENC3=1:GOTO1000
  203. 3280 IFL=18THENC4=1:GOTO1000
  204. 3285 IFL=27THENC4=1:GOTO1000
  205. 3290 GOTO1990
  206. 3295 IFL=16ORL=20THEN3305
  207. 3300 GOTO1990
  208. 3305 IFL=16ANDK=0THENPRINT"CAN'T! DOOR IS LOCKED FROM OTHER SIDE":GOTO1190
  209. 3310 PRINT"OK":GOTO1190
  210. 3350 IFL<>5THENPRINT"NOT HERE":GOTO1190
  211. 3360 IFR=1THENPRINT"ALREADY INFLATED":GOTO1190
  212. 3370 PRINT"OK":R=1:GOTO1190
  213. 3380 IFL<>8THENPRINT"NOT HERE":GOTO1190
  214. 3390 FORX=1TO6:IFO(X)=0ORO(X)=8THENHB=HB+1
  215. 3400 NEXTX
  216. 3405 IFHB=6THEN3420
  217. 3410 PRINT"NOT READY":HB=0:GOTO1190
  218. 3420 FORX=1TO6:IFO(X)=0THENI=I-1
  219. 3430 O(X)=40:NEXTX
  220. 3450 H=1:GOTO1000
  221. 3460 IFH=0THENPRINT"NOT READY":GOTO1190
  222. 3470 IFL=8ORL=36THENPRINT"NEED TO GET IN FIRST":GOTO1190
  223. 3480 IFL=34THEN3500
  224. 3485 IFL=35THEN3570
  225. 3490 GOTO1990
  226. 3500 Z=13:Y=5:GOSUB6400
  227. 3510 Z=8:Y=11:GOSUB6400
  228. 3520 Z=3:Y=17:GOSUB6400
  229. 3530 Z=8:Y=23:GOSUB6400
  230. 3540 Z=13:Y=29:GOSUB6400
  231. 3550 PRINT"[147]"
  232. 3560 L=35:GOTO1000
  233. 3570 Z=13:Y=29:GOSUB6400
  234. 3580 Z=8:Y=23:GOSUB6400
  235. 3590 Z=3:Y=17:GOSUB6400
  236. 3600 Z=8:Y=11:GOSUB6400
  237. 3610 Z=13:Y=5:GOSUB6400
  238. 3620 PRINT"[147]"
  239. 3630 L=34:GOTO1000
  240. 3640 IFO(19)THENPRINT"DON'T HAVE":GOTO1190
  241. 3650 IFL>27ANDL<32THENPRINT"YOU QUICKLY GRAB IT BACK!":GOTO11900
  242. 3660 O(19)=L:I=I-1:GOTO1000
  243. 3800 IFL<>2THEN1990
  244. 3810 PRINT"YOU FELL OFF":S=1:L=11:FORZZ=1TO1000:NEXT:GOTO1000
  245. 3900 IFO(9)=0ORO(9)=LTHENPRINT"SIGN SAYS:AN APPROPRIATE PLACE":GOTO1190
  246. 3910 PRINT"CAN'T FIND":GOTO1190
  247. 3950 IFO(19)=0THEN3080
  248. 3960 PRINT"NEED SNORKEL"GOTO1190
  249. 5000 REM DIRECTION
  250. 5010 IFD$(X,L)="-"THENRETURN
  251. 5020 IFD$(X,L)="O"THENPRINT"OUT":RETURN
  252. 5030 IFD$(X,L)="N"THENPRINT"NORTH":RETURN
  253. 5040 IFD$(X,L)="E"THENPRINT"EAST":RETURN
  254. 5050 IFD$(X,L)="S"THENPRINT"SOUTH":RETURN
  255. 5060 IFD$(X,L)="W"THENPRINT"WEST":RETURN
  256. 5070 IFD$(X,L)="U"THENPRINT"UP":RETURN
  257. 5080 IFD$(X,L)="D"THENPRINT"DOWN":RETURN
  258. 5200 REM OBJECTS
  259. 5210 IFO(13)=0ANDL=31THENPRINT"AN UNDERWATER TUNNEL":RETURN
  260. 5220 IFL=13ORL=14ORL=17ORL=18THENPRINT"VENT"
  261. 5230 IFL=13ANDC1=1THENPRINT"VENT COVER":RETURN
  262. 5240 IFL=14ANDC2=1THENPRINT"VENT COVER":RETURN
  263. 5250 IFL=17ANDC3=1THENPRINT"VENT COVER":RETURN
  264. 5260 IFL=18ANDC4=1THENPRINT"VENT COVER":RETURN
  265. 5270 IFH=1ANDL=8ORL=36THENPRINT"HOT AIR BALLOON":RETURN
  266. 5280 Z=INT(10*RND(1))+1
  267. 5290 IFL=6ANDZ=1THENPRINT"THE BUTLER WITH TWO STICKS OF DYNAMITE":RETURN
  268. 5300 IFL=3ANDZ=3THENPRINT"THE MAID WITH A PACK OF BLOODHOUNDS":RETURN
  269. 5310 IFL=7ANDZ=5THENPRINT"THE GARDENER WITH A BULLDOZER":RETURN
  270. 5320 IFL=33ANDZ<5THENPRINT"A BAT PASSES CLOSERE BY":RETURN
  271. 5330 IFL=27ANDZ<3THENPRINT"YOU HAVE COBWEBS IN YOUR HAIR":RETURN
  272. 5340 IFL=25ANDZ<3THENPRINT"A RODENT BRUSHES YOUR LEG":RETURN
  273. 5350 IF L=4ANDZ=7THENPRINT"A TOAD JUMPS ACROSS THE CREEK":RETURN
  274. 5360 IFL=28ANDO(14)=0ANDZ<5THENPRINT"A HUNGRY GULL CIRCLES OVERHEAD":RETURN
  275. 5370 IFL=2ANDZ=8THENPRINT"A PRIMATE WATCHES FROM ABOVE":RETURN
  276. 5390 RETURN
  277. 6000 IF C$="GET WELL"THENS=0:PRINT"RECOVERED":GOTO 1190
  278. 6020 GOTO1990
  279. 6100 IFO(19)=0THENPRINT"ALREADY HAVE OBJECT":GOTO1190
  280. 6115 IFO(19)=40ANDO(7)=0THENO(19)=0:I=I+1:GOTO1000
  281. 6120 IFO(19)=40ANDO(7)=LTHENO(19)=0:I=I+1:GOTO1000
  282. 6130 IF0(19)=LTHENO(19)=0:I=I+1:GOTO1000
  283. 6140 GOTO1990
  284. 6150 IFO(13)=0THENPRINT"ALREADY HAVE":GOTO1190
  285. 6160 IFO(13)=40ANDL=14THENO(13)=0:I=I+1:GOTO1000
  286. 6170 IFO(13)=LTHENO(13)=0:I=I+1:GOTO1000
  287. 6180 GOTO1990
  288. 6200 REM
  289. 6210 PRINT"YOU HAD JUST ENOUGH STRENGTH TO GET AWAY"
  290. 6211 FORX=1TO3000:NEXTX:S=1:L=11:GOTO1000
  291. 6300 IFV=0THENPRINT"SERVAL WON'T LET YOU":GOTO1190
  292. 6310 L=19:GOTO1000
  293. 6400 REM
  294. 6410 PRINT"[147]":FORI=1TOZ:PRINT:NEXT
  295. 6420 PRINTTAB(Y)"- - -"
  296. 6425 PRINTTAB(Y-1)"-     -"
  297. 6430 PRINTTAB(Y-2)"========="
  298. 6440 PRINTTAB(Y-1)"-     -"
  299. 6445 PRINTTAB(Y)"-   -"
  300. 6450 PRINTTAB(Y+1)".-."
  301. 6455 PRINTTAB(Y+1)". ."
  302. 6460 PRINTTAB(Y+1)"---"
  303. 6470 PRINTTAB(Y+1)"***"
  304. 6480 PRINTTAB(Y+1)"---"
  305. 6485 FORX=1TO1000:NEXTX
  306. 6490 RETURN
  307. 6500 REM
  308. 6510 RETURN
  309. 6550 PRINT"[147]"
  310. 6560 PRINT:PRINTTAB(5)"HOW TO BUILD A HOT AIR BALLOON"
  311. 6570 PRINT:PRINTTAB(8)"#1 BALLOON"
  312. 6575 PRINTTAB(8)"#2 HEAT SOURCE"
  313. 6580 PRINTTAB(8)"#3 FUEL"
  314. 6585 PRINTTAB(8)"#4 GONDOLA OR CONTAINER"
  315. 6590 PRINTTAB(8)"#5 CABLE OR TWINE"
  316. 6595 PRINTTAB(8)"#6 MATCHES OR LIGHTER"
  317. 6600 PRINT"BUILD A BALLOON AT AN APPROPRIATE PLACE"
  318. 6605 PRINTTAB(8)
  319. 6610 INPUT"PRESS RETURN TO CONTINUE";C$
  320. 6620 GOTO1000
  321. 7000 REM
  322. 7010 IFE=0THENPRINT"CAN'T FIND":GOTO1190
  323. 7030 IFL<>16THENPRINT"NOT HERE":GOTO1190
  324. 7040 PRINT"COMBINATION LOCK"
  325. 7050 INPUT"ENTER FIRST NUMBER";F$(1)
  326. 7055 GOSUB6500
  327. 7060 IFVAL(F$(1))<>VAL(N$(1))THENPRINT"NOT CORRECT":GOTO1190
  328. 7070 INPUT"ENTER SECOND NUMBER";F$(2)
  329. 7075 GOSUB6500
  330. 7080 IFVAL(F$(2))<>VAL(N$(2))THENPRINT"NOT CORRECT":GOTO1190
  331. 7090 INPUT"ENTER LAST NUMBER";F$(3)
  332. 7095 GOSUB6500
  333. 7100 IFVAL(F$(3))<>VAL(N$(3))THENPRINT"NOT CORRECT":GOTO1190
  334. 7105 F=1
  335. 7110 PRINT"CLICK!..........INSIDE IS A WILL":GOTO1190
  336. 7200 PRINT"[147]"
  337. 7210 FORI=1TO6:PRINT:NEXTI
  338. 7220 PRINT" **************************************"
  339. 7225 PRINT" *";SPC(36);"*"
  340. 7230 PRINT" *                WILL                *"
  341. 7235 PRINT" *                                    *"
  342. 7240 PRINT" * I,MR STONE,LEAVE ALL MY WORLDLY    *"
  343. 7245 PRINT" * POSSESSIONS TO WHOMEVER OPENS THIS *"
  344. 7250 PRINT" * SAFE.                              *"
  345. 7255 PRINT" *";SPC(36);"*"
  346. 7260 PRINT" **************************************"
  347. 7265 PRINT
  348. 7270 PRINT"          <<<CONGRATULATIONS>>>":END
  349. 7500 PRINT"[147]":PRINT
  350. 7510 PRINT"WELCOME TO STONEVILLE. YOU HAVE RECENTLY"
  351. 7520 PRINT"LEARNED THAT THE WEALTHY MR. STONE DIED AND"
  352. 7530 PRINT"RUMOUR HAS IT THAT THE ECCENTRIC MISER"
  353. 7540 PRINT"HAS LEFT HIS ENTIRE ESTATE TO WHOMEVER"
  354. 7550 PRINT"FINDS AND OPENS HIS SAFE. "
  355. 7560 PRINT
  356. 7570 PRINT"TO PLAY,YOU MUST MANIPULATE OBJECTS AND"
  357. 7580 PRINT"EXPLORE YOUR SURROUNDINGS BY USING TWO"
  358. 7590 PRINT"WORD COMMANDS. FOR EXAMPLE,'GET BASKET'"
  359. 7600 PRINT"OR'GO SOUTH'. TO SPEED UP DIRECTIONAL"
  360. 7605 PRINT"MOVEMENT,'GO' COMMANDS MAY BE SHORTENED"
  361. 7610 PRINT"TO INCLUDE 1 LETTER SUCH AS 'GO S'.":PRINT
  362. 7615 PRINT"THE COMMAND 'SAVE GAME' WILL PRESERVE"
  363. 7620 PRINT"YOUR PROGRESS FOR PLAY AT A LATER TIME"
  364. 7625 PRINT"OR IF YOU PREFER TO JUST END THE GAME"
  365. 7630 PRINT"THEN ENTER 'END GAME'. AND IF NEEDED"
  366. 7640 PRINT"'CLEAR SCREEN'WILL RESET YOUR LOCATION."
  367. 7680 INPUT"PRESS RETURN TO CONTINUE";C$:RETURN
  368. 8000 DATABALLOON,FALLEN WEATHER BALLOON,3,STOVE,SMALL WOOD BURNING STOVE
  369. 8005 DATA1,BASKET,LARGE WICKER BASKET,12
  370. 8010 DATALOGS,LOGS,40,TWINE,ROLL OF TWINE,17,MATCHES,BOOK OF MATCHES,15
  371. 8020 DATABAG,BURLAP BAG,18,RAFT,INFLATABLE RAFT,1,SIGN,SIGN,8
  372. 8030 DATANET,FISH NET,7,SHOES,JOGGING SHOES,10,AXE,AXE,10
  373. 8040 DATAMASK,SWIM MASK,40,TROUT,TROUT,29,GOBLET,CRYSTAL GOBLET,19
  374. 8050 DATABOTTLE,EMPTY BOTTLE OF CHABLIS,33,BOOK,BOOK,14,PICTURE
  375. 8055 DATAPICTURE OF MR STONE,16
  376. 8060 DATASNORKEL,SNORKEL,40,MANOR,STONEVILLE MANOR,9,MANOR
  377. 8065 DATASTONEVILLE MANOR,1
  378. 8070 DATA SHACK,OLD ABANDONED SHACK,36,TABLE,WOODEN TABLE,37
  379. 8075 DATACREDENZA,WALNUT CREDENZA,14
  380. 8080 DATASAFE,SAFE,40,CASE,CASE OF CHABLIS,18,TREES,TREES,2
  381. 8090 DATADOOR,DOOR,20,DOOR,DOOR,16,SERVAL,AN IMPORTED SERVAL,18
  382. 8100 DATASTORE,GENERAL STORE,9,STAIRWAY,STAIRWAY,19,HOSPITAL,HOSPITAL,9
  383. 8110 DATAIN THE COURTYARD,IN A WOODED AREA,IN A MEADOW,ALONG A SLIPPERY CREEK
  384. 8115 DATAON THE BANK OF A LAKE,IN A BARREN FIELD,ON A ROCKY TRAIL
  385. 8120 DATAAT THE EDGE OF A GORGE,IN THE MAIN STREET,INSIDE THE GENERAL STORE
  386. 8125 DATAINSIDE THE HOSPITAL,IN THE FOYER,IN THE PARLOR
  387. 8130 DATA IN THE STUDY,IN AN ORIEL,IN THE GALLERY,IN THE ATRIUM
  388. 8135 DATAIN THE WEST WING OF THE WINE CELLER
  389. 8136 DATAIN THE EAST WING OF THE WINE CELLER
  390. 8140 DATAAT AN OUTLET IN THE DUCT
  391. 8141 DATAAT A FORK IN THE DUCT,AT A TURN IN THE DUCT
  392. 8142 DATA AT A FORK IN THE DUCT,AT A TURN IN THE DUCT
  393. 8143 DATA AT AN OUTLET IN THE DUCT
  394. 8150 DATAAT AN OUTLET IN THE DUCT,AT AN OUTLET IN THE DUCT
  395. 8151 DATAON THE LAKE,IN THE SOUTHERN BAY,UNDER THE SURFACE OF THE LAKE
  396. 8152 DATAUNDER THE SURFACE OF THE LAKE
  397. 8160 DATAALONG AN UNDERGROUND RIVER,INSIDE A CAVERN,IN A HOT AIR BALLOON
  398. 8161 DATAIN A HOT AIR BALLOON
  399. 8162 DATAON THE TOP OF A PLATEAU,INSIDE THE SHACK
  400. 8170 DATAW,2,S,4,-,0,E,1,S,3,N,9,N,2,E,4,-,0,W,3,E,5,N,1,W,4,-,0
  401. 8175 DATA-,0,S,9,E,7,-,0,W,6,E,8,-,0
  402. 8180 DATAW,7,-,0,-,0,S,2,N,6,-,0,O,9,-,0,-,0,O,9,-,0,-,0,O,9
  403. 8185 DATAS,13,-,0,N,12,E,14,S,17,W,13,E,15,S,16
  404. 8190 DATAW,14,-,0,-,0,N,14,W,17,-,0,O,1,N,13,E,16,E,19,-,0,-,0,W,18,U,20,-
  405. 8192 DATA0,D,19,-,0,-,0,O,13,S,22,-,0,N,21,E,23,-,0
  406. 8200 DATAW,22,N,24,S,25,O,14,S,23,-,0,N,23,W,26,-,0,O,17,D,27,E,25,O,18,U,26
  407. 8205 DATA-,0,O,5,S,29,-,0,N,28,-,0,-,0
  408. 8210 DATAU,28,S,31,-,0,U,29,N,30,-,0,E,31,W,33,-,0,E,32,-,0,-,0,O,8,-,0,-,0,O
  409. 8215 DATA36,-,0,-,0,-,0,-,0,-,0,O,36,-,0,-,0
  410. 8220 DATAVENT IS COVERED,SOMETHING IS TOO BIG
  411. 8225 DATAINSIDE IS A NOTE WITH THE NUMBER
  412. 8230 DATA13,14,17,18,21,24,26,27
  413. 8300 REM
  414. 8310 D$=CHR$(4)
  415. 8320 RETURN
  416. 8400 END
  417. 17746 PRINT
  418.