home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
8bitfiles.net/archives
/
archives.tar
/
archives
/
commodore-users-of-norman
/
CUON_18_(11-1984).d64
/
dial-a-word
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2019-04-13
|
972b
|
50 lines
5 REM DIAL-A-WORD/64
10 DIM A(7)
20 A$="ABCDEFGHIJKLMNOPQRSTUVWXY"
30 FOR I=1TO7
40 A(I)=0
50 NEXT I
60 NP=0
70 FL=0
79 REM-- GET TELEPHONE NUMBER--
80 PRINTCHR$(147);TAB(15);"DIAL-A-WORD"
90 PRINT
100 PRINT"PLEASE TYPE IN A 7 DIGIT PHONE NUMBER"
110 PRINT"(IN THIS FORM: 5558888);"
120 PRINT"THEN PRESS <RETURN>."
130 PRINT
140 INPUT "NUMBER";N$
149 REM --CHECK FOR ERRORS IN INPUT--
150 IF LEN(N$)<>7 THEN 80
160 FORI=1TO7
170 IF MID$(N$,I,1)<"0"ORMID$(N$,I,1)>"9"THENFL=1
180 NEXTI
190 IFFL<>0THEN70
200 PRINTCHR$(147);
209 REM --PRINT CURRENT COMBINATION OF LETTERS--
210 FORI=1TO7
220 IFMID$(N$,I,1)<"2"THEN PRINT MID$(N$,I,1);:GOTO240
230 PRINTMID$(A$,VAL(MID$(N$,I,1))*3-5+A(I),1);
240 NEXTI
250 PRINT"";
260 NP=NP+1
270 IFNP<110 THEN350
279 REM--IF SCREEN FULL, PRINT MESSAGE--280 ?
290 PRINT"PRESS <C> TO CONTINUE, <Q> TO QUIT.";
299 REM--WAIT FOR KEY TO BE PRESSED--
300 GET K$
310 IFK$="Q"THEN END
320 IFK$<>"C" THEN300
330 NP=0
340 PRINTCHR$(147);
349 REM--PROODUCE NEXT COMBINAATION--
350 P=1
360 A(P)=A(P)+1
370 IF A(P)<3ANDMID$(N$,P,1)>"1"THEN210
380 A(P)=0
390 P=P+1
400 IFP<8THEN360
410 PRINT
420 PRINT"DONE!"
430 END