home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
compuserve
/
Basic
/
CHAR.MRG
< prev
next >
Wrap
Text File
|
2006-10-19
|
1KB
|
37 lines
100 REM CHAR/CODER BY B.A. TRAVER, 552 SEVILLE ST., PHILA., PA 19128
110 REM FOR FURTHER INFORMATION, SEND S.A.S.E.
120 CALL CLEAR :: PRINT "CHAR/CODER"
130 PRINT :"DIRECTIONS: ENTER DATA AS INDICATED FOR EACH LINE OF YOUR PROGRAM
WHICH INCLUDES A CALL CHAR STATEMENT."
140 PRINT :"UNLESS YOU INDICATE OTHER-":"WISE, LINE NUMBERING STARTS AT 100 AND
INCREMENTS BY 10 AUTOMATICALLY."
150 PRINT :"ALSO, UNLESS YOU INDICATE OTHERWISE, CHARACTER NUMBERSARE INCREMEN
TED BY 1 AUTO- MATICALLY.": :
160 DEF L$(L)=CHR$(INT(L/256))&CHR$(L-256*INT(L/256))
170 DEF A199$(M$)=CHR$(199)&CHR$(LEN(M$))&M$
180 DEF A200$(M$)=CHR$(200)&CHR$(LEN(M$))&M$
190 L=100
200 OPEN #1:"DSK1.CHARACTERS",VARIABLE 163
210 GOSUB 320
220 GOSUB 310
230 PRINT :"ANOTHER (Y/N)? ";
240 CALL KEY(0,K,S):: IF S=0 THEN 240
250 IF K<>78 AND K<>89 THEN 240 ELSE PRINT CHR$(K): :
260 IF K=89 THEN L=L+10 :: C$=STR$(VAL(C$)+1):: GOTO 210
270 PRINT #1:CHR$(255)&CHR$(255)
280 CLOSE #1
290 PRINT :"NOW ENTER THE FOLLOWING TO SEE YOUR PROGRAM, WHICH YOU CAN SAVE AND
MODIFY LATER:": :" NEW":" MERGE DSK1.CHARACTERS"
300 END
310 PRINT #1:L$(L)&CHR$(157)&A200$("CHAR")&CHR$(183)&A200$(C$)&CHR$(179)&A199$(D
$)&CHR$(182)&CHR$(0):: RETURN
320 REM ACCEPT INPUT
330 PRINT "LINE:";L
340 ACCEPT AT(23,7)SIZE(-4):L
350 PRINT :"CALL CHAR"
360 PRINT "CHAR NUMBER: ";C$
370 ACCEPT AT(23,14)SIZE(-3):C$
380 PRINT "CHAR STRING:"
390 ACCEPT AT(23,14):D$ :: RETURN