home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-users-of-norman / CUON_19_(11-1984).d64 / menu (.txt) < prev    next >
Commodore BASIC  |  2019-04-13  |  1KB  |  49 lines
  1. 100 REM VIC/64 DISK MENU
  2. 120 PRINT"":POKE53280,0:POKE53281,0
  3. 130 PRINT"[147]READING DISK DIRECTORY[158] "
  4. 140 DIMP$(100)
  5. 150 REM DIRECTORY
  6. 160 REM  PEEPER
  7. 170 OPEN1,8,0,"$"
  8. 180 REM LOAD ARRAY P$
  9. 190 GET#1,B$:IFST<>0THEN270
  10. 200 IFB$<>CHR$(34)THEN190
  11. 210 P$=""
  12. 220 GET#1,B$:IFB$<>CHR$(34)THENP$=P$+B$:GOTO220
  13. 230 GET#1,B$:IFB$=CHR$(32)THEN230
  14. 240 P$(X)=P$
  15. 250 GET#1,B$:IFB$<>"" THEN250
  16. 260 IFST=0THENX=X+1:GOTO180
  17. 270 CLOSE1
  18. 280 REM  DISPLAY MENU
  19. 290 N=10
  20. 300 PRINT"[147][159] [195]OMMODORE [213]SERS OF [206]ORMAN [204]IBRARY [196]ISK [158]"
  21. 310 PRINT"  ";P$(0);"":PRINT
  22. 320 IFN<10THENN=10
  23. 330 IFN>100THENN=100
  24. 340 FORJ=(N-9)TON:PRINTJ;"- ";P$(J):NEXTJ
  25. 350 PRINT:PRINT"PRESS[157][157][157][157][157]     [159]N[146]EXT SCREEN   [146]";
  26. 360 PRINT"    [159]L[146]AST SCREEN[146]"
  27. 370 PRINT"     [159]E[146][158]XIT TO BASIC [146]";
  28. 380 PRINT"    [159]S[146][158] LOAD ONLY[146]"
  29. 390 PRINT"     [159]R[146] LOAD AND RUN[146]"
  30. 400 Z$="":GETZ$:IFZ$=""THEN400
  31. 410 IFZ$="N"THENN=N+10:GOTO300
  32. 420 IFZ$="L"THENN=N-10:GOTO300
  33. 430 IFZ$="E"THENPRINT"MENU STILL PRESENT":END
  34. 440 IFZ$="S"THENGOSUB470:GOTO570
  35. 450 IFZ$="R"THENGOSUB470:GOTO540
  36. 460 GOTO400
  37. 470 REM SELECT AND            PRINT LOAD
  38. 480 PRINT"PROGRAM #";
  39. 490 INPUTS:PRINT""
  40. 500 IFS<1ORS>XTHEN480
  41. 510 IFLEN(P$(S))>12THENP$(S)=LEFT$(P$(S),12)+"*"
  42. 520 PRINT"LOAD"+CHR$(34)+P$(S)+CHR$(34)+",8,1[145][145][145]"
  43. 530 RETURN
  44. 540 REM LOAD AND RUN
  45. 550 POKE631,13:POKE632,82:POKE633,85:POKE634,78:POKE635,13:POKE198,5
  46. 560 END
  47. 570 REM LOAD ONLY
  48. 580 POKE631,13:POKE198,1
  49.