home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-users-of-norman / CUON_18_(11-1984).d64 / qwikload_save64 (.txt) < prev    next >
Commodore BASIC  |  2019-04-13  |  1KB  |  50 lines
  1. 10 REM FROM COMPUTE 4/84 PG 152
  2. 20 REM ENTERED IN CUON LIBRARY BY SAM BARRETT
  3. 100 PRINT"[147]TAPE OR DISK (T/D)?";
  4. 105 GETB$:IFB$=""THEN105
  5. 110 IFB$<>"T"ANDB$<>"D"THEN105
  6. 120 PRINTB$:PRINT"SAVE OR LOAD (S/L)?";
  7. 125 GETA$:IFA$=""THEN125
  8. 130 IFA$<>"S"ANDA$<>"L"THEN125
  9. 140 PRINTA$:INPUT"FILENAME";F$
  10. 144 INPUT"STARTING ADDRESS";X:AH=INT(X/256):AL=X-AH*256
  11. 147 IFB$="D"THEN500
  12. 150 IFA$="L"THEN300
  13. 159 REM TAPE SAVE
  14. 160 INPUT"END ADDRESS";X:X=X+1:BH=INT(X/256):BL=X-BH*256
  15. 190 GOSUB400:POKE251,AL:POKE252,AH
  16. 200 POKE780,251:POKE781,BL:POKE782,BH:SYS65496:GOTO330
  17. 299 REM TAPE LOAD
  18. 300 GOSUB400
  19. 310 POKE780,0:POKE781,AL:POKE782,AH:SYS65493
  20. 320 IF(ST AND 48)THENPRINT"?LOAD":PRINT"ERROR"
  21. 330 CLOSE1:END
  22. 399 REM OPEN TAPE CHANNEL
  23. 400 L=LEN(F$):POKE183,L:S=256*PEEK(50)+PEEK(49)
  24. 410 FORX=1TOL:POKES+X-1,ASC(MID$(F$,X,1)):NEXT
  25. 420 POKE780,1:POKE781,1:POKE782,0:SYS65466
  26. 430 POKE780,L:POKE781,PEEK(49):POKE782,PEEK(50):SYS65469
  27. 440 POKE157,128:RETURN
  28. 500 IFA$="L"THEN700
  29. 529 REM DISK SAVE
  30. 530 INPUT"END ADDRESS";X:X=X+1:BH=INT(X/256):BL=X-BH*256
  31. 540 OPEN15,8,15,"I0"
  32. 550 OPEN3,8,1,"0:"+F$+",P,W"
  33. 560 INPUT#15,EN,EM$,ET,ES
  34. 570 IFEN=0THEN650
  35. 580 IFEN<>63THENPRINTEN;EM$;ET;ES:GOTO760
  36. 590 PRINT"FILE EXISTS.  REPLACE (Y/N)?";
  37. 600 GETA$:IFA$=""THEN600
  38. 610 PRINTA$:IFA$<>"Y"THEN760
  39. 620 PRINT#15,"S0:"+F$+",P,W"
  40. 630 CLOSE15:CLOSE3:GOTO540
  41. 650 POKE157,128:POKE251,AL:POKE252,AH
  42. 660 POKE780,251:POKE781,BL:POKE782,BH:SYS65496:GOTO760
  43. 699 REM DISK LOAD
  44. 700 OPEN15,8,15,"I0"
  45. 710 OPEN3,8,0,"0:"+F$+",P,R"
  46. 720 INPUT#15,EN,EM$,ET,ES
  47. 730 IFENTHENPRINTEN;EM$;ET;ES:GOTO760
  48. 750 POKE157,128:POKE185,0:POKE780,0:POKE781,AL:POKE782,AH:SYS65493
  49. 760 CLOSE3:CLOSE15:END
  50.