home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-scene-files / Coverdisks / CDU / V4D05.D64 / prob1b (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  2.2 KB  |  96 lines
  1. 1000 ! THIS ASSEMBLY LANGUAGE PROGRAM,
  2. 1010 ! ONCE YOU HAVE ASSEMBLED IT USING
  3. 1020 ! 6510+ OR SIMILAR, WILL PRODUCE
  4. 1030 ! A SMOOTH SCROLLING MESSAGE ON
  5. 1040 ! THE BOTTOM LINE OF THE SCREEN.
  6. 1050 !
  7. 1060 *=$C000
  8. 1070 !
  9. 1080 SEI
  10. 1090 LDA #$7F
  11. 1100 STA $DC0D
  12. 1110 LDA $DC0D
  13. 1120 LDA #$1B
  14. 1130 STA $D011
  15. 1140 LDA #$F2  ;_ SET LATCH AT BOTTOM
  16. 1150 STA $D012 ;  LINE OF SCREEN
  17. 1160 LDA #<IRQ
  18. 1170 STA $0314
  19. 1180 LDA #>IRQ
  20. 1190 STA $0315
  21. 1200 LDA #$01
  22. 1210 STA $D019
  23. 1220 STA $D01A
  24. 1230 LDA #147  ;_ CLEAR SCREEN
  25. 1240 JSR $FFD2 ;
  26. 1250 LDA #14   ;_ LOWER CASE CHAR. SET
  27. 1260 JSR $FFD2 ;
  28. 1270 CLI
  29. 1280 RTS;_ RETURN TO BASIC
  30. 1290 !
  31. 1300 PIXELS BYT $00 ;_ PIXEL OFFSET
  32. 1310 BYTENO BYT $00 ;_ POS'N IN MESSAGE
  33. 1320 !
  34. 1330 IRQ ;
  35. 1340 LDX #$02 ;_ TIMING LOOP OF
  36. 1350 L1 DEX   ;  11 CYCLES
  37. 1360 BNE L1   ;
  38. 1365 !
  39. 1370 LDA PIXELS ;_ PIXEL SHIFT OF
  40. 1380 ORA #$C0   ;  BOTTOM LINE
  41. 1390 STA $D016  ;
  42. 1400 LDA #$FB
  43. 1410 L2 CMP $D012 ;_ WAIT UNTIL RASTER
  44. 1420 BNE L2       ;  LINE IS IN BORDER
  45. 1430 LDA #$C8
  46. 1440 STA $D016 ;_ RESET PIXEL SHIFT
  47. 1450 LDA PIXELS ;_ HORIZ. PIXEL OFFSET
  48. 1460 SEC
  49. 1470 SBC #1 ;_ =SPEED (1-8)
  50. 1480 AND #7 ;_ GIVES BYTE IN RANGE 0-7
  51. 1490 STA PIXELS ;_ STORE NEW OFFSET
  52. 1500 BCS RETURN ;_ BRANCH TO RETURN
  53. 1505 !
  54. 1510 LDX #$00            ;
  55. 1520 BR1 LDA 1024+960+1,X;
  56. 1530 STA 1024+960,X      ; SHIFT BOTTOM
  57. 1540 LDA 55296+960+1,X   ; LINE LEFT BY
  58. 1550 STA 55296+960,X     ; ONE FULL
  59. 1560 INX                 ; CHAR. POS'N
  60. 1570 CPX #$27            ;
  61. 1580 BNE BR1             ;
  62. 1585 !
  63. 1590 LDX BYTENO
  64. 1600 INX             ;_ NEXT CHARACTER
  65. 1610 CPX #MESS1-MESS ;_ MESSAGE DONE?
  66. 1620 BNE BR2         ;_ NOT YET!
  67. 1630 LDX #$00        ;_ RESET POSITION
  68. 1640 BR2 STX BYTENO  ;_ STORE POSITION
  69. 1645 !
  70. 1650 LDA MESS,X    ;_ GET NEXT CHAR.
  71. 1660 STA 1024+999  ;_ AND STORE IT
  72. 1670 LDA #1        ;
  73. 1680 STA 55296+999 ;_ COLOUR IT WHITE
  74. 1685 !
  75. 1690 RETURN ;
  76. 1695 !
  77. 1700 LDA #$01  ;
  78. 1710 STA $D019 ; NEXT LATCH
  79. 1720 JMP $EA31 ;
  80. 1730 !
  81. 1740 !
  82. 1750 MESS ;_ MESSAGE START
  83. 1760 ;
  84. 1770 BYT " THIS PROGRAM WAS WRITTEN"
  85. 1780 BYT " BY JASON FINCH FOR COMMO"
  86. 1790 BYT "DORE DISK USER TECHNO INF"
  87. 1800 BYT "O (MARCH 1991). IF YOU WO"
  88. 1810 BYT "ULD LIKE TO KNOW HOW TO D"
  89. 1820 BYT "O THIS SORT OF SMOOTH SCR"
  90. 1830 BYT "OLLER THEN CONSULT THE CO"
  91. 1840 BYT "MMENTS IN THE PROGRAM. SI"
  92. 1850 BYT "GNED: JRF....            "
  93. 1860 BYT "               "
  94. 1870 ;
  95. 1880 MESS1 ;_ MESS1-MESS=MESSAGE LENGTH
  96.