home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / utl / hexem.ba < prev    next >
Text File  |  2006-10-19  |  2KB  |  38 lines
  1. 1 'HEXEM.BA - An old CO file "reloader" revised by Robert Benson 7/16/90
  2. 10 CLS:INPUT"File name to save";F$:OPENF$FOROUTPUTAS1:DEFINTI-N
  3. 11 LINEINPUT"Top address: ";S$:AA=VAL(S$)
  4. 12 LINEINPUT"End address: ";X$:AE=VAL(X$)
  5. 13 LINEINPUT"Exe address: ";Z$
  6. 14 PRINT#1,"1 'CO program to build:"F$
  7. 15 PRINT#1,"10 CLS:CLEAR50,"S$":X=99:AA="S$
  8. 16 PRINT#1,"11 DEFINTI-N:H$="CHR$(34)"0123456789ABCDEF"CHR$(34)
  9. 17 PRINT#1,"12 PRINT@59,"CHR$(34)"Data line"CHR$(34)
  10. 18 PRINT#1,"13 PRINT@99,"CHR$(34)"File address"CHR$(34)
  11. 19 PRINT#1,"14 READA$:X=X+1:PRINT@72,X"
  12. 20 PRINT#1,"15 B$=MID$(A$,1,2):GOSUB25:N=K"
  13. 21 PRINT#1,"16 IFK=0THENSAVEM"CHR$(34)F$CHR$(34)","S$","X$","Z$":END"
  14. 22 PRINT#1,"17 B$=MID$(A$,3,2):GOSUB25:L=K"
  15. 23 PRINT#1,"18 B$=MID$(A$,5,2):GOSUB25:L=K*256+L:L1=0"
  16. 24 PRINT#1,"19 FORI=1TON"
  17. 25 PRINT#1,"20 J=I*2+5:B$=MID$(A$,J,2):GOSUB25"
  18. 26 PRINT#1,"21 POKEAA,K:PRINT@112,AA:AA=AA+1:L1=L1+K"
  19. 27 PRINT#1,"22 NEXTI"
  20. 28 PRINT#1,"23 IFL<>L1THENBEEP:PRINT@165,"CHR$(34)"Checksum error"CHR$(34)":END"
  21. 29 PRINT#1,"24 GOTO14"
  22. 30 PRINT#1,"25 B1$=LEFT$(B$,1):K1=INSTR(1,H$,B1$):IF K1=0GOTO28"
  23. 31 PRINT#1,"26 B1$=RIGHT$(B$,1):K2=INSTR(1,H$,B1$):IF K2=0GOTO28"
  24. 32 PRINT#1,"27 K=(K1-1)*16+K2-1:RETURN"
  25. 33 PRINT#1,"28 BEEP:PRINT@165,"CHR$(34)"Non HEX Character in DATA"CHR$(34)":END"
  26. 34 CLS:X=99
  27. 35 X=X+1:N=0:M=0:M$="":N$=STR$(X):N$=RIGHT$(N$,3)
  28. 36 PRINT@72,AA:KK=PEEK(AA):GOSUB42:M$=M$+H$:M=M+KK:N=N+1:AA=AA+1
  29. 37 IFAA>AEORN=56GOTO38ELSE36
  30. 38 K1=M/256:K2=M-K1*256:KK=K1:GOSUB42:M1$=H$:KK=K2:GOSUB42:M2$=H$:KK=N
  31. 39 GOSUB42:M3$=H$:PRINT#1,N$" DATA "M3$M2$M1$M$:IFAA<AEGOTO35
  32. 40 X=X+1:N$=STR$(X):N$=RIGHT$(N$,3):PRINT#1,N$" DATA 000000"
  33. 41 MENU
  34. 42 KX=KK/16:KY=KK-KX*16
  35. 43 IFKX>9THENKX=KX+55ELSEKX=KX+48
  36. 44 IFKY>9THENKY=KY+55ELSEKY=KY+48
  37. 45 H$=CHR$(KX)+CHR$(KY):RETURN
  38.