home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / genie-commodore-file-library / C64-128BBS / STR3.5SRC.ARC / ST / R.CASINO (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  20.1 KB  |  576 lines
  1. 100 POKE152,PEEK(251)
  2. 110 GOTO480
  3. 120 :
  4. 130 :REM START OF USER JUMP TABLE.
  5. 140 :
  6. 150 GOTO790 :REM CHECK FOR CARRIER.
  7. 160 GOTO850 :REM SEND P$+CHR$(13) OUT.
  8. 170 GOTO860 :REM SEND P$ OUT.
  9. 180 GOTO1000:REM GET L$ FROM MODEM.
  10. 190 GOTO1250:REM CALL FOR CHAT.
  11. 200 GOTO1290:REM ENGAGE CHAT MODE.
  12. 210 GOTO1400:REM SEND 'P' TO USERFILE.
  13. 220 GOTO1440:REM READ ERROR CHANNEL.
  14. 230 GOTO1460:REM READ SYSTEM CLOCK.
  15. 240 GOTO1560:REM DISPLAY USER STATS.
  16. 250 GOTO1700:REM DISPLAY USER ONLINE.
  17. 260 GOTO1720:REM EDIT USER STATISTICS.
  18. 270 GOTO2080:REM REMOTE SYSOP MENU.
  19. 280 GOTO2300:REM DISPLAY DIR.
  20. 290 GOTO2600:REM BREAK RC INTO LO/HI.
  21. 300 GOTO2640:REM UPDATE (USER LOG).
  22. 310 GOTO2650:REM SAME AS 2330.
  23. 320 GOTO2660:REM GET U$() FROM DISK.
  24. 330 GOTO2670:REM GET N$() FROM DISK.
  25. 340 GOTO2680:REM SEND U$() TO DISK.
  26. 350 GOTO2690:REM SEND N$() TO DISK.
  27. 360 GOTO2740:REM FIND DV,DR$ IN DR%().
  28. 370 GOTO2760:REM FIND DV,DR$
  29. 380 GOTO2770:REM INCREMENT DV,DR$.
  30. 390 GOTO2830:REM HANG UP PHONE.
  31. 400 GOTO2900:REM FIND TIME CONNECTED.
  32. 410 GOTO3040:REM RETURN TO BBS.
  33. 420 GOTO3050:REM LOAD NEXT MODULE.
  34. 430 GOTO2930:REM GET SC() FROM DISK.
  35. 440 GOTO3010:REM SEND SC() TO DISK.
  36. 450 :
  37. 460 :REM END OF USER JUMP TABLE.
  38. 470 :
  39. 480 B1=56577:B2=56579:Q$=CHR$(34):B3=56590:B4=56588:DV=8:N$=CHR$(0):SI=54272
  40. 490 DIMIN%(255),OT%(255),U$(12),N$(12),DR%(7):DR$="0"
  41. 500 GOSUB580:GOSUB510:GOTO560
  42. 510 OPEN1,8,5,"0:(BBS.CONFIG)":FORT=0TO9:INPUT#1,A:IFA=0THEN530
  43. 520 FORI=0TOA-1:INPUT#1,A$,A,A:NEXT
  44. 530 NEXT:INPUT#1,DR:FORI=0TODR-1:INPUT#1,DR%(I):NEXT:DR=DR+7
  45. 540 INPUT#1,RF:AA=-((RFAND128)=128):RF$=MID$(STR$(AA),2)+":(USERFILE)"
  46. 550 INPUT#1,SY$,BD$,MT%,RC,S1$,S2$,RR,P1$,P2$,D5,D6:CLOSE1:RETURN
  47. 560 F$=CHR$(13):P=0:POKE51972,P:SYS51976:BS=255:UL$=""
  48. 570 DC$="[149] --===[129]***[158]===[153]---===[159]***[154]===---[156]===***[158]===--[152]":GOTO3110
  49. 580 FORI=1TO64:OT%(I)=I:NEXT:OT%(20)=8:OT%(160)=32
  50. 590 OT%(12)=12:FORI=65TO90:OT%(I)=I+32:NEXT:OT%(34)=ASC("'")
  51. 600 FORI=91TO95:OT%(I)=I:NEXT:FORI=193TO218:OT%(I)=I-128:NEXT
  52. 610 OT%(5)=0:OT%(8)=0:OT%(9)=0:OT%(14)=0:OT%(17)=0:OT%(18)=0:OT%(28)=0
  53. 620 OT%(29)=0:OT%(30)=0:OT%(31)=0
  54. 630 FORI=0TO255:T=OT%(I):IFT<>0THENIN%(T)=I:IN%(T+128)=I
  55. 640 NEXT:IN%(160)=32:IN%(32)=32:RETURN
  56. 650 TI$="000000":A$=""
  57. 660 GOSUB790:IFCDTHENRETURN
  58. 670 GOSUB2900:IFSY=0ANDCO>240THENCD=1:RETURN
  59. 680 GETZ$:IFSY=0THENGET#5,A$
  60. 690 IFZ$="[133]"THENSY=SY+1:GOSUB2080:SY=SY-1:RETURN
  61. 700 IFZ$="[134]"THENGOSUB1290:TI$="000000":RETURN
  62. 710 IFZ$="[140]"THENCD=1:RETURN
  63. 720 IFZ$<>""ORA$<>""THEN760
  64. 730 IFVAL(TI$)<400THEN660
  65. 740 OPEN1,8,5,"0:(USER LOG),A":PRINT#1,UL$:PRINT#1,"[212]IME [197]LAPSED![152]":CLOSE1
  66. 750 CD=1:UL$="":RETURN
  67. 760 IFA$=""ORZ$=""THENGOSUB780
  68. 770 RETURN
  69. 780 POKESI+4,21:POKESI+4,20:RETURN
  70. 790 CD=0:IFSYTHENRETURN
  71. 800 IF(PEEK(B1)AND16)<>HLTHENRETURN
  72. 810 TI$="000000"
  73. 820 IF(PEEK(B1)AND16)<>HLTHENRETURN
  74. 830 IFVAL(TI$)>5THENCD=1:RETURN
  75. 840 GOTO820
  76. 850 P$=P$+F$
  77. 860 IFL=55THENPRINT#4,P$;:RETURN
  78. 870 IFSYTHENPRINTP$;:GOTO910
  79. 880 IFCGTHENPRINTP$;:PRINT#5,P$;:GOTO910
  80. 890 FORI=1TOLEN(P$):A$=MID$(P$,I,1):IFA$=""THENGOSUB780
  81. 900 PRINTA$;:PRINT#5,CHR$(OT%(ASC(A$)));:NEXT
  82. 910 I=PEEK(673)AND1:GET#5,A$:IFA$=""THENGETA$
  83. 920 IFA$=CHR$(160)THENA$=" "
  84. 930 IF(A$>""ANDMM)ORA$=" "ORA$="/"ORCDTHEN990
  85. 940 IFA$=""THEN970
  86. 950 IFITHEN910
  87. 960 RETURN
  88. 970 GET#5,A$:IFA$=""THENGETA$
  89. 980 IFA$=""THEN970
  90. 990 ONPEEK(673)AND1GOTO990:RETURN
  91. 1000 L$="":FORI=1TOL:PRINT"[164][157]";
  92. 1010 GOSUB650:IFCDTHENRETURN
  93. 1020 IFZ$<>""THENT=ASC(Z$):A$=Z$:GOTO1060
  94. 1030 IFCGTHENT=ASC(A$+N$):GOTO1050
  95. 1040 T=IN%(ASC(A$+N$)):A$=CHR$(T)
  96. 1050 IFT=0THEN1010
  97. 1060 IFT=34THENT=39:A$="'"
  98. 1070 IFT=20ANDL$<>""THENL$=LEFT$(L$,LEN(L$)-1):I=I-1:GOTO1130
  99. 1080 IFT=20ANDL$=""THEN1010
  100. 1090 IFT=13ANDSYTHENPRINT" ":RETURN
  101. 1100 IFT=13THENPRINT" ":PRINT#5,F$;:RETURN
  102. 1110 IFT=10THEN1010
  103. 1120 IFLEN(L$)=38THENP$="":GOSUB860:GOTO1010
  104. 1130 IFI=>30AND(ASC(A$+N$)AND127)=32ANDMMTHENT=13:GOTO1090
  105. 1140 IFSYTHENPRINTA$;:GOTO1200
  106. 1150 IF(T=20)ANDCGANDECTHENPRINTA$;:PRINT#5,A$;:GOTO1200
  107. 1160 IFT=20ANDECTHENPRINTA$;:PRINT#5,CHR$(OT%(ASC(A$)));:GOTO1200
  108. 1170 IFECTHENPRINTA$;:PRINT#5,"-";:GOTO1200
  109. 1180 IFCGTHENPRINTA$;:PRINT#5,A$;:GOTO1200
  110. 1190 PRINTA$;:PRINT#5,CHR$(OT%(ASC(A$)));
  111. 1200 IFT=20THEN1010
  112. 1210 L$=L$+A$:NEXT:T=13:EC=0:GOTO1090
  113. 1220 P$=F$+"[197]NTER [193]CCESS LEVEL: ":GOSUB860:L=5:GOSUB1000:IFCDTHENRETURN
  114. 1230 IFVAL(L$)<0ORVAL(L$)>65535ORL$=""THENRETURN
  115. 1240 L=VAL(L$):A2=INT(L/256):A1=L-A2*256:A$=CHR$(A1)+CHR$(A2):RETURN
  116. 1250 IFSA<>1THENP$=F$+F$+SY$+" IS NOT AVAILABLE RIGHT NOW.":GOSUB850:RETURN
  117. 1260 P$="[195]ALLING "+SY$+"....":GOSUB850:FORI=1TO20:GETA$:IFA$="[134]"THEN1290
  118. 1270 GOSUB780:FORT=1TO600:NEXT:NEXT
  119. 1280 P$="[212]RY AGAIN LATER....":GOSUB850:RETURN
  120. 1290 P$=F$+F$+SY$+", CHATTING WITH "+U$(1)+F$:GOSUB850
  121. 1300 PRINT"[164][157]";:GETZ$:GET#5,A$:GOSUB790
  122. 1310 IFCG=0THENA$=CHR$(IN%(ASC(A$+N$)))
  123. 1320 IFZ$="[134]"ORCDTHENP$=F$+SY$+" HAS RETURNED TO "+BD$+".":GOSUB850:RETURN
  124. 1330 IFZ$="[133]"THENSY=SY+1:GOSUB2080:SY=SY-1
  125. 1340 IFA$=CHR$(0)ORA$=""THENA$=Z$
  126. 1350 IFA$=""THEN1300
  127. 1360 IFA$=""THENGOSUB780
  128. 1370 IFA$=CHR$(13)THENPRINT" ";:PRINT#5,CHR$(10);
  129. 1380 PRINT" [157]";:IFCGTHENPRINTA$;:PRINT#5,A$;:GOTO1300
  130. 1390 PRINTA$;:PRINT#5,CHR$(OT%(ASC(A$)));:GOTO1300
  131. 1400 GOSUB2610:AA=RF:GOSUB2740
  132. 1410 FORL=1TO2:PRINT#15-B,"P"CHR$(99)CHR$(R1)CHR$(R2)CHR$(1):GOSUB1440:NEXT
  133. 1420 GOSUB1440:IFER$<"20"ORER$="50"THENRETURN
  134. 1430 PRINT"[197]RROR IN (USERFILE)!":GOSUB2830:STOP
  135. 1440 ES$="":GOSUB1450:ER$=LEFT$(ES$,2):RETURN
  136. 1450 GET#15-B,A$:ES$=ES$+A$:ON-(A$<>CHR$(13))GOTO1450:RETURN
  137. 1460 T1$="00:00:00.0 XX":SYS51982,T1$:TM$=T1$+""
  138. 1470 HO$=LEFT$(TM$,2):MI$=MID$(TM$,4,2):FZ$=RIGHT$(TM$,2)
  139. 1520 IFVAL(LEFT$(TM$,2))<>12ANDFZ$<>"AM"THENC2=1:GOTO1550
  140. 1530 IFC2THENOPEN1,8,5,"@0:(T.CALLERS),S,W":PRINT#1," ":CLOSE1:DT=DT+1
  141. 1540 IFC2THENC2=0:NT=0:IFSFTHENOPEN1,8,5,"@0:(USER LOG),S,W":CLOSE1
  142. 1550 DA$=M$+STR$(DT):RETURN
  143. 1560 P$=F$+"[217]OUR [211]TATISTICS...."+F$:GOSUB850
  144. 1570 P$="[206]AME          : "+U$(1):GOSUB850
  145. 1580 P$="[193]CCESS LEVEL  :"+STR$(AC):GOSUB850:GOSUB1460
  146. 1590 P$="[196]ATE/[212]IME     : "+DA$+" "+TM$:GOSUB850:GOSUB2900
  147. 1600 P$="[195]ONNECT [212]IME  :"+STR$(CO)+" MINS.":GOSUB850
  148. 1610 P$="[205]EMBER #      : "+R$:GOSUB850
  149. 1620 P$="[208]ASSWORD      : "+U$(4):GOSUB850
  150. 1630 P$="[193]GE           : "+U$(6):GOSUB850
  151. 1640 P$="[210]EAL [206]AME     : "+U$(7):GOSUB850
  152. 1650 P$="[212]OTAL [213]/[204]'S   : "+U$(9):GOSUB850
  153. 1660 P$="[212]OTAL [196]/[204]'S   : "+U$(10):GOSUB850
  154. 1670 P$="       [[210]ATIO - "+MID$(STR$(RR),2)+":1]":GOSUB850
  155. 1680 P$="[204]AST CALL DATE: "+U$(11):GOSUB850
  156. 1690 P$="[212]OTAL CALLS   : "+U$(12):GOSUB850:RETURN
  157. 1700 PRINT"[156]"F$U$(1)" <*> [204]VL-"+MID$(STR$(AC),2):GOSUB2900
  158. 1710 PRINTTM$" [195]ONNECTED:"STR$(CO)" MINS.[152]":RETURN
  159. 1720 P$=" [147][197]NTER ACCOUNT # OF USER.":GOSUB850
  160. 1730 P$="[193]CCOUNT # OF CURRENT USER: "+R$:GOSUB850
  161. 1740 P$="[214][213]:":GOSUB860:L=3:GOSUB1000:IFCDTHENRETURN
  162. 1750 IFL$=""THENRETURN
  163. 1760 E$=L$:IFL$=R$THENFORL=1TO12:N$(L)=U$(L):NEXT:AA=AC:GOTO1780
  164. 1770 OPEN3,RF,3,RF$:RC=VAL(L$):GOSUB1400:GOSUB2670:CLOSE3
  165. 1780 P$=" [147]1 - [206]AME      : "+N$(1)+F$+"2 - [208]HONE     : "+N$(2):GOSUB850:GOSUB2630
  166. 1790 P$="3 - [193]CCESS [204]VL:"+STR$(AA)+F$+"4 - [208]ASSWORD  : "+N$(4):GOSUB850
  167. 1800 P$="5 - # OF [197]MAIL: "+N$(5)+F$+"6 - [193]GE       : "+N$(6):GOSUB850
  168. 1810 P$="7 - [210]EAL NAME : "+N$(7)+F$+"8 - C/G MODE  : "+N$(8):GOSUB850
  169. 1820 P$="9 - [212]OTAL [213]/[204] : "+N$(9)+F$+"[193] - [212]OTAL [196]/[204] : "+N$(10):GOSUB850
  170. 1830 P$="[194] - [204]AST CALL : "+N$(11):GOSUB850
  171. 1840 P$="[195] - # CALLS   : "+N$(12):GOSUB850
  172. 1850 IFL=55THENL=0:PRINT#4:CLOSE4:GOTO1780
  173. 1860 P$=F$+"[215]HICH TO CHANGE:":GOSUB860:L=1:GOSUB1000:IFCDTHENRETURN
  174. 1870 IFL$=""ANDR$=E$THENFORL=1TO12:U$(L)=N$(L):NEXT:AC=AA:GOTO1720
  175. 1880 IFL$=""THEN1720
  176. 1890 IFL$="S"ORL$="[211]"THEN1980
  177. 1900 IFL$="P"ORL$="[208]"THENL=55:OPEN4,4,7:GOTO1780
  178. 1910 S=(ASC(L$)AND127)-64:IFS=>1ANDS<=3THENS=S+9:GOTO1940
  179. 1920 S=VAL(L$):IFS<1ORS>14THEN1780
  180. 1930 IFS=3THENGOSUB1220:N$(3)=A$:AA=A:GOTO1780
  181. 1940 IFS=11THENGOSUB2730:GOTO1780
  182. 1950 P$=F$+"["+N$(S)+"]:[195]HANGE TO->":GOSUB860
  183. 1960 L=20:GOSUB1000:IFCDTHENRETURN
  184. 1970 N$(S)=L$:GOTO1780
  185. 1980 P$=F$+"[211]AVE STATS WHERE? (DEFAULT="+E$+"):":GOSUB860
  186. 1990 L=3:GOSUB1000:IFCDTHENRETURN
  187. 2000 IFL$<>""ANDVAL(L$)>0THENE$=L$
  188. 2010 P$=F$+"[211]AVE AT: "+E$:GOSUB850
  189. 2020 P$="[195]ORRECT? (Y/N):":GOSUB860:L=1:GOSUB1000:IFCDTHENRETURN
  190. 2030 IFL$<>"Y"ANDL$<>"[217]"THEN1780
  191. 2040 OPEN3,RF,3,RF$:RC=VAL(E$):GOSUB1400
  192. 2050 GOSUB2690
  193. 2060 CLOSE3
  194. 2070 RETURN
  195. 2080 AA=DV:GOSUB2740
  196. 2090 P$=" [147]":GOSUB850
  197. 2100 P$=DC$+F$+"   --**]> [210]EMOTE [211]YS-[207]P [205]ENU <[**--"+F$+DC$+F$:GOSUB850
  198. 2110 P$="[214] - [214]ALIDATE USER":GOSUB850
  199. 2120 P$="[193] - [211]CAN ANY SEQ ON DISK":GOSUB850
  200. 2130 P$="$ - [196]IRECTORY":GOSUB850
  201. 2140 P$="@ - [196]OS COMMANDS":GOSUB850
  202. 2150 P$="[213] - [211]CAN USER LOG":GOSUB850
  203. 2160 P$="[212] - [212]ODAY'S CALLERS":GOSUB850
  204. 2170 P$="# - [212]OGGLE DRIVE #"+STR$(DV)+";"+DR$:GOSUB850
  205. 2180 P$=F$+"[210][211][205]"+MID$(STR$(DV),2)+";"+DR$+":":GOSUB860:L=1:GOSUB1000:IFCDTHENRETURN
  206. 2190 IFL$=""THENRETURN
  207. 2200 L$=CHR$(ASC(L$)AND127)
  208. 2210 GOSUB2640:UL$=UL$+"[211]YSOP-"+L$+CHR$(13)
  209. 2220 ON-(L$="U")-2*(L$="A")-3*(L$="V")-4*(L$="$")GOSUB2440,2550,1720,2300
  210. 2230 ON-(A$="#")-2*(L$="T")GOSUB2770,2540
  211. 2240 IFL$="?"THEN2090
  212. 2250 IFL$<>"@"THEN2180
  213. 2260 P$=F$+">":GOSUB860:L=39:GOSUB1000:IFCDTHENRETURN
  214. 2270 IFL$=""THENGOSUB1440:P$=F$+ES$:GOSUB850:GOTO2180
  215. 2280 IFLEFT$(L$,4)=P2$+":"THENPRINT#15-B,RIGHT$(L$,LEN(L$)-4)
  216. 2290 GOTO2180
  217. 2300 P$=F$:GOSUB850:OPEN1,DV,0,"$"+DR$+":*"
  218. 2310 GOSUB1440:IFER$>"01"THENCLOSE1:P$=F$+ES$:GOSUB850:RETURN
  219. 2320 GET#1,A$:GET#1,A$
  220. 2330 GET#1,A$:GET#1,A$:IF(ST)AND64THENCLOSE1:RETURN
  221. 2340 GET#1,LO$:GET#1,HI$
  222. 2350 LO$=LO$+N$:HI$=HI$+N$
  223. 2360 P$=STR$(ASC(LO$+CHR$(0))+256*ASC(HI$+CHR$(0)))+" "
  224. 2370 GET#1,A$:IFA$=""THEN2410
  225. 2380 GET#5,Z$:IFZ$=""THENGETZ$
  226. 2390 IFZ$=" "THENCLOSE1:RETURN
  227. 2400 P$=P$+A$:GOTO2370
  228. 2410 IFECANDMID$(P$,8,1)="("THEN2330
  229. 2420 GOSUB850:IFA$=" "THENCLOSE1:RETURN
  230. 2430 GOTO2330
  231. 2440 FI$="(USER LOG)"
  232. 2450 OPEN1,DV,5,DR$+":"+FI$:P$="":GOSUB1440:IFER$>"01"THENCLOSE1:RETURN
  233. 2460 GET#1,A$:IF(ST)AND64THEN2510
  234. 2470 GET#5,Z$:IFZ$=""THENGETZ$
  235. 2480 IFZ$=" "ORZ$="/"THEN2510
  236. 2490 IFA$=CHR$(13)ORLEN(P$)=39THENGOSUB850:P$="":GOTO2460
  237. 2500 P$=P$+A$:GOTO2460
  238. 2510 GOSUB850:CLOSE1:P$=F$+"[211]CRATCH? (Y/N):":GOSUB860:L=1:GOSUB1000
  239. 2520 IFL$=""OR(L$<>"Y"ANDL$<>"[217]")THENRETURN
  240. 2530 OPEN1,DV,5,"@"+DR$+":"+FI$+",S,W":PRINT#1," ":CLOSE1:RETURN
  241. 2540 FI$="(T.CALLERS)":GOTO2450
  242. 2550 P$=F$+"[211]CAN FILE: ":GOSUB860:L=16:GOSUB1000
  243. 2560 FI$=L$:GOTO2450
  244. 2570 POKEB3,65:POKEB4,40:POKEB2,231:POKEB1,57:POKEB4,48:RETURN
  245. 2580 GOSUB2570:POKEB2,PEEK(B2)OR32:POKEB1,PEEK(B1)AND223:POKEB1,PEEK(B1)OR32
  246. 2590 POKEB1,PEEK(B1)AND223:POKEB4,40:POKEB4,47:POKEB2,230:GOSUB2570:RETURN
  247. 2600 HI=INT(RC/256):LO=RC-(HI*256):RETURN
  248. 2610 GOSUB2600:R1=LO:R2=HI:RETURN
  249. 2620 AC=VAL(U$(3)):A2=INT(AC/256):A1=AC-A2*256:RETURN
  250. 2630 AA=VAL(N$(3)):RETURN
  251. 2640 IFLEN(UL$)<230THENRETURN
  252. 2650 OPEN1,8,5,"0:(USER LOG),A":PRINT#1,UL$:CLOSE1:UL$="":RETURN
  253. 2660 GOSUB2670:FORI=1TO12:U$(I)=N$(I):NEXT:RETURN
  254. 2670 FORT=1TO12:INPUT#3,N$(T):NEXT:RETURN
  255. 2680 FORI=1TO12:N$(I)=U$(I):NEXT
  256. 2690 N$(0)="":FORT=1TO12:N$(0)=N$(0)+Q$+N$(T)+CHR$(13):NEXT
  257. 2700 PRINT#3,N$(0):RC=1:GOSUB1400:RETURN
  258. 2730 RETURN
  259. 2740 B=AA-8:IFB<0THENB=0
  260. 2750 AA=-((DR%(B)AND128)=128):DR$=MID$(STR$(AA),2):RETURN
  261. 2760 GOSUB2740:AA=-((DVAND128)=128):DR$=MID$(STR$(AA),2):RETURN
  262. 2770 IFDR$="0"THENAA=DV:GOSUB2740:IFDR$="1"THENRETURN
  263. 2780 DV=DV+1:IFDV>15THENDV=8
  264. 2790 FORL=0TO(DR-8):IFDV<>(DR%(L)AND63)THENNEXT:GOTO2780
  265. 2800 IFA1AND32ORSYTHEN2820
  266. 2810 AA=DV:GOSUB2740:IFDR%(B)AND64THEN2780
  267. 2820 AA=DV:GOSUB2740:DR$="0":RETURN
  268. 2830 ON(MT%-1)GOTO2840,2850,2880,2890,2580,2580
  269. 2840 POKEB2,PEEK(B2)OR32:POKEB1,PEEK(B1)AND223:RETURN
  270. 2850 FORT=1TO2000:NEXT:PRINT#5,"+++";:FORT=1TO2000:NEXT:PRINT#5,"[193][212][200]"+CHR$(13)
  271. 2860 FORT=1TO2000:NEXT:PRINT#5,"[193][212][218]"+CHR$(13):FORT=1TO2000:NEXT
  272. 2870 PRINT#5,"[193][212][205]0"+CHR$(13)::FORT=1TO2000:NEXT:PRINT#5,"[193][212][214]0"+CHR$(13):RETURN
  273. 2880 POKEB2,38:POKEB1,38:RETURN
  274. 2890 POKEB1,PEEK(B1)OR32:RETURN
  275. 2900 GOSUB1460:CT=VAL(HO$):MI=VAL(MI$):CO=ABS((LH*60+LM)-(CT*60+MI))
  276. 2910 IFLH=12ANDC2THENCO=ABS(CO-720)
  277. 2920 RETURN
  278. 2930 OPEN3,8,3,"0:(SCORES)":GOSUB220:IFER$>"01"THENCLOSE3:RETURN
  279. 2940 RC=R:GOSUB2610:B=0:GOSUB1410:GET#3,A$:IF(ST)AND64THENSC=0:GOTO2960
  280. 2950 INPUT#3,SC
  281. 2960 IFSC=0THENSC=I:CLOSE3:DIMSC(SC):RETURN
  282. 2970 IFI>SCTHENDIMSC(I):GOTO2990
  283. 2980 DIMSC(SC)
  284. 2990 FORT=1TOSC:INPUT#3,SC(T):NEXT:CLOSE3:IFI>SCTHENSC=I
  285. 3000 RETURN
  286. 3010 OPEN3,8,3,"0:(SCORES)":GOSUB220:IFER$>"01"THENCLOSE3:RETURN
  287. 3020 RC=R:GOSUB2600:B=0:GOSUB1410:SC$=STR$(SC)+CHR$(13):FORT=1TOSC
  288. 3030 SC$=SC$+STR$(SC(T))+CHR$(13):NEXT:PRINT#3,SC$;:RC=1:GOSUB1410:CLOSE3:RETURN
  289. 3040 FI$="(ST/R 3.5)":DV=D5
  290. 3050 OPEN1,8,5,"@0:(DATA),S,W":PRINT#1,R$:AA=DV:GOSUB2760:FORT=1TO12
  291. 3060 PRINT#1,Q$U$(T):NEXT:PRINT#1,LH:PRINT#1,LM:PRINT#1,SA:PRINT#1,SY
  292. 3070 PRINT#1,SF:PRINT#1,HL:PRINT#1,M$:PRINT#1,DT:PRINT#1,LEN(F$):PRINT#1,Q$LN$
  293. 3080 PRINT#1,DV:PRINT#1,NW:PRINT#1,HM$:CLOSE1:POKE252,32
  294. 3090 POKE251,PEEK(152):PRINT"[146][147]LOAD"Q$DR$":"FI$Q$","DVAND127""
  295. 3100 POKE631,131:POKE198,1:NEW
  296. 3110 OPEN1,8,5,"0:(DATA)":INPUT#1,R$:R=VAL(R$):FORT=1TO12
  297. 3120 INPUT#1,U$(T):NEXT:INPUT#1,LH,LM,SA,SY,SF,HL,M$,DT,T,LN$,DV,NW
  298. 3130 HM$="":FORT=1TO200:GET#1,A$:IFA$=""THENA$=CHR$(0)
  299. 3140 HM$=HM$+A$:NEXT
  300. 3150 CLOSE1:GOSUB2620:CG=VAL(U$(8)):IFT=2THENF$=CHR$(13)+CHR$(10)
  301. 3160 REM -----------------------------
  302. 3170 REM -    YOUR PROGRAM SHOULD    -
  303. 3180 REM -    START AT LINE 3160!    -
  304. 3190 REM -----------------------------
  305. 3200 T=RND(-RND(-TI)):GOSUB370:DZ=DV:I=18:GOSUB430
  306. 3210 SS=SC(18)
  307. 3220 P$=F$+U$(1)+", YOU HAVE $"+MID$(STR$(SS),2)+".00":GOSUB160
  308. 3230 OPEN1,DVAND127,5,DR$+":(TOPTEN)":GOSUB220
  309. 3235 DIMTT$(10),TT(10):IFER$>"01"THENCLOSE1:GOTO3250
  310. 3240 FORT=1TO10:INPUT#1,TT$(T),TT(T):NEXT:CLOSE1
  311. 3250 DEFFNR(X)=INT(RND(0)*X)+1:IFSS>0THEN3270
  312. 3260 SS=500:P$="[212]HE [200]OUSE HAS GIVEN A"+STR$(SS)+".00 CREDIT!":GOSUB160
  313. 3270 P$="? - [196]ISPLAY MENU.":GOSUB160
  314. 3280 GOSUB250:P$=F$+"[154]$"+MID$(STR$(SS),2)+":":GOSUB170:L=1:GOSUB180
  315. 3290 IFCDTHENGOSUB390:GOTO410
  316. 3300 IFL$=""THEN3280
  317. 3310 E$=CHR$(ASC(L$)AND127):IFE$="Q"THEN3480
  318. 3320 IFE$="?"THEN3380
  319. 3330 IFE$="Y"THENGOSUB190
  320. 3340 IFE$="H"THENGOSUB3440
  321. 3350 IFE$<"A"ORE$>"E"THEN3280
  322. 3360 ONASC(E$)-64GOSUB3490,3980,4340,4850,5250:GOTO3280
  323. 3370 RETURN
  324. 3380 P$=" [147]"+DC$+F$+"        -+*$[ [195]ASINO [205]ENU ]$*+-"+F$+DC$+F$:GOSUB160
  325. 3390 P$="[193] - [196]ICE               [196] - [193]CEY-[196]UCEY":GOSUB160
  326. 3400 P$="[129][194] - [195]RAPS              [197] - [194]LACK [202]ACK":GOSUB160
  327. 3410 P$="[158][195] - [211]LOTS              [200] - [200]IGH [211]CORES":GOSUB160
  328. 3420 P$="[217] - [217]ELL FOR [211]YSOP     ? - [212]HIS MENU":GOSUB160
  329. 3430 P$="[209] - [210]ETURN TO [194][194][211]":GOSUB160:GOTO3280
  330. 3440 P$=F$+"[212]OP [212]EN [200]IGH [211]CORES:"+F$:GOSUB160
  331. 3450 FORT=1TO10:P$=MID$(STR$(T),(-(T>9))+1)+". "
  332. 3460 P$=P$+LEFT$(TT$(T)+"                     ",20)+STR$(TT(T))+".00"
  333. 3470 GOSUB160:NEXT:RETURN
  334. 3480 DV=DZ:GOSUB370:SC(18)=SS:GOSUB440:GOTO410
  335. 3490 P$=F$+"[129][217]OU HAVE NOW ENTERED THE GAME OF [196]ICE!":GOSUB160
  336. 3500 P$=F$+"[212]HE [210]ULES ARE SIMPLE.  [217]OU PICK A":GOSUB160
  337. 3510 P$="NUMBER BETWEEN 1 AND 6.  [201] WILL ROLL":GOSUB160
  338. 3520 P$="THREE DICE.  [212]HE ODDS ARE:"+F$:GOSUB160
  339. 3530 P$="1 MATCH   = 1 TO 1 ODDS.":GOSUB160
  340. 3540 P$="2 MATCHES = 2 TO 1 ODDS.":GOSUB160
  341. 3550 P$="3 MATCHES = 5 TO 1 ODDS."+F$+F$+"[210][197][212][213][210][206] ABORTS GAME.":GOSUB160
  342. 3560 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: ":GOSUB170
  343. 3570 L=20:GOSUB180:IFCDORL$=""THENRETURN
  344. 3580 IFL$="?"THEN3500
  345. 3590 BT=VAL(L$):IFBT<1ORBT>SSTHEN3560
  346. 3600 P$=F$+"[217]OUR BET STANDS AT "+L$:GOSUB160
  347. 3610 P$="[206]UMBER TO BET ON? (1-6): ":GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  348. 3620 IFL$=""THENP$=F$+"[194]ET ABORTED, [195]HICKEN....":GOSUB160:GOTO3560
  349. 3630 IFL$<"1"ORL$>"6"THEN3610
  350. 3640 D0=VAL(L$):D2=0:FORT=1TO3:D1=FNR(6):N=D1:GOSUB3680:IFD1=D0THEND2=D2+1
  351. 3650 NEXT:IFD2=0THENSS=SS-BT:P$=F$+"[150][211]ORRY, NO MATCHES.  [217]OU LOSE!":GOSUB160:GOTO3560
  352. 3660 P$="[156][195]ONGRATULATIONS!!  [217]OU HAVE"+STR$(D2)+" MATCHES!!":GOSUB160
  353. 3670 SS=SS+BT*(-(D2=1)-2*(D2=2)-5*(D2=3)):GOSUB3900:GOTO3560
  354. 3680 P$=F$:GOSUB160:GOSUB3700:GOSUB3740:ONNGOSUB3840,3850,3860,3870,3880,3890
  355. 3690 GOSUB3740:GOSUB3720:RETURN
  356. 3700 P$=",-------,":IFCGTHENP$="[176][192][192][192][192][192][192][192][174]"
  357. 3710 GOSUB160:RETURN
  358. 3720 P$="'-------'":IFCGTHENP$="[173][192][192][192][192][192][192][192][189]"
  359. 3730 GOSUB160:RETURN
  360. 3740 P$="!       !":IFCGTHENP$="[221]       [221]"
  361. 3750 GOSUB160:RETURN
  362. 3760 P$="!   *   !":IFCGTHENP$="[221]   *   [221]"
  363. 3770 GOSUB160:RETURN
  364. 3780 P$="! *     !":IFCGTHENP$="[221] *     [221]"
  365. 3790 GOSUB160:RETURN
  366. 3800 P$="!     * !":IFCGTHENP$="[221]     * [221]"
  367. 3810 GOSUB160:RETURN
  368. 3820 P$="! *   * !":IFCGTHENP$="[221] *   * [221]"
  369. 3830 GOSUB160:RETURN
  370. 3840 GOSUB3740:GOSUB3760:GOSUB3740:RETURN
  371. 3850 GOSUB3780:GOSUB3740:GOSUB3800:RETURN
  372. 3860 GOSUB3780:GOSUB3760:GOSUB3800:RETURN
  373. 3870 GOSUB3820:GOSUB3740:GOSUB3820:RETURN
  374. 3880 GOSUB3820:GOSUB3760:GOSUB3820:RETURN
  375. 3890 GOSUB3820:GOSUB3820:GOSUB3820:RETURN
  376. 3900 FORT=1TO10:IFSS<=TT(T)THENNEXT:RETURN
  377. 3910 IFT=10THENTT(T)=SS:TT$(T)=U$(1):GOTO3930
  378. 3920 FORI=9TOTSTEP-1:TT(I+1)=TT(I):TT$(I+1)=TT$(I):NEXT:TT(T)=SS:TT$(T)=U$(1)
  379. 3930 P$=F$+F$+"[156][195][207][206][199][210][193][212][213][204][193][212][201][207][206][211]!!!!"+F$+"[153][217]OU ARE A TOP [212][197][206] WINNER!!!!"
  380. 3940 GOSUB160:P$=F$+"[217]OU NOW HOLD THE #"+MID$(STR$(T),2)+" POSITION."+F$
  381. 3950 GOSUB160:DV=DZ:GOSUB370:OPEN1,DVAND127,5,"@"+DR$+":(TOPTEN),S,W":GOSUB220
  382. 3960 IFER$>"01"THENRETURN
  383. 3970 FORT=1TO10:PRINT#1,TT$(T)","TT(T):NEXT:CLOSE1:RETURN
  384. 3980 P$=F$+"[159][217]OU ARE NOW ENTERING [195]RAPS.":GOSUB160
  385. 3990 P$=F$+"[201]F YOU ROLL A 2, 3 OR 12 ON YOUR FIRST":GOSUB160
  386. 4000 P$="ROLL, YOU LOSE.  [201]F YOU ROLL A 7 OR 11":GOSUB160
  387. 4010 P$="ON YOUR FIRST ROLL YOU WIN.":GOSUB160
  388. 4020 P$="[207]THERWISE, THE DICE ARE ROLLED UNTIL":GOSUB160
  389. 4030 P$="THE TOTAL OF THE FIRST ROLL IS ROLLED":GOSUB160
  390. 4040 P$="AGAIN.  [201]N WHICH CASE YOU WIN.":GOSUB160
  391. 4050 P$="[201]F, AFTER THE FIRST ROLL, YOU ROLL A":GOSUB160
  392. 4060 P$="7 OR 11, YOU LOSE (CRAP OUT).":GOSUB160
  393. 4070 P$=F$+"[210][197][212][213][210][206] AT BET ABORTS GAME.":GOSUB160
  394. 4080 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: "
  395. 4090 GOSUB170:L=20:GOSUB180:IFCDORL$=""THENRETURN
  396. 4100 IFL$="?"THEN3990
  397. 4110 BT=VAL(L$):IFBT<1ORBT>SSTHEN4080
  398. 4120 P$=F$+"[217]OUR BET STANDS AT"+STR$(BT)+F$+"[208]RESS [210][197][212][213][210][206] TO ROLL. [209] - [209]UITS: "
  399. 4130 GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  400. 4140 IFL$="Q"ORL$="[209]"THEN4080
  401. 4150 D1=FNR(6):N=D1:GOSUB3680:D2=FNR(6):N=D2:GOSUB3680:D0=D1+D2
  402. 4160 P$=F$+"[217]OUR TOTAL IS:"+STR$(D0):GOSUB160
  403. 4170 IFD0=2ORD0=3ORD0=12THEN4250
  404. 4180 IFD0=7ORD0=11THEN4310
  405. 4190 P$=F$+"[208]RESS [210][197][212][213][210][206] TO ROLL AGAIN: ":GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  406. 4200 D1=FNR(6):N=D1:GOSUB3680:D2=FNR(6):N=D2:GOSUB3680:D3=D1+D2
  407. 4210 P$=F$+"[217]OUR TOTAL IS:"+STR$(D3):GOSUB160
  408. 4220 IFD3=7ORD3=11THEN4290
  409. 4230 IFD3=D0THEN4320
  410. 4240 P$=F$+"[196]OES NOT MATCH YOUR FIRST ROLL OF"+STR$(D0):GOSUB160:GOTO4190
  411. 4250 IFD0=2THENP$="[211]NAKE [197]YES!"
  412. 4260 IFD0=3THENP$="[195]OCK [197]YES!"
  413. 4270 IFD0=12THENP$="[194]OX [195]ARS!"
  414. 4280 GOSUB160:GOTO4300
  415. 4290 P$="[217]OU CRAPPED OUT!":GOSUB160
  416. 4300 P$="[217]OU LOSE YOUR BET!!":GOSUB160:SS=SS-BT:GOTO4080
  417. 4310 P$="[193] NATURAL!":GOSUB160:GOTO4330
  418. 4320 P$="[217]OU MATCHED YOUR FIRST ROLL!":GOSUB160
  419. 4330 P$="[217]OU [215][201][206] YOUR BET!":GOSUB160:SS=SS+BT:GOSUB3900:GOTO4080
  420. 4340 P$=F$+"[150][215]ELCOME TO [211]LOTS, [207]NE [193]RMED [194]ANDITS!":GOSUB160
  421. 4350 P$=F$+"[212]HE RULES ARE SIMPLE:  [217]OU MAY BET":GOSUB160
  422. 4360 P$="[199]OLD [195]HIPS WORTH $1.00, $2.00, $5.00,":GOSUB160
  423. 4370 P$="$10.00, $20.00.  [212]HE PAYOFFS ARE:"+F$:GOSUB160
  424. 4380 P$="3 [194]ARS --------------- 100 TO 1":GOSUB160
  425. 4390 P$="3 [194]ELLS --------------  80 TO 1":GOSUB160
  426. 4400 P$="3 [204]EMONS -------------  50 TO 1":GOSUB160
  427. 4410 P$="3 [208]LUMS --------------  30 TO 1":GOSUB160
  428. 4420 P$="3 [208]EACHES ------------  25 TO 1":GOSUB160
  429. 4430 P$="2 [194]ARS, 1 [194]ELL -------  10 TO 1":GOSUB160
  430. 4440 P$="2 [194]ELLS, 1 [204]EMON -----   9 TO 1":GOSUB160
  431. 4450 P$="2 [204]EMONS, 1 [208]LUM -----   8 TO 1":GOSUB160
  432. 4460 P$="2 [208]LUMS, 1 [208]EACH -----   7 TO 1":GOSUB160
  433. 4470 P$="2 [208]EACHES, 1 [207]RANGE --   5 TO 1":GOSUB160
  434. 4480 P$="2 [207]RANGES, [193]NYTHING --   2 TO 1":GOSUB160
  435. 4490 P$=F$+"[210][197][212][213][210][206] AT BET ABORTS GAME.":GOSUB160
  436. 4500 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: "
  437. 4510 GOSUB170:L=2:GOSUB180:IFCDORL$=""THENRETURN
  438. 4520 IFL$="?"THEN4350
  439. 4530 BT=VAL(L$):IFBT<1ORBT>SSTHEN4500
  440. 4540 IFBT=1ORBT=2ORBT=5ORBT=10ORBT=20THEN4560
  441. 4550 P$=F$+"[207]NLY BET $1, $2, $5, $10, OR $20!!":GOSUB160:GOTO4500
  442. 4560 P$=F$+"[217]OUR BET STANDS AT"+STR$(BT)+F$+"[208]RESS [210][197][212][213][210][206] TO PULL LEVER. "
  443. 4570 P$=P$+F$+"[209] - [209]UITS: ":GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  444. 4580 IFL$="Q"ORL$="[209]"THEN4500
  445. 4590 H$(1)="[194]AR":H$(2)="[194]ELL":H$(3)="[204]EMON":H$(4)="[208]LUM":H$(5)="[208]EACH"
  446. 4600 H$(6)="[207]RANGE":D1=FNR(6):P$=F$+H$(D1):GOSUB160
  447. 4610 D2=FNR(6):P$="            "+H$(D2):GOSUB160
  448. 4620 D3=FNR(6):P$="                        "+H$(D3):GOSUB160:D0=0
  449. 4630 IF(D1=1)AND(D2=1)AND(D3=1)THEND0=100
  450. 4640 IF(D1=2)AND(D2=2)AND(D3=2)THEND0=80
  451. 4650 IF(D1=3)AND(D2=3)AND(D3=3)THEND0=50
  452. 4660 IF(D1=4)AND(D2=4)AND(D3=4)THEND0=30
  453. 4670 IF(D1=5)AND(D2=5)AND(D3=5)THEND0=25
  454. 4680 IF(D1=6)AND(D2=6)AND(D3=6)THEND0=2
  455. 4690 IFD0>0THEN4810
  456. 4700 FORT=1TO6:D(T)=0:NEXT
  457. 4710 D(D1)=D(D1)+1:D(D2)=D(D2)+1:D(D3)=D(D3)+1
  458. 4720 FORT=1TO6:IFD(T)<>2THENNEXT:GOTO4840
  459. 4730 FORI=1TO6:IFD(I)<>1THENNEXT:GOTO4840
  460. 4740 IFT=1ANDI=2THEND0=10
  461. 4750 IFT=2ANDI=3THEND0=9
  462. 4760 IFT=3ANDI=4THEND0=8
  463. 4770 IFT=4ANDI=5THEND0=7
  464. 4780 IFT=5ANDI=6THEND0=5
  465. 4790 IFT=6THEND0=2
  466. 4800 IFD0=0THEN4840
  467. 4810 IFD0=100THENP$=F$+F$+"              [202][129][193][158][195][203][159][208][207][156][212][152]!!!!"+F$:GOSUB160
  468. 4820 P$="[156][217]OU WIN AT"+STR$(D0)+" TO 1 ODDS!":GOSUB160:SS=SS+(BT*D0)
  469. 4830 GOSUB3900:GOTO4500
  470. 4840 P$=F$+"[217]OU LOSE YOUR BET.":GOSUB160:SS=SS-BT:GOTO4500
  471. 4850 P$=F$+"[158][211]O YOU WANT TO PLAY [193]CEY-[196]UCY!":GOSUB160
  472. 4860 P$=F$+"[212]HIS GAME IS SIMILAR TO THE ACTUAL":GOSUB160
  473. 4870 P$="CARD GAME, WITH THE EXCEPTION THAT":GOSUB160
  474. 4880 P$="NO [211]PLITS ARE ALLOWED.":GOSUB160
  475. 4890 P$=F$+"[217]OU WILL BE DEALT TWO CARDS.  [201]F THE":GOSUB160
  476. 4900 P$="THIRD CARD DEALT NUMERICALLY LIES":GOSUB160
  477. 4910 P$="BETWEEN THE FIRST TWO, YOU WIN YOUR":GOSUB160
  478. 4920 P$="BET.  [207]THERWISE, YOU LOSE.  [212]HE SECOND":GOSUB160
  479. 4930 P$="THE SECOND CARD CAN COUNT AS EITHER     1 OR 14.":GOSUB160
  480. 4940 P$=F$+"[210][197][212][213][210][206] AT BET ABORTS GAME.":GOSUB160
  481. 4950 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: "
  482. 4960 GOSUB170:L=10:GOSUB180:IFCDORL$=""THENRETURN
  483. 4970 IFL$="?"THEN4860
  484. 4980 BT=VAL(L$):IFBT<1ORBT>SSTHEN4950
  485. 4990 P$=F$+"[217]OUR BET STANDS AT "+L$+F$+"[208]RESS [210][197][212][213][210][206] FOR DEAL. [209] - [209]UIT: "
  486. 5000 GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  487. 5010 IFL$="Q"ORL$="[209]"THENP$=F$+"[195]AN'T TAKE THE [200][197][193][212]?":GOSUB160:GOTO4950
  488. 5020 D$(1)="[202]ACK":D$(2)="[209]UEEN":D$(3)="[203]ING":D1=FNR(13):D2=FNR(13)
  489. 5030 IFD1=1THENP$="[193]CE":GOTO5050
  490. 5040 P$=MID$(STR$(D1),2):IFD1>10THENP$=D$(D1-10)
  491. 5050 P$=LEFT$(P$+"                    ",20)
  492. 5060 IFD2=1THEND$="[193]CE":GOTO5080
  493. 5070 D$=MID$(STR$(D2),2):IFD2>10THEND$=D$(D2-10)
  494. 5080 P$=F$+P$+D$:GOSUB170:IFD2>1THEN5120
  495. 5090 P$="=(1 OR 14): ":GOSUB170:L=2:GOSUB180:IFCDTHENRETURN
  496. 5100 IFL$<>"1"ANDL$<>"14"THENP$="":GOTO5030
  497. 5110 D2=VAL(L$)
  498. 5120 P$=F$+F$+"[217]OUR BET STANDS AT"+STR$(BT)+F$+"[210][197][212][213][210][206] FOR THIRD CARD."
  499. 5130 P$=P$+F$+"[196] - [196]OUBLE BET: ":GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  500. 5140 IFL$<>"D"ANDL$<>"[196]"THEN5170
  501. 5150 IFBT*2>SSTHENP$=F$+"[206]OT ENOUGH TO [196]OUBLE!":GOSUB160:GOTO5170
  502. 5160 BT=BT*2
  503. 5170 D3=FNR(13):IFD3=1THENP$="[193]CE":GOTO5190
  504. 5180 P$=MID$(STR$(D3),2):IFD3>10THENP$=D$(D3-10)
  505. 5190 L=10-INT(LEN(P$)/2):P$=F$+RIGHT$("          ",L)+P$:GOSUB160
  506. 5200 IF(D3<D1ORD3>D2)AND(D1<D2)THEN5240
  507. 5210 IF(D3<D2ORD3>D1)AND(D2<D1)THEN5240
  508. 5220 IFD1=D2ANDD3<>D1THEN5240
  509. 5230 P$=F$+"[156][217]OU WON YOUR BET!":GOSUB160:SS=SS+BT:GOSUB3900:GOTO4950
  510. 5240 P$=F$+"[211]ORRY, YOU LOSE.":GOSUB160:SS=SS-BT:GOTO4950
  511. 5250 P$=F$+"[217]OU'VE COME TO THE [194]LACK [202]ACK TABLE!":GOSUB160
  512. 5260 P$=F$+"[200]ERE, YOU TRY TO GET A HAND OF CARDS":GOSUB160
  513. 5270 P$="CLOSE OR EQUAL TO 21 WITHOUT GOING":GOSUB160
  514. 5280 P$="OVER.  [195]LOSER THAN THE [195]OMPUTER/[196]EALER":GOSUB160
  515. 5290 P$="IS.  [217]OU CAN DOUBLE YOUR BET IF YOU":GOSUB160
  516. 5300 P$="THINK YOU HAVE A WINNING HAND.  [207]N":GOSUB160
  517. 5310 P$="TIES, THE PLAYER WINS.  [212]HE [196]EALER":GOSUB160
  518. 5320 P$="ALWAYS WINS WITH A NATURAL BLACK [202]ACK.":GOSUB160
  519. 5330 P$="[201]F YOU HAVE 5 OR MORE CARDS WITH OUT":GOSUB160
  520. 5340 P$="GOING OVER 21, YOU AUTOMATICALLY WIN!":GOSUB160
  521. 5350 P$=F$+"[210][197][212][213][210][206] AT INITAL BET ABORTS.":GOSUB160
  522. 5360 GOSUB250:P$=F$+"[217]OU HAVE $"+MID$(STR$(SS),2)+F$+"[215]HAT IS YOUR BET: "
  523. 5370 GOSUB170:L=10:GOSUB180:IFCDORL$=""THENRETURN
  524. 5380 IFL$="?"THEN5260
  525. 5390 BT=VAL(L$):IFBT<1ORBT>SSTHEN5360
  526. 5400 D0=0:P0=0:C$(1)="[202]ACK":C$(2)="[209]UEEN":C$(3)="[203]ING":D=2:P=2
  527. 5410 D(1)=FNR(13):D(2)=FNR(13):C$=MID$(STR$(D(2)),2):IFD(2)>10THENC$=C$(D(2)-10)
  528. 5420 P(1)=FNR(13):P(2)=FNR(13):P0=P(1)+P(2):DB=1:IFD(2)=1THENC$="[193]CE"
  529. 5430 P$=F$+"[196]EALER HAS A "+C$+" SHOWING.":GOSUB160
  530. 5440 P$=F$+"[217]OU HAVE:":GOSUB160:P$=F$:FORT=1TOP
  531. 5450 C$=MID$(STR$(P(T)),2):IFP(T)>10THENC$=C$(P(T)-10)
  532. 5460 IFP(T)=1ORP(T)=14THENC$="[193]CE"
  533. 5470 P$=P$+C$+", ":NEXT:GOSUB160
  534. 5480 IFP>2THENJ=P:GOTO5500
  535. 5490 FORJ=1TOP:IFP(J)<>1THENNEXT:GOTO5540
  536. 5500 IFP(J)<>1THEN5540
  537. 5510 P$=F$+"[215]ILL YOUR [193]CE = (1 OR 11): ":GOSUB170:L=2:GOSUB180:IFCDTHENRETURN
  538. 5520 IFL$<>"1"ANDL$<>"11"THEN5510
  539. 5530 P(J)=VAL(L$)-3*(L$="11"):IFP=2THENNEXT
  540. 5540 P0=0:FORT=1TOP:P1=P(T):IFP1>10THENP1=10-1*(P1=14)
  541. 5550 P0=P0+P1:NEXT:P$=F$+"[217]OU HAVE A TOTAL OF"+STR$(P0)
  542. 5560 GOSUB160:IFP0>21THEN5830
  543. 5570 IFP=5THEN5820
  544. 5580 D$="":IFDBTHEND$="[196] - [196]OUBLE, "
  545. 5590 P$=F$+"[217]OUR BET STANDS AT"+STR$(BT)+F$+D$+"[200] - HIT, [211] - [211]TAND: "
  546. 5600 GOSUB170:L=1:GOSUB180:IFCDTHENRETURN
  547. 5610 IFL$="H"ORL$="[200]"THENP=P+1:P(P)=FNR(13):GOTO5440
  548. 5620 IFL$="S"ORL$="[211]"THEN5660
  549. 5630 IF(L$<>"D"ANDL$<>"[196]")ORDB=0THEN5540
  550. 5640 IFBT*2>SSTHENP$=F$+"[206]OT ENOUGH MONEY TO [196]OUBLE.":GOSUB160:GOTO5540
  551. 5650 BT=BT*2:DB=0:GOTO5540
  552. 5660 P1=P0-P(1):IFP(1)>10THENP1=P0-10-(P(1)=14):IFFNR(1)>.35THENP1=P0
  553. 5670 P$=F$+"[196]EALER HAS:":GOSUB160
  554. 5680 D0=0:FORT=1TOD:D1=D(T):IFD1>10THEND1=10-(D1=14)
  555. 5690 D0=D0+D1:NEXT
  556. 5700 IFD>2THEN5730
  557. 5710 IFD(1)=1ANDD0<12THEND(1)=14:GOTO5680
  558. 5720 IFD(2)=1ANDD0<12THEND(2)=14:GOTO5680
  559. 5730 P$=F$:FORT=1TOD:C$=MID$(STR$(D(T)),2):IFD(T)>10THENC$=C$(D(T)-10)
  560. 5740 IFD(T)=1ORD(T)=14THENC$="[193]CE"
  561. 5750 P$=P$+C$+", ":NEXT:GOSUB160
  562. 5760 P$=F$+"[198]OR A TOTAL OF"+STR$(D0):GOSUB160:IFD0>21THEN5810
  563. 5770 IFD0=21ANDD=2THENP$=F$+"[196]EALER HAS  A NATURAL 21! [217]OU LOSE.":GOTO5850
  564. 5780 IFD0>P1ANDD0>17THEN5870
  565. 5790 FORT=1TO3000:NEXT
  566. 5800 P$="[196]EALER TAKES A HIT.":GOSUB160:D=D+1:D(D)=FNR(13):GOTO5670
  567. 5810 P$=F$+"[212]HE [196]EALER [194][213][211][212][197][196]!!  [217]OU WIN!!":GOTO5860
  568. 5820 P$=F$+"[198]IVE CARDS!! [193]UTOMATIC WIN!!":GOTO5860
  569. 5830 P$=F$+"[217]OU [194]USTED! [196]EALER WINS!":GOTO5850
  570. 5840 P$=F$+"[212]HE [196]EALER WINS!!"
  571. 5850 GOSUB160:SS=SS-BT:GOTO5360
  572. 5860 GOSUB160:SS=SS+BT:GOSUB3900:GOTO5360
  573. 5870 P$=F$+"[212]HE [196]EALER STANDS AT"+STR$(D0):GOSUB160
  574. 5880 IFP0=>D0THENP$=F$+"[217]OU WIN YOUR BET!":GOTO5860
  575. 5890 GOTO5840
  576.