home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / genie-commodore-file-library / C64-128BBS / STR39.PFILE1.ARC / (ST / R.TRIVIA (.txt)
Encoding:
Commodore BASIC  |  2019-04-13  |  10.7 KB  |  315 lines
  1. 100 POKE152,PEEK(251)
  2. 110 GOTO460
  3. 120 :
  4. 130 :REM START OF USER JUMP TABLE.
  5. 140 :
  6. 150 GOTO650 :REM CHECK FOR CARRIER.
  7. 160 GOTO710 :REM SEND P$+CHR$(13) OUT.
  8. 170 GOTO720 :REM SEND P$ OUT.
  9. 180 GOTO760 :REM GET L$ FROM MODEM.
  10. 190 GOTO870:REM CALL FOR CHAT.
  11. 200 GOTO910:REM ENGAGE CHAT MODE.
  12. 210 GOTO970:REM SEND 'P' TO USERFILE.
  13. 220 GOTO1010:REM READ ERROR CHANNEL.
  14. 230 GOTO1030:REM READ SYSTEM CLOCK.
  15. 240 GOTO1090:REM DISPLAY USER STATS.
  16. 250 GOTO1230:REM DISPLAY USER ONLINE.
  17. 260 GOTO1250:REM EDIT USER STATISTICS.
  18. 270 GOTO1620:REM REMOTE SYSOP MENU.
  19. 280 GOTO1840:REM DISPLAY DIR.
  20. 290 GOTO2140:REM BREAK RC INTO LO/HI.
  21. 300 GOTO2180:REM UPDATE (USER LOG).
  22. 310 GOTO2190:REM SAME AS 2330.
  23. 320 GOTO2200:REM GET U$() FROM DISK.
  24. 330 GOTO2210:REM GET N$() FROM DISK.
  25. 340 GOTO2220:REM SEND U$() TO DISK.
  26. 350 GOTO2230:REM SEND N$() TO DISK.
  27. 360 GOTO2250:REM FIND DV,DR$.
  28. 370 GOTO2270:REM INCREMENT DV,DR$.
  29. 380 GOTO2330:REM HANG UP PHONE.
  30. 390 GOTO2400:REM FIND TIME CONNECTED.
  31. 400 GOTO2430:REM RETURN TO BBS.
  32. 410 GOTO2440:REM LOAD NEXT MODULE.
  33. 420 GOTO820:REM SEND SEQ/8;0 TO MODEM
  34. 430 :
  35. 440 :REM END OF USER JUMP TABLE.
  36. 450 :
  37. 460 B1=56577:B2=56579:Q$=CHR$(34):B3=56590:B4=56588:DV=8:N$=CHR$(0):SI=54272
  38. 470 DIMU$(15),N$(15),DR%(7):DR$="0"
  39. 480 GOSUB490:GOTO540
  40. 490 OPEN1,8,5,"0:(BBS.CONFIG)":FORT=0TO9:INPUT#1,A:IFA=0THEN510
  41. 500 FORI=0TOA-1:INPUT#1,A$,A,A:NEXT
  42. 510 NEXT:INPUT#1,DR:FORI=0TODR-1:INPUT#1,DR%(I):NEXT:DR=DR+7
  43. 520 INPUT#1,RF:AA=-((RFAND128)=128):RF$=MID$(STR$(AA),2)+":(USERFILE)"
  44. 530 INPUT#1,SY$,BD$,MT%,RC,S1$,S2$,RR,P1$,P2$,D5,D6,MF,N5,N3,N4:CLOSE1:RETURN
  45. 540 F$=CHR$(13):P=0:POKE51972,P:SYS51976:BS=255:UL$=""
  46. 550 DC$="[149] --===[129]***[158]===[153]---===[159]***[154]===---[156]===***[158]===--[152]":GOTO2500
  47. 560 IFA$="[133]"THENSY=SY+1:GOSUB1620:SY=SY-1:RETURN
  48. 570 IFA$="[134]"THENGOSUB910:TI$="000000":RETURN
  49. 580 IFA$="[140]"THENCD=1:RETURN
  50. 590 IFL<>65535THENRETURN
  51. 600 OPEN1,8,5,"0:(USER LOG),A":PRINT#1,UL$:PRINT#1,"[212]IME [197]LAPSED![152]":CLOSE1
  52. 610 CD=1:UL$="":RETURN
  53. 620 IFA$=""ORZ$=""THENGOSUB640
  54. 630 RETURN
  55. 640 POKESI+4,21:POKESI+4,20:RETURN
  56. 650 CD=0:IFSYTHENRETURN
  57. 660 IF(PEEK(B1)AND16)<>HLTHENRETURN
  58. 670 TI$="000000"
  59. 680 IF(PEEK(B1)AND16)<>HLTHENRETURN
  60. 690 IFVAL(TI$)>5THENCD=1:RETURN
  61. 700 GOTO680
  62. 710 P$=P$+F$
  63. 720 IFL=55THENPRINT#4,P$;
  64. 730 POKE52030,SY:POKE52040,MM:SYS51994,P$:CD=PEEK(52033):A$=CHR$(PEEK(52034))
  65. 740 IFA$=CHR$(0)THENA$=""
  66. 750 RETURN
  67. 760 GOSUB2400:IFCO>VAL(U$(14))THEN800
  68. 770 POKE52038,EC:POKE52039,L:POKE52040,MM:POKE52030,SY
  69. 780 L$="                                       ":SYS52003,L$:CD=PEEK(52033)
  70. 790 L=PEEK(52034)+256*PEEK(52036):A$=CHR$(PEEK(52034)):GOSUB560:RETURN
  71. 800 P$=F$+F$+"[217]OU [200]AVE [197]XCEEDED [217]OUR [212]IME [204]IMIT!!"+F$+"[199][207][207][196][194][217][197]!"+F$:GOSUB160
  72. 810 GOSUB390:GOTO400
  73. 820 OPEN1,8,5,"0:"+FI$:GOSUB220:IFER$>"01"THENCLOSE1:RETURN
  74. 830 SYS52021:CLOSE1:RETURN
  75. 840 P$=F$+"[197]NTER [193]CCESS LEVEL: ":GOSUB720:L=5:GOSUB760:IFCDTHENRETURN
  76. 850 IFVAL(L$)<0ORVAL(L$)>65535ORL$=""THENRETURN
  77. 860 L=VAL(L$):A2=INT(L/256):A1=L-A2*256:A$=L$:RETURN
  78. 870 IFSA<>1THENP$=F$+F$+SY$+" IS NOT AVAILABLE RIGHT NOW.":GOSUB710:RETURN
  79. 880 P$="[195]ALLING "+SY$+"....":GOSUB710:FORI=1TO20:GETA$:IFA$="[134]"THEN910
  80. 890 GOSUB640:FORT=1TO600:NEXT:NEXT
  81. 900 P$="[212]RY AGAIN LATER....":GOSUB710:RETURN
  82. 910 P$=F$+F$+SY$+", CHATTING WITH "+U$(1)+F$:GOSUB710
  83. 920 SYS50212:A$=CHR$(PEEK(52034)):CD=PEEK(52033)
  84. 930 IFA$="[133]"ORCDTHENP$=F$+SY$+" HAS RETURNED TO "+BD$+".":GOSUB160:RETURN
  85. 940 IFA$="[134]"THENSY=SY+1:GOTO1620:SY=SY-1:GOTO920
  86. 950 IFA$="[140]"THENCD=1:RETURN
  87. 960 RETURN
  88. 970 GOSUB2150:AA=RF:GOSUB2250
  89. 980 FORL=1TO2:PRINT#15-B,"P"CHR$(99)CHR$(R1)CHR$(R2)CHR$(1):GOSUB1010:NEXT
  90. 990 GOSUB1010:IFER$<"20"ORER$="50"THENRETURN
  91. 1000 PRINT"[197]RROR IN (USERFILE)!":GOSUB2330:STOP
  92. 1010 ES$="":GOSUB1020:ER$=LEFT$(ES$,2):RETURN
  93. 1020 GET#15-B,A$:ES$=ES$+A$:ON-(A$<>CHR$(13))GOTO1020:RETURN
  94. 1030 T1$="00:00:00.0 XX":SYS51982,T1$:TM$=T1$+""
  95. 1040 HO$=LEFT$(TM$,2):MI$=MID$(TM$,4,2):FZ$=RIGHT$(TM$,2)
  96. 1050 IFVAL(LEFT$(TM$,2))<>12ANDFZ$<>"AM"THENC2=1:GOTO1080
  97. 1060 IFC2THENOPEN1,8,5,"@0:(T.CALLERS),S,W":PRINT#1," ":CLOSE1:DT=DT+1
  98. 1070 IFC2THENC2=0:NT=0:IFSFTHENOPEN1,8,5,"@0:(USER LOG),S,W":CLOSE1
  99. 1080 DA$=M$+STR$(DT):RETURN
  100. 1090 P$=F$+"[217]OUR [211]TATISTICS...."+F$:GOSUB710
  101. 1100 P$="[206]AME          : "+U$(1):GOSUB710
  102. 1110 P$="[193]CCESS LEVEL  :"+STR$(AC):GOSUB710:GOSUB1030
  103. 1120 P$="[196]ATE/[212]IME     : "+DA$+" "+TM$:GOSUB710:GOSUB2400
  104. 1130 P$="[195]ONNECT [212]IME  :"+STR$(CO)+" MINS.":GOSUB710
  105. 1140 P$="[205]EMBER #      : "+R$:GOSUB710
  106. 1150 P$="[208]ASSWORD      : "+U$(4):GOSUB710
  107. 1160 P$="[193]GE           : "+U$(6):GOSUB710
  108. 1170 P$="[210]EAL [206]AME     : "+U$(7):GOSUB710
  109. 1180 P$="[212]OTAL [213]/[204]'S   : "+U$(9):GOSUB710
  110. 1190 P$="[212]OTAL [196]/[204]'S   : "+U$(10):GOSUB710
  111. 1200 P$="       [[210]ATIO - "+MID$(STR$(RR),2)+":1]":GOSUB710
  112. 1210 P$="[204]AST CALL DATE: "+U$(11):GOSUB710
  113. 1220 P$="[212]OTAL CALLS   : "+U$(12):GOSUB710:RETURN
  114. 1230 PRINT"[156]"F$U$(1)" <*> [204]VL-"+MID$(STR$(AC),2):GOSUB2400
  115. 1240 PRINTTM$" [195]ONNECTED:"STR$(CO)" MINS.[152]":RETURN
  116. 1250 P$=" [147][197]NTER ACCOUNT # OF USER.":GOSUB710
  117. 1260 P$="[193]CCOUNT # OF CURRENT USER: "+R$:GOSUB710
  118. 1270 P$="[214][213]:":GOSUB720:L=3:GOSUB760:IFCDTHENRETURN
  119. 1280 IFL$=""THENRETURN
  120. 1290 E$=L$:IFL$=R$THENFORL=1TO15:N$(L)=U$(L):NEXT:AA=AC:GOTO1310
  121. 1300 OPEN3,RF,3,RF$:RC=VAL(L$):GOSUB970:GOSUB2210:CLOSE3
  122. 1310 P$=" [147]1 - [206]AME      : "+N$(1)+F$+"2 - [208]HONE     : "+N$(2):GOSUB710:GOSUB2170
  123. 1320 P$="3 - [193]CCESS [204]VL:"+STR$(AA)+F$+"4 - [208]ASSWORD  : "+N$(4):GOSUB710
  124. 1330 P$="5 - # OF [197]MAIL: "+N$(5)+F$+"6 - [193]GE       : "+N$(6):GOSUB710
  125. 1340 P$="7 - [210]EAL NAME : "+N$(7)+F$+"8 - C/G MODE  : "+N$(8):GOSUB710
  126. 1350 P$="9 - [212]OTAL [213]/[204] : "+N$(9)+F$+"[193] - [212]OTAL [196]/[204] : "+N$(10):GOSUB710
  127. 1360 P$="[194] - [204]AST CALL : "+N$(11):GOSUB710
  128. 1370 P$="[195] - # CALLS   : "+N$(12):GOSUB710
  129. 1380 P$="[196] - [195]ALLS/[196]AY : "+N$(13)+F$+"[197] - [212]IME/[195]ALL: "+N$(14):GOSUB160
  130. 1390 P$="[198] - [195]ALLS[212]ODAY: "+N$(15):GOSUB160
  131. 1400 IFL=55THENL=0:PRINT#4:CLOSE4:GOTO1310
  132. 1410 P$=F$+"[215]HICH TO CHANGE:":GOSUB720:L=1:GOSUB760:IFCDTHENRETURN
  133. 1420 IFL$=""ANDR$=E$THENFORL=1TO15:U$(L)=N$(L):NEXT:AC=AA:GOTO1250
  134. 1430 IFL$=""THEN1250
  135. 1440 IFL$="S"ORL$="[211]"THEN1520
  136. 1450 IFL$="P"ORL$="[208]"THENL=55:OPEN4,4,7:GOTO1310
  137. 1460 S=(ASC(L$)AND127)-64:IFS=>1ANDS<=6THENS=S+9:GOTO1490
  138. 1470 S=VAL(L$):IFS<1ORS>9THEN1310
  139. 1480 IFS=3THENGOSUB840:N$(3)=A$:AA=A:GOTO1310
  140. 1490 P$=F$+"["+N$(S)+"]:[195]HANGE TO->":GOSUB720
  141. 1500 L=20:GOSUB760:IFCDTHENRETURN
  142. 1510 N$(S)=L$:GOTO1310
  143. 1520 P$=F$+"[211]AVE STATS WHERE? (DEFAULT="+E$+"):":GOSUB720
  144. 1530 L=3:GOSUB760:IFCDTHENRETURN
  145. 1540 IFL$<>""ANDVAL(L$)>0THENE$=L$
  146. 1550 P$=F$+"[211]AVE AT: "+E$:GOSUB710
  147. 1560 P$="[195]ORRECT? (Y/N):":GOSUB720:L=1:GOSUB760:IFCDTHENRETURN
  148. 1570 IFL$<>"Y"ANDL$<>"[217]"THEN1310
  149. 1580 OPEN3,RF,3,RF$:RC=VAL(E$):GOSUB970
  150. 1590 GOSUB2230
  151. 1600 CLOSE3
  152. 1610 RETURN
  153. 1620 AA=DV:GOSUB2250
  154. 1630 P$=" [147]":GOSUB710
  155. 1640 P$=DC$+F$+"   --**]> [210]EMOTE [211]YS-[207]P [205]ENU <[**--"+F$+DC$+F$:GOSUB710
  156. 1650 P$="[214] - [214]ALIDATE USER":GOSUB710
  157. 1660 P$="[193] - [211]CAN ANY SEQ ON DISK":GOSUB710
  158. 1670 P$="$ - [196]IRECTORY":GOSUB710
  159. 1680 P$="@ - [196]OS COMMANDS":GOSUB710
  160. 1690 P$="[213] - [211]CAN USER LOG":GOSUB710
  161. 1700 P$="[212] - [212]ODAY'S CALLERS":GOSUB710
  162. 1710 P$="# - [212]OGGLE DRIVE #"+STR$(DV)+";"+DR$:GOSUB710
  163. 1720 P$=F$+"[210][211][205]"+MID$(STR$(DV),2)+";"+DR$+":":GOSUB720:L=1:GOSUB760:IFCDTHENRETURN
  164. 1730 IFL$=""THENRETURN
  165. 1740 L$=CHR$(ASC(L$)AND127)
  166. 1750 GOSUB2180:UL$=UL$+"[211]YSOP-"+L$+CHR$(13)
  167. 1760 ON-(L$="U")-2*(L$="A")-3*(L$="V")-4*(L$="$")GOSUB1980,2090,1250,1840
  168. 1770 ON-(A$="#")-2*(L$="T")GOSUB2270,2080
  169. 1780 IFL$="?"THEN1630
  170. 1790 IFL$<>"@"THEN1720
  171. 1800 P$=F$+">":GOSUB720:L=39:GOSUB760:IFCDTHENRETURN
  172. 1810 IFL$=""THENGOSUB1010:P$=F$+ES$:GOSUB710:GOTO1720
  173. 1820 IFLEFT$(L$,4)=P2$+":"THENPRINT#15-B,RIGHT$(L$,LEN(L$)-4)
  174. 1830 GOTO1720
  175. 1840 P$=F$:GOSUB710:OPEN1,DV,0,"$"+DR$+":*"
  176. 1850 GOSUB1010:IFER$>"01"THENCLOSE1:P$=F$+ES$:GOSUB710:RETURN
  177. 1860 GET#1,A$:GET#1,A$
  178. 1870 GET#1,A$:GET#1,A$:IF(ST)AND64THENCLOSE1:RETURN
  179. 1880 GET#1,LO$:GET#1,HI$
  180. 1890 LO$=LO$+N$:HI$=HI$+N$
  181. 1900 P$=STR$(ASC(LO$+CHR$(0))+256*ASC(HI$+CHR$(0)))+" "
  182. 1910 GET#1,A$:IFA$=""THEN1950
  183. 1920 GET#5,Z$:IFZ$=""THENGETZ$
  184. 1930 IFZ$=" "THENCLOSE1:RETURN
  185. 1940 P$=P$+A$:GOTO1910
  186. 1950 IFECANDMID$(P$,8,1)="("THEN1870
  187. 1960 GOSUB710:IFA$=" "THENCLOSE1:RETURN
  188. 1970 GOTO1870
  189. 1980 FI$="(USER LOG)"
  190. 1990 OPEN1,DV,5,DR$+":"+FI$:P$="":GOSUB1010:IFER$>"01"THENCLOSE1:RETURN
  191. 2000 GET#1,A$:IF(ST)AND64THEN2050
  192. 2010 GET#5,Z$:IFZ$=""THENGETZ$
  193. 2020 IFZ$=" "ORZ$="/"THEN2050
  194. 2030 IFA$=CHR$(13)ORLEN(P$)=39THENGOSUB710:P$="":GOTO2000
  195. 2040 P$=P$+A$:GOTO2000
  196. 2050 GOSUB710:CLOSE1:P$=F$+"[211]CRATCH? (Y/N):":GOSUB720:L=1:GOSUB760
  197. 2060 IFL$=""OR(L$<>"Y"ANDL$<>"[217]")THENRETURN
  198. 2070 OPEN1,DV,5,"@"+DR$+":"+FI$+",S,W":PRINT#1," ":CLOSE1:RETURN
  199. 2080 FI$="(T.CALLERS)":GOTO1990
  200. 2090 P$=F$+"[211]CAN FILE: ":GOSUB720:L=16:GOSUB760
  201. 2100 FI$=L$:GOTO1990
  202. 2110 POKEB3,65:POKEB4,40:POKEB2,231:POKEB1,57:POKEB4,48:RETURN
  203. 2120 GOSUB2110:POKEB2,PEEK(B2)OR32:POKEB1,PEEK(B1)AND223:POKEB1,PEEK(B1)OR32
  204. 2130 POKEB1,PEEK(B1)AND223:POKEB4,40:POKEB4,47:POKEB2,230:GOSUB2110:RETURN
  205. 2140 HI=INT(RC/256):LO=RC-(HI*256):RETURN
  206. 2150 GOSUB2140:R1=LO:R2=HI:RETURN
  207. 2160 AC=VAL(U$(3)):A2=INT(AC/256):A1=AC-A2*256:RETURN
  208. 2170 AA=VAL(N$(3)):RETURN
  209. 2180 IFLEN(UL$)<230THENRETURN
  210. 2190 OPEN1,8,5,"0:(USER LOG),A":PRINT#1,UL$:CLOSE1:UL$="":RETURN
  211. 2200 GOSUB2210:FORI=1TO15:U$(I)=N$(I):NEXT:RETURN
  212. 2210 FORI=1TO15:INPUT#3,N$(I):NEXT:RETURN
  213. 2220 N$(0)="":FORI=1TO15:N$(0)=N$(0)+Q$+N$(I)+CHR$(13):NEXT
  214. 2230 PRINT#3,N$(0):RC=1:GOSUB970:RETURN
  215. 2240 RETURN
  216. 2250 B=AA-8:IFB<0ORB>7THENB=0
  217. 2260 B=B-7*(AA=15):AA=-((DR%(B)AND128)=128):DR$=MID$(STR$(AA),2):RETURN
  218. 2270 IFDR$="0"THENAA=DV:GOSUB2250:IFDR$="1"THENRETURN
  219. 2280 DV=DV+1:IFDV>15THENDV=8
  220. 2290 FORL=0TO(DR-8):IFDV<>(DR%(L)AND63)THENNEXT:GOTO2280
  221. 2300 IFA1AND32ORSYTHEN2320
  222. 2310 AA=DV:GOSUB2250:IFDR%(B)AND64THEN2280
  223. 2320 AA=DV:GOSUB2250:DR$="0":RETURN
  224. 2330 ON(MT%-1)GOTO2340,2350,2380,2390,2120,2120
  225. 2340 POKEB2,PEEK(B2)OR32:POKEB1,PEEK(B1)AND223:RETURN
  226. 2350 FORT=1TO2000:NEXT:PRINT#5,"+++";:FORT=1TO2000:NEXT:PRINT#5,"[193][212][200]"
  227. 2360 FORT=1TO2000:NEXT:PRINT#5,"[193][212][216]2[205]0[209]0[214]0[197]0[211]0=0":RETURN
  228. 2380 POKEB2,38:POKEB1,38:RETURN
  229. 2390 POKEB1,PEEK(B1)OR32:RETURN
  230. 2400 GOSUB1030:CT=VAL(HO$):MI=VAL(MI$):CO=ABS((LH*60+LM)-(CT*60+MI))
  231. 2410 IFLH=12ANDC2THENCO=ABS(CO-720)
  232. 2420 RETURN
  233. 2430 FI$="(ST/R 3.?)":DV=D5
  234. 2440 OPEN1,8,5,"@0:(DATA),S,W":PRINT#1,R$:FORT=1TO15
  235. 2450 PRINT#1,Q$U$(T):NEXT:PRINT#1,LH:PRINT#1,LM:PRINT#1,SA:PRINT#1,SY
  236. 2460 PRINT#1,SF:PRINT#1,HL:PRINT#1,M$:PRINT#1,DT:PRINT#1,LEN(F$):PRINT#1,Q$LN$
  237. 2470 PRINT#1,DV:PRINT#1,NW:PRINT#1,L$:CLOSE1
  238. 2480 POKE252,32:POKE251,PEEK(152):AA=DV:GOSUB360:GOSUB2190:IFDV<128THENDR$="0"
  239. 2490 PRINT"[146][147]LOAD"Q$DR$":"FI$Q$","DVAND127"":POKE631,131:POKE198,1:NEW
  240. 2500 OPEN1,8,5,"0:(DATA)":INPUT#1,R$:R=VAL(R$):FORT=1TO15
  241. 2510 INPUT#1,U$(T):NEXT:INPUT#1,LH,LM,SA,SY,SF,HL,M$,DT,T,LN$,DV,NW,L$
  242. 2540 CLOSE1:GOSUB2160:CG=VAL(U$(8)):IFT=2THENF$=CHR$(13)+CHR$(10)
  243. 2550 REM -    YOUR PROGRAM SHOULD    -
  244. 2560 REM -    START AT LINE 3080!    -
  245. 2570 REM -----------------------------
  246. 2580 DIMTQ$(16,16),TA$(16,16),TU$(16,16),TR(16),CA$(16,1):I=17:GOSUB3090
  247. 2590 IFVAL(RIGHT$(U$(12),2))<>DTTHENFORT=1TO16:SC(T)=0:NEXT
  248. 2600 OPEN1,8,5,"0:(TRIVIA)":CB=1
  249. 2610 INPUT#1,CA:FORT=1TOCA:INPUT#1,CA$(T,0),CA$(T,1),TR(T):FORI=1TOTR(T)
  250. 2620 INPUT#1,TQ$(T,I),TA$(T,I),TU$(T,I):NEXT:NEXT:CLOSE1:GOTO2750
  251. 2630 GOSUB250:P$=F$+"[150][212]:":GOSUB170:L=1:GOSUB180:IFCDTHENGOSUB380:GOTO400
  252. 2640 IFL$=""THEN2630
  253. 2650 GOSUB300:UL$=UL$+"[212]RIVIA - "+L$+F$
  254. 2660 IFL$="A"ORL$="[193]"THEN2840
  255. 2670 IFL$="Q"ORL$="[209]"THENGOSUB3170:GOTO400
  256. 2680 IFL$="S"ORL$="[211]"THENGOSUB3260
  257. 2690 IFL$="L"ORL$="[204]"THEN3030
  258. 2700 IFL$="C"ORL$="[195]"THEN3200
  259. 2710 IFL$="Y"ORL$="[217]"THENGOSUB190
  260. 2720 IFL$="+"ORL$="-"THEN3240
  261. 2730 IFL$<>"?"THEN2630
  262. 2740 IFMFANDCGTHENFI$="(M.TRIVIA)":GOSUB420:IFER$="00"THEN2630
  263. 2750 P$=" [147]"+DC$+F$+"         --**]> [212]RIVIA <[**--"+F$+DC$:GOSUB160
  264. 2760 P$=F$+"[151][193] - [193]NSWER A QUESTION":GOSUB160
  265. 2770 P$="[152][204] - [204]IST QUESTIONS":GOSUB160
  266. 2780 P$="[154][195] - [195]HANGE CATAGORY: "+CA$(CB,0):GOSUB160
  267. 2790 P$="[155][217] - [217]ELL FOR [211]YSOP":GOSUB160
  268. 2800 P$="[150]+ - [211]TEP UP A CATAGORY":GOSUB160
  269. 2810 P$="[129]- - [211]TEP DOWN A CATAGORY":GOSUB160
  270. 2820 P$="[159][211] - [217]OUR [211]CORE":GOSUB160
  271. 2830 P$="[155][209] - [209]UIT":GOSUB160:GOTO2630
  272. 2840 P$=F$+"[193]NSWER QUESTION #(1-"+MID$(STR$(TR(CB)),2)+"):":GOSUB170:L=2:GOSUB180
  273. 2850 IFL$=""THEN2630
  274. 2860 RT=VAL(L$):IFRT<1ORRT>TR(CB)THEN2630
  275. 2870 IFTU$(CB,RT)>""THENP$=F$+TU$(CB,RT)+" HAS ALREADY ANSWERED IT!":GOSUB160:GOTO2630
  276. 2880 RC=SC(CB):GOSUB290:T=LO:IFRT>7THENT=HI
  277. 2890 IF((T)AND(2^(RT-1+8*(RT>8))))=0THEN2910
  278. 2900 P$=F$+"[159][217]OU HAVE ALREADY TRIED.":GOSUB160:GOTO2630
  279. 2910 P$=F$+TQ$(CB,RT)+F$+F$+"[217]OUR ANSWER: ":GOSUB170:L=38:GOSUB180
  280. 2920 IFCDTHENGOSUB380:GOTO400
  281. 2930 SC(CB)=SC(CB)+2^(RT-1)
  282. 2940 IFL$<>TA$(CB,RT)THENP$="[201]NCORRECT.[152]":GOSUB300:UL$=UL$+P$+F$:GOSUB160:GOTO2630
  283. 2950 P$="[150][193]BSOLUTELY [195]ORRECT! [195]ONGRATULATIONS!":GOSUB160
  284. 2960 SC(17)=SC(17)+5:P$="[217]OUR SCORE IS NOW:"+STR$(SC(17))
  285. 2970 GOSUB300:UL$=UL$+"[195]ORRECT. [211]CORE ="+STR$(SC(17))+F$
  286. 2980 GOSUB160:TU$(CB,RT)=U$(1)
  287. 2990 OPEN1,8,5,"@0:(TRIVIA),S,W":PRINT#1,CA:FORT=1TOCA:PRINT#1,Q$CA$(T,0)
  288. 3000 PRINT#1,Q$CA$(T,1):PRINT#1,TR(T):FORI=1TOTR(T)
  289. 3010 PRINT#1,Q$TQ$(T,I):PRINT#1,Q$TA$(T,I):PRINT#1,Q$TU$(T,I):NEXT:NEXT:CLOSE1
  290. 3020 GOTO2630
  291. 3030 P$=F$+"[195]ATAGORY : "+CA$(CB,0):GOSUB160
  292. 3040 P$="[208]OSTED ON: "+CA$(CB,1)+F$:GOSUB160:FORRT=1TOTR(CB):A$=TU$(CB,RT)
  293. 3050 IFA$=""THENA$="[206]O ONE!"
  294. 3060 P$=MID$(STR$(RT),1-(RT>9))+". [150]"+TQ$(CB,RT)+F$+"[158][193]NSWERED BY: "+A$:GOSUB160
  295. 3070 IFTU$(CB,RT)>""THENP$="[129]  [193]NSWER IS: "+TA$(CB,RT):GOSUB160
  296. 3080 NEXT:GOTO2630
  297. 3090 OPEN3,8,3,"0:(SCORES)":GOSUB220:IFER$>"01"THENCLOSE3:RETURN
  298. 3100 RC=R:GOSUB2150:GOSUB980:GET#3,A$:IF(ST)AND64THENSC=0:GOTO3120
  299. 3110 INPUT#3,SC
  300. 3120 IFSC=0THENSC=I:CLOSE3:DIMSC(SC):RETURN
  301. 3130 IFI>SCTHENDIMSC(I):GOTO3150
  302. 3140 DIMSC(SC)
  303. 3150 FORT=1TOSC:INPUT#3,SC(T):NEXT:CLOSE3:IFI>SCTHENSC=I
  304. 3160 RETURN
  305. 3170 OPEN3,8,3,"0:(SCORES)":GOSUB220:IFER$>"01"THENCLOSE3:RETURN
  306. 3180 RC=R:GOSUB2150:GOSUB980:SC$=STR$(SC)+CHR$(13):FORT=1TOSC
  307. 3190 SC$=SC$+STR$(SC(T))+CHR$(13):NEXT:PRINT#3,SC$;:RC=1:GOSUB2150:CLOSE3:RETURN
  308. 3200 P$=F$:GOSUB160:FORT=1TOCA:P$=STR$(T)+" - "+CA$(T,0):GOSUB160:NEXT
  309. 3210 P$=F$+"[197]NTER CATAGORY #:":GOSUB170:L=2:GOSUB180:IFCDTHENGOSUB380:GOTO400
  310. 3220 T=VAL(L$):IFT<1ORT>CATHEN2630
  311. 3230 CB=T:P$=F$+"[217]OU ARE NOW IN THE "+CA$(CB,0)+" CATAGORY.":GOSUB160:GOTO2630
  312. 3240 IFL$="+"THENL$=STR$(CB+1):GOTO3220
  313. 3250 L$=STR$(CB-1):GOTO3220
  314. 3260 P$=F$+"[217]OUR [211]CORE IS:"+STR$(SC(17)):GOSUB160:RETURN
  315.