home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
txt
/
pixplt.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
1KB
|
25 lines
0 'PIXPLT.BA SCOTT T. SCHAD CLUB 100 Library - 415/939-1246 BBS, 937-5039 NEWSLETTER, 932-8856 VOICE
1 CLS:PRINT"PIXEL PLOT (c) STS 1988":PRINT:C=0:R=0:P=0:B=0:W=0:A$="":B$="":FILES:PRINT:INPUT"FILE TO PLOT";F$:OPENF$FORINPUTAS1
2 INPUT"PRINT WIDTH(<=130)";PW:IFPW>130THEN2
3 INPUT"PAGE LENGTH(<=60)";PL:IFPL>60THEN3
4 PRINT"WORD-WRAP? (Y/N)";:IFCHR$(ASC(INPUT$(1))AND95)="Y"THENWW$="ON"ELSEWW$="OFF
5 GOSUB9
6 A$=INPUT$(1,1):B=B+1:IFEOF(1)THEN22
7 IFC=0THENPRINT@J+40,"Ln#:"R+1
8 GOSUB10:GOTO6
9 CLS:P=P+1:LINE(PW,0)-(PW,PL):LINE-(0,PL):J=INT(PW/6)+1:PRINT@J,F$:PRINT@30,"Page#"P:PRINT@70,"WordW:"WW$:PRINT@110,"PageW:"PW:PRINT@150,"PageL:"PL:RETURN
10 IFR=PLTHENR=0:GOSUB9
11 IFA$<>" "THEN16
12 C=C+1:IFB$<>" " ANDB$<>""THENW=W+1
13 IFWW$="OFF"THENRETURN
14 IFC>PW-15THENR=R+1:C=0
15 RETURN
16 IFA$=CHR$(13) ANDB$<>" " ANDB$<>""THENW=W+1
17 IFA$=CHR$(13)THENR=R+1:C=0:RETURN
18 IFA$=CHR$(9)THENC=C+8:RETURN
19 IFA$=CHR$(10)THENRETURN
20 IFC=>PWTHENR=R+1:C=0
21 C=C+1:PSET(C,R):B$=A$:RETURN
22 IFB$<>" "THENW=W+1
23 PRINT@J+120,"LINES:";(P-1)*PL+R:PRINT@J+160,"PAGES:"P:PRINT@J+200,"WORDS:"W:PRINT@J+240,"BYTES:"B:PRINT@J+280,"More?(Y/N)";:CLOSE1:IFCHR$(ASC(INPUT$(1))AND95)="Y"THEN1ELSEMENU