home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / prt / newprt.ba < prev    next >
Text File  |  2006-10-19  |  2KB  |  33 lines
  1. 0 'NEWPRT.BA Ed Juge 4/83
  2. 1 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  3. 2 '<GRPH>p causes forced end of page
  4. 3 'Defaults for margins (L,R), print
  5. 4 '   title on page 1 (HD$) and line
  6. 5 '   spacing (LS) exist in line 30.
  7. 6 CLS:CLEAR2000:S=0:FILES:L=20:R=60:HD$="Y":LS=1:C$=STRING$(60,32):LN=0:PG=1:GOSUB10:INPUT".DO file to print  ";N$
  8. 7 GOSUB10:INPUT"Margins (L,R)   ";L,R:IFL=0THENL=1
  9. 8 L$=STRING$(L-1,32):GOSUB10:INPUT"Line Spacing (1/2)  ";LS:GOSUB10:INPUT"Enter page title";H$
  10. 9 GOSUB10:INPUT"Title on Pg.1  (Y/N) ";HD$:OPENN$FORINPUTAS1:GOTO11
  11. 10 PRINT@205,C$:PRINT@205,"";:RETURN
  12. 11 CLS:IFH$=""THEN PH$=L$+DATE$:GOTO13
  13. 12 PH$=STRING$(R-8,32)+DATE$:IFH$<>""THENMID$(PH$,L,(LEN(H$)))=H$
  14. 13 IFHD$="Y"ORHD$="y"THENPR$=L$:GOSUB31
  15. 14 PR$=L$
  16. 15 IFLN>=50THENGOTO29
  17. 16 FORJ=LEN(PR$)TOR:  PR$=PR$+INPUT$(1,1):  IFEOF(1)THENCLOSE:EN=1:GOTO24
  18. 17   IFRIGHT$(PR$,1)=CHR$(10)THENPF=1:GOTO23
  19. 18 IFRIGHT$(PR$,1)=CHR$(128)THENPR$=LEFT$(PR$,J-1):GOTO29
  20. 19   NEXTJ
  21. 20 IFMID$(PR$,J,1)=" "THEN22
  22. 21 J=J-1:GOTO20
  23. 22 NX$=MID$(PR$,J+1,R):PR$=MID$(PR$,1,J):GOTO24
  24. 23 PR$=LEFT$(PR$,LEN(PR$)-2)
  25. 24 IFMID$(PR$,L,3)="   "THEN26
  26. 25 IFMID$(PR$,L,1)=" "THEN PR$=MID$(PR$,2,LEN(PR$)):GOTO25
  27. 26 LPRINTPR$:LN=LN+1:IFEN=1THEN29
  28. 27 IFLS=2THENLPRINT:LN=LN+1
  29. 28 PR$=L$+NX$:NX$="":GOTO 15
  30. 29 FOR J1=LNTO65:LPRINT:NEXTJ1:PG=PG+1:IFEN=1THENMENU
  31. 30 IFX$<>""THEN31 ELSEPRINT@160,"";:INPUT"  <ENTER> = next page, <N> = nonstop";X$
  32. 31 CLS:LPRINTPH$:LPRINTL$;"Page ";PG:LPRINT:LPRINT:LN=4:GOTO16
  33.