home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / genie-commodore-file-library / C64-128Toolkit / MSD-DU15.ARC / DIALER.C (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  1.4 KB  |  60 lines
  1. 10 REM TOUCH-TONE DIALER
  2. 20 REM BY BOB HUFFMAN
  3. 30 :
  4. 50 DIM B$(50),C$(50)
  5. 100 DATA COMMODORE,1-(215) 337-7100
  6. 110 DATA RON & NANCY,1-(202) 456-1414
  7. 120 DATA COMPUTE!,1-(919) 275-9809
  8. 130 DATA MCI,"        886-8385
  9. 140 [131] IBM ACCESS CODE,"           39562
  10. 990 DATA 0,0
  11. 992 POKE 53281,15:POKE 53280,12
  12. 993 PRINT CHR$(147)CHR$(151)
  13. 1000 P=1
  14. 1010 READ B$(P),C$(P)
  15. 1020 IF B$(P)="0" THEN 1040
  16. 1030 P=P+1:GOTO 1010
  17. 1040 PM=P-1:CF=.975:K=.059604645
  18. 1050 FOR N=0 TO 3:READ F:F=F*CF/K
  19. 1060 RH(N)=INT(F/256):RL(N)=F-256*RH(N):NEXT
  20. 1070 DATA 697,770,852,941
  21. 1080 FOR N=0 TO 2:READ F:F=F*CF/K
  22. 1090 CH(N)=INT(F/256):CL(N)=F-256*CH(N):NEXT
  23. 1091 DATA 1209,1336,1477
  24. 1092 V1=54272:V2=V1+7:POKE V1+24,15
  25. 1093 POKE V1+5,0:POKE V1+6,240
  26. 1094 POKE V2+5,0:POKE V2+6,240
  27. 1100 P=1
  28. 1110 PRINT CHR$(147)"KEY  PARTY"TAB(27)"NUMBER":PRINT
  29. 1120 IF B$(P)="0" THEN 1220
  30. 1130 PRINT P;TAB(4)B$(P);TAB(23)C$(P)
  31. 1140 P=P+1
  32. 1150 IF (P-1)/18=INT((P-1)/18) THEN 1170
  33. 1160 GOTO1120
  34. 1170 PRINT:INPUT "ENTER KEY OR RETURN FOR NEXT PAGE";A$
  35. 1180 A=VAL(A$+CHR$(0))
  36. 1190 IF A=0 THEN 1110
  37. 1200 IF A>PM THEN PRINT"TRY AGAIN":A$="":GOTO 1170
  38. 1210 NB$=C$(A):GOTO 1270
  39. 1220 PRINT:INPUT "ENTER KEY OR RETURN TO END";A$
  40. 1230 A=VAL(A$+CHR$(0))
  41. 1235 IF A$="R" THEN P=1:A$="":GOTO 1110
  42. 1240 IF A=0 THEN END
  43. 1250 IF A>PM THEN PRINT"TRY AGAIN":A$="":GOTO 1220
  44. 1260 NB$=C$(A)
  45. 1270 FOR J=1 TO LEN(NB$)
  46. 1280 N$=MID$(NB$,J,1)
  47. 1290 IF N$="0" THEN N$="11"
  48. 1300 IF N$="*" THEN N$="10"
  49. 1310 IF N$="#" THEN N$="12"
  50. 1320 IF N$=" "ORN$="-"ORN$="("ORN$=")"THEN 1410
  51. 1330 VA=VAL(N$)-1
  52. 1340 R%=VA/3
  53. 1350 C%=VA-3*R%
  54. 1360 POKE V1+1,RH(R%):POKE V1,RL(R%)
  55. 1370 POKE V2+1,CH(C%):POKE V2,CL(C%)
  56. 1380 POKE V1+4,17:POKE V2+4,17
  57. 1390 FOR N=1 TO 100:NEXT
  58. 1400 POKE V1+4,0:POKE V2+4,0
  59. 1410 NEXT:P=1:A$="":GOTO 1110
  60.