8bitfiles.net/archives/archives.tar/archives/genie-commodore-file-library/C64Adventure/BASEBALL-ADVNTRE

Commodore BASIC | 2019-04-13 | 24.4 KB | 908 lines

1 REM *** BASEBALL ADVENTURE BY
2 REM *** SAMUAL CHIANG
3 REM *** TRANSLATED FOR THE 64 BY
4 REM *** DONNA K. WOODY
5 POKE53280,5:POKE53281,1:PRINTCHR$(144):POKE53272,23:PRINTCHR$(8)
10 GOSUB2040:GOTO270
12 :
13 REM *** ROOM DESCRIPTIONS ***
14 :
20 ONAGOTO30,40,50,60,70,80,90,100,110,120,130,140,150,160,170,180
22 ZZ=A-16:ONZZGOTO190,200,210,220,230,240,250,260
30 PRINT" IN THE PARKING LOT.":N=2:GOTO340
40 PRINT" OUTSIDE OF [195]ANDLESTICK [208]ARK.     [212]HERE IS A SIGN OVER THE ENTRANCE."
42 N=6:S=1:GOTO340
50 PRINT" IN YOUR OFFICE.":N=5:GOTO340
60 PRINT" IN A VERY LONG HALLWAY.  [212]HERE   ARE STAIRS GOING DOWN."
65 E=5:D=17:GOTO340
70 PRINT" IN THE WEST END OF AN OUTER E/W  HALLWAY."
75 N=10:W=4:E=6:S=3:GOTO340
80 PRINT" IN THE EAST END OF AN OUTER E/W  HALLWAY."
85 N=11:W=5:E=7:S=2:GOTO340
90 PRINT" IN AN EXTREMELY LONG HALLWAY.    [212]HERE ARE STAIRS GOING UP."
95 W=6:U=14:GOTO340
100 PRINT" IN THE STANDS. + SECTION 26 +"
105 S=9:GOTO340
110 PRINT" IN THE STANDS. + SECTION 12 +"
115 S=10:N=8:GOTO340
120 PRINT" IN THE STANDS. + SECTION  6 +"
125 S=5:E=11:N=9:GOTO340
130 PRINT" IN THE STANDS. + SECTION  9 +"
135 S=6:N=12:W=10:GOTO340
140 PRINT" IN THE STANDS. + SECTION 15 +"
145 S=11:N=13:GOTO340
150 PRINT" IN THE STANDS. + SECTION 27 +"
155 S=12:GOTO340
160 PRINT"[160]IN A SECOND LEVEL HALLWAY.       [212]HERE ARE STAIRS GOING DOWN."
165 S=24:E=16:W=15:D=7:GOTO340
170 PRINT" IN AN OFFICE.  [212]HERE IS A SIGN   ABOVE AN OFFICIOUS LOOKING GIRL."
175 E=14:GOTO340
180 PRINT" IN THE [208]RESS [194]OX.  [217]OU SEE A     FAMOUS SPORTSCASTER."
185 W=14:GOTO340
190 PRINT" IN A LOWER LEVEL HALLWAY.  [212]HERE ARE STAIRS GOING UP."
195 N=20:W=19:E=18:U=4:GOTO340
200 PRINT"[160]IN THE CLUBHOUSE.":W=17:GOTO340
210 PRINT"[160]IN THE LOCKER ROOM.":E=17:GOTO340
220 PRINT" IN THE [199]IANTS' DUGOUT.  [217]OU SEE  THE MANAGER."
225 S=17:N=21:GOTO340
230 PRINT"[160]BEHIND THE PLATE, NEXT TO THE"
232 PRINT"BACKSTOP.  [212]HE [199]IANTS' DUGOUT IS SOUTH,"
234 PRINT"THE FIELD IS WEST, AND THE [196]ODGERS'     DUGOUT IS NORTH OF YOU."
236 N=22:W=23:S=20:GOTO340
240 PRINT"[160]IN THE [196]ODGERS' DUGOUT.":S=21:GOTO340
250 PRINT"[160]IN THE BATTERS' BOX.":E=21:GOTO340
260 PRINT"[160]IN THE SCOREBOARD CONTROL ROOM.  [217]OU SEE A BUTTON ON A CONTROL PANEL."
265 N=14:GOTO340
266 :
267 REM *** DIM VARIABLES, INITIALIZE ***
268 :
270 DIMA$(58),A(58),B(12),B$(35),C$(10),D(35),H$(58),I(58),PL$(5),EV$(5),DG$(5)
290 FORA=1TO20:READA$(A),A(A):H$(A)=A$(A):NEXT
292 FORA=1TO35:READB$(A):NEXT:FORA=13TO35:READD(A):NEXT
300 FORV=1TO5:READPL$(V):READEV$(V):READDG$(V):NEXTV
310 A=3:PT=0:CL=0:HB=0:BT=0:CP=0:TK=0:FB=0:CH=0:JR=0:CA=0:FT=0:WJ=0:WC=0:WP=0
312 CK=0:MY=0:WL=0
320 N=0:W=0:S=0:E=0:U=0:D=0:PRINTCHR$(147):PRINT"[217]OU'RE";
330 GOTO20
335 :
337 :
340 FORB=1TO12:B(B)=0:NEXTB
346 :
347 REM *** DIRECTIONS ***
348 :
350 PRINT:PRINT"[197]XITS: "
360 IFWTHENPRINT"[160][215]EST";:B(1)=W:B(2)=W
370 IFNTHENPRINT"[160][206]ORTH";:B(3)=N:B(4)=N
380 IFETHENPRINT"[160][197]AST";:B(5)=E:B(6)=E
390 IFSTHENPRINT"[160][211]OUTH";:B(7)=S:B(8)=S
400 IFUTHENPRINT"[160][213]P";:B(9)=U:B(10)=U
410 IFDTHENPRINT"[160][196]OWN";:B(11)=D:B(12)=D
412 :
413 REM *** IF ROOM = 1 & CASH IS   ***
414 REM *** THERE THEN END GAME     ***
415 REM *** MESSAGE FOR WINNER      ***
416 :
420 IFA=3ANDCH=1THEN2240
422 :
423 REM *** IF ROOM = 23 MESSAGE    ***
424 :
430 PRINT:PRINT:IFA=23THENPOKE781,10:POKE782,1:SYS65520:GOSUB3000:GOTO2030
432 :
433 REM *** IF NOT WEARING UNIFORM  ***
434 REM *** THEN MESSAGE            ***
435 :
440 IF(WP<>1ORWC<>1ORWL<>1ORWJ<>1)ANDA=21THENGOSUB3050:GOTO2030
442 :
443 REM *** IF WEARING UNIFORM      ***
444 REM *** PANTS, CLEATES, JERSEY, ***
445 REM *** & CAP, THEN MESSAGE     ***
446 :
450 IFWP=1ANDWJ=1ANDWC=1ANDWL=1ANDFT=0THENGOSUB3650
452 :
453 REM *** CHECK FOR ITEMS AT YOUR ***
454 REM *** LOCATION AND PRINT THEM ***
455 :
460 FORB=1TO20:IFA=ABS(A(B))THENC=C+1:GOTO480
470 NEXTB:PRINT:GOTO500
480 IFC<2THENPRINT"[212]HINGS YOU SEE HERE:"
490 PRINT"[160]"A$(B):GOTO470
492 :
493 REM *** INCREMENT TIME & CHECK  ***
494 REM *** TO SEE IF INNINGS HAVE  ***
495 REM *** PASSED TO COMPLETE GAME ***
496 :
500 XX=XX+1
510 IFXX/13=INT(XX/13)THENGOSUB3100
520 IFXX>=125THEN2300
526 :
527 REM *** GET COMMAND ***
528 :
530 V=FRE(0):C=0:PRINT:INPUT"[195]OMMAND";A$
535 IFA$="BUY COKE"THENA$="GIVE MONEY"
540 IFA$="LOOK"THEN320
544 :
545 REM *** CHECK FOR VALID         ***
546 REM *** COMMAND - CHECK FOR     ***
547 REM *** DIRECTION FIRST         ***
549 :
550 PRINT:FORB=1TO12:IFA$=B$(B)THEN570
560 NEXT:GOTO590
570 IFB(B)<>0THENA=B(B):GOTO320
574 :
575 REM *** NOT VALID DIRECTION ***
576 :
580 PRINT"[217]OU CAN'T GO THAT WAY!":GOTO530
586 :
587 REM *** INVENTORY COMMAND ***
588 :
590 IFA$<>"I"ANDRIGHT$(A$,3)<>"ORY"THEN620
600 PRINT"[217]OU ARE CARRYING:":FORK=1TO10:PRINTC$(K);"   ";:IFPOS(0)>19THENPRINT
610 NEXT:GOTO530
612 :
613 REM *** NOT DIRECTION OR        ***
614 REM *** OR INVENTORY COMMAND    ***
615 REM *** CHECK FOR VALID VERB    ***
620 FORB=13TO35:F=LEN(B$(B)):IFLEFT$(A$,F)=B$(B)THEN640
625 :
626 REM *** NOT VALID VERB ***
627 :
630 NEXT:PRINT"[196]ON'T KNOW WHAT "CHR$(34);A$;CHR$(34);" MEANS.":GOTO530
635 :
636 REM *** VALID COMMAND VERB ***
637 REM *** FIND LAST 3 LETTERS ***
638 REM *** OF NOUN             ***
639 :
640 D$=MID$(A$,LEN(B$(B))+2):E$=RIGHT$(D$,3)
643 :
644 REM *** D(B) HOLDS CODE FOR ***
645 REM *** SYNONYM VERBS       ***
646 REM *** CHECK FOR VERB #    ***
647 REM *** & TAKE ACTION       ***
648 :
650 IFD(B)<>1THEN850
655 :
656 REM *** GET ITEM                ***
657 :
660 FORJ=1TO20:IFE$=RIGHT$(A$(J),3)ANDA=ABS(A(J))THEN680
665 :
666 REM *** DOESN'T RECOGNIZE NOUN ***
667 REM *** FROM LIST              ***
668 :
670 NEXT:PRINT"[201] SEE NO "D$" HERE.":GOTO500
675 :
676 REM *** IF A(J) IS NEGATIVE #  ***
677 REM *** THEN YOU CAN'T GET NOUN***
678 :
680 IFA(J)<0THENPRINT"[217]OU CAN'T GET THAT!":GOTO500
685 :
686 REM *** GET ITEM               ***
687 :
690 IFR<11THENGOSUB3150:GOTO720
695 :
696 REM *** YOU'RE CARRYING TOO     ***
697 REM *** TOO MANY ITEMS          ***
698 :
700 PRINT"[217]OU'RE CARRYING TOO MUCH.  [217]OU SHOULD   DROP SOMETHING FIRST."
705 :
706 REM *** GOTO DROP SECTION       ***
707 :
710 GOTO500
715 :
716 REM *** SET VARIABLE TO 1 IF   ***
717 REM *** LAST 3 LETTERS OF NOUN ***
718 REM *** MATCH ITEM PICKED UP   ***
719 :
720 IFE$="NTS"THENPT=1
730 IFE$="TES"THENCL=1
740 IFE$="BAT"THENHB=1
750 IFE$="ALL"THENBT=1
760 IFE$="PON"THENCP=1
770 IFE$="KET"THENTK=1
780 IFE$="BEE"THENFB=1
790 IFE$="ASH"THENCH=1
800 IFE$="SEY"THENJR=1
810 IFE$="CAP"THENCA=1
820 IFE$="OKE"THENCK=1
830 IFE$="NEY"THENMY=1
835 :
836 REM *** GOTO DELAY LOOP        ***
837 :
840 GOTO2010
845 :
846 REM *** DROP COMMAND            ***
847 :
850 IFD(B)<>2THEN1050
855 :
856 REM *** FIND OUT IF ITEM IS    ***
857 REM *** BEING CARRIED          ***
858 :
860 FORJ=1TO10:IFE$=RIGHT$(C$(J),3)THEN880
865 :
868 REM *** YOU DON'T HAVE THE ITEM ***
869 :
870 NEXT:PRINT"[217]OU'RE NOT CARRYING IT.":GOTO500
872 :
873 REM *** PUT ITEM BACK IN NOUN  ***
874 REM *** LIST - REMOVE FROM     ***
875 REM *** CARRY LIST - DECREMENT ***
876 REM *** # OF ITEMS BEING       ***
877 REM *** CARRIED                ***
878 :
880 FORK=1TO58:IFA$(K)=""THENA$(K)=C$(J):A(K)=A:H(J)=0:GOTO900
890 NEXT
900 PRINT"[207][203]!":FORK1=1TO58:IFC$(J)=H$(K1)THENC$(J)="":R=R-1:GOTO920
910 NEXT
912 :
913 REM *** AFTER DROPPING ITEM    ***
914 REM *** SET VARIABLE TO 0 IF   ***
915 REM *** LAST 3 LETTERS OF NOUN ***
916 REM *** MATCH                  ***
917 :
920 IFE$="ALL"THENBT=0
930 IFE$="BAT"THENHB=0
940 IFE$="PON"THENCP=0
950 IFE$="KET"THENTK=0
960 IFE$="BEE"THENFB=0
970 IFE$="ASH"THENCH=0
980 IFE$="NTS"THENPT=0:WP=0:FT=0
990 IFE$="TES"THENCL=0:WL=0:FT=0
1000 IFE$="SEY"THENJR=0:WJ=0:FT=0
1010 IFE$="CAP"THENCA=0:WC=0:FT=0
1020 IFE$="OKE"THENCK=0
1030 IFE$="NEY"THENMY=0
1032 :
1033 REM *** GOTO DELAY LOOP      ***
1034 :
1040 GOTO2010
1042 :
1043 REM *** LOOK/READ COMMAND    ***
1044 :
1050 IFD(B)<>3THEN1110
1052 :
1053 REM *** IF ROOM = 2 & NOUN =  ***
1054 REM *** SIGN THEN READ        ***
1055 :
1060 IFA=2ANDE$="IGN"THENGOSUB3200:GOTO2020
1065 :
1066 REM *** IF ROOM = 15 & NOUN = ***
1067 REM *** SIGN THEN READ        ***
1068 :
1070 IFA=15ANDE$="IGN"THENGOSUB3250:GOTO2010
1075 :
1076 REM *** IF HOLDING BAT, READ  ***
1077 :
1080 IFE$="BAT"ANDHB=1THENPRINT"[212]HE BAT IS SIGNED BY [210]EGGIE [202]ACKSON!":GOTO2020
1085 :
1086 REM *** IF HOLDING BALL, READ ***
1087 :
1090 IFE$="ALL"ANDBT=1THENPRINT"[212]HE BALL IS SIGNED BY [205]ARV [212]HRONBERRY!":GOTO2020
1095 :
1096 REM *** IF HOLDING COUPON, READ **
1097 :
1100 IFE$="PON"ANDCP=1THENGOSUB3260:GOTO2010
1105 :
1106 REM *** KISS COMMAND          ***
1107 :
1110 IFD(B)<>4THEN1200
1112 :
1113 REM *** IF ROOM = 1 AND NOUN  ***
1114 REM *** = BUSINESS MAN THEN   ***
1115 REM *** MESSAGE               ***
1116 :
1120 IFA=1ANDE$="MAN"THENPRINT"[200]E LIKES IT!  [210]EMEMBER YOU'RE IN [211].[198].":GOTO2020
1123 :
1124 REM *** IF ROOM = 9 AND NOUN  ***
1125 REM *** = OLD HAG THEN KISS   ***
1126 REM *** MESSAGE               ***
1127 :
1130 IF1=9ANDE$="HAG"THENPRINT"[217]UCK!!!":GOTO2010
1132 :
1133 REM *** IF ROOM = 12 & NOUN = ***
1134 REM *** DODGER FAN THEN KISS  ***
1135 REM *** MESSAGE               ***
1136 :
1140 IFA=12ANDE$="FAN"THENGOSUB3270:GOTO2020
1142 :
1143 REM *** IF ROOM = 13 AND NOUN ***
1144 REM *** = COKE VENDOR THEN    ***
1145 REM *** KISS MESSAGE          ***
1146 :
1150 IFA=13ANDE$="DOR"THENPRINT"[212]HAT WON'T GET YOU ANY FREE COKES!":GOTO2020
1151 :
1153 REM *** IF ROOM = 13 & NOUN = ***
1154 REM *** PRETTY GIRL THEN      ***
1155 REM *** KISS MESSAGE          ***
1156 :
1160 IFA=15ANDE$="IRL"THENPRINT"[217]OU LIKE IT!":GOTO2010
1162 :
1163 REM *** IF ROOM = 16 & NOUN = ***
1164 REM *** COSELL THEN KISS      ***
1165 REM *** MESSAGE               ***
1166 :
1170 IFA=16ANDE$="ELL"THENPRINT"[217]OUR MOUTH ISN'T BIG ENOUGH FOR HIS!":GOTO2020
1172 :
1173 REM *** IF ROOM = 20 & NOUN = ***
1174 REM *** ROBINSON THEN KISS    ***
1175 REM *** MESSAGE               ***
1176 :
1180 IFA=20ANDE$="SON"THENPRINT"[200]IS WIFE IS WATCHING!":GOTO2010
1183 :
1184 REM *** IF ROOM = 22 & NOUN = ***
1185 REM *** LASORDA THEN KISS     ***
1186 REM *** MESSAGE               ***
1187 :
1190 IFA=22ANDE$="RDA"THENPRINT"[212]HEIR YOUR LIPS!":GOTO2010
1195 :
1196 REM *** TALK/SPEAK COMMAND     ***
1197 :
1200 IFD(B)<>5THEN1290
1202 :
1203 REM *** IF ROOM = 1 & NOUN =  ***
1204 REM *** BUSINESS MAN THEN     ***
1205 REM *** TALK MESSAGE          ***
1206 :
1210 IFA=1ANDE$="MAN"ANDA(1)=-1THENGOSUB3280:GOTO2020
1212 :
1213 REM *** IF ROOM = 9 & NOUN =  ***
1214 REM *** OLD HAG THEN TALK     ***
1215 REM *** MESSAGE               ***
1216 :
1220 IFA=9ANDE$="HAG"THENPRINT"[211]HE SAYS:":PRINT"  [200]I, [195]UTIE!":GOTO2010
1222 :
1223 REM *** IF ROOM = 12 & NOUN = ***
1224 REM *** DODGER FAN THEN TALK  ***
1225 REM *** MESSAGE               ***
1226 :
1230 IFA=12ANDE$="FAN"THENGOSUB3290:GOTO2010
1232 :
1233 REM *** IF ROOM = 13 & NOUN = ***
1234 REM *** COKE VENDOR THEN TALK ***
1235 REM *** MESSAGE               ***
1236 :
1240 IFA=13ANDE$="DOR"THENPRINT"[200]E YELLS:":PRINT"[195]OKES!!!  [201]CE COLD [195]OKES!!!":GOTO2010
1242 :
1243 REM *** IF ROOM = 15 & NOUN = ***
1244 REM *** PRETTY GIRL THEN TALK ***
1245 REM *** MESSAGE               ***
1246 :
1250 IFA=15ANDE$="IRL"THENGOSUB3310:GOTO2010
1252 :
1253 REM *** IF ROOM = 16 & NOUN = ***
1254 REM *** COSELL THEN TALK      ***
1255 REM *** MESSAGE               ***
1256 :
1260 IFA=16ANDE$="ELL"THENGOSUB3320:GOTO2030
1262 :
1263 REM *** IF ROOM = 20 & NOUN = ***
1264 REM *** ROBINSON THEN TALK    ***
1265 REM *** MESSAGE               ***
1266 :
1270 IFA=20ANDE$="SON"THENGOSUB3350:GOTO2020
1272 :
1273 REM *** IF ROOM = 22 & NOUN = ***
1274 REM *** LASORDA THEN TALK     ***
1275 REM *** MESSAGE               ***
1276 :
1280 IFA=22ANDE$="RDA"THENGOSUB3370:GOTO2020
1282 :
1283 REM *** DRINK/SWALLOW         ***
1284 :
1290 IFD(B)<>6THEN1340
1292 :
1293 REM *** IF NOUN = COKE & YOU   ***
1294 REM *** ARE CARRYING IT THEN   ***
1295 REM *** DRINK IT               ***
1296 :
1300 IFE$="OKE"AMDCK=1THENGOSUB3380:GOTO1320
1302 :
1303 REM *** IF DIDN'T DRINK COKE   ***
1304 REM *** THEN GOTO SELL/GIVE/   ***
1305 REM *** TRADE COMMAND          ***
1306 :
1310 GOTO1340
1312 :
1313 REM *** CHANGE COKE TO BOTTLE  ***
1314 REM *** IN CARRY LIST          ***
1315 :
1320 FORV=1TO10:IFC$(V)="COKE"THENC$(V)="BOTTLE":H$(3)="BOTTLE":GOTO2010
1330 NEXTV
1332 :
1333 REM *** SELL/GIVE/TRADE        ***
1334 REM *** COMMAND                ***
1335 :
1340 IFD(B)<>7THEN1510
1342 :
1343 REM *** IF ROOM =1 & YOU HAVE  ***
1344 REM *** TICKET THEN MESSAGE    ***
1345 :
1350 IFA=1ANDE$="KET"ANDTK=1THENGOSUB3390:GOTO1370
1352 :
1353 REM *** GOTO NEXT POSSIBLE     ***
1354 REM *** SELL/GIVE/TAKE         ***
1355 :
1360 GOTO1390
1362 :
1363 REM *** CHANGE TICKET TO MONEY ***
1364 REM *** IN CARRY ITEMS         ***
1365 :
1370 FORV=1TO10:IFC$(V)="TICKET"THENC$(V)="MONEY":H$(3)="MONEY":GOTO2020
1380 NEXTV
1382 :
1383 REM *** IF ROOM =13 & YOU HAVE ***
1384 REM *** MONEY THEN MESSAGE     ***
1385 :
1390 IFA=13ANDE$="NEY"ANDMY=1THENGOSUB3430:GOTO1410
1400 GOTO1430
1405 :
1406 REM *** CHANGE MONEY TO COKE   ***
1407 :
1410 FORV=1TO10:IFC$(V)="MONEY"THENC$(V)="COKE":H$(3)="COKE":GOTO2020
1420 NEXTV
1425 :
1426 REM *** IF ROOM = 20 & NOUN =  ***
1427 REM *** COKE THEN GIVE COKE    ***
1428 :
1430 IFA=20ANDE$="OKE"ANDCK=1THENGOSUB3450:GOTO1450
1440 GOTO1470
1442 :
1443 REM *** CHANGE COKE TO JERSEY  ***
1444 :
1450 FORV=1TO10:IFC$(V)="COKE"THENC$(V)="JERSEY":GOTO2020
1460 NEXTV
1462 :
1463 REM *** IF ROOM = 15 & NOUN =  ***
1464 REM *** COUPON THEN GET CAP    ***
1465 :
1470 IFA=15ANDE$="PON"ANDCP=1THENGOSUB3470:GOTO1490
1480 GOTO1510
1482 :
1483 REM *** CHANGE COUPON TO CAP   ***
1484 REM *** CARRY LIST             ***
1485 :
1490 FORV=1TO10:IFC$(V)="COUPON"THENC$(V)="CAP":H$(8)="CAP":GOTO2020
1500 NEXTV
1502 :
1503 REM *** KILL, ATTACK, HIT      ***
1504 REM *** COMMAND                ***
1505 :
1510 IFD(B)<>8THEN1610
1512 :
1513 REM *** IF ROOM = 1 & NOUN =   ***
1514 REM *** BUSINESS MAN           ***
1515 :
1520 IFA=1ANDE$="MAN"ANDA(1)=-1THENGOSUB3660:GOTO2020
1522 :
1523 REM *** IF ROOM = 9 & NOUN =   ***
1524 REM *** OLD HAG                ***
1525 :
1530 IFA=9ANDE$="HAG"THENGOSUB3690:GOTO2020
1532 :
1533 REM *** IF ROOM = 12 & NOUN =  ***
1534 REM *** DODGERS' FAN           ***
1535 :
1540 IFA=12ANDE$="FAN"THENGOSUB3710:GOTO2020
1542 :
1543 REM *** IF ROOM = 13 & NOUN =  ***
1544 REM *** COKE VENDOR            ***
1545 :
1550 IFA=13ANDE$="DOR"THENGOSUB3720:GOTO2020
1552 :
1553 REM *** IF ROOM = 15 & NOUN =  ***
1554 REM *** PRETTY GIRL            ***
1555 :
1560 IFA=15ANDE$="IRL"THENGOSUB3730:GOTO2020
1562 :
1563 REM *** IF ROOM = 16 & NOUN =  ***
1564 REM *** COSELL                 ***
1565 :
1570 IFA=16ANDE$="ELL"THENPRINT"[193]L [205]ICHEALS AND [194]OB [213]ECKER STOP YOU!":GOTO2010
1572 :
1573 REM *** IF ROOM = 20 & NOUN =  ***
1574 REM *** ROBINSON               ***
1575 :
1580 IFA=20ANDE$="SON"THENPRINT"[194]ILL [204]ASKEY AND [202]EFF [204]EONARD STOP YOU!":GOTO2010
1582 :
1583 REM *** IF ROOM = 22 & NOUN =  ***
1584 REM *** LASORDA                ***
1590 IFA=22ANDE$="RDA"ANDCH=0THENGOSUB3480:GOTO2030
1595 :
1596 REM *** IF HAVE BAT & BALL &   ***
1597 REM *** NOUN = BALL            ***
1598 :
1605 IFBT=1ANDHB=1ANDE$="ALL"THENPRINT"[217]OU SWING AND MISS!":GOTO2010
1606 :
1607 REM *** THROW/FLY/PLAY         ***
1608 REM *** COMMAND                ***
1609 :
1610 IFD(B)<>9THEN1740
1612 :
1613 REM *** IF ROOM FROM 7TO 14 &  ***
1614 REM *** NOUN = BALL            ***
1615 :
1620 IF(A>7ANDA<14)ANDBT=1ANDE$="ALL"ANDCH=0THENGOSUB3530
1652 :
1653 REM *** IF ROOM FROM 7 TO 14 & ***
1654 REM *** NOUN = FRISBEE         ***
1655 :
1660 IF(A>7ANDA<14)ANDBT=1ANDE$="BEE"ANDFB=1THENGOSUB3570
1692 :
1693 REM *** IF ROOM = 21 & NOUN =  ***
1694 REM *** BAT & CARRYING BAT     ***
1695 :
1700 IFA=21ANDE$="BAT"ANDHB=1THENGOSUB3610
1732 :
1733 REM *** PUSH/PRESS COMMAND     ***
1734 :
1740 IFD(B)<>10THEN1760
1742 :
1743 REM *** IF ROOM = 24 & NOUN =  ***
1744 REM *** BUTTON                 ***
1745 :
1750 IFE$="TON"ANDA=24THENPRINT"[212]HE SCORE BOARD FLASHES    [199][207][144][146]":GOTO2020
1752 :
1753 REM *** CLIMB/GO COMMAND       ***
1754 :
1760 IFD(B)<>11THEN1790
1762 :
1763 REM *** IF ROOM = 4 & NOUN =   ***
1764 REM *** STAIRS                 ***
1765 :
1770 IFA=4ANDE$="IRS"THENPRINT"[207][203]!":A=17:GOTO2010
1772 :
1773 REM *** IF ROOM = 7 & NOUN =   ***
1774 REM *** STAIRS                 ***
1775 :
1780 IFA=7ANDE$="IRS"THENPRINT"[207][203]!":A=14:GOTO2010
1782 :
1783 REM *** WEAR COMMAND           ***
1784 :
1790 IFD(B)<>12THEN1840
1792 :
1793 REM *** IF NOUN = PANTS & HAVE ***
1794 REM *** THEM, PUT THEM ON      ***
1795 :
1800 IFE$="NTS"ANDPT=1ANDWP=0THENPRINT"[217]OU PUT ON THE PANTS!":WP=1:GOTO2010
1802 :
1803 REM *** IF NOUN = JERSEY & HAVE***
1804 REM *** IT, THEN PUT IT ON     ***
1805 :
1810 IFE$="SEY"ANDJR=1ANDWJ=0THENPRINT"[217]OU PUT ON THE JERSEY!":WJ=1:GOTO2010
1812 :
1813 REM *** IF NOUN = CLEATES &    ***
1814 REM *** HAVE THEM, THEN WEAR   ***
1815 :
1820 IFE$="TES"ANDCL=1ANDWL=0THENPRINT"[217]OU PUT ON THE CLEATES!":WL=1:GOTO2010
1822 :
1823 REM *** IF NOUN = CAP & HAVE   ***
1824 REM *** IT, THEN WEAR          ***
1825 :
1830 IFE$="CAP"ANDCA=1ANDWC=0THENPRINT"[217]OU PUT ON THE CAP!":WC=1:GOTO2010
1839 :
1840 REM *** NOT VALID VERB        ***
1841 :
1850 PRINT"[217]OU CAN'T DO THAT NOW!":GOTO500
1852 :
1853 REM *** DON'T KNOW WHAT IT DOES***
1854 :
1860 REM FORK2=1TO10:IFC$(K2)=R$:GOSUB1870:RETURN
1870 REM IFR$=""THENI(K3)=0
1880 RETURN
1882 :
1883 REM *** UPDATE LIST OF NOUNS   ***
1884 REM *** AFTER VERB ACTION      ***
1885 :
1890 FORK2=1TO58:IFA$(K2)=H$(K3)THENGOSUB3630
1900 NEXT:RETURN
1910 GOTO2010
1920 RETURN
1922 :
1923 REM *** DATA FOR NOUN & CODE   ***
1924 REM *** FOR NOUN               ***
1925 :
1930 DATABUSINESS MAN,-1,SIGN,-2,TICKET,3,STAIRS,-4,STAIRS,-7,BASEBALL,8
1932 DATAOLD HAG,-9,COUPON,10,FRISBEE,11,"[196]ODGER FAN",-12,"[195]OKE VENDOR",-13
1934 DATASIGN,-15,PRETTY GIRL,-15,"[195]OSELL",-16,BUTTON,-24,CLEATES,18
1936 DATAPANTS,19,"[210]OBINSON",-20,BAT,21
1940 DATA"[204]ASORDA",-22
1950 DATAWEST,W,NORTH,N,EAST,E,SOUTH,S,UP,U,DOWN,D,GET,DROP,LOOK,READ,KISS
1952 DATATALK,SPEAK,DRINK,SWALLOW,SELL,GIVE,TRADE,KILL,ATTACK,HIT,THROW
1954 DATAFLY,PLAY,PUSH,PRESS,CLIMB,GO,WEAR
1960 DATA1,2,3,3,4,5,5,6,6,7,7,7,8,8,8,9,9,9,10,10,11,11,12
1970 DATA"[202]ACK [195]LARK",HITS A HOME RUN,"[198]ERNANDO [214]ALENZEULA","[212]OM [207]'[205]ALLEY"
1972 DATAHITS A DOUBLE,"[208]EDRO [199]UERRERO","[196]UANE [203]UIPER",HITS A SINGLE
1974 DATA"[202]ERRY [210]EUSS","[195]HILI [196]AVIS",STEALS A BASE,"[211]TEVE [211]AX"
1976 DATA"[202]OHNNIE [204]EMASTER",MAKES A GREAT PLAY,"[196]USTY [194]AKER"
1977 :
1978 REM *** DON'T KNOW WHAT IT DOES***
1979 :
1980 FORK4=1TO21:IFA$(J)=H$(K4)THENI(K4)=1:K4=60
1990 NEXT:RETURN
2002 :
2003 REM *** VARYING LENGTH DELAY  ***
2004 REM *** LOOPS BEFORE ZEROING  ***
2005 REM *** DIRECTIONS & PRINTING ***
2006 REM *** ROOM DESCRIPTION      ***
2007 REM *** (LINES 2010-2030)     ***
2008 :
2010 FORV=1TO2500:NEXT:GOTO320
2020 FORV=1TO4000:NEXT:GOTO320
2030 FORV=1TO3500:NEXT:GOTO320
2032 :
2033 REM *** TITLE PAGE &          ***
2035 :
2040 PRINTCHR$(147):POKE783,PEEK(783)AND254
2050 POKE781,5:POKE782,3:SYS65520:PRINT"[194] [193] [211] [197] [194] [193] [204] [204]   [193] [196] [214] [197] [206] [212] [213] [210] [197][146]"
2060 POKE781,10:POKE782,12:SYS65520:PRINT"[194]Y [211]AMUEL [195]HIANG"
2070 POKE781,15:POKE782,5:SYS65520:PRINT"[152][212]RANSLATED FOR THE [195]OMMODORE BY"
2072 POKE781,17:POKE782,13:SYS65520:PRINT"[149][196]ONNA [203]. [215]OODY[144]"
2080 POKE781,23:POKE782,7:SYS65520:PRINT"[208][210][197][211][211] [193][206][217] [203][197][217] [212][207] [195][207][206][212][201][206][213][197]";
2082 POKE198,0:WAIT198,1:GETZ$:PRINTCHR$(147)
2090 PRINT:PRINT
2092 :
2093 REM *** INSTRUCTIONS           ***
2094 :
2100 PRINT"[193]S IN OTHER ADVENTURES, ONE OR TWO WORD"
2102 PRINT"COMMANDS ARE USED TO COMMUNICATE WITH"
2104 PRINT"THE COMPUTER, SUCH AS 'GET KEY', 'DROP"
2106 PRINT"KEY', 'OPEN DOOR'."
2110 PRINT:PRINT
2120 PRINT"[212]O MOVE IN A PARTICULAR DIRECTION,"
2122 PRINT"ENTER THE DIRECTION 'SOUTH' OR SIMPLY"
2124 PRINT"THE FIRST LETTER OF THAT DIRECTION 'S'."
2130 PRINT:PRINT
2140 PRINT"[197]NTERING 'LOOK' WILL REFRESH YOUR"
2142 PRINT"MEMORY ABOUT YOUR ENVIRONMENT, AND"
2144 PRINT"ENTERING 'INVENTORY' OR 'I' WILL SHOW"
2146 PRINT"YOU WHAT YOU ARE CARRYING."
2150 POKE781,23:POKE782,7:SYS65520:PRINT"[208][210][197][211][211] [193][206][217] [203][197][217] [212][207] [195][207][206][212][201][206][213][197]";
2152 POKE198,0:WAIT198,1:GETZ$:PRINTCHR$(147)
2160 PRINT:PRINT
2170 PRINT"[212]HE TIME IS THE PRESENT.  [217]OU ARE IN"
2172 PRINT"CHARGE OF THE GATE RECIEPTS AT A GREAT"
2174 PRINT"METROPOLITAN BASEBALL STADIUM."
2175 PRINT
2180 PRINT:PRINT"[193]S YOU WERE ABOUT TO PUT THE MONEY FROM"
2182 PRINT"THE GATE INTO THE SAFE, YOU WERE STRUCK"
2184 PRINT"FROM BEHIND AND LOST CONCIOUSNESS. [215]HEN"
2186 PRINT"YOU AWAKE, THE GAME IS JUST BEGINNING"
2188 PRINT"AND THE MONEY IS GONE."
2190 PRINT
2200 PRINT:PRINT"[217]OU MUST FIND THE MONEY WHICH IS STILL"
2202 PRINT"IN THE STADIUM AND RETURN IT TO YOUR"
2204 PRINT"OFFICE BEFORE THE GAME IS OVER.  [201]F YOU"
2206 PRINT"DO NOT, YOUR HIGH PAYING JOB IS"
2208 PRINT"FORFEIT."
2210 PRINT"              * [199][207][207][196] [204][213][195][203] *"
2220 POKE781,23:POKE782,7:SYS65520:PRINT"[208][210][197][211][211] [193][206][217] [203][197][217] [212][207][160][195][207][206][212][201][206][213][197]";
2222 POKE198,0:WAIT198,1:GETZ$:PRINTCHR$(147)
2230 RETURN
2232 :
2233 REM *** END GAME MESSAGE FOR   ***
2234 REM *** WINNER                 ***
2235 :
2240 PRINTCHR$(147)
2250 PRINT
2260 PRINT"[202]UST AS YOU PUT THE MONEY SAFELY INTO"
2262 PRINT"THE SAFE, [199]IANTS' OWNER [194]OB [204]URIE WALKS"
2264 PRINT"IN SMILING AND SAYS '[198]OR DOING SUCH A"
2266 PRINT"GOOD JOB, [201]'M GOING TO PROMOTE YOU TO"
2268 PRINT"GENERAL MANAGER.  [207]F COURSE, YOU WILL"
2269 PRINT"YOU WILL GET A SUBSTANTIAL RAISE.'"
2270 PRINT:PRINT:PRINT"[193]S GENERAL MANAGER, YOU MAKE JUST THE"
2272 PRINT"RIGHT MOVES AND TAKE THE [199]IANTS TO THE"
2274 PRINT"[215]ORLD [211]ERIES WHERE THEY SWEEP THE"
2276 PRINT"[217]ANKEES IN FOUR GAMES."
2280 POKE781,22:POKE782,10:SYS65520:PRINT"* [195][207][206][199][210][193][212][213][204][193][212][201][207][206][211] *"
2290 GOTO2350
2292 :
2293 REM *** END GAME MESSAGE FOR   ***
2294 REM *** LOSER                  ***
2295 :
2300 PRINTCHR$(147)
2310 POKE781,5:POKE782,9:SYS65520:PRINT"* [212][200][197] [199][193][205][197] [201][211] [207][214][197][210] *"
2330 POKE781,8:POKE782,0:SYS65520
2340 PRINT"[217]OUR TIME IS UP!  [212]HE [199]IANTS WON, BUT"
2342 PRINT"YOU LOST.  [193]FTER YOUR BOSS FINDS OUT"
2344 PRINT"WHAT HAPPENED, HE NOT ONLY FIRES YOU,"
2346 PRINT"HE ALSO EXILES YOU TO [207]AKLAND WHERE YOU"
2348 PRINT"HAVE TO WORK FOR THE (UGH!) [193]'S."
2350 PRINT:PRINT"[196]O YOU WANT TO PLAY AGAIN (Y/N)?";:POKE 198,0:WAIT198,1:GETKE$
2360 IFKE$="Y"THENRUN
2370 IFKE$="N"THEN2380
2375 PRINT"[145][145][145][145]":GOTO2350
2379 REM *****************************
2380 GOTO63000
2381 :
2382 :
2390 REM *****************************
2995 :
2996 REM *** MORE DESCRIPTION     ***
2998 :
3000 PRINT"[217]OU GO UP TO PINCH HIT FOR [202]ACK [195]LARK,"
3010 PRINT"BUT HE WANTS HIS SWINGS, AND SINCE HE"
3020 PRINT"HAS A BETTER AVERAGE, HE FORCES YOU TO  GO BACK!":A=21:RETURN
3045 :
3046 REM *** NOT WEARING A FULL    ***
3047 REM *** UNIFORM               ***
3049 :
3050 PRINT:PRINT:PRINT"[212]HE UMPIRES STOP YOU FROM GOING OUT ON"
3055 PRINT"THE FIELD AND SAY:"
3060 PRINT"'[193] PLAYER MUST BE IN FULL UNIFORM TO    PLAY!'":A=20:RETURN
3095 :
3096 REM *** PRINT INNING # WHEN   ***
3097 REM *** DIVISIBLE BY 13       ***
3098 :
3100 PRINT"[201]NNING #";XX/13:PRINTPL$(INT(RND(1)*5)+1);" ";
3110 PRINTEV$(INT(RND(1)*5)+1);"!!!":RETURN
3145 :
3146 REM *** SUBROUTINE TO PICK UP ***
3147 REM *** ITEM & PRINT OK       ***
3148 :
3150 FORK=1TO10
3152 IFC$(K)=""THENC$(K)=A$(J):GOSUB1980:H(K)=J:A$(J)="":A(J)=0
3154 IFC$(K)=""THENK=10:R=R+1:PRINT"[207]K!"
3161 NEXT
3162 RETURN
3195 :
3196 REM *** READ SIGN IN ROOM # 2 ***
3197 :
3200 PRINT"[212]HE SIGN READS:":PRINT
3210 PRINT"[194][193][211][197][194][193][204] [199][193][205][197] [212][207][196][193][217]":PRINT
3220 PRINT"[199][201][193][206][212][211] [214][211]. [196][207][196][199][197][210][211]":PRINT
3230 PRINT"[211][207][204][196][160][207][213][212]":RETURN
3245 :
3246 REM *** READ SIGN IN ROOM 15  ***
3247 :
3250 PRINT"[212]HE SIGN READS:":PRINT"[195][207][206][212][197][211][212] [212][207][196][193][217]":RETURN
3253 :
3254 REM *** READ COUPON           ***
3255 :
3260 PRINT"[212]HE COUPON READS:":PRINTTAB(12)"[217]OU'RE A WINNER!":RETURN
3262 :
3263 REM *** MESSAGE FOR KISS      ***
3264 REM *** DODGER FAN            ***
3265 :
3270 PRINT"[200]E LIKES IT!  [215]HAT DO YOU EXPECT FROM A [196]ODGERS FAN!":RETURN
3272 :
3273 REM *** MESSAGE FOR TALK MAN  ***
3274 REM *** DOESN'T HAVE A TICKET ***
3275 :
3280 PRINT"[212]HE MAN SAYS:":PRINT"[210]ATS!!!  [212]HE GAME IS SOLD OUT!":RETURN
3282 :
3283 REM *** MESSAGE FOR TALK      ***
3284 REM *** DODGER FAN            ***
3285 :
3290 PRINT"[200]E SAYS:":PRINT"[193]AARGH!!!  [212]HE [196]ODGERS ALWAYS LOSE TO"
3300 PRINT"THE [199]IANTS!":RETURN
3302 :
3303 REM *** MESSAGE FOR TALK      ***
3304 REM *** PRETTY GIRL           ***
3305 :
3310 PRINT"[211]HE SAYS:":PRINT"[196]O YOU HAVE A WINNING COUPON?":RETURN
3312 :
3313 REM *** MESSAGE FOR TALK      ***
3314 REM *** COSELL                ***
3315 :
3320 PRINT"[200]E SAYS:":PRINT"[212]HIS GAME IS A DEBACLE!  [212]HE AWESOME"
3330 PRINT"[199]IANTS ARE AGAIN TOTALLY HUMILIATING"
3340 PRINT"THE LOWLY [204]OS [193]NGELES [196]ODGERS!":RETURN
3342 :
3343 REM *** MESSAGE FOR TALK      ***
3344 REM *** ROBINSON              ***
3345 :
3350 PRINT"[200]E SAYS:":PRINT"[217]OU KNOW, KID, [201]'VE ALWAYS WANTED TO BE"
3360 PRINT"LIKE [205]EAN [202]OE [199]REENE.":RETURN
3362 :
3363 REM *** MESSAGE FOR TALK      ***
3364 REM *** LASORDA               ***
3365 :
3370 PRINT"[200]E SAYS:":PRINT"[201] JUST GOT A BIG PAY BONUS!  [200]EY!  [200]EY!":RETURN
3372 :
3373 REM *** MESSAGE FOR DRINK COKE ***
3374 REM *** FROM VENDOR            ***
3375 :
3380 PRINT"[199]OOD, YOU WERE THIRSTY":CK=0:K3=E:M$="BOTTLE":GOSUB1890:RETURN
3382 :
3383 REM *** MESSAGE FOR SELL TICKET***
3384 :
3390 PRINT"[212]HE MAN TAKES THE TICKET AND HANDS YOU"
3400 PRINT"SOME MONEY!  [200]E THEN RUSHES INTO THE"
3410 PRINT"BALLPARK TO SEE THE GAME.":TK=0:K3=0:MY=1:A(1)=0:M$="MONEY":GOSUB1890
3420 RETURN
3425 :
3426 REM *** MESSAGE FOR BUY COKE   ***
3427 :
3430 PRINT"[212]HE VENDOR TAKES YOUR MONEY AND HANDS"
3440 PRINT"YOU A COKE!":MY=0:CK=1:K3=3:M$="COKE":GOSUB1890:RETURN
3442 :
3443 REM *** ROBINSON DRINKS COKE   ***
3444 REM *** & GIVES YOU JERSEY     ***
3445 :
3450 PRINT"[200]E GULPS THE COKE DOWN AND IN GRATITUDE"
3460 PRINT"THROWS YOU HIS JERSEY!":JR=1:CK=0:K3=3:M$="JERSEY":GOSUB1890:RETURN
3462 :
3463 REM *** GET CAP FOR COUPON    ***
3464 REM *** MESSAGE               ***
3465 :
3470 PRINT"[212]HE GIRL TAKES THE COUPON AND HANDS YOU"
3471 PRINT"YOU A [199]IANTS CAP.":CA=1:CP=0:K3=0:M$="CAP":GOSUB1890:RETURN
3473 :
3474 REM *** MESSAGE IF ATTACK     ***
3475 REM *** LASORDA               ***
3476 :
3480 PRINT"[193]S YOU CHARGE TOWARD HIM, HE BECOMES"
3490 PRINT"FRIGHTENED AND RUSHES ONTO THE FIELD."
3500 PRINT"[201]N HIS RUSH TO ESCAPE, SOMETHING FALLS"
3510 PRINT"OUT OF HIS POCKET!":CH=1:K3=20:M$="LOTS OF CASH":GOSUB1890:A(20)=22
3520 RETURN
3522 :
3523 REM *** THROW BALL MESSAGE &   ***
3524 REM *** UPDATE CARRY LIST      ***
3530 PRINT"[212]HE BALL SAILS OVER THE FIELD.  [201]T HITS"
3540 PRINTDG$(INT(RND(1)*5)+1);"ON THE HEAD!"
3550 PRINT"[200]E'S OUT COLD!!":FORV=1TO10:IFC$(V)="BASEBALL"THENC$(V)=""
3560 K3=6:M$="":GOSUB1890:A(6)=0:NEXTV:RETURN
3570 PRINT"[212]HE FRISBEE FLIES ONTO THE FIELD.  [201]T"
3580 PRINT"HITS "DG$(INT(RND(1)*5)+1);"ON THE HEAD!"
3590 PRINT"[194]RING ON THE STRETCHER!!!!":FORV=1TO10:IFC$(V)="FRISBEE"THENC$(V)=""
3600 K3=9:M$="":GOSUB1890:A(9)=0:NEXTV:RETURN
3602 :
3603 REM *** THROW/FLY/PLAY BAT     ***
3604 :
3610 PRINT"[215]HAT AN ARM!  [201]T HITS "DG$(ING(RND(1)*5)+1)
3620 PRINT"ON THE HEAD.  [200]E'S NOT MOVING!!!":FORV=1TO10
3625 IFC$(V)="BAT"THENC$(V)="":K3=19:M$="":GOSUB1890:A(19)=0:NEXTV:RETURN
3630 A$(K2)=M$:H$(K3)=M$:A(K2)=A(K2)*(M$<>"")*-1:I(K3)=I(K3)*(M$<>"")*-1:RETURN
3642 :
3643 REM *** MESSAGE IF WEARING FULL***
3644 REM *** UNIFORM                ***
3645 :
3650 PRINT"[217]OU ARE NOW IN FULL UNIFORM!":PRINT:PRINT:FT=1:RETURN
3652 :
3653 REM *** MESSAGE IF HIT BUSINESS***
3654 REM *** MAN                    ***
3655 :
3660 PRINT"[194]EFORE YOU CAN HIT HIM, HE HITS YOU"
3670 PRINT"OVER THE HEAD HEAD WITH HIS BREIFCASE."
3680 PRINT"[207]UCH!!":RETURN
3682 :
3683 REM *** MESSAGE IF HIT OLD HAG ***
3684 :
3690 PRINT"[194]EFORE YOU CAN HIT HER, SHE STABS YOU"
3700 PRINT"WITH A KNITTING NEEDLE.  [207]WWW!!":RETURN
3702 :
3703 REM *** MESSAGE IF HIT FAN     ***
3704 :
3710 PRINT"[217]OU DON'T WANT TO BEAT UP A WIMPY GUY   LIKE HIM!": RETURN
3712 :
3713 REM *** MESSAGE IF HIT VENDOR  ***
3714 :
3720 PRINT"[212]HAT WOULDN'T BE FAIR.  [200]E'S HOLDING    THE COKES!":RETURN
3722 :
3723 REM *** MESSAGE IF HIT PRETTY  ***
3724 REM *** GIRL                   ***
3725 :
3730 PRINT"[194]EFORE YOU CAN HIT HER. SHE KICKS YOU"
3740 PRINT"IN A VERY SENSITIVE AREA. [217]IKES!":RETURN
50000 REM ****************************
50010 REM *                          *
50020 REM *       VARIABLES USED     *
50030 REM *                          *
50040 REM ****************************
50050 :
50100 REM C$() = ITEMS BEING CARRIED
50110 REM E$   = LAST 3 LETTERS OF NOUN
50120 REM D()  = NUMBER OF VERB
50130 REM A()  = NUMBER OF VERB
50140 REM A$() = LIST OF NOUNS
50150 REM PL$()= PLAYER OF ONE TEAM
50160 REM EV$()= ACTION OF PLAYER
50170 REM DG$()= PLAYER OF 2ND TEAM
50180 REM H$() =
50190 REM I    =
50200 REM R    = # ITEMS CARRIED
50210 REM A    = ROOM #
63000 REM     LINK BACK
63010 PRINT"[147]LOAD"CHR$(34)"HELLO"CHR$(34)",8":PRINT"RUN"
63020 POKE198,0:POKE631,13:POKE632,13:POKE198,2:END