home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
compuserve
/
Basic
/
TEXTO.PRO
< prev
next >
Wrap
Text File
|
2006-10-19
|
2KB
|
62 lines
100 ! TEXTTO/PRO BY CURT PURDY ID# 74226,472
110 ! REVISED BY BARRY TRAVER ID# 70436,373
120 ! CONVERTS DIS/VAR 80 TEXT FILE TO PROGRAM FORMAT
130 ! D/V80 FILE CAN BE MADE WITH <LIST "DSK1.FILENAME">
140 ! OR USE E/A , TI-WRITER TO CREATE & SAVE PROGRAM
150 ! *DO NOT* USE C/R'S AT END OF LINE
160 ! USE FIXED MODE OR REPLACE WITH BLANK USING (RS)
170 ! *DO NOT* SAVEFILE (SF) BUT PRINTFILE (PF) TO LOSE GARBAGE AT END
180 ! IF STANDARD LINE NUMBER INCREMENT OF 10 IS USED THEN NO EDITING IS REQUIRE
D
190 ! OTHERWISE, IF # CHARACTERS/LINE > 80 THEN INSERT @ IN 81ST
200 ! RUN THIS PROGRAM
210 ! AFTER ">READY" ENTER "NEW" THEN
220 ! MERGE"DSK1.<FILENAME>" THEN
230 ! BRING UP EVERY LINE# WITH FCTN."X" & DELETE 1ST SPACE
240 ! I.E. HOLD DOWN FCTN & ALTERNATELY HIT X,1,X,1...
250 ! SAVE DSK1.<PROGNAME>
260 !
270 REM ON ERROR 540
280 DEF P(M$)=POS(M$," ",1)-1
290 PRINT "TEXTTO/PRO": : :: INPUT "SAVED DIS/VAR 80 FILENAME? ":F$ :: IF SEG$(
F$,1,3)<>"DSK" THEN F$="DSK1."&F$
300 PRINT :"CHOOSE ONE:": :" 1.STANDARD INCREMENT OF 10": :" 2.TEXT EDITED WITH
@": :"WHAT IS YOUR CHOICE?";
310 CALL KEY(0,K,S):: IF S=0 THEN 310 ELSE IF K<49 OR K>50 THEN 300 ELSE K=K-48
:: PRINT K: :
320 INPUT "TEMPORARY MERGED FILENAME? ":M$ :: IF SEG$(M$,1,3)<>"DSK" THEN M$="D
SK1."&M$
330 PRINT
340 OPEN #1:F$,INPUT ,DISPLAY
350 OPEN #2:M$,OUTPUT,DISPLAY ,VARIABLE 163,SEQUENTIAL
360 LINPUT #1:A1$
370 IF A1$="" THEN 360
380 IF EOF(1)<>0 THEN 440
390 LINPUT #1:A2$
400 ON K GOTO 410,430
410 P2=P(A2$):: IF P2<1 THEN P2=1
420 IF SEG$(A2$,1,P2)<>STR$(VAL(SEG$(A1$,1,P(A1$)))+10)THEN A1$=SEG$(A1$&RPT$("
",80),1,80)&A2$ :: GOTO 380 ELSE 440
430 IF SEG$(A2$,1,1)="@" THEN A1$=SEG$(A1$&RPT$(" ",80),1,80)&SEG$(A2$,2,LEN(A2$
)-1):: GOTO 380
440 GOSUB 550
450 A1$=A2$
460 IF EOF(1)=0 THEN 380
470 IF SEG$(A1$,1,1)<>"@" THEN GOSUB 550
480 PRINT #2:CHR$(255)&CHR$(255)
490 CLOSE #1 :: CLOSE #2
500 PRINT :"READ REMARKS AT BEGINNING OFTHIS PROGRAM FOR INSTRUCTION"
510 PRINT "ON CHANGING YOUR TEMPORARY MERGED FORMAT TO A PROGRAM"
520 PRINT "THAT CAN BE RUN & SAVED."
530 STOP
540 PRINT :"READ REMARKS AT BEGINNING OFTHIS PROGRAM FOR INSTRUCTION" :: RETURN
550 A$=A1$ :: B=P(A1$)
560 C=INT(VAL(SEG$(A1$,1,B))/256)
570 D=VAL(SEG$(A1$,1,B))-(C*256)
580 E=LEN(A1$)-B
590 PRINT A1$
600 A1$=CHR$(C)&CHR$(D)&SEG$(A1$,B+1,LEN(A1$))&CHR$(0)
610 PRINT #2:A1$ :: RETURN
620 END